Documentation
*************

GNU Emacs Lisp has convenient on-line help facilities, most of which derive their information from the documentation strings associated with functions and variables.  This chapter describes how to write good documentation strings for your Lisp programs, as well as how to write programs to access documentation.

Note that the documentation strings for Emacs are not the same thing as the Emacs manual.  Manuals have their own source files, written in the Texinfo language; documentation strings are specified in the definitions of the functions and variables they apply to.  A collection of documentation strings is not sufficient as a manual because a good manual is not organized in that fashion; it is organized in terms of topics of discussion.

Documentation Basics
====================

A documentation string is written using the Lisp syntax for strings, with double-quote characters surrounding the text of the string.  This is because it really is a Lisp string object.  The string serves as documentation when it is written in the proper place in the definition of a function or variable.  In a function definition, the documentation string follows the argument list.  In a variable definition, the documentation string follows the initial value of the variable.

When you write a documentation string, make the first line a complete sentence (or two complete sentences) since some commands, such as apropos, show only the first line of a multi-line documentation string.  Also, you should not indent the second line of a documentation string, if you have one, because that looks odd when you use C-h f (describe-function) or C-h v (describe-variable). See Documentation Tips.

Documentation strings may contain several special substrings, which stand for key bindings to be looked up in the current keymaps when the documentation is displayed.  This allows documentation strings to refer to the keys for related commands and be accurate even when a user rearranges the key bindings.  (see Accessing Documentation.)

Within the Lisp world, a documentation string is kept with the function or variable that it describes:

  * The documentation for a function is stored in the function definition itself (see Lambda Expressions).  The function documentation knows how to extract it.

  * The documentation for a variable is stored in the variable's property list under the property name variable-documentation.  The function documentation-property knows how to extract it.

To save space, the documentation for preloaded functions and variables (including primitive functions and autoloaded functions) are stored in the file emacs/etc/DOC-VERSION.  The data structure inside Emacs has an integer offset into the file, where the documentation string ought to be.  The functions documentation the documentation-property read the documentation from the file emacs/etc/DOC-VERSION when they notice the integer there; this is transparent to the user.  Keeping the documentation strings out of the Emacs core image saves a significant amount of space. See Building Emacs.

For information on the uses of documentation strings, see Help (The GNU Emacs Manual).

The emacs/etc directory contains two utilities that you can use to print nice-looking hardcopy for the file emacs/etc/DOC-VERSION.  These are sorted-doc.c and digest-doc.c.

Access to Documentation Strings
===============================

 -- Function: documentation-property symbol property &optional verbatim
     This function returns the documentation string that is recorded SYMBOL's property list under property PROPERTY.  It retrieves the text from the file emacs/etc/DOC-VERSION if necessary, and runs substitute-command-keys to substitute actual key bindings.  (This substitution is not done if VERBATIM is non-nil; the VERBATIM argument exists only as of Emacs 19.)

          (documentation-property 'command-line-processed
             'variable-documentation)
               => "t once command line has been processed"

          (symbol-plist 'command-line-processed)
               => (variable-documentation 188902)

 -- Function: documentation function &optional verbatim
     This function returns the documentation string of FUNCTION. This function will access the documentation string if it is stored in the emacs/etc/DOC-VERSION file.

     In addition, documentation runs substitute-command-keys on the resulting string, so the value contains the actual (current) key bindings.  (This is not done if VERBATIM is non-nil; the VERBATIM argument exists only as of Emacs 19.)

     The function documentation signals a void-function error unless FUNCTION has a function definition.  However, it is ok if the function definition has no documentation string.  In that case, documentation returns nil.

Here is an example of using the two functions, documentation and documentation-property, to display the documentation strings for several symbols in a *Help* buffer.

     (defun describe-symbols (pattern)
       "Describe the Emacs Lisp symbols matching PATTERN.
     All symbols that have PATTERN in their name are described
     in the `*Help*' buffer."
       (interactive "sDescribe symbols matching: ")
       (let ((describe-func
              (function
               (lambda (s)

                 ;; Print description of symbol.
                 (if (fboundp s)             ; It is a function.
                     (princ
                      (format "%s\t%s\n%s\n\n" s
                        (if (commandp s)
                            (let ((keys (where-is-internal s)))
                              (if keys
                                  (concat
                                   "Keys: "
                                   (mapconcat 'key-description
                                              keys " "))
                                "Keys: none"))
                          "Function")

                        (or (documentation s)
                            "not documented"))))

                 (if (boundp s)              ; It is a variable.

                     (princ
                      (format "%s\t%s\n%s\n\n" s
                        (if (user-variable-p s)
                            "Option " "Variable")

                        (or (documentation-property
                              s 'variable-documentation)
                            "not documented")))))))
             sym-list)

         ;; Build a list of symbols that match pattern.
         (mapatoms (function
                    (lambda (sym)
                      (if (string-match pattern (symbol-name sym))
                          (setq sym-list (cons sym sym-list))))))

         ;; Display the data.
         (with-output-to-temp-buffer "*Help*"
           (mapcar describe-func (sort sym-list 'string<))
           (print-help-return-message))))

The describe-symbols function works like apropos, but provides more information.

     (describe-symbols "goal")

     ---------- Buffer: *Help* ----------
     goal-column     Option
     *Semipermanent goal column for vertical motion, as set by C-x C-n, or nil.

     set-goal-column Command: C-x C-n
     Set the current horizontal position as a goal for C-n and C-p.

     Those commands will move to this position in the line moved to
     rather than trying to keep the same horizontal position.
     With a non-nil argument, clears out the goal column
     so that C-n and C-p resume vertical motion.
     The goal column is stored in the variable `goal-column'.

     temporary-goal-column   Variable
     Current goal column for vertical motion.
     It is the column where point was
     at the start of current run of vertical motion commands.
     When the `track-eol' feature is doing its job, the value is 9999.
     ---------- Buffer: *Help* ----------

 -- Function: Snarf-documentation filename
     This function is used only during Emacs initialization, just before the runnable Emacs is dumped.  It finds the file offsets of the documentation strings stored in the file FILENAME, and records them in the in-core function definitions and variable property lists in place of the actual strings.  See Building Emacs.

     Emacs finds the file FILENAME in the emacs/etc directory. When the dumped Emacs is later executed, the same file is found in the directory doc-directory.  Usually FILENAME is "DOC-VERSION".

 -- Variable: doc-directory
     This variable holds the name of the directory which should contion the file "DOC-VERSION" that contains documentation strings for built-in and preloaded functions and variables.

     In most cases, this is the same as data-directory.  They may be different when you run Emacs from the directory where you built it, without actually installing it.  See data-directory in Help Functions.

     In older Emacs versions, exec-directory was used for this.

Substituting Key Bindings in Documentation
==========================================

When documentation strings refer to key sequences, they should do so based on the current, actual key bindings.  They can do so using certain special text sequences described below.  Accessing documentation strings in the usual way substitutes current key binding information for these special sequences.  This works by calling substitute-command-keys. You can also call that function yourself.

Here is a list of the special sequences and what they mean:

\[COMMAND]
     stands for a key sequence that will invoke COMMAND, or M-x COMMAND if COMMAND has no key bindings.

\{MAPVAR}
     stands for a summary of the value of MAPVAR, which should be a keymap.  The summary is made by describe-bindings.

\<MAPVAR>
     stands for no text itself.  It is used for a side effect: it specifies MAPVAR as the keymap for any following \[COMMAND] sequences in this documentation string.

Please note: each \ must be doubled when written in a string in Emacs Lisp.

 -- Function: substitute-command-keys string
     This function scans STRING for the above special sequences and replaces them by what they stand for, returning the result as a string. This permits display of documentation that refers accurately to the users's own customized key bindings.

Here are examples of the special sequences:

     (substitute-command-keys
        "To abort recursive edit, type: \\[abort-recursive-edit]")
     => "To abort recursive edit, type: C-]"

     (substitute-command-keys
        "The keys that are defined for the minibuffer here are:
       \\{minibuffer-local-must-match-map}")
     => "The keys that are defined for the minibuffer here are:

     ?               minibuffer-completion-help
     SPC             minibuffer-complete-word
     TAB             minibuffer-complete
     LFD             minibuffer-complete-and-exit
     RET             minibuffer-complete-and-exit
     C-g             abort-recursive-edit
     "

     (substitute-command-keys
        "To abort a recursive edit from the minibuffer, type\
     \\<minibuffer-local-must-match-map>\\[abort-recursive-edit].")
     => "To abort a recursive edit from the minibuffer, type C-g."

Describing Characters for Help Messages
=======================================

These functions convert events, key sequences or characters to textual descriptions.  These descriptions are useful for including arbitrary text characters or key sequences in messages, because they convert non-printing and whitespace characters to sequences of printing characters.  The description of a non-whitespace printing character is the character itself.

 -- Function: key-description sequence
     This function returns a string containing the Emacs standard notation for the input events in SEQUENCE.  The argument SEQUENCE may be a string, vector or list.  See Input Events, for more information about valid events.  See also the examples for single-key-description, below.

 -- Function: single-key-description event
     This function returns a string describing EVENT in the standard Emacs notation for keyboard input.  A normal printing character appears as itself, but a control character turns into a string starting with C-, a meta character turns into a string starting with M-, and space, linefeed, etc. appear as SPC, LFD, etc.  A function key symbol appears as itself.  An event which is a list appears as the name of the symbol in the CAR of the list.

          (single-key-description ?\C-x)
               => "C-x"

          (key-description "\C-x \M-y \n \t \r \f123")
               => "C-x SPC M-y SPC LFD SPC TAB SPC RET SPC C-l 1 2 3"

          (single-key-description 'C-mouse-1)
               => "C-mouse-1"

 -- Function: text-char-description character
     This function returns a string describing CHARACTER in the standard Emacs notation for characters that appear in text---like single-key-description, except that control characters are represented with a leading caret (which is how control characters in Emacs buffers are usually displayed).

          (text-char-description ?\C-c)
               => "^C"

          (text-char-description ?\M-m)
               => "M-m"

          (text-char-description ?\C-\M-m)
               => "M-^M"

Help Functions
==============

Emacs provides a variety of on-line help functions, all accessible to the user as subcommands of the prefix C-h.  For more information about them, see Help (The GNU Emacs Manual).  Here we describe some program-level interfaces to the same information.

 -- Command: apropos regexp &optional do-all predicate
     This function finds all symbols whose names contain a match for the regular expression REGEXP, and returns a list of them. It also displays the symbols in a buffer named *Help*, each with a one-line description.

     If DO-ALL is non-nil, then apropos also shows key bindings for the functions that are found.

     If PREDICATE is non-nil, it should be a function to be called on each symbol that has matched REGEXP.  Only symbols for which PREDICATE returns a non-nil value are listed or displayed.

     In the first of the following examples, apropos finds all the symbols with names containing exec.  In the second example, it finds and returns only those symbols that are also commands. (We don't show the output that results in the *Help* buffer.)

          (apropos "exec")
               => (Buffer-menu-execute command-execute exec-directory
              exec-path execute-extended-command execute-kbd-macro
              executing-kbd-macro executing-macro)

          (apropos "exec" nil 'commandp)
               => (Buffer-menu-execute execute-extended-command)

     The command C-h a (command-apropos) calls apropos, but specifies a PREDICATE to restrict the output to symbols that are commands.  The call to apropos looks like this:

          (apropos string t 'commandp)

 -- Command: super-apropos regexp &optional do-all
     This function differs from apropos in that it searches documentation strings as well as symbol names for matches for REGEXP.  By default, it searches only the documentation strings, and only those of functions and variables that are included in Emacs when it is dumped.  If DO-ALL is non-nil, it scans the names and documentation strings of all functions and variables.

 -- Variable: help-map
     The value of this variable is a local keymap for characters following the Help key, C-h.

 -- Prefix Command: help-command
     This symbol is not a function; its function definition is actually the keymap known as help-map.  It is defined in help.el as follows:

          (define-key global-map "\C-h" 'help-command)
          (fset 'help-command help-map)

 -- Function: print-help-return-message &optional function
     This function builds a string which is a message explaining how to restore the previous state of the windows after a help command.  After building the message, it applies FUNCTION to it if FUNCTION is non-nil.  Otherwise it calls message to display it in the echo area.

     This function expects to be called inside a with-output-to-temp-buffer special form, and expects standard-output to have the value bound by that special form. For an example of its use, see the long example in Accessing Documentation.

 -- Variable: help-char
     The value of this variable is the help character---the character that Emacs recognizes as meaning Help.  By default, it is 8, which is C-h.  When Emacs reads this character, if help-form is non-nil Lisp expression, it evaluates that expression, and displays the result in a window if it is a string.

     Usually the value of help-form's value is nil.  Then the help character has no special meaning at the level of command input, and it becomes part of a key sequence in the normal way.  The standard key binding of C-h is a prefix key for several general-purpose help features.

     The help character is special after prefix keys, too.  If it has no binding as a subcommand of the prefix key, it runs describe-prefix-bindings, which displays a list of all the subcommands of the prefix key.

 -- Variable: help-form
     If this variable is non-nil, its value is a form to evaluate whenever the character help-char is read.  If evaluating the form produces a string, that string is displayed.

     A command that calls read-event or read-char probably should bind help-form to a non-nil expression while it does input.  (The exception is when C-h is meaningful input.) Evaluating this expression should result in a string that explains what the input is for and how to enter it properly.

     Entry to the minibuffer binds this variable to the value of minibuffer-help-form (see Minibuffer Misc).

 -- Variable: prefix-help-command
     This variable holds a function to print help for a prefix character. The function is called when the user types a prefix key followed by the help character, and the help character has no binding after that prefix. The variable's default value is describe-prefix-bindings.

 -- Function: describe-prefix-bindings
     This function calls describe-bindings to display a list of all the subcommands of the prefix key of the most recent key sequence.  The prefix described consists of all but the last event of that key sequence.

The following two functions are found in the library helper. They are for modes that want to provide help without relinquishing control, such as the ``electric'' modes.  You must load that library with (require 'helper) in order to use them.  Their names begin with Helper to distinguish them from the ordinary help functions.

 -- Command: Helper-describe-bindings
     This command pops up a window displaying a help buffer containing a listing of all of the key bindings from both the local and global keymaps. It works by calling describe-bindings.

 -- Command: Helper-help
     This command provides help for the current mode.  It prompts the user in the minibuffer with the message Help (Type ? for further options), and then provides assistance in finding out what the key bindings are, and what the mode is intended for.  It returns nil.

     This can be customized by changing the map Helper-help-map.

 -- Variable: data-directory
     This variable holds the name of the directory in which Emacs finds certain documentation and text files that come with Emacs.  In older Emacs versions, exec-directory was used for this.

 -- Macro: make-help-screen fname help-line help-text help-map
     This macro defines a help command named FNAME which acts like a prefix key which shows a list of the subcommands it offers.

     When invoked, FNAME displays HELP-TEXT in a window, then reads and executes a key sequence according to HELP-MAP.  The string HELP-TEXT should describe of the bindings available in HELP-MAP.

     The command FNAME is defined to handle a few events itself, by scrolling the display of HELP-TEXT.  When FNAME reads one of those special events, it does the scrolling and then reads another event.  When it reads an event which is not one of those few, and which has a binding in HELP-MAP, it executes that key's binding and then returns.

     The argument HELP-LINE should be a single-line summary of the alternatives in HELP-MAP.  In the current version of Emacs, this argument is used only if you set the option three-step-help to t.

 -- User Option: three-step-help
     If this variable is non-nil, commands defined with make-help-screen display their HELP-LINE strings in the echo area at first, and display the longer HELP-TEXT strings only if the user types the help character again.