1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
|
{
pas2jni - JNI bridge generator for Pascal.
Copyright (c) 2013 by Yury Sidorov.
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
****************************************************************************}
unit def;
{$mode objfpc}{$H+}
interface
uses
Classes, SysUtils, contnrs;
type
TDefType = (dtNone, dtUnit, dtClass, dtRecord, dtProc, dtField, dtProp, dtParam, dtVar,
dtType, dtConst, dtProcType, dtEnum, dtSet);
TDefClass = class of TDef;
{ TDef }
TDef = class
private
FAliasName: string;
FRefCnt: integer;
FItems: TObjectList;
FInSetUsed: boolean;
procedure CheckItems;
function GetAliasName: string;
function GetCount: integer;
function GetIsUsed: boolean;
function GetItem(Index: Integer): TDef;
procedure SetItem(Index: Integer; const AValue: TDef);
protected
procedure SetIsUsed(const AValue: boolean); virtual;
function ResolveDef(d: TDef; ExpectedClass: TDefClass = nil): TDef;
procedure AddRef;
procedure DecRef;
procedure SetExtUsed(ExtDef: TDef; AUsed: boolean; var HasRef: boolean);
public
DefType: TDefType;
DefId: integer;
SymId: integer;
Name: string;
Parent: TDef;
Tag: integer;
IsPrivate: boolean;
constructor Create; virtual; overload;
constructor Create(AParent: TDef; AType: TDefType); virtual; overload;
destructor Destroy; override;
function Add(ADef: TDef): integer;
function Insert(Index: integer; ADef: TDef): integer;
function FindDef(ADefId: integer; Recursive: boolean = True): TDef;
procedure ResolveDefs; virtual;
procedure SetNotUsed;
property Items[Index: Integer]: TDef read GetItem write SetItem; default;
property Count: integer read GetCount;
property IsUsed: boolean read GetIsUsed write SetIsUsed;
property RefCnt: integer read FRefCnt;
property AliasName: string read GetAliasName write FAliasName;
end;
{ TClassDef }
TClassDef = class(TDef)
private
FHasClassRef: boolean;
protected
procedure SetIsUsed(const AValue: boolean); override;
public
AncestorClass: TClassDef;
HasAbstractMethods: boolean;
HasReplacedItems: boolean;
ImplementsReplacedItems: boolean;
procedure ResolveDefs; override;
end;
TRecordDef = class(TDef)
public
Size: integer;
end;
TBasicType = (btVoid, btByte, btShortInt, btWord, btSmallInt, btLongWord, btLongInt, btInt64,
btSingle, btDouble, btString, btWideString, btBoolean, btChar, btWideChar, btEnum, btPointer,
btGuid);
{ TTypeDef }
TTypeDef = class(TDef)
protected
procedure SetIsUsed(const AValue: boolean); override;
public
BasicType: TBasicType;
end;
{ TReplDef }
TReplDef = class(TDef)
protected
procedure SetIsUsed(const AValue: boolean); override;
public
IsReplaced: boolean;
IsReplImpl: boolean;
ReplacedItem: TReplDef;
function CanReplaced: boolean; virtual;
function IsReplacedBy(d: TReplDef): boolean; virtual;
procedure CheckReplaced;
end;
TVarOption = (voRead, voWrite, voConst, voVar, voOut);
TVarOptions = set of TVarOption;
{ TVarDef }
TVarDef = class(TReplDef)
private
FHasTypeRef: boolean;
protected
procedure SetIsUsed(const AValue: boolean); override;
public
VarOpt: TVarOptions;
VarType: TDef;
constructor Create; override;
procedure ResolveDefs; override;
function IsReplacedBy(d: TReplDef): boolean; override;
function CanReplaced: boolean; override;
end;
TProcType = (ptProcedure, ptFunction, ptConstructor, ptDestructor);
TProcOption = (poOverride, poOverload, poMethodPtr, poPrivate, poProtected);
TProcOptions = set of TProcOption;
{ TProcDef }
TProcDef = class(TReplDef)
private
FHasRetTypeRef: boolean;
protected
procedure SetIsUsed(const AValue: boolean); override;
public
ProcType: TProcType;
ReturnType: TDef;
ProcOpt: TProcOptions;
procedure ResolveDefs; override;
function IsReplacedBy(d: TReplDef): boolean; override;
function CanReplaced: boolean; override;
end;
TUnitDef = class(TDef)
public
OS: string;
CPU: string;
IntfCRC: string;
PPUVer: integer;
UsedUnits: array of TUnitDef;
Processed: boolean;
end;
TConstDef = class(TVarDef)
public
Value: string;
end;
{ TSetDef }
TSetDef = class(TDef)
private
FHasElTypeRef: boolean;
protected
procedure SetIsUsed(const AValue: boolean); override;
public
Size: integer;
Base: integer;
ElMax: integer;
ElType: TTypeDef;
end;
const
ReplDefs = [dtField, dtProp, dtProc];
implementation
{ TReplDef }
procedure TReplDef.SetIsUsed(const AValue: boolean);
var
i: integer;
begin
i:=RefCnt;
inherited SetIsUsed(AValue);
if (i = 0) and (RefCnt > 0) then
CheckReplaced;
end;
function TReplDef.CanReplaced: boolean;
begin
Result:=not (IsPrivate or (Parent = nil) or (Parent.DefType <> dtClass));
end;
function TReplDef.IsReplacedBy(d: TReplDef): boolean;
begin
Result:=d.CanReplaced and (CompareText(Name, d.Name) = 0);
end;
procedure TReplDef.CheckReplaced;
function _Scan(cls: TClassDef): boolean;
var
i: integer;
d: TReplDef;
c: TClassDef;
begin
Result:=False;
c:=cls.AncestorClass;
if c = nil then
exit;
for i:=0 to c.Count - 1 do begin
d:=TReplDef(c[i]);
if (d.DefType in ReplDefs) and IsReplacedBy(d) then begin
d.IsReplaced:=True;
ReplacedItem:=d;
Result:=True;
break;
end;
end;
if not Result then
Result:=_Scan(c);
if Result then begin
cls.ImplementsReplacedItems:=True;
c.HasReplacedItems:=True;
end;
end;
begin
if not CanReplaced then
exit;
if _Scan(TClassDef(Parent)) then
IsReplImpl:=True;
end;
{ TSetDef }
procedure TSetDef.SetIsUsed(const AValue: boolean);
begin
inherited SetIsUsed(AValue);
SetExtUsed(ElType, AValue, FHasElTypeRef);
end;
{ TTypeDef }
procedure TTypeDef.SetIsUsed(const AValue: boolean);
begin
if BasicType in [btEnum] then
inherited SetIsUsed(AValue)
else
if AValue then
AddRef
else
DecRef;
end;
{ TProcDef }
procedure TProcDef.SetIsUsed(const AValue: boolean);
var
i: integer;
begin
if IsPrivate then
exit;
if AValue and (RefCnt = 0) then begin
for i:=0 to Count - 1 do
if TVarDef(Items[i]).VarType = nil then
exit; // If procedure has unsupported parameters, don't use it
end;
inherited SetIsUsed(AValue);
if ReturnType <> Parent then
SetExtUsed(ReturnType, AValue, FHasRetTypeRef);
end;
procedure TProcDef.ResolveDefs;
begin
inherited ResolveDefs;
ReturnType:=ResolveDef(ReturnType);
end;
function TProcDef.IsReplacedBy(d: TReplDef): boolean;
var
i: integer;
p: TProcDef;
begin
Result:=False;
if d.DefType <> dtProc then
exit;
p:=TProcDef(d);
if (ReturnType <> p.ReturnType) and (Count = p.Count) and inherited IsReplacedBy(p) then begin
// Check parameter types
for i:=0 to Count - 1 do
if TVarDef(Items[i]).VarType <> TVarDef(p.Items[i]).VarType then
exit;
Result:=True;
end;
end;
function TProcDef.CanReplaced: boolean;
begin
Result:=inherited CanReplaced and (ProcType = ptFunction);
end;
{ TClassDef }
procedure TClassDef.SetIsUsed(const AValue: boolean);
begin
inherited SetIsUsed(AValue);
SetExtUsed(AncestorClass, AValue, FHasClassRef);
end;
procedure TClassDef.ResolveDefs;
begin
inherited ResolveDefs;
AncestorClass:=TClassDef(ResolveDef(AncestorClass, TClassDef));
end;
{ TVarDef }
procedure TVarDef.SetIsUsed(const AValue: boolean);
begin
if IsPrivate then
exit;
inherited SetIsUsed(AValue);
SetExtUsed(VarType, AValue, FHasTypeRef);
end;
procedure TVarDef.ResolveDefs;
begin
inherited ResolveDefs;
VarType:=ResolveDef(VarType);
end;
function TVarDef.IsReplacedBy(d: TReplDef): boolean;
begin
Result:=(d.DefType in [dtProp, dtField]) and (VarType <> TVarDef(d).VarType) and inherited IsReplacedBy(d);
end;
function TVarDef.CanReplaced: boolean;
begin
Result:=(voRead in VarOpt) and inherited CanReplaced;
end;
constructor TVarDef.Create;
begin
inherited Create;
VarOpt:=[voRead, voWrite];
end;
{ TDef }
procedure TDef.CheckItems;
begin
if FItems = nil then
FItems:=TObjectList.Create(True);
end;
function TDef.GetAliasName: string;
begin
if FAliasName <> '' then
Result:=FAliasName
else
Result:=Name;
end;
function TDef.GetCount: integer;
begin
if FItems = nil then
Result:=0
else begin
CheckItems;
Result:=FItems.Count;
end;
end;
function TDef.GetIsUsed: boolean;
begin
Result:=FRefCnt > 0;
end;
function TDef.GetItem(Index: Integer): TDef;
begin
CheckItems;
Result:=TDef(FItems[Index]);
end;
procedure TDef.SetIsUsed(const AValue: boolean);
var
i: integer;
f: boolean;
begin
if FInSetUsed or (DefType = dtNone) or IsPrivate then
exit;
if AValue then begin
AddRef;
f:=FRefCnt = 1;
end
else begin
if FRefCnt = 0 then
exit;
DecRef;
f:=FRefCnt = 0;
end;
if f then begin
// Update userd mark of children only once
FInSetUsed:=True;
try
for i:=0 to Count - 1 do
Items[i].IsUsed:=AValue;
finally
FInSetUsed:=False;
end;
// Update parent's used mark
if (Parent <> nil) and (Parent.DefType = dtUnit) then
if AValue then
Parent.AddRef
else
Parent.DecRef;
end;
end;
function TDef.ResolveDef(d: TDef; ExpectedClass: TDefClass): TDef;
begin
if (d = nil) or (d.DefType <> dtNone) then begin
Result:=d;
exit;
end;
Result:=d.Parent.FindDef(d.DefId);
if (ExpectedClass <> nil) and (Result <> nil) then
if not (Result is ExpectedClass) then
raise Exception.CreateFmt('Unexpected class. Expected: %s, got: %s', [ExpectedClass.ClassName, Result.ClassName]);
end;
procedure TDef.AddRef;
begin
Inc(FRefCnt);
end;
procedure TDef.DecRef;
begin
if FRefCnt > 0 then
Dec(FRefCnt);
end;
procedure TDef.SetExtUsed(ExtDef: TDef; AUsed: boolean; var HasRef: boolean);
var
OldRefCnt: integer;
begin
if ExtDef = nil then
exit;
if AUsed then begin
if HasRef then
exit;
OldRefCnt:=ExtDef.RefCnt;
ExtDef.IsUsed:=True;
HasRef:=OldRefCnt <> ExtDef.RefCnt;
end
else
if HasRef and not IsUsed then begin
ExtDef.IsUsed:=False;
HasRef:=False;
end;
end;
procedure TDef.SetItem(Index: Integer; const AValue: TDef);
begin
CheckItems;
FItems[Index]:=AValue;
end;
constructor TDef.Create;
begin
DefId:=-1;
DefType:=dtNone;
end;
constructor TDef.Create(AParent: TDef; AType: TDefType);
begin
Create;
if AParent <> nil then
AParent.Add(Self);
DefType:=AType;
end;
destructor TDef.Destroy;
begin
FreeAndNil(FItems);
if (Parent <> nil) and (Parent.FItems <> nil) then begin
Parent.FItems.OwnsObjects:=False;
try
Parent.FItems.Remove(Self);
finally
Parent.FItems.OwnsObjects:=True;
end;
end;
inherited Destroy;
end;
function TDef.Add(ADef: TDef): integer;
begin
Result:=Insert(Count, ADef);
end;
function TDef.Insert(Index: integer; ADef: TDef): integer;
begin
CheckItems;
Result:=Index;
FItems.Insert(Result, ADef);
ADef.Parent:=Self;
end;
function TDef.FindDef(ADefId: integer; Recursive: boolean): TDef;
function _Find(d: TDef): TDef;
var
i: integer;
begin
Result:=nil;
for i:=0 to d.Count - 1 do
with d[i] do begin
if (DefType <> dtNone) and (DefId = ADefId) then begin
Result:=d[i];
break;
end;
if Recursive and (Count > 0) then begin
Result:=_Find(d[i]);
if Result <> nil then
break;
end;
end;
end;
begin
Result:=_Find(Self);
end;
procedure TDef.ResolveDefs;
var
i: integer;
begin
for i:=0 to Count - 1 do
Items[i].ResolveDefs;
end;
procedure TDef.SetNotUsed;
begin
if FRefCnt = 0 then
exit;
FRefCnt:=1;
IsUsed:=False;
end;
end.
|