1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
|
{
Basic node optimizer stuff
Copyright (c) 2007 by Florian Klaempfl
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
****************************************************************************
}
unit optbase;
{$i fpcdefs.inc}
interface
uses
globtype;
type
{ this should maybe replaced by a spare set,
using a dyn. array makes assignments cheap }
tdfaset = array of byte;
PDFASet = ^TDFASet;
toptinfo = record
{ index of the current node inside the dfa sets, aword(-1) if no entry }
index : aword;
def : tdfaset;
use : tdfaset;
life : tdfaset;
end;
poptinfo = ^toptinfo;
{ basic set operations for dfa sets }
{ add e to s }
procedure DFASetInclude(var s : tdfaset;e : integer);
{ add s to d }
procedure DFASetIncludeSet(var d : tdfaset;const s : tdfaset);
{ remove e from s }
procedure DFASetExclude(var s : tdfaset;e : integer);
{ test if s contains e }
function DFASetIn(const s : tdfaset;e : integer) : boolean;
{ d:=s1+s2; }
procedure DFASetUnion(var d : tdfaset;const s1,s2 : tdfaset);
{ d:=s1*s2; }
procedure DFASetIntersect(var d : tdfaset;const s1,s2 : tdfaset);
{ d:=s1-s2; }
procedure DFASetDiff(var d : tdfaset;const s1,s2 : tdfaset);
{ s1<>s2; }
function DFASetNotEqual(const s1,s2 : tdfaset) : boolean;
{ output DFA set }
procedure PrintDFASet(var f : text;s : TDFASet);
implementation
uses
cutils;
procedure DFASetInclude(var s : tdfaset;e : integer);
var
i,
oldhigh,
e8 : Integer;
begin
e8:=e div 8;
if e8>high(s) then
begin
oldhigh:=high(s);
SetLength(s,e8+1);
for i:=oldhigh+1 to high(s) do
s[i]:=0;
end;
s[e8]:=s[e8] or (1 shl (e mod 8));
end;
procedure DFASetIncludeSet(var d : tdfaset;const s : tdfaset);
var
i : integer;
begin
if length(s)>length(d) then
SetLength(d,length(s));
for i:=0 to high(s) do
d[i]:=d[i] or s[i];
end;
procedure DFASetExclude(var s : tdfaset;e : integer);
var
e8 : Integer;
begin
e8:=e div 8;
if e8>high(s) then
SetLength(s,e8+1);
s[e8]:=s[e8] and not(1 shl (e mod 8));
end;
function DFASetIn(const s : tdfaset;e : integer) : boolean;
var
e8 : Integer;
begin
result:=false;
e8:=e div 8;
if e8>high(s) then
exit;
result:=(s[e8] and (1 shl (e mod 8)))<>0;
end;
procedure DFASetUnion(var d : tdfaset;const s1,s2 : tdfaset);
var
i : integer;
begin
SetLength(d,max(Length(s1),Length(s2)));
for i:=0 to high(s1) do
d[i]:=s1[i];
for i:=0 to high(s2) do
d[i]:=d[i] or s2[i];
end;
procedure DFASetIntersect(var d : tdfaset;const s1,s2 : tdfaset);
var
i : integer;
begin
SetLength(d,min(Length(s1),Length(s2)));
for i:=0 to min(high(s1),high(s2)) do
d[i]:=s1[i] and s2[i];
end;
procedure DFASetDiff(var d : tdfaset;const s1,s2 : tdfaset);
var
i : integer;
begin
SetLength(d,length(s1));
for i:=0 to high(d) do
if i>high(s2) then
d[i]:=s1[i]
else
d[i]:=s1[i] and not(s2[i]);
end;
function DFASetNotEqual(const s1,s2 : tdfaset) : boolean;
var
i : integer;
begin
result:=true;
{ one set could be larger than the other }
if length(s1)>length(s2) then
begin
for i:=0 to high(s2) do
if s1[i]<>s2[i] then
exit;
{ check remaining part being zero }
for i:=length(s2) to high(s1) do
if s1[i]<>0 then
exit;
end
else
begin
for i:=0 to high(s1) do
if s1[i]<>s2[i] then
exit;
{ check remaining part being zero }
for i:=length(s1) to high(s2) do
if s2[i]<>0 then
exit;
end;
result:=false;
end;
procedure PrintDFASet(var f : text;s : TDFASet);
var
i : integer;
first : boolean;
begin
first:=true;
for i:=0 to Length(s)*8 do
begin
if DFASetIn(s,i) then
begin
if not(first) then
write(f,',');
write(f,i);
first:=false;
end;
end;
end;
end.
|
