// -*- MPC -*-
// $Id$

project {
  // Set the idl compiler and flags as template values, except for
  // automake.  It has it's own settings in AutomakeWorkspaceHelper.pm and
  // expects to see $(TAO_IDL) in the generated Makefile.am
  specific(!automake) {
    tao_idl      = $(ACE_ROOT)/bin/tao_idl
    tao_idl_dep  = $(ACE_ROOT)/bin/tao_idl
    tao_idlflags = -Wb,pre_include=ace/pre.h \
                   -Wb,post_include=ace/post.h -I$(TAO_ROOT)
  }

  Define_Custom(IDL) {
    automatic            = 1
    dependent            = $(TAO_IDL_DEP)
    command              = $(TAO_IDL)
    libpath              = $(ACE_ROOT)/lib
    inputext             = .idl
    source_pre_extension = C
    header_pre_extension = C, S
    source_outputext     = .cpp, .cxx, .cc, .C
    header_outputext     = .h, .hpp, .hxx, .hh
    keyword idlflags     = commandflags

    // Inline related options
    optional(inline_outputext) {
      commandflags(!-SS && !-Ssi || !-Sci || -GT && !-SS && !-oS) += .inl, .i
    }
    optional(inline_pre_extension) {
      commandflags(!-SS && !-Ssi && !-oS) += S
    }
    optional(inline_pre_extension) {
      commandflags(!-Sci) += C
    }

    // Source related options
    optional(source_pre_extension) {
      commandflags(!-SS && !-oS) += S
    }
    optional(source_pre_extension) {
      commandflags(-GA && !-oA) += A
    }
    optional(header_outputext) {
      commandflags(-SS && !-oS) += S
    }

    // Other
    optional(template_outputext) {
      commandflags(-GT && !-SS && !-oS) += S_T.cpp, S_T.cxx, S_T.cc, S_T.C
    }
    optional(header_pre_extension) {
      commandflags(-GT && !-SS && !-oS) += S_T
    }
    optional(header_pre_extension) {
      commandflags(-GA && !-oA || -GX) += A
    }
  }

  after    += TAO_IDL_EXE
  idlflags += $(TAO_IDLFLAGS)
  idlflags += -Sa -St
}