//$Id$
project(CodecFactory) : taolib, tao_output, install, core_anytypecode, tao_versioning_idl_defaults, nolink_codecfactory {
  sharedname    = TAO_CodecFactory
  dynamicflags  = TAO_CODECFACTORY_BUILD_DLL

  Source_Files {
    CodecFactory
  }

  Header_Files {
    CodecFactory
  }

  Inline_Files {
    CodecFactory
  }

  Template_Files {
    CodecFactory
  }

  Resource_Files {
    CodecFactory
  }

  PIDL_Files {
    CodecFactory
  }

  IDL_Files {
    idlflags += -Gp -Gd -Sci -SS -Sorb -Sal -GX \
                -Wb,export_macro=TAO_CodecFactory_Export \
                -Wb,export_include=tao/CodecFactory/codecfactory_export.h \
                -Wb,include_guard=TAO_CODECFACTORY_SAFE_INCLUDE \
                -Wb,safe_include=tao/CodecFactory/CodecFactory.h \
                -o CodecFactory
    idlflags -= -Sa -St
    CodecFactory/IOP_Codec.pidl
  }

  IDL_Files {
    idlflags += -Sci -SS -Sorb -Sa -GX \
                -Wb,export_macro=TAO_CodecFactory_Export \
                -Wb,export_include=tao/CodecFactory/codecfactory_export.h \
                -Wb,unique_include=tao/CodecFactory/CodecFactory.h \
                -o CodecFactory
    CodecFactory/IOP_Codec_include.pidl
  }

  Pkgconfig_Files {
    CodecFactory/TAO_CodecFactory.pc.in
  }
}