// -*- MPC -*-
// $Id$

project(airplane_idl) : taoidldefaults {
  IDL_Files {
    Airplane.idl
  }
  custom_only = 1
}


project(airplane server) : portableserver, orbsvcsexe, minimum_corba, iortable, imr_client {
  after += airplane_idl 

  IDL_Files {
  }

  Source_Files {
    AirplaneC.cpp
    AirplaneS.cpp
    airplane_i.cpp
    airplane_server_i.cpp
    airplane_server.cpp
  }
}

project(airplane client) : portableserver, orbsvcsexe, minimum_corba, iortable {
  after += airplane_idl 

  IDL_Files {
  }

  Source_Files {
    AirplaneC.cpp
    AirplaneS.cpp
    airplane_client_i.cpp
    airplane_client.cpp
  }
}

project(nestea_idl): taoidldefaults {
  IDL_Files {
    Nestea.idl
  }

  custom_only = 1
}

project(nestea server) : portableserver, orbsvcsexe, minimum_corba, iortable, imr_client {
  avoids += ace_for_tao
  after  += nestea_idl

  IDL_Files {
  }

  Source_Files {
    NesteaC.cpp
    NesteaS.cpp
    nestea_i.cpp
    nestea_server_i.cpp
    nestea_server.cpp
  }
  // To avoid link errors with SunCC 5.[34], put this project's
  // object files (and resulting SunWS_cache directory) in a different
  // location than the default.
  verbatim(gnuace, macros) {
    VDIR := .obj/nestea_server/
  }
}

project(nestea client) : portableserver, orbsvcsexe, minimum_corba, iortable {
  after += nestea_idl

  IDL_Files {
  }

  Source_Files {
    NesteaC.cpp
    NesteaS.cpp
    nestea_client_i.cpp
    nestea_client.cpp
  }
  // To avoid link errors with SunCC 5.[34], put this project's
  // object files (and resulting SunWS_cache directory) in a different
  // location than the default.
  verbatim(gnuace, macros) {
    VDIR := .obj/nestea_client/
  }
}