blob: c124fd4a7ce3487db9e9f8c27892dc654a387413 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
|
# Building upon same version as llvm. Let's assume they did their homework and
# it's a good version. Compare:
# ~~~
# https://repology.org/badge/vertical-allrepos/cmake.svg?minversion=3.4.3
# ~~~
cmake_minimum_required(VERSION 3.4.3)
project(ccache LANGUAGES C CXX)
set(CMAKE_PROJECT_DESCRIPTION "a fast C/C++ compiler cache")
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED YES)
set(CMAKE_CXX_EXTENSIONS NO)
set(CMAKE_C_STANDARD 99)
set(CMAKE_C_STANDARD_REQUIRED YES)
set(CMAKE_C_EXTENSIONS NO)
# Always export compile_commands.json as it's useful for so many tools.
set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
#
# Settings
#
include(StandardSettings)
include(StandardWarnings)
include(DefaultBuildType)
#
# Configuration
#
include(GenerateConfigurationFile)
include(GenerateVersionFile)
#
# 3rd party
#
option(USE_LIBZSTD_FROM_INTERNET "Download and use libzstd from the Internet"
OFF)
find_package(zstd 1.1.2 REQUIRED)
option(USE_LIBB2_FROM_INTERNET "Download and use libb2 from the Internet" OFF)
find_package(libb2 0.98 REQUIRED)
#
# special flags
#
# Note: cppcheck will scan everything after this point. Zstd and libb2 are above
# so they don't get scanned.
#
include(CodeAnalysis)
option(ENABLE_TRACING "Enable possibility to use internal ccache tracing" OFF)
#
# ccache_lib
#
add_subdirectory(src)
#
# ccache
#
add_executable(ccache src/main.cpp)
target_link_libraries(ccache PRIVATE standard_settings standard_warnings
ccache_lib)
add_subdirectory(doc)
#
# installation
#
include(GNUInstallDirs)
install(TARGETS ccache DESTINATION ${CMAKE_INSTALL_BINDIR})
# before adding documentation to package run misc/update_authors.sh
#
# install(TARGETS documentation DESTINATION ${CMAKE_INSTALL_DOCDIR})
#
# packaging
#
include(CCachePackConfig)
#
# test and unittest
#
option(ENABLE_TESTING "Enable Tests" ON)
if(ENABLE_TESTING)
enable_testing()
add_subdirectory(unittest)
add_subdirectory(test)
# Note: VERSION_GREATER_EQUAL requires cmake 3.17
if(NOT ${CMAKE_VERSION} VERSION_LESS "3.17")
list(APPEND CMAKE_CTEST_ARGUMENTS "--output-on-failure")
endif()
# Add 'check' target which will compile & run tests
if(CMAKE_CONFIGURATION_TYPES)
add_custom_target(
check
COMMAND ${CMAKE_CTEST_COMMAND} --force-new-ctest-process
--output-on-failure --build-config "$<CONFIGURATION>"
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
DEPENDS ccache unittest)
else()
add_custom_target(
check
COMMAND ${CMAKE_CTEST_COMMAND} --force-new-ctest-process
--output-on-failure
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
DEPENDS ccache unittest)
endif()
endif()
#
# Special formatting targets. You can also run the scripts without cmake/make!
#
find_program(CLANG_FORMAT_EXE NAMES "clang-format"
DOC "Path to clang-format executable")
mark_as_advanced(CLANG_FORMAT_EXE) # don't show in ccmake
if(NOT CLANG_FORMAT_EXE)
message(WARNING "clang-format not found.")
else()
add_custom_target(
format
COMMAND misc/format.sh
COMMENT "Formatting code"
USES_TERMINAL
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
add_custom_target(
check_format
COMMAND misc/check_format.sh
COMMENT "Checking correctly formatted code"
USES_TERMINAL
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
endif()
|
