path: root/doc/gawkinet.info

This is gawkinet.info, produced by makeinfo version 6.7 from
gawkinet.texi.

This is Edition 1.6 of 'TCP/IP Internetworking with 'gawk'', for the
5.1.0 (or later) version of the GNU implementation of AWK.


   Copyright (C) 2000, 2001, 2002, 2004, 2009, 2010, 2016, 2019, 2020,
2021 Free Software Foundation, Inc.


   Permission is granted to copy, distribute and/or modify this document
under the terms of the GNU Free Documentation License, Version 1.3 or
any later version published by the Free Software Foundation; with the
Invariant Sections being "GNU General Public License", the Front-Cover
texts being (a) (see below), and with the Back-Cover Texts being (b)
(see below).  A copy of the license is included in the section entitled
"GNU Free Documentation License".

  a. "A GNU Manual"

  b. "You have the freedom to copy and modify this GNU manual.  Buying
     copies from the FSF supports it in developing GNU and promoting
     software freedom."
INFO-DIR-SECTION Network applications
START-INFO-DIR-ENTRY
* awkinet: (gawkinet).          TCP/IP Internetworking With 'gawk'.
END-INFO-DIR-ENTRY


File: gawkinet.info,  Node: Top,  Next: Preface,  Prev: (dir),  Up: (dir)

General Introduction
********************

This file documents the networking features in GNU Awk ('gawk') version
4.0 and later.

   This is Edition 1.6 of 'TCP/IP Internetworking with 'gawk'', for the
5.1.0 (or later) version of the GNU implementation of AWK.


   Copyright (C) 2000, 2001, 2002, 2004, 2009, 2010, 2016, 2019, 2020,
2021 Free Software Foundation, Inc.


   Permission is granted to copy, distribute and/or modify this document
under the terms of the GNU Free Documentation License, Version 1.3 or
any later version published by the Free Software Foundation; with the
Invariant Sections being "GNU General Public License", the Front-Cover
texts being (a) (see below), and with the Back-Cover Texts being (b)
(see below).  A copy of the license is included in the section entitled
"GNU Free Documentation License".

  a. "A GNU Manual"

  b. "You have the freedom to copy and modify this GNU manual.  Buying
     copies from the FSF supports it in developing GNU and promoting
     software freedom."

* Menu:

* Preface::                          About this document.
* Introduction::                     About networking.
* Using Networking::                 Some examples.
* Some Applications and Techniques:: More extended examples.
* Links::                            Where to find the stuff mentioned in this
                                     document.
* GNU Free Documentation License::   The license for this document.
* Index::                            The index.

* Stream Communications::          Sending data streams.
* Datagram Communications::        Sending self-contained messages.
* The TCP/IP Protocols::           How these models work in the Internet.
* Basic Protocols::                The basic protocols.
* Ports::                          The idea behind ports.
* Making Connections::             Making TCP/IP connections.
* Gawk Special Files::             How to do 'gawk' networking.
* Special File Fields::            The fields in the special file name.
* Comparing Protocols::            Differences between the protocols.
* File /inet/tcp::                 The TCP special file.
* File /inet/udp::                 The UDP special file.
* TCP Connecting::                 Making a TCP connection.
* Troubleshooting::                Troubleshooting TCP/IP connections.
* Interacting::                    Interacting with a service.
* Setting Up::                     Setting up a service.
* Email::                          Reading email.
* Web page::                       Reading a Web page.
* Primitive Service::              A primitive Web service.
* Interacting Service::            A Web service with interaction.
* CGI Lib::                        A simple CGI library.
* Simple Server::                  A simple Web server.
* Caveats::                        Network programming caveats.
* Challenges::                     Where to go from here.
* PANIC::                          An Emergency Web Server.
* GETURL::                         Retrieving Web Pages.
* REMCONF::                        Remote Configuration Of Embedded Systems.
* URLCHK::                         Look For Changed Web Pages.
* WEBGRAB::                        Extract Links From A Page.
* STATIST::                        Graphing A Statistical Distribution.
* MAZE::                           Walking Through A Maze In Virtual Reality.
* MOBAGWHO::                       A Simple Mobile Agent.
* STOXPRED::                       Stock Market Prediction As A Service.
* PROTBASE::                       Searching Through A Protein Database.


File: gawkinet.info,  Node: Preface,  Next: Introduction,  Prev: Top,  Up: Top

Preface
*******

In May of 1997, Jürgen Kahrs felt the need for network access from
'awk', and, with a little help from me, set about adding features to do
this for 'gawk'.  At that time, he wrote the bulk of this Info file.

   The code and documentation were added to the 'gawk' 3.1 development
tree, and languished somewhat until I could finally get down to some
serious work on that version of 'gawk'.  This finally happened in the
middle of 2000.

   Meantime, Jürgen wrote an article about the Internet special files
and '|&' operator for 'Linux Journal', and made a networking patch for
the production versions of 'gawk' available from his home page.  In
August of 2000 (for 'gawk' 3.0.6), this patch also made it to the main
GNU 'ftp' distribution site.

   For release with 'gawk', I edited Jürgen's prose for English grammar
and style, as he is not a native English speaker.  I also rearranged the
material somewhat for what I felt was a better order of presentation,
and (re)wrote some of the introductory material.

   The majority of this document and the code are his work, and the high
quality and interesting ideas speak for themselves.  It is my hope that
these features will be of significant value to the 'awk' community.


Arnold Robbins
Nof Ayalon, ISRAEL
March, 2001


File: gawkinet.info,  Node: Introduction,  Next: Using Networking,  Prev: Preface,  Up: Top

1 Networking Concepts
*********************

This major node provides a (necessarily) brief introduction to computer
networking concepts.  For many applications of 'gawk' to TCP/IP
networking, we hope that this is enough.  For more advanced tasks, you
will need deeper background, and it may be necessary to switch to
lower-level programming in C or C++.

   There are two real-life models for the way computers send messages to
each other over a network.  While the analogies are not perfect, they
are close enough to convey the major concepts.  These two models are the
phone system (reliable byte-stream communications), and the postal
system (best-effort datagrams).

* Menu:

* Stream Communications::       Sending data streams.
* Datagram Communications::     Sending self-contained messages.
* The TCP/IP Protocols::        How these models work in the Internet.
* Making Connections::          Making TCP/IP connections.


File: gawkinet.info,  Node: Stream Communications,  Next: Datagram Communications,  Prev: Introduction,  Up: Introduction

1.1 Reliable Byte-streams (Phone Calls)
=======================================

When you make a phone call, the following steps occur:

  1. You dial a number.

  2. The phone system connects to the called party, telling them there
     is an incoming call.  (Their phone rings.)

  3. The other party answers the call, or, in the case of a computer
     network, refuses to answer the call.

  4. Assuming the other party answers, the connection between you is now
     a "duplex" (two-way), "reliable" (no data lost), sequenced (data
     comes out in the order sent) data stream.

  5. You and your friend may now talk freely, with the phone system
     moving the data (your voices) from one end to the other.  From your
     point of view, you have a direct end-to-end connection with the
     person on the other end.

   The same steps occur in a duplex reliable computer networking
connection.  There is considerably more overhead in setting up the
communications, but once it's done, data moves in both directions,
reliably, in sequence.


File: gawkinet.info,  Node: Datagram Communications,  Next: The TCP/IP Protocols,  Prev: Stream Communications,  Up: Introduction

1.2 Best-effort Datagrams (Mailed Letters)
==========================================

Suppose you mail three different documents to your office on the other
side of the country on two different days.  Doing so entails the
following.

  1. Each document travels in its own envelope.

  2. Each envelope contains both the sender and the recipient address.

  3. Each envelope may travel a different route to its destination.

  4. The envelopes may arrive in a different order from the one in which
     they were sent.

  5. One or more may get lost in the mail.  (Although, fortunately, this
     does not occur very often.)

  6. In a computer network, one or more "packets" may also arrive
     multiple times.  (This doesn't happen with the postal system!)

   The important characteristics of datagram communications, like those
of the postal system are thus:

   * Delivery is "best effort;" the data may never get there.

   * Each message is self-contained, including the source and
     destination addresses.

   * Delivery is _not_ sequenced; packets may arrive out of order,
     and/or multiple times.

   * Unlike the phone system, overhead is considerably lower.  It is not
     necessary to set up the call first.

   The price the user pays for the lower overhead of datagram
communications is exactly the lower reliability; it is often necessary
for user-level protocols that use datagram communications to add their
own reliability features on top of the basic communications.


File: gawkinet.info,  Node: The TCP/IP Protocols,  Next: Making Connections,  Prev: Datagram Communications,  Up: Introduction

1.3 The Internet Protocols
==========================

The Internet Protocol Suite (usually referred to as just TCP/IP)(1)
consists of a number of different protocols at different levels or
"layers."  For our purposes, three protocols provide the fundamental
communications mechanisms.  All other defined protocols are referred to
as user-level protocols (e.g., HTTP, used later in this Info file).

* Menu:

* Basic Protocols::             The basic protocols.
* Ports::                       The idea behind ports.

   ---------- Footnotes ----------

   (1) It should be noted that although the Internet seems to have
conquered the world, there are other networking protocol suites in
existence and in use.


File: gawkinet.info,  Node: Basic Protocols,  Next: Ports,  Prev: The TCP/IP Protocols,  Up: The TCP/IP Protocols

1.3.1 The Basic Internet Protocols
----------------------------------

IP
     The Internet Protocol.  This protocol is almost never used directly
     by applications.  It provides the basic packet delivery and routing
     infrastructure of the Internet.  Much like the phone company's
     switching centers or the Post Office's trucks, it is not of much
     day-to-day interest to the regular user (or programmer).  It
     happens to be a best effort datagram protocol.  In the early
     twenty-first century, there are two versions of this protocol in
     use:

     IPv4
          The original version of the Internet Protocol, with 32-bit
          addresses, on which most of the current Internet is based.

     IPv6
          The "next generation" of the Internet Protocol, with 128-bit
          addresses.  This protocol is in wide use in certain parts of
          the world, but has not yet replaced IPv4.(1)

     Versions of the other protocols that sit "atop" IP exist for both
     IPv4 and IPv6.  However, as the IPv6 versions are fundamentally the
     same as the original IPv4 versions, we will not distinguish further
     between them.

UDP
     The User Datagram Protocol.  This is a best effort datagram
     protocol.  It provides a small amount of extra reliability over IP,
     and adds the notion of "ports", described in *note TCP and UDP
     Ports: Ports.

TCP
     The Transmission Control Protocol.  This is a duplex, reliable,
     sequenced byte-stream protocol, again layered on top of IP, and
     also providing the notion of ports.  This is the protocol that you
     will most likely use when using 'gawk' for network programming.

   All other user-level protocols use either TCP or UDP to do their
basic communications.  Examples are SMTP (Simple Mail Transfer
Protocol), FTP (File Transfer Protocol), and HTTP (HyperText Transfer
Protocol).

   ---------- Footnotes ----------

   (1) There isn't an IPv5.


File: gawkinet.info,  Node: Ports,  Prev: Basic Protocols,  Up: The TCP/IP Protocols

1.3.2 TCP and UDP Ports
-----------------------

In the postal system, the address on an envelope indicates a physical
location, such as a residence or office building.  But there may be more
than one person at the location; thus you have to further quantify the
recipient by putting a person or company name on the envelope.

   In the phone system, one phone number may represent an entire
company, in which case you need a person's extension number in order to
reach that individual directly.  Or, when you call a home, you have to
say, "May I please speak to ..."  before talking to the person directly.

   IP networking provides the concept of addressing.  An IP address
represents a particular computer, but no more.  In order to reach the
mail service on a system, or the FTP or WWW service on a system, you
must have some way to further specify which service you want.  In the
Internet Protocol suite, this is done with "port numbers", which
represent the services, much like an extension number used with a phone
number.

   Port numbers are 16-bit integers.  Unix and Unix-like systems reserve
ports below 1024 for "well known" services, such as SMTP, FTP, and HTTP.
Numbers 1024 and above may be used by any application, although there is
no promise made that a particular port number is always available.


File: gawkinet.info,  Node: Making Connections,  Prev: The TCP/IP Protocols,  Up: Introduction

1.4 Making TCP/IP Connections (And Some Terminology)
====================================================

Two terms come up repeatedly when discussing networking: "client" and
"server".  For now, we'll discuss these terms at the "connection level",
when first establishing connections between two processes on different
systems over a network.  (Once the connection is established, the higher
level, or "application level" protocols, such as HTTP or FTP, determine
who is the client and who is the server.  Often, it turns out that the
client and server are the same in both roles.)

   The "server" is the system providing the service, such as the web
server or email server.  It is the "host" (system) which is _connected
to_ in a transaction.  For this to work though, the server must be
expecting connections.  Much as there has to be someone at the office
building to answer the phone,(1) the server process (usually) has to be
started first and be waiting for a connection.

   The "client" is the system requesting the service.  It is the system
_initiating the connection_ in a transaction.  (Just as when you pick up
the phone to call an office or store.)

   In the TCP/IP framework, each end of a connection is represented by a
pair of (ADDRESS, PORT) pairs.  For the duration of the connection, the
ports in use at each end are unique, and cannot be used simultaneously
by other processes on the same system.  (Only after closing a connection
can a new one be built up on the same port.  This is contrary to the
usual behavior of fully developed web servers which have to avoid
situations in which they are not reachable.  We have to pay this price
in order to enjoy the benefits of a simple communication paradigm in
'gawk'.)

   Furthermore, once the connection is established, communications are
"synchronous".(2)  I.e., each end waits on the other to finish
transmitting, before replying.  This is much like two people in a phone
conversation.  While both could talk simultaneously, doing so usually
doesn't work too well.

   In the case of TCP, the synchronicity is enforced by the protocol
when sending data.  Data writes "block" until the data have been
received on the other end.  For both TCP and UDP, data reads block until
there is incoming data waiting to be read.  This is summarized in the
following table, where an "x" indicates that the given action blocks.

TCP        x       x
UDP        x

   ---------- Footnotes ----------

   (1) In the days before voice mail systems!

   (2) For the technically savvy, data reads block--if there's no
incoming data, the program is made to wait until there is, instead of
receiving a "there's no data" error return.


File: gawkinet.info,  Node: Using Networking,  Next: Some Applications and Techniques,  Prev: Introduction,  Up: Top

2 Networking With 'gawk'
************************

The 'awk' programming language was originally developed as a
pattern-matching language for writing short programs to perform data
manipulation tasks.  'awk''s strength is the manipulation of textual
data that is stored in files.  It was never meant to be used for
networking purposes.  To exploit its features in a networking context,
it's necessary to use an access mode for network connections that
resembles the access of files as closely as possible.

   'awk' is also meant to be a prototyping language.  It is used to
demonstrate feasibility and to play with features and user interfaces.
This can be done with file-like handling of network connections.  'gawk'
trades the lack of many of the advanced features of the TCP/IP family of
protocols for the convenience of simple connection handling.  The
advanced features are available when programming in C or Perl.  In fact,
the network programming in this major node is very similar to what is
described in books such as 'Internet Programming with Python', 'Advanced
Perl Programming', or 'Web Client Programming with Perl'.

   However, you can do the programming here without first having to
learn object-oriented ideology; underlying languages such as Tcl/Tk,
Perl, Python; or all of the libraries necessary to extend these
languages before they are ready for the Internet.

   This major node demonstrates how to use the TCP protocol.  The UDP
protocol is much less important for most users.

* Menu:

* Gawk Special Files::          How to do 'gawk' networking.
* TCP Connecting::              Making a TCP connection.
* Troubleshooting::             Troubleshooting TCP/IP connections.
* Interacting::                 Interacting with a service.
* Setting Up::                  Setting up a service.
* Email::                       Reading email.
* Web page::                    Reading a Web page.
* Primitive Service::           A primitive Web service.
* Interacting Service::         A Web service with interaction.
* Simple Server::               A simple Web server.
* Caveats::                     Network programming caveats.
* Challenges::                  Where to go from here.


File: gawkinet.info,  Node: Gawk Special Files,  Next: TCP Connecting,  Prev: Using Networking,  Up: Using Networking

2.1 'gawk''s Networking Mechanisms
==================================

The '|&' operator for use in communicating with a "coprocess" is
described in *note Two-way Communications With Another Process:
(gawk)Two-way I/O. It shows how to do two-way I/O to a separate process,
sending it data with 'print' or 'printf' and reading data with
'getline'.  If you haven't read it already, you should detour there to
do so.

   'gawk' transparently extends the two-way I/O mechanism to simple
networking through the use of special file names.  When a "coprocess"
that matches the special files we are about to describe is started,
'gawk' creates the appropriate network connection, and then two-way I/O
proceeds as usual.

   At the C, C++, and Perl level, networking is accomplished via
"sockets", an Application Programming Interface (API) originally
developed at the University of California at Berkeley that is now used
almost universally for TCP/IP networking.  Socket level programming,
while fairly straightforward, requires paying attention to a number of
details, as well as using binary data.  It is not well-suited for use
from a high-level language like 'awk'.  The special files provided in
'gawk' hide the details from the programmer, making things much simpler
and easier to use.

   The special file name for network access is made up of several
fields, all of which are mandatory:

     /NET-TYPE/PROTOCOL/LOCALPORT/HOSTNAME/REMOTEPORT

   The NET-TYPE field lets you specify IPv4 versus IPv6, or lets you
allow the system to choose.

* Menu:

* Special File Fields::         The fields in the special file name.
* Comparing Protocols::         Differences between the protocols.


File: gawkinet.info,  Node: Special File Fields,  Next: Comparing Protocols,  Prev: Gawk Special Files,  Up: Gawk Special Files

2.1.1 The Fields of the Special File Name
-----------------------------------------

This node explains the meaning of all of the fields, as well as the
range of values and the defaults.  All of the fields are mandatory.  To
let the system pick a value, or if the field doesn't apply to the
protocol, specify it as '0' (zero):

NET-TYPE
     This is one of 'inet4' for IPv4, 'inet6' for IPv6, or 'inet' to use
     the system default (which is likely to be IPv4).  For the rest of
     this document, we will use the generic '/inet' in our descriptions
     of how 'gawk''s networking works.

PROTOCOL
     Determines which member of the TCP/IP family of protocols is
     selected to transport the data across the network.  There are two
     possible values (always written in lowercase): 'tcp' and 'udp'.
     The exact meaning of each is explained later in this node.

LOCALPORT
     Determines which port on the local machine is used to communicate
     across the network.  Application-level clients usually use '0' to
     indicate they do not care which local port is used--instead they
     specify a remote port to connect to.

     It is vital for application-level servers to use a number different
     from '0' here because their service has to be available at a
     specific publicly known port number.  It is possible to use a name
     from '/etc/services' here.

HOSTNAME
     Determines which remote host is to be at the other end of the
     connection.  Application-level clients must enter a name different
     from '0'.  The name can be either symbolic (e.g.,
     'jpl-devvax.jpl.nasa.gov') or numeric (e.g., '128.149.1.143').

     Application-level servers must fill this field with a '0' to
     indicate their being open for all other hosts to connect to them
     and enforce connection level server behavior this way.  It is not
     possible for an application-level server to restrict its
     availability to one remote host by entering a host name here.

REMOTEPORT
     Determines which port on the remote machine is used to communicate
     across the network.  For '/inet/tcp' and '/inet/udp',
     application-level clients _must_ use a number other than '0' to
     indicate to which port on the remote machine they want to connect.

     Application-level servers must not fill this field with a '0'.
     Instead they specify a local port to which clients connect.  It is
     possible to use a name from '/etc/services' here.

   Experts in network programming will notice that the usual
client/server asymmetry found at the level of the socket API is not
visible here.  This is for the sake of simplicity of the high-level
concept.  If this asymmetry is necessary for your application, use
another language.  For 'gawk', it is more important to enable users to
write a client program with a minimum of code.  What happens when first
accessing a network connection is seen in the following pseudocode:

     if ((name of remote host given) && (other side accepts connection)) {
       rendez-vous successful; transmit with getline or print
     } else {
       if ((other side did not accept) && (localport == 0))
         exit unsuccessful
       if (TCP) {
         set up a server accepting connections
         this means waiting for the client on the other side to connect
       } else
         ready
     }

   The exact behavior of this algorithm depends on the values of the
fields of the special file name.  When in doubt, *note Table 2.1:
table-inet-components. gives you the combinations of values and their
meaning.  If this table is too complicated, focus on the three lines
printed in *bold*.  All the examples in *note Networking With 'gawk':
Using Networking, use only the patterns printed in bold letters.

PROTOCOL    LOCAL       HOST NAME   REMOTE      RESULTING CONNECTION-LEVEL
            PORT                    PORT        BEHAVIOR
------------------------------------------------------------------------------
*tcp*       *0*         *x*         *x*         *Dedicated client, fails if
                                                immediately connecting to a
                                                server on the other side
                                                fails*
udp         0           x           x           Dedicated client
*tcp,       *x*         *x*         *x*         *Client, switches to
udp*                                            dedicated server if
                                                necessary*
*tcp,       *x*         *0*         *0*         *Dedicated server*
udp*
tcp, udp    x           x           0           Invalid
tcp, udp    0           0           x           Invalid
tcp, udp    x           0           x           Invalid
tcp, udp    0           0           0           Invalid
tcp, udp    0           x           0           Invalid

Table 2.1: '/inet' Special File Components

   In general, TCP is the preferred mechanism to use.  It is the
simplest protocol to understand and to use.  Use UDP only if
circumstances demand low-overhead.


File: gawkinet.info,  Node: Comparing Protocols,  Prev: Special File Fields,  Up: Gawk Special Files

2.1.2 Comparing Protocols
-------------------------

This node develops a pair of programs (sender and receiver) that do
nothing but send a timestamp from one machine to another.  The sender
and the receiver are implemented with each of the two protocols
available and demonstrate the differences between them.

* Menu:

* File /inet/tcp::              The TCP special file.
* File /inet/udp::              The UDP special file.


File: gawkinet.info,  Node: File /inet/tcp,  Next: File /inet/udp,  Prev: Comparing Protocols,  Up: Comparing Protocols

2.1.2.1 '/inet/tcp'
...................

Once again, always use TCP. (Use UDP when low overhead is a necessity.)
The first example is the sender program:

     # Server
     BEGIN {
       print strftime() |& "/inet/tcp/8888/0/0"
       close("/inet/tcp/8888/0/0")
     }

   The receiver is very simple:

     # Client
     BEGIN {
       "/inet/tcp/0/localhost/8888" |& getline
       print $0
       close("/inet/tcp/0/localhost/8888")
     }

   TCP guarantees that the bytes arrive at the receiving end in exactly
the same order that they were sent.  No byte is lost (except for broken
connections), doubled, or out of order.  Some overhead is necessary to
accomplish this, but this is the price to pay for a reliable service.
It does matter which side starts first.  The sender/server has to be
started first, and it waits for the receiver to read a line.


File: gawkinet.info,  Node: File /inet/udp,  Prev: File /inet/tcp,  Up: Comparing Protocols

2.1.2.2 '/inet/udp'
...................

The server and client programs that use UDP are almost identical to
their TCP counterparts; only the PROTOCOL has changed.  As before, it
does matter which side starts first.  The receiving side blocks and
waits for the sender.  In this case, the receiver/client has to be
started first:

     # Server
     BEGIN {
       print strftime() |& "/inet/udp/8888/0/0"
       close("/inet/udp/8888/0/0")
     }

   The receiver is almost identical to the TCP receiver:

     # Client
     BEGIN {
       print "hi!" |& "/inet/udp/0/localhost/8888"
       "/inet/udp/0/localhost/8888" |& getline
       print $0
       close("/inet/udp/0/localhost/8888")
     }

   In the case of UDP, the initial 'print' command is the one that
actually sends data so that there is a connection.  UDP and "connection"
sounds strange to anyone who has learned that UDP is a connectionless
protocol.  Here, "connection" means that the 'connect()' system call has
completed its work and completed the "association" between a certain
socket and an IP address.  Thus there are subtle differences between
'connect()' for TCP and UDP; see the man page for details.(1)

   UDP cannot guarantee that the datagrams at the receiving end will
arrive in exactly the same order they were sent.  Some datagrams could
be lost, some doubled, and some could arrive out of order.  But no
overhead is necessary to accomplish this.  This unreliable behavior is
good enough for tasks such as data acquisition, logging, and even
stateless services like the original versions of NFS.

   ---------- Footnotes ----------

   (1) This subtlety is just one of many details that are hidden in the
socket API, invisible and intractable for the 'gawk' user.  The
developers are currently considering how to rework the network
facilities to make them easier to understand and use.


File: gawkinet.info,  Node: TCP Connecting,  Next: Troubleshooting,  Prev: Gawk Special Files,  Up: Using Networking

2.2 Establishing a TCP Connection
=================================

Let's observe a network connection at work.  Type in the following
program and watch the output.  Within a second, it connects via TCP
('/inet/tcp') to a remote server and asks the service 'daytime' on the
machine what time it is:

     BEGIN {
       daytime_server     = "time-a-g.nist.gov"
       daytime_connection = "/inet/tcp/0/" daytime_server "/daytime"
       daytime_connection |& getline
       print $0
       daytime_connection |& getline
       print $0
       close(daytime_connection)
     }

   Even experienced 'awk' users will find the fourth and sixth line
strange in two respects:

   * A string containing the name of a special file is used as a shell
     command that pipes its output into 'getline'.  One would rather
     expect to see the special file being read like any other file
     ('getline < "/inet/tcp/0/time-a-g.nist.gov/daytime"').

   * The operator '|&' has not been part of any 'awk' implementation
     (until now).  It is actually the only extension of the 'awk'
     language needed (apart from the special files) to introduce network
     access.

   The '|&' operator was introduced in 'gawk' 3.1 in order to overcome
the crucial restriction that access to files and pipes in 'awk' is
always unidirectional.  It was formerly impossible to use both access
modes on the same file or pipe.  Instead of changing the whole concept
of file access, the '|&' operator behaves exactly like the usual pipe
operator except for two additions:

   * Normal shell commands connected to their 'gawk' program with a '|&'
     pipe can be accessed bidirectionally.  The '|&' turns out to be a
     quite general, useful, and natural extension of 'awk'.

   * Pipes that consist of a special file name for network connections
     are not executed as shell commands.  Instead, they can be read and
     written to, just like a full-duplex network connection.

   In the earlier example, the '|&' operator tells 'getline' to read a
line from the special file '/inet/tcp/0/time-a-g.nist.gov/daytime'.  We
could also have printed a line into the special file.  But instead we
just consumed an empty leading line, printed it, then read a line with
the time, printed that, and closed the connection.  (While we could just
let 'gawk' close the connection by finishing the program, in this Info
file we are pedantic and always explicitly close the connections.)

   Network services like 'daytime' are not really useful because there
are so many better ways to print the current time.  In the early days of
TCP networking, such a service may have looked like a good idea for
testing purposes.  Later, simple TCP services like these have been used
to teach TCP/IP networking and therefore you can still find much
educational material of good quality on the Internet about such outdated
services.  The list of servers (https://tf.nist.gov/tf-cgi/servers.cgi)
that still support the legacy service daytime
(https://en.wikipedia.org/wiki/Daytime_Protocol) can be found at
Wikipedia.  We hesitated to use this service in this manual because it
is hard to find servers that still support services like 'daytime'
openly to the Internet.  Later on we will see that some of these
nostalgic protocols have turned into security risks.


File: gawkinet.info,  Node: Troubleshooting,  Next: Interacting,  Prev: TCP Connecting,  Up: Using Networking

2.3 Troubleshooting Connection Problems
=======================================

It may well be that for some reason the program shown in the previous
example does not run on your machine.  When looking at possible reasons
for this, you will learn much about typical problems that arise in
network programming.

   For the rest of this major node, we will assume you work on a
POSIX-style system that supports TCP/IP. If the previous example program
does not run on your machine, it may help to replace the value assigned
to the variable 'daytime_server' with the name (or the IP address) of
another server from the list mentioned above.  Now you should see the
date and time being printed by the program, otherwise you may have run
out of servers that support the 'daytime' service.

   Try changing the service to 'chargen' or 'ftp'.  This way, the
program connects to other services that should give you some response.
If you are curious, you should have a look at your '/etc/services' file.
It could look like this:

     # /etc/services:
     #
     # Network services, Internet style
     #
     # Name     Number/Protocol  Alternate name # Comments

     echo        7/tcp
     echo        7/udp
     discard     9/tcp         sink null
     discard     9/udp         sink null
     daytime     13/tcp
     daytime     13/udp
     chargen     19/tcp        ttytst source
     chargen     19/udp        ttytst source
     ftp         21/tcp
     telnet      23/tcp
     smtp        25/tcp        mail
     finger      79/tcp
     www         80/tcp        http      # WorldWideWeb HTTP
     www         80/udp        # HyperText Transfer Protocol
     pop-2       109/tcp       postoffice    # POP version 2
     pop-2       109/udp
     pop-3       110/tcp       # POP version 3
     pop-3       110/udp
     nntp        119/tcp       readnews untp  # USENET News
     irc         194/tcp       # Internet Relay Chat
     irc         194/udp
     ...

   Here, you find a list of services that traditional Unix machines
usually support.  If your GNU/Linux machine does not do so, it may be
that these services are switched off in some startup script.  Systems
running some flavor of Microsoft Windows usually do _not_ support these
services.  Nevertheless, it _is_ possible to do networking with 'gawk'
on Microsoft Windows.(1)  The first column of the file gives the name of
the service, and the second column gives a unique number and the
protocol that one can use to connect to this service.  The rest of the
line is treated as a comment.  You see that some services ('echo')
support TCP as well as UDP.

   ---------- Footnotes ----------

   (1) Microsoft preferred to ignore the TCP/IP family of protocols
until 1995.  Then came the rise of the Netscape browser as a landmark
"killer application."  Microsoft added TCP/IP support and their own
browser to Microsoft Windows 95 at the last minute.  They even
back-ported their TCP/IP implementation to Microsoft Windows for
Workgroups 3.11, but it was a rather rudimentary and half-hearted
implementation.  Nevertheless, the equivalent of '/etc/services' resides
under 'C:\WINNT\system32\drivers\etc\services' on Microsoft Windows 2000
and Microsoft Windows XP. On Microsoft Windows 7, 8 and 10 there is a
directory '%WinDir%\System32\Drivers\Etc' that holds the 'hosts' file
(https://support.microsoft.com/en-us/help/972034/how-to-reset-the-hosts-file-back-to-the-default)
and probably also a 'services' file
(https://www.ibm.com/support/knowledgecenter/SSRNYG_7.2.1/com.ibm.rational.synergy.install.win.doc/topics/sg_r_igw_services_file.html).


File: gawkinet.info,  Node: Interacting,  Next: Setting Up,  Prev: Troubleshooting,  Up: Using Networking

2.4 Interacting with a Network Service
======================================

The next program begins really interacting with a network service by
printing something into the special file.  It asks the so-called
'finger' service if a user of the machine is logged in.  When testing
this program, try to change the variable 'finger_server' to some other
machine name in your local network:

     BEGIN {
       finger_server     = "andrew.cmu.edu"
       finger_connection = "/inet/tcp/0/" finger_server "/finger"
       print "wnace" |& finger_connection
       while ((finger_connection |& getline) > 0)
         print $0
       close(finger_connection)
     }

   After telling the service on the machine which user to look for, the
program repeatedly reads lines that come as a reply.  When no more lines
are available (because the service has closed the connection), the
program also closes the connection.  If you tried to replace
'finger_server' with some other server name, the script probably
reported being unable to open the connection, because most servers today
no longer support this service.  Try replacing the login name of
Professor Nace ('wnace') with another login name (like 'help').  You
will receive a list of login names similar to the one you asked for.  In
the 1980s you could get a list of all users currently logged in by
asking for an empty string ('""').

   The final 'close()' call could be safely deleted from the above
script, because the operating system closes any open connection by
default when a script reaches the end of execution.  But, in order to
avoid portability problems, it is best to always close connections
explicitly.  With the Linux kernel, for example, proper closing results
in flushing of buffers.  Letting the close happen by default may result
in discarding buffers.

   When looking at '/etc/services' you may have noticed that the
'daytime' service is also available with 'udp'.  In the earlier
examples, change 'tcp' to 'udp' and try if the 'finger' and 'daytime'
clients still work as expected.  They probably will not respond because
a wise administrator switched off these services.  But if they do, you
may see the expected day and time message.  The program then hangs,
because it waits for more lines to come from the service.  However, they
never do.  This behavior is a consequence of the differences between TCP
and UDP. When using UDP, neither party is automatically informed about
the other closing the connection.  Continuing to experiment this way
reveals many other subtle differences between TCP and UDP. To avoid such
trouble, you should always remember the advice Douglas E. Comer and
David Stevens give in Volume III of their series 'Internetworking With
TCP' (page 14):

     When designing client-server applications, beginners are strongly
     advised to use TCP because it provides reliable,
     connection-oriented communication.  Programs only use UDP if the
     application protocol handles reliability, the application requires
     hardware broadcast or multicast, or the application cannot tolerate
     virtual circuit overhead.

   This advice is actually quite dated and we hesitated to repeat it
here.  But we left it in because we are still observing beginners
running into this pitfall.  While this advice has aged quite well, some
other ideas from the 1980s have not.  The 'finger' service may still be
available in Microsoft Windows Server 2019
(https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/finger),
but it turned out to be a never-ending cause of trouble.  First of all,
it is now obvious that a server should never reveal personal data about
its users to anonymous client software that connects over the wild wild
Internet.  So every server on the Internet should reject 'finger'
requests (by disabling the port and by disabling the software serving
this port).  But things got even worse in 2020 when it turned out that
even the client software (the 'finger' command documented in the link
above) is a security problem.  A tool called DarkFinger
(https://seclists.org/fulldisclosure/2020/Sep/30) allows to leverage the
Microsoft Windows 'finger.exe' as a file downloader and help evade
network security devices.


File: gawkinet.info,  Node: Setting Up,  Next: Email,  Prev: Interacting,  Up: Using Networking

2.5 Setting Up a Service
========================

The preceding programs behaved as clients that connect to a server
somewhere on the Internet and request a particular service.  Now we set
up such a service to mimic the behavior of the 'daytime' service.  Such
a server does not know in advance who is going to connect to it over the
network.  Therefore, we cannot insert a name for the host to connect to
in our special file name.

   Start the following program in one window.  Notice that the service
does not have the name 'daytime', but the number '8888'.  From looking
at '/etc/services', you know that names like 'daytime' are just
mnemonics for predetermined 16-bit integers.  Only the system
administrator ('root') could enter our new service into '/etc/services'
with an appropriate name.  Also notice that the service name has to be
entered into a different field of the special file name because we are
setting up a server, not a client:

     BEGIN {
       print strftime() |& "/inet/tcp/8888/0/0"
       close("/inet/tcp/8888/0/0")
     }

   Now open another window on the same machine.  Copy the client program
given as the first example (*note Establishing a TCP Connection: TCP
Connecting.) to a new file and edit it, changing the variable
'daytime_server' to 'localhost' and the port name 'daytime' to '8888'.
Then start the modified client.  You should get a reply like this:

     $ gawk -f awklib/eg/network/daytimeclient.awk
     -| Sun Dec 27 17:33:57 CET 2020
     -| Sun Dec 27 17:33:57 CET 2020

Both programs explicitly close the connection.

   Now we will intentionally make a mistake to see what happens when the
name '8888' (the port) is already used by another service.  Start the
server program in both windows.  The first one works, but the second one
complains that it could not open the connection.  Each port on a single
machine can only be used by one server program at a time.  Now terminate
the server program and change the name '8888' to 'echo'.  After
restarting it, the server program does not run any more, and you know
why: there is already an 'echo' service running on your machine.  But
even if this isn't true, you would not get your own 'echo' server
running on a Unix machine, because the ports with numbers smaller than
1024 ('echo' is at port 7) are reserved for 'root'.  On machines running
some flavor of Microsoft Windows, there is no restriction that reserves
ports 1 to 1024 for a privileged user; hence, you can start an 'echo'
server there.  Even in later version of Microsoft Windows, this
restriction of the Unix world seems to have never been adopted 'Does
windows(10/server-2016) have privileged ports?'
(https://social.technet.microsoft.com/Forums/windowsserver/en-US/334f0770-eda9-475a-a27f-46b80ab7e872/does-windows10server2016-have-privileged-ports-?forum=ws2016).
In Microsoft Windows it is the level of the firewall that handles port
access restrictions, not the level of the operating system's kernel.

   Turning this short server program into something really useful is
simple.  Imagine a server that first reads a file name from the client
through the network connection, then does something with the file and
sends a result back to the client.  The server-side processing could be:

     BEGIN {
       NetService = "/inet/tcp/8888/0/0"
       NetService |& getline       # sets $0 and the fields
       CatPipe    = ("cat " $1)
       while ((CatPipe | getline) > 0)
         print $0 |& NetService
       close(NetService)
     }

and we would have a remote copying facility.  Such a server reads the
name of a file from any client that connects to it and transmits the
contents of the named file across the net.  The server-side processing
could also be the execution of a command that is transmitted across the
network.  From this example, you can see how simple it is to open up a
security hole on your machine.  If you allow clients to connect to your
machine and execute arbitrary commands, anyone would be free to do 'rm
-rf *'.

   The client side connects to port number 8888 on the server side and
sends the name of the desired file to be sent across the same TCP
connection.  The main loop reads all content coming in from the TCP
connection line-wise and prints it.

     BEGIN {
       NetService = "/inet/tcp/0/localhost/8888"
       print "README" |& NetService
       while ((NetService |& getline) > 0)
         print $0
       close(NetService)
     }


File: gawkinet.info,  Node: Email,  Next: Web page,  Prev: Setting Up,  Up: Using Networking

2.6 Reading Email
=================

The distribution of email is usually done by dedicated email servers
that communicate with your machine using special protocols.  In this
node we show how simple the basic steps are.(1)

   To receive email, we use the Post Office Protocol (POP). Sending can
be done with the much older Simple Mail Transfer Protocol (SMTP).

   When you type in the following program, replace the EMAILHOST by the
name of your local email server.  Ask your administrator if the server
has a POP service, and then use its name or number in the program below.
Now the program is ready to connect to your email server, but it will
not succeed in retrieving your mail because it does not yet know your
login name or password.  Replace them in the program and it shows you
the first email the server has in store:

     BEGIN {
       POPService  = "/inet/tcp/0/EMAILHOST/pop3"
       RS = ORS = "\r\n"
       print "user NAME"             |& POPService
       POPService                    |& getline
       print "pass PASSWORD"         |& POPService
       POPService                    |& getline
       print "retr 1"                |& POPService
       POPService                    |& getline
       if ($1 != "+OK") exit
       print "quit"                  |& POPService
       RS = "\r\n\\.\r\n"
       POPService |& getline
       print $0
       close(POPService)
     }

   We redefine the record separators 'RS' and 'ORS' because the protocol
(POP) requires CR-LF to separate lines.  After identifying yourself to
the email service, the command 'retr 1' instructs the service to send
the first of all your email messages in line.  If the service replies
with something other than '+OK', the program exits; maybe there is no
email.  Otherwise, the program first announces that it intends to finish
reading email, and then redefines 'RS' in order to read the entire email
as multiline input in one record.  From the POP RFC, we know that the
body of the email always ends with a single line containing a single
dot.  The program looks for this using 'RS = "\r\n\\.\r\n"'.  When it
finds this sequence in the mail message, it quits.  You can invoke this
program as often as you like; it does not delete the message it reads,
but instead leaves it on the server.

   ---------- Footnotes ----------

   (1) No, things are _not_ that simple any more.  Things _were_ that
simple when email was young in the 20th century.  These days,
unencrypted plaintext authentication is usually disallowed on non-secure
connections.  Since encryption of network connections is not supported
in 'gawk', you should not use 'gawk' to write such scripts.  We left
this node as it is because it demonstrates how application level
protocols work in principle (a command being issued by the client
followed by a reply coming back).  Unfortunately, modern application
level protocols are much more flexible in the sequence of actions.  For
example, modern POP3 servers may introduce themselves with an unprompted
initial line that arrives before the initial command.  Dealing with such
variance is not worth the effort in 'gawk'.


File: gawkinet.info,  Node: Web page,  Next: Primitive Service,  Prev: Email,  Up: Using Networking

2.7 Reading a Web Page
======================

Retrieving a web page from a web server is as simple as retrieving email
from an email server.  We only have to use a similar, but not identical,
protocol and a different port.  The name of the protocol is HyperText
Transfer Protocol (HTTP) and the port number is usually 80.  As in the
preceding node, ask your administrator about the name of your local web
server or proxy web server and its port number for HTTP requests.

   The following program employs a rather crude approach toward
retrieving a web page.  It uses the prehistoric syntax of HTTP 0.9,
which almost all web servers still support.  The most noticeable thing
about it is that the program directs the request to the local proxy
server whose name you insert in the special file name (which in turn
calls 'www.yahoo.com'):

     BEGIN {
       RS = ORS = "\r\n"
       HttpService = "/inet/tcp/0/PROXY/80"
       print "GET http://www.yahoo.com"     |& HttpService
       while ((HttpService |& getline) > 0)
          print $0
       close(HttpService)
     }

   Again, lines are separated by a redefined 'RS' and 'ORS'.  The 'GET'
request that we send to the server is the only kind of HTTP request that
existed when the web was created in the early 1990s.  HTTP calls this
'GET' request a "method," which tells the service to transmit a web page
(here the home page of the Yahoo!  search engine).  Version 1.0 added
the request methods 'HEAD' and 'POST'.  The current version of HTTP is
1.1,(1)(2) and knows the additional request methods 'OPTIONS', 'PUT',
'DELETE', and 'TRACE'.  You can fill in any valid web address, and the
program prints the HTML code of that page to your screen.

   Notice the similarity between the responses of the POP and HTTP
services.  First, you get a header that is terminated by an empty line,
and then you get the body of the page in HTML. The lines of the headers
also have the same form as in POP. There is the name of a parameter,
then a colon, and finally the value of that parameter.

   Images ('.png' or '.gif' files) can also be retrieved this way, but
then you get binary data that should be redirected into a file.  Another
application is calling a CGI (Common Gateway Interface) script on some
server.  CGI scripts are used when the contents of a web page are not
constant, but generated on demand at the moment you send a request for
the page.  For example, to get a detailed report about the current
quotes of Motorola stock shares, call a CGI script at Yahoo!  with the
following:

     get = "GET http://quote.yahoo.com/q?s=MOT&d=t"
     print get |& HttpService

   You can also request weather reports this way.

   ---------- Footnotes ----------

   (1) Version 1.0 of HTTP was defined in RFC 1945.  HTTP 1.1 was
initially specified in RFC 2068.  In June 1999, RFC 2068 was made
obsolete by RFC 2616, an update without any substantial changes.

   (2) Version 2.0 of HTTP (https://en.wikipedia.org/wiki/HTTP/2) was
defined in RFC7540 (https://tools.ietf.org/html/rfc7540) and was derived
from Google's SPDY (https://en.wikipedia.org/wiki/SPDY) protocol.  It is
said to be widely supported.  As of 2020 the most popular web sites
still identify themselves as supporting HTTP/1.1.  Version 3.0 of HTTP
(https://en.wikipedia.org/wiki/HTTP/3) is still a draft and was derived
from Google's QUIC (https://en.wikipedia.org/wiki/QUIC) protocol.


File: gawkinet.info,  Node: Primitive Service,  Next: Interacting Service,  Prev: Web page,  Up: Using Networking

2.8 A Primitive Web Service
===========================

Now we know enough about HTTP to set up a primitive web service that
just says '"Hello, world"' when someone connects to it with a browser.
Compared to the situation in the preceding node, our program changes the
role.  It tries to behave just like the server we have observed.  Since
we are setting up a server here, we have to insert the port number in
the 'localport' field of the special file name.  The other two fields
(HOSTNAME and REMOTEPORT) have to contain a '0' because we do not know
in advance which host will connect to our service.

   In the early 1990s, all a server had to do was send an HTML document
and close the connection.  Here, we adhere to the modern syntax of HTTP.
The steps are as follows:

  1. Send a status line telling the web browser that everything is okay.

  2. Send a line to tell the browser how many bytes follow in the body
     of the message.  This was not necessary earlier because both
     parties knew that the document ended when the connection closed.
     Nowadays it is possible to stay connected after the transmission of
     one web page.  This avoids the network traffic necessary for
     repeatedly establishing TCP connections for requesting several
     images.  Thus, it is necessary to tell the receiving party how many
     bytes will be sent.  The header is terminated as usual with an
     empty line.

  3. Send the '"Hello, world"' body in HTML. The useless 'while' loop
     swallows the request of the browser.  We could actually omit the
     loop, and on most machines the program would still work.  First,
     start the following program:

     BEGIN {
       RS = ORS = "\r\n"
       HttpService = "/inet/tcp/8080/0/0"
       Hello = "<HTML><HEAD>" \
               "<TITLE>A Famous Greeting</TITLE></HEAD>" \
               "<BODY><H1>Hello, world</H1></BODY></HTML>"
       Len = length(Hello) + length(ORS)
       print "HTTP/1.0 200 OK"          |& HttpService
       print "Content-Length: " Len ORS |& HttpService
       print Hello                      |& HttpService
       while ((HttpService |& getline) > 0)
          continue;
       close(HttpService)
     }

   Now, on the same machine, start your favorite browser and let it
point to <http://localhost:8080> (the browser needs to know on which
port our server is listening for requests).  If this does not work, the
browser probably tries to connect to a proxy server that does not know
your machine.  If so, change the browser's configuration so that the
browser does not try to use a proxy to connect to your machine.


File: gawkinet.info,  Node: Interacting Service,  Next: Simple Server,  Prev: Primitive Service,  Up: Using Networking

2.9 A Web Service with Interaction
==================================

This node shows how to set up a simple web server.  The subnode is a
library file that we will use with all the examples in *note Some
Applications and Techniques::.

* Menu:

* CGI Lib::                     A simple CGI library.

   Setting up a web service that allows user interaction is more
difficult and shows us the limits of network access in 'gawk'.  In this
node, we develop a main program (a 'BEGIN' pattern and its action) that
will become the core of event-driven execution controlled by a graphical
user interface (GUI). Each HTTP event that the user triggers by some
action within the browser is received in this central procedure.
Parameters and menu choices are extracted from this request, and an
appropriate measure is taken according to the user's choice:

     BEGIN {
       if (MyHost == "") {
          "uname -n" | getline MyHost
          close("uname -n")
       }
       if (MyPort ==  0) MyPort = 8080
       HttpService = "/inet/tcp/" MyPort "/0/0"
       MyPrefix    = "http://" MyHost ":" MyPort
       SetUpServer()
       while ("awk" != "complex") {
         # header lines are terminated this way
         RS = ORS = "\r\n"
         Status   = 200          # this means OK
         Reason   = "OK"
         Header   = TopHeader
         Document = TopDoc
         Footer   = TopFooter
         if        (GETARG["Method"] == "GET") {
             HandleGET()
         } else if (GETARG["Method"] == "HEAD") {
             # not yet implemented
         } else if (GETARG["Method"] != "") {
             print "bad method", GETARG["Method"]
         }
         Prompt = Header Document Footer
         print "HTTP/1.0", Status, Reason       |& HttpService
         print "Connection: Close"              |& HttpService
         print "Pragma: no-cache"               |& HttpService
         len = length(Prompt) + length(ORS)
         print "Content-length:", len           |& HttpService
         print ORS Prompt                       |& HttpService
         # ignore all the header lines
         while ((HttpService |& getline) > 0)
             ;
         # stop talking to this client
         close(HttpService)
         # wait for new client request
         HttpService |& getline
         # do some logging
         print systime(), strftime(), $0
         # read request parameters
         CGI_setup($1, $2, $3)
       }
     }

   This web server presents menu choices in the form of HTML links.
Therefore, it has to tell the browser the name of the host it is
residing on.  When starting the server, the user may supply the name of
the host from the command line with 'gawk -v MyHost="Rumpelstilzchen"'.
If the user does not do this, the server looks up the name of the host
it is running on for later use as a web address in HTML documents.  The
same applies to the port number.  These values are inserted later into
the HTML content of the web pages to refer to the home system.

   Each server that is built around this core has to initialize some
application-dependent variables (such as the default home page) in a
function 'SetUpServer()', which is called immediately before entering
the infinite loop of the server.  For now, we will write an instance
that initiates a trivial interaction.  With this home page, the client
user can click on two possible choices, and receive the current date
either in human-readable format or in seconds since 1970:

     function SetUpServer() {
       TopHeader = "<HTML><HEAD>"
       TopHeader = TopHeader \
          "<title>My name is GAWK, GNU AWK</title></HEAD>"
       TopDoc    = "<BODY><h2>\
         Do you prefer your date <A HREF=" MyPrefix \
         "/human>human</A> or \
         <A HREF=" MyPrefix "/POSIX>POSIXed</A>?</h2>" ORS ORS
       TopFooter = "</BODY></HTML>"
     }

   On the first run through the main loop, the default line terminators
are set and the default home page is copied to the actual home page.
Since this is the first run, 'GETARG["Method"]' is not initialized yet,
hence the case selection over the method does nothing.  Now that the
home page is initialized, the server can start communicating to a client
browser.

   It does so by printing the HTTP header into the network connection
('print ... |& HttpService').  This command blocks execution of the
server script until a client connects.

   If you compare this server script with the primitive one we wrote
before, you will notice two additional lines in the header.  The first
instructs the browser to close the connection after each request.  The
second tells the browser that it should never try to _remember_ earlier
requests that had identical web addresses (no caching).  Otherwise, it
could happen that the browser retrieves the time of day in the previous
example just once, and later it takes the web page from the cache,
always displaying the same time of day although time advances each
second.

   Having supplied the initial home page to the browser with a valid
document stored in the parameter 'Prompt', it closes the connection and
waits for the next request.  When the request comes, a log line is
printed that allows us to see which request the server receives.  The
final step in the loop is to call the function 'CGI_setup()', which
reads all the lines of the request (coming from the browser), processes
them, and stores the transmitted parameters in the array 'PARAM'.  The
complete text of these application-independent functions can be found in
*note A Simple CGI Library: CGI Lib.  For now, we use a simplified
version of 'CGI_setup()':

     function CGI_setup(   method, uri, version, i) {
       delete GETARG;         delete MENU;        delete PARAM
       GETARG["Method"] = $1
       GETARG["URI"] = $2
       GETARG["Version"] = $3
       i = index($2, "?")
       # is there a "?" indicating a CGI request?
       if (i > 0) {
         split(substr($2, 1, i-1), MENU, "[/:]")
         split(substr($2, i+1), PARAM, "&")
         for (i in PARAM) {
           j = index(PARAM[i], "=")
           GETARG[substr(PARAM[i], 1, j-1)] = \
                                       substr(PARAM[i], j+1)
         }
       } else {    # there is no "?", no need for splitting PARAMs
         split($2, MENU, "[/:]")
       }
     }

   At first, the function clears all variables used for global storage
of request parameters.  The rest of the function serves the purpose of
filling the global parameters with the extracted new values.  To
accomplish this, the name of the requested resource is split into parts
and stored for later evaluation.  If the request contains a '?', then
the request has CGI variables seamlessly appended to the web address.
Everything in front of the '?' is split up into menu items, and
everything behind the '?' is a list of 'VARIABLE=VALUE' pairs (separated
by '&') that also need splitting.  This way, CGI variables are isolated
and stored.  This procedure lacks recognition of special characters that
are transmitted in coded form(1).  Here, any optional request header and
body parts are ignored.  We do not need header parameters and the
request body.  However, when refining our approach or working with the
'POST' and 'PUT' methods, reading the header and body becomes
inevitable.  Header parameters should then be stored in a global array
as well as the body.

   On each subsequent run through the main loop, one request from a
browser is received, evaluated, and answered according to the user's
choice.  This can be done by letting the value of the HTTP method guide
the main loop into execution of the procedure 'HandleGET()', which
evaluates the user's choice.  In this case, we have only one
hierarchical level of menus, but in the general case, menus are nested.
The menu choices at each level are separated by '/', just as in file
names.  Notice how simple it is to construct menus of arbitrary depth:

     function HandleGET() {
       if (       MENU[2] == "human") {
         Footer = strftime() TopFooter
       } else if (MENU[2] == "POSIX") {
         Footer = systime()  TopFooter
       }
     }

   The disadvantage of this approach is that our server is slow and can
handle only one request at a time.  Its main advantage, however, is that
the server consists of just one 'gawk' program.  No need for installing
an 'httpd', and no need for static separate HTML files, CGI scripts, or
'root' privileges.  This is rapid prototyping.  This program can be
started on the same host that runs your browser.  Then let your browser
point to <http://localhost:8080>.

   It is also possible to include images into the HTML pages.  Most
browsers support the not very well-known '.xbm' format, which may
contain only monochrome pictures but is an ASCII format.  Binary images
are possible but not so easy to handle.  Another way of including images
is to generate them with a tool such as GNUPlot, by calling the tool
with the 'system()' function or through a pipe.

   ---------- Footnotes ----------

   (1) As defined in RFC 2068.


File: gawkinet.info,  Node: CGI Lib,  Prev: Interacting Service,  Up: Interacting Service

2.9.1 A Simple CGI Library
--------------------------

     HTTP is like being married: you have to be able to handle whatever
     you're given, while being very careful what you send back.
                          -- _Phil Smith III,
         <http://www.netfunny.com/rhf/jokes/99/Mar/http.html>_

   In *note A Web Service with Interaction: Interacting Service, we saw
the function 'CGI_setup()' as part of the web server "core logic"
framework.  The code presented there handles almost everything necessary
for CGI requests.  One thing it doesn't do is handle encoded characters
in the requests.  For example, an '&' is encoded as a percent sign
followed by the hexadecimal value: '%26'.  These encoded values should
be decoded.  Following is a simple library to perform these tasks.  This
code is used for all web server examples throughout the rest of this
Info file.  If you want to use it for your own web server, store the
source code into a file named 'inetlib.awk'.  Then you can include these
functions into your code by placing the following statement into your
program (on the first line of your script):

     @include inetlib.awk

But beware, this mechanism is only possible if you invoke your web
server script with 'igawk' instead of the usual 'awk' or 'gawk'.  Here
is the code:

     # CGI Library and core of a web server
     # Global arrays
     #   GETARG --- arguments to CGI GET command
     #   MENU   --- menu items (path names)
     #   PARAM  --- parameters of form x=y

     # Optional variable MyHost contains host address
     # Optional variable MyPort contains port number
     # Needs TopHeader, TopDoc, TopFooter
     # Sets MyPrefix, HttpService, Status, Reason

     BEGIN {
       if (MyHost == "") {
          "uname -n" | getline MyHost
          close("uname -n")
       }
       if (MyPort ==  0) MyPort = 8080
       HttpService = "/inet/tcp/" MyPort "/0/0"
       MyPrefix    = "http://" MyHost ":" MyPort
       SetUpServer()
       while ("awk" != "complex") {
         # header lines are terminated this way
         RS = ORS    = "\r\n"
         Status      = 200             # this means OK
         Reason      = "OK"
         Header      = TopHeader
         Document    = TopDoc
         Footer      = TopFooter
         if        (GETARG["Method"] == "GET") {
             HandleGET()
         } else if (GETARG["Method"] == "HEAD") {
             # not yet implemented
         } else if (GETARG["Method"] != "") {
             print "bad method", GETARG["Method"]
         }
         Prompt = Header Document Footer
         print "HTTP/1.0", Status, Reason     |& HttpService
         print "Connection: Close"            |& HttpService
         print "Pragma: no-cache"             |& HttpService
         len = length(Prompt) + length(ORS)
         print "Content-length:", len         |& HttpService
         print ORS Prompt                     |& HttpService
         # ignore all the header lines
         while ((HttpService |& getline) > 0)
             continue
         # stop talking to this client
         close(HttpService)
         # wait for new client request
         HttpService |& getline
         # do some logging
         print systime(), strftime(), $0
         CGI_setup($1, $2, $3)
       }
     }

     function CGI_setup(method, uri, version,    i)
     {
         delete GETARG
         delete MENU
         delete PARAM
         GETARG["Method"] = method
         GETARG["URI"] = uri
         GETARG["Version"] = version

         i = index(uri, "?")
         if (i > 0) {  # is there a "?" indicating a CGI request?
             split(substr(uri, 1, i-1), MENU, "[/:]")
             split(substr(uri, i+1), PARAM, "&")
             for (i in PARAM) {
                 PARAM[i] = _CGI_decode(PARAM[i])
                 j = index(PARAM[i], "=")
                 GETARG[substr(PARAM[i], 1, j-1)] = \
                                              substr(PARAM[i], j+1)
             }
         } else { # there is no "?", no need for splitting PARAMs
             split(uri, MENU, "[/:]")
         }
         for (i in MENU)     # decode characters in path
             if (i > 4)      # but not those in host name
                 MENU[i] = _CGI_decode(MENU[i])
     }

   This isolates details in a single function, 'CGI_setup()'.  Decoding
of encoded characters is pushed off to a helper function,
'_CGI_decode()'.  The use of the leading underscore ('_') in the
function name is intended to indicate that it is an "internal" function,
although there is nothing to enforce this:

     function _CGI_decode(str,   hexdigs, i, pre, code1, code2,
                                 val, result)
     {
        hexdigs = "123456789abcdef"

        i = index(str, "%")
        if (i == 0) # no work to do
           return str

        do {
           pre = substr(str, 1, i-1)   # part before %xx
           code1 = substr(str, i+1, 1) # first hex digit
           code2 = substr(str, i+2, 1) # second hex digit
           str = substr(str, i+3)      # rest of string

           code1 = tolower(code1)
           code2 = tolower(code2)
           val = index(hexdigs, code1) * 16 \
                 + index(hexdigs, code2)

           result = result pre sprintf("%c", val)
           i = index(str, "%")
        } while (i != 0)
        if (length(str) > 0)
           result = result str
        return result
     }

   This works by splitting the string apart around an encoded character.
The two digits are converted to lowercase characters and looked up in a
string of hex digits.  Note that '0' is not in the string on purpose;
'index()' returns zero when it's not found, automatically giving the
correct value!  Once the hexadecimal value is converted from characters
in a string into a numerical value, 'sprintf()' converts the value back
into a real character.  The following is a simple test harness for the
above functions:

     BEGIN {
       CGI_setup("GET",
       "http://www.gnu.org/cgi-bin/foo?p1=stuff&p2=stuff%26junk" \
            "&percent=a %25 sign",
       "1.0")
       for (i in MENU)
           printf "MENU[\"%s\"] = %s\n", i, MENU[i]
       for (i in PARAM)
           printf "PARAM[\"%s\"] = %s\n", i, PARAM[i]
       for (i in GETARG)
           printf "GETARG[\"%s\"] = %s\n", i, GETARG[i]
     }

   And this is the result when we run it:

     $ gawk -f testserv.awk
     -| MENU["4"] = www.gnu.org
     -| MENU["5"] = cgi-bin
     -| MENU["6"] = foo
     -| MENU["1"] = http
     -| MENU["2"] =
     -| MENU["3"] =
     -| PARAM["1"] = p1=stuff
     -| PARAM["2"] = p2=stuff&junk
     -| PARAM["3"] = percent=a % sign
     -| GETARG["p1"] = stuff
     -| GETARG["percent"] = a % sign
     -| GETARG["p2"] = stuff&junk
     -| GETARG["Method"] = GET
     -| GETARG["Version"] = 1.0
     -| GETARG["URI"] = http://www.gnu.org/cgi-bin/foo?p1=stuff&
     p2=stuff%26junk&percent=a %25 sign


File: gawkinet.info,  Node: Simple Server,  Next: Caveats,  Prev: Interacting Service,  Up: Using Networking

2.10 A Simple Web Server
========================

In the preceding node, we built the core logic for event-driven GUIs.
In this node, we finally extend the core to a real application.  No one
would actually write a commercial web server in 'gawk', but it is
instructive to see that it is feasible in principle.

   The application is ELIZA, the famous program by Joseph Weizenbaum
that mimics the behavior of a professional psychotherapist when talking
to you.  Weizenbaum would certainly object to this description, but this
is part of the legend around ELIZA. Take the site-independent core logic
and append the following code:

     function SetUpServer() {
       SetUpEliza()
       TopHeader = \
         "<HTML><title>An HTTP-based System with GAWK</title>\
         <HEAD><META HTTP-EQUIV=\"Content-Type\"\
         CONTENT=\"text/html; charset=iso-8859-1\"></HEAD>\
         <BODY BGCOLOR=\"#ffffff\" TEXT=\"#000000\"\
         LINK=\"#0000ff\" VLINK=\"#0000ff\"\
         ALINK=\"#0000ff\"> <A NAME=\"top\">"
       TopDoc    = "\
        <h2>Please choose one of the following actions:</h2>\
        <UL>\
        <LI>\
        <A HREF=" MyPrefix "/AboutServer>About this server</A>\
        </LI><LI>\
        <A HREF=" MyPrefix "/AboutELIZA>About Eliza</A></LI>\
        <LI>\
        <A HREF=" MyPrefix \
           "/StartELIZA>Start talking to Eliza</A></LI></UL>"
       TopFooter = "</BODY></HTML>"
     }

   'SetUpServer()' is similar to the previous example, except for
calling another function, 'SetUpEliza()'.  This approach can be used to
implement other kinds of servers.  The only changes needed to do so are
hidden in the functions 'SetUpServer()' and 'HandleGET()'.  Perhaps it
might be necessary to implement other HTTP methods.  The 'igawk' program
that comes with 'gawk' may be useful for this process.

   When extending this example to a complete application, the first
thing to do is to implement the function 'SetUpServer()' to initialize
the HTML pages and some variables.  These initializations determine the
way your HTML pages look (colors, titles, menu items, etc.).

   The function 'HandleGET()' is a nested case selection that decides
which page the user wants to see next.  Each nesting level refers to a
menu level of the GUI. Each case implements a certain action of the
menu.  At the deepest level of case selection, the handler essentially
knows what the user wants and stores the answer into the variable that
holds the HTML page contents:

     function HandleGET() {
       # A real HTTP server would treat some parts of the URI as a file name.
       # We take parts of the URI as menu choices and go on accordingly.
       if (MENU[2] == "AboutServer") {
         Document    = "This is not a CGI script.\
           This is an httpd, an HTML file, and a CGI script all \
           in one GAWK script. It needs no separate www-server, \
           no installation, and no root privileges.\
           <p>To run it, do this:</p><ul>\
           <li> start this script with \"gawk -f httpserver.awk\",</li>\
           <li> and on the same host let your www browser open location\
                \"http://localhost:8080\"</li>\
           </ul>\<p>\ Details of HTTP come from:</p><ul>\
                 <li>Hethmon:  Illustrated Guide to HTTP</p>\
                 <li>RFC 2068</li></ul><p>JK 14.9.1997</p>"
       } else if (MENU[2] == "AboutELIZA") {
         Document    = "This is an implementation of the famous ELIZA\
             program by Joseph Weizenbaum. It is written in GAWK and\
             uses an HTML GUI."
       } else if (MENU[2] == "StartELIZA") {
         gsub(/\+/, " ", GETARG["YouSay"])
         # Here we also have to substitute coded special characters
         Document    = "<form method=GET>" \
           "<h3>" ElizaSays(GETARG["YouSay"]) "</h3>\
           <p><input type=text name=YouSay value=\"\" size=60>\
           <br><input type=submit value=\"Tell her about it\"></p></form>"
       }
     }

   Now we are down to the heart of ELIZA, so you can see how it works.
Initially the user does not say anything; then ELIZA resets its money
counter and asks the user to tell what comes to mind open-heartedly.
The subsequent answers are converted to uppercase characters and stored
for later comparison.  ELIZA presents the bill when being confronted
with a sentence that contains the phrase "shut up."  Otherwise, it looks
for keywords in the sentence, conjugates the rest of the sentence,
remembers the keyword for later use, and finally selects an answer from
the set of possible answers:

     function ElizaSays(YouSay) {
       if (YouSay == "") {
         cost = 0
         answer = "HI, IM ELIZA, TELL ME YOUR PROBLEM"
       } else {
         q = toupper(YouSay)
         gsub("'", "", q)
         if (q == qold) {
           answer = "PLEASE DONT REPEAT YOURSELF !"
         } else {
           if (index(q, "SHUT UP") > 0) {
             answer = "WELL, PLEASE PAY YOUR BILL. ITS EXACTLY ... $"\
                      int(100*rand()+30+cost/100)
           } else {
             qold = q
             w = "-"                 # no keyword recognized yet
             for (i in k) {          # search for keywords
               if (index(q, i) > 0) {
                 w = i
                 break
               }
             }
             if (w == "-") {         # no keyword, take old subject
               w    = wold
               subj = subjold
             } else {                # find subject
               subj = substr(q, index(q, w) + length(w)+1)
               wold = w
               subjold = subj        #  remember keyword and subject
             }
             for (i in conj)
                gsub(i, conj[i], q)   # conjugation
             # from all answers to this keyword, select one randomly
             answer = r[indices[int(split(k[w], indices) * rand()) + 1]]
             # insert subject into answer
             gsub("_", subj, answer)
           }
         }
       }
       cost += length(answer) # for later payment : 1 cent per character
       return answer
     }

   In the long but simple function 'SetUpEliza()', you can see tables
for conjugation, keywords, and answers.(1)  The associative array 'k'
contains indices into the array of answers 'r'.  To choose an answer,
ELIZA just picks an index randomly:

     function SetUpEliza() {
       srand()
       wold = "-"
       subjold = " "

       # table for conjugation
       conj[" ARE "     ] = " AM "
       conj["WERE "     ] = "WAS "
       conj[" YOU "     ] = " I "
       conj["YOUR "     ] = "MY "
       conj[" IVE "     ] =\
       conj[" I HAVE "  ] = " YOU HAVE "
       conj[" YOUVE "   ] =\
       conj[" YOU HAVE "] = " I HAVE "
       conj[" IM "      ] =\
       conj[" I AM "    ] = " YOU ARE "
       conj[" YOURE "   ] =\
       conj[" YOU ARE " ] = " I AM "

       # table of all answers
       r[1]   = "DONT YOU BELIEVE THAT I CAN  _"
       r[2]   = "PERHAPS YOU WOULD LIKE TO BE ABLE TO _ ?"
       ...

       # table for looking up answers that
       # fit to a certain keyword
       k["CAN YOU"]      = "1 2 3"
       k["CAN I"]        = "4 5"
       k["YOU ARE"]      =\
       k["YOURE"]        = "6 7 8 9"
       ...
     }

   Some interesting remarks and details (including the original source
code of ELIZA) are found on Mark Humphrys's home page 'How my program
passed the Turing Test' (https://computing.dcu.ie/~humphrys/eliza.html).
Wikipedia provides much background information about ELIZA
(https://en.wikipedia.org/wiki/ELIZA), including the original design of
the software and its early implementations.

   ---------- Footnotes ----------

   (1) The version shown here is abbreviated.  The full version comes
with the 'gawk' distribution.


File: gawkinet.info,  Node: Caveats,  Next: Challenges,  Prev: Simple Server,  Up: Using Networking

2.11 Network Programming Caveats
================================

By now it should be clear that debugging a networked application is more
complicated than debugging a single-process single-hosted application.
The behavior of a networked application sometimes looks noncausal
because it is not reproducible in a strong sense.  Whether a network
application works or not sometimes depends on the following:

   * How crowded the underlying network is

   * If the party at the other end is running or not

   * The state of the party at the other end

   The most difficult problems for a beginner arise from the hidden
states of the underlying network.  After closing a TCP connection, it's
often necessary to wait a short while before reopening the connection.
Even more difficult is the establishment of a connection that previously
ended with a "broken pipe."  Those connections have to "time out" for a
minute or so before they can reopen.  Check this with the command
'netstat -a', which provides a list of still-active connections.


File: gawkinet.info,  Node: Challenges,  Prev: Caveats,  Up: Using Networking

2.12 Where To Go From Here
==========================

Now, you have learned enough to build your own application.  You could,
for example, take part in the Loebner Contest to win $100,000.  The
Loebner Prize is the first formal instantiation of a Turing Test.  Hugh
Loebner agreed with The Cambridge Center for Behavioral Studies to
underwrite a contest designed to implement the Turing Test.  Dr. Loebner
pledged a Grand Prize of $100,000 for the first computer whose responses
were indistinguishable from a human's.  Each year an annual prize of
$2000 and a bronze medal is awarded to the _most_ human computer.  The
winner of the annual contest is the best entry relative to other entries
that year, irrespective of how good it is in an absolute sense.  Here is
an example of a conversation with the winning program of 1997:

     (c)1997 Cambridge Center For Behavioral Studies all rights reserved [CONVERSE]
     [Intelligent Research Ltd.] Start at: [1997/04/29 08:59:40]
     PROGRAM[10:39:20]Hi, my name is Catherine, what's yours?
     JUDGE02[10:39:36]My name is Nathan.
     PROGRAM[10:39:37]Well, it's nice to meet you, Nathan.
     PROGRAM[10:39:45]Did you see that story on CNN last night about the lesbian
     PROGRAM[10:40:03]couple who came out at a White House party on Sunday?
     JUDGE02[10:40:45]No.  I'm sorry I missed that.  How did the Prez take it?
     PROGRAM[10:40:47]Ellen Degeneres was one of them - she was kissing her lover
     PROGRAM[10:41:08]in front of Bill Clinton. Do you think he was very
     PROGRAM[10:41:21]embarrassed?
     JUDGE02[10:41:37]You tell me.  I didn't see it.
     PROGRAM[10:41:38]Are you still a Friend of Bill Clinton?
     JUDGE02[10:42:22]Yes.  I would like to talk about something else.  Do you know anything about sculpture.
     PROGRAM[10:42:24]Well, I suppose he's doing his best like most of us, but he
     PROGRAM[10:42:35]does seem to attract an UNUSUAL amount of bad publicity,
     PROGRAM[10:42:51]wouldnt you say--can it all be bad luck?
     JUDGE02[10:43:20]I asked you if you knew anything about sculpture.
     PROGRAM[10:43:21]OK, but what happens now--does it all drift on, with
     PROGRAM[10:43:36]everyone waiting to see how much his friends have said about
     PROGRAM[10:43:47]him under threat of lots and lots of jail-or will something
     PROGRAM[10:44:01]dramatic actually happen?
     JUDGE02[10:44:19]Do you know what sculpture is?
     PROGRAM[10:44:20]Well, youre more a fan of his than I am I guess---though I
     PROGRAM[10:44:34]cant SWEAR what Id have done in that locked hotel room, I
     PROGRAM[10:44:51]must say.
     JUDGE02[10:45:26]Have you ever been to the Salmagundi Club?
     PROGRAM[10:45:29]Never. to go back to the original discussion Time to get
     PROGRAM[10:45:43]off this one I think and onto something more down to earth!
     JUDGE02[10:46:20]What is more down to earth than art?
     PROGRAM[10:46:21]I don't know what -- to be honest. -
     PROGRAM[10:46:30]I suppose it depends on where you're coming from, but as the
     PROGRAM[10:46:46]song goes in My Fair Lady, "Why can't a woman be more like a
     PROGRAM[10:47:03]man? "
     JUDGE02[10:47:52]I liked that song but I prefer "Why can't children be more like we are"
     JUDGE02[10:48:10]from another play the name of which I cannot remember.
     PROGRAM[10:48:12]What, if anything, do you enjoy about being a man?
     JUDGE02[10:49:01]I would enjoy all aspects of life no matter what my gender.
     PROGRAM[10:49:02]Do you think of yourself as being attractive?

   This program insists on always speaking about the same story around
Bill Clinton.  You see, even a program with a rather narrow mind can
behave so much like a human being that it can win this prize.  It is
quite common to let these programs talk to each other via network
connections.  But during the competition itself, the program and its
computer have to be present at the place the competition is held.  We
all would love to see a 'gawk' program win in such an event.  Maybe it
is up to you to accomplish this?

   Some other ideas for useful networked applications:
   * Read the file 'doc/awkforai.txt' in earlier 'gawk'
     distributions.(1)  It was written by Ronald P. Loui (at the time,
     Associate Professor of Computer Science, at Washington University
     in St.  Louis, <loui@ai.wustl.edu>) and summarizes why he taught
     'gawk' to students of Artificial Intelligence.  Here are some
     passages from the text:

          The GAWK manual can be consumed in a single lab session and
          the language can be mastered by the next morning by the
          average student.  GAWK's automatic initialization, implicit
          coercion, I/O support and lack of pointers forgive many of the
          mistakes that young programmers are likely to make.  Those who
          have seen C but not mastered it are happy to see that GAWK
          retains some of the same sensibilities while adding what must
          be regarded as spoonsful of syntactic sugar.
          ...
          There are further simple answers.  Probably the best is the
          fact that increasingly, undergraduate AI programming is
          involving the Web.  Oren Etzioni (University of Washington,
          Seattle) has for a while been arguing that the "softbot" is
          replacing the mechanical engineers' robot as the most
          glamorous AI testbed.  If the artifact whose behavior needs to
          be controlled in an intelligent way is the software agent,
          then a language that is well-suited to controlling the
          software environment is the appropriate language.  That would
          imply a scripting language.  If the robot is KAREL, then the
          right language is "turn left; turn right."  If the robot is
          Netscape, then the right language is something that can
          generate 'netscape -remote
          'openURL(http://cs.wustl.edu/~loui)'' with elan.
          ...
          AI programming requires high-level thinking.  There have
          always been a few gifted programmers who can write high-level
          programs in assembly language.  Most however need the ambient
          abstraction to have a higher floor.
          ...
          Second, inference is merely the expansion of notation.  No
          matter whether the logic that underlies an AI program is
          fuzzy, probabilistic, deontic, defeasible, or deductive, the
          logic merely defines how strings can be transformed into other
          strings.  A language that provides the best support for string
          processing in the end provides the best support for logic, for
          the exploration of various logics, and for most forms of
          symbolic processing that AI might choose to call "reasoning"
          instead of "logic."  The implication is that PROLOG, which
          saves the AI programmer from having to write a unifier, saves
          perhaps two dozen lines of GAWK code at the expense of
          strongly biasing the logic and representational expressiveness
          of any approach.

     Now that 'gawk' itself can connect to the Internet, it should be
     obvious that it is suitable for writing intelligent web agents.

   * 'awk' is strong at pattern recognition and string processing.  So,
     it is well suited to the classic problem of language translation.
     A first try could be a program that knows the 100 most frequent
     English words and their counterparts in German or French.  The
     service could be implemented by regularly reading email with the
     program above, replacing each word by its translation and sending
     the translation back via SMTP. Users would send English email to
     their translation service and get back a translated email message
     in return.  As soon as this works, more effort can be spent on a
     real translation program.

   * Another dialogue-oriented application (on the verge of ridicule) is
     the email "support service."  Troubled customers write an email to
     an automatic 'gawk' service that reads the email.  It looks for
     keywords in the mail and assembles a reply email accordingly.  By
     carefully investigating the email header, and repeating these
     keywords through the reply email, it is rather simple to give the
     customer a feeling that someone cares.  Ideally, such a service
     would search a database of previous cases for solutions.  If none
     exists, the database could, for example, consist of all the
     newsgroups, mailing lists and FAQs on the Internet.

   ---------- Footnotes ----------

   (1) The file is no longer distributed with 'gawk', since the
copyright on the file is not clear.


File: gawkinet.info,  Node: Some Applications and Techniques,  Next: Links,  Prev: Using Networking,  Up: Top

3 Some Applications and Techniques
**********************************

In this major node, we look at a number of self-contained scripts, with
an emphasis on concise networking.  Along the way, we work towards
creating building blocks that encapsulate often-needed functions of the
networking world, show new techniques that broaden the scope of problems
that can be solved with 'gawk', and explore leading edge technology that
may shape the future of networking.

   We often refer to the site-independent core of the server that we
built in *note A Simple Web Server: Simple Server.  When building new
and nontrivial servers, we always copy this building block and append
new instances of the two functions 'SetUpServer()' and 'HandleGET()'.

   This makes a lot of sense, since this scheme of event-driven
execution provides 'gawk' with an interface to the most widely accepted
standard for GUIs: the web browser.  Now, 'gawk' can rival even Tcl/Tk.

   Tcl and 'gawk' have much in common.  Both are simple scripting
languages that allow us to quickly solve problems with short programs.
But Tcl has Tk on top of it, and 'gawk' had nothing comparable up to
now.  While Tcl needs a large and ever-changing library (Tk, which was
originally bound to the X Window System), 'gawk' needs just the
networking interface and some kind of browser on the client's side.
Besides better portability, the most important advantage of this
approach (embracing well-established standards such HTTP and HTML) is
that _we do not need to change the language_.  We let others do the work
of fighting over protocols and standards.  We can use HTML, JavaScript,
VRML, or whatever else comes along to do our work.

* Menu:

* PANIC::                       An Emergency Web Server.
* GETURL::                      Retrieving Web Pages.
* REMCONF::                     Remote Configuration Of Embedded Systems.
* URLCHK::                      Look For Changed Web Pages.
* WEBGRAB::                     Extract Links From A Page.
* STATIST::                     Graphing A Statistical Distribution.
* MAZE::                        Walking Through A Maze In Virtual Reality.
* MOBAGWHO::                    A Simple Mobile Agent.
* STOXPRED::                    Stock Market Prediction As A Service.
* PROTBASE::                    Searching Through A Protein Database.


File: gawkinet.info,  Node: PANIC,  Next: GETURL,  Prev: Some Applications and Techniques,  Up: Some Applications and Techniques

3.1 PANIC: An Emergency Web Server
==================================

At first glance, the '"Hello, world"' example in *note A Primitive Web
Service: Primitive Service, seems useless.  By adding just a few lines,
we can turn it into something useful.

   The PANIC program tells everyone who connects that the local site is
not working.  When a web server breaks down, it makes a difference if
customers get a strange "network unreachable" message, or a short
message telling them that the server has a problem.  In such an
emergency, the hard disk and everything on it (including the regular web
service) may be unavailable.  Rebooting the web server off a USB drive
makes sense in this setting.

   To use the PANIC program as an emergency web server, all you need are
the 'gawk' executable and the program below on a USB drive.  By default,
it connects to port 8080.  A different value may be supplied on the
command line:

     BEGIN {
       RS = ORS = "\r\n"
       if (MyPort ==  0) MyPort = 8080
       HttpService = "/inet/tcp/" MyPort "/0/0"
       Hello = "<HTML><HEAD><TITLE>Out Of Service</TITLE>" \
          "</HEAD><BODY><H1>" \
          "This site is temporarily out of service." \
          "</H1></BODY></HTML>"
       Len = length(Hello) + length(ORS)
       while ("awk" != "complex") {
         print "HTTP/1.0 200 OK"          |& HttpService
         print "Content-Length: " Len ORS |& HttpService
         print Hello                      |& HttpService
         while ((HttpService |& getline) > 0)
            continue;
         close(HttpService)
       }
     }


File: gawkinet.info,  Node: GETURL,  Next: REMCONF,  Prev: PANIC,  Up: Some Applications and Techniques

3.2 GETURL: Retrieving Web Pages
================================

GETURL is a versatile building block for shell scripts that need to
retrieve files from the Internet.  It takes a web address as a
command-line parameter and tries to retrieve the contents of this
address.  The contents are printed to standard output, while the header
is printed to '/dev/stderr'.  A surrounding shell script could analyze
the contents and extract the text or the links.  An ASCII browser could
be written around GETURL. But more interestingly, web robots are
straightforward to write on top of GETURL. On the Internet, you can find
several programs of the same name that do the same job.  They are
usually much more complex internally and at least 10 times as big.

   At first, GETURL checks if it was called with exactly one web
address.  Then, it checks if the user chose to use a special proxy
server whose name is handed over in a variable.  By default, it is
assumed that the local machine serves as proxy.  GETURL uses the 'GET'
method by default to access the web page.  By handing over the name of a
different method (such as 'HEAD'), it is possible to choose a different
behavior.  With the 'HEAD' method, the user does not receive the body of
the page content, but does receive the header:

     BEGIN {
       if (ARGC != 2) {
         print "GETURL - retrieve Web page via HTTP 1.0"
         print "IN:\n    the URL as a command-line parameter"
         print "PARAM(S):\n    -v Proxy=MyProxy"
         print "OUT:\n    the page content on stdout"
         print "    the page header on stderr"
         print "JK 16.05.1997"
         print "ADR 13.08.2000"
         exit
       }
       URL = ARGV[1]; ARGV[1] = ""
       if (Proxy     == "")  Proxy     = "127.0.0.1"
       if (ProxyPort ==  0)  ProxyPort = 80
       if (Method    == "")  Method    = "GET"
       HttpService = "/inet/tcp/0/" Proxy "/" ProxyPort
       ORS = RS = "\r\n\r\n"
       print Method " " URL " HTTP/1.0" |& HttpService
       HttpService                      |& getline Header
       print Header > "/dev/stderr"
       while ((HttpService |& getline) > 0)
         printf "%s", $0
       close(HttpService)
     }

   This program can be changed as needed, but be careful with the last
lines.  Make sure transmission of binary data is not corrupted by
additional line breaks.  Even as it is now, the byte sequence
'"\r\n\r\n"' would disappear if it were contained in binary data.  Don't
get caught in a trap when trying a quick fix on this one.


File: gawkinet.info,  Node: REMCONF,  Next: URLCHK,  Prev: GETURL,  Up: Some Applications and Techniques

3.3 REMCONF: Remote Configuration of Embedded Systems
=====================================================

Today, you often find powerful processors in embedded systems.
Dedicated network routers and controllers for all kinds of machinery are
examples of embedded systems.  Processors like the Intel 80x86 or the
AMD Elan are able to run multitasking operating systems, such as XINU or
GNU/Linux in embedded PCs.  These systems are small and usually do not
have a keyboard or a display.  Therefore it is difficult to set up their
configuration.  There are several widespread ways to set them up:

   * DIP switches

   * Read Only Memories such as EPROMs

   * Serial lines or some kind of keyboard

   * Network connections via 'telnet' or SNMP

   * HTTP connections with HTML GUIs

   In this node, we look at a solution that uses HTTP connections to
control variables of an embedded system that are stored in a file.
Since embedded systems have tight limits on resources like memory, it is
difficult to employ advanced techniques such as SNMP and HTTP servers.
'gawk' fits in quite nicely with its single executable which needs just
a short script to start working.  The following program stores the
variables in a file, and a concurrent process in the embedded system may
read the file.  The program uses the site-independent part of the simple
web server that we developed in *note A Web Service with Interaction:
Interacting Service.  As mentioned there, all we have to do is to write
two new procedures 'SetUpServer()' and 'HandleGET()':

     function SetUpServer() {
       TopHeader = "<HTML><title>Remote Configuration</title>"
       TopDoc = "<BODY>\
         <h2>Please choose one of the following actions:</h2>\
         <UL>\
           <LI><A HREF=" MyPrefix "/AboutServer>About this server</A></LI>\
           <LI><A HREF=" MyPrefix "/ReadConfig>Read Configuration</A></LI>\
           <LI><A HREF=" MyPrefix "/CheckConfig>Check Configuration</A></LI>\
           <LI><A HREF=" MyPrefix "/ChangeConfig>Change Configuration</A></LI>\
           <LI><A HREF=" MyPrefix "/SaveConfig>Save Configuration</A></LI>\
         </UL>"
       TopFooter  = "</BODY></HTML>"
       if (ConfigFile == "") ConfigFile = "config.asc"
     }

   The function 'SetUpServer()' initializes the top level HTML texts as
usual.  It also initializes the name of the file that contains the
configuration parameters and their values.  In case the user supplies a
name from the command line, that name is used.  The file is expected to
contain one parameter per line, with the name of the parameter in column
one and the value in column two.

   The function 'HandleGET()' reflects the structure of the menu tree as
usual.  The first menu choice tells the user what this is all about.
The second choice reads the configuration file line by line and stores
the parameters and their values.  Notice that the record separator for
this file is '"\n"', in contrast to the record separator for HTTP. The
third menu choice builds an HTML table to show the contents of the
configuration file just read.  The fourth choice does the real work of
changing parameters, and the last one just saves the configuration into
a file:

     function HandleGET() {
       if (MENU[2] == "AboutServer") {
         Document  = "This is a GUI for remote configuration of an\
           embedded system. It is is implemented as one GAWK script."
       } else if (MENU[2] == "ReadConfig") {
         RS = "\n"
         while ((getline < ConfigFile) > 0)
            config[$1] = $2;
         close(ConfigFile)
         RS = "\r\n"
         Document = "Configuration has been read."
       } else if (MENU[2] == "CheckConfig") {
         Document = "<TABLE BORDER=1 CELLPADDING=5>"
         for (i in config)
           Document = Document "<TR><TD>" i "</TD>" \
             "<TD>" config[i] "</TD></TR>"
         Document = Document "</TABLE>"
       } else if (MENU[2] == "ChangeConfig") {
         if ("Param" in GETARG) {            # any parameter to set?
           if (GETARG["Param"] in config) {  # is  parameter valid?
             config[GETARG["Param"]] = GETARG["Value"]
             Document = (GETARG["Param"] " = " GETARG["Value"] ".")
           } else {
             Document = "Parameter <b>" GETARG["Param"] "</b> is invalid."
           }
         } else {
           Document = "<FORM method=GET><h4>Change one parameter</h4>\
             <TABLE BORDER CELLPADDING=5>\
             <TR><TD>Parameter</TD><TD>Value</TD></TR>\
             <TR><TD><input type=text name=Param value=\"\" size=20></TD>\
                 <TD><input type=text name=Value value=\"\" size=40></TD>\
             </TR></TABLE><input type=submit value=\"Set\"></FORM>"
         }
       } else if (MENU[2] == "SaveConfig") {
         for (i in config)
           printf("%s %s\n", i, config[i]) > ConfigFile
         close(ConfigFile)
         Document = "Configuration has been saved."
       }
     }

   We could also view the configuration file as a database.  From this
point of view, the previous program acts like a primitive database
server.  Real SQL database systems also make a service available by
providing a TCP port that clients can connect to.  But the application
level protocols they use are usually proprietary and also change from
time to time.  This is also true for the protocol that MiniSQL uses.


File: gawkinet.info,  Node: URLCHK,  Next: WEBGRAB,  Prev: REMCONF,  Up: Some Applications and Techniques

3.4 URLCHK: Look for Changed Web Pages
======================================

Most people who make heavy use of Internet resources have a large
bookmark file with pointers to interesting web sites.  It is impossible
to regularly check by hand if any of these sites have changed.  A
program is needed to automatically look at the headers of web pages and
tell which ones have changed.  URLCHK does the comparison after using
GETURL with the 'HEAD' method to retrieve the header.

   Like GETURL, this program first checks that it is called with exactly
one command-line parameter.  URLCHK also takes the same command-line
variables 'Proxy' and 'ProxyPort' as GETURL, because these variables are
handed over to GETURL for each URL that gets checked.  The one and only
parameter is the name of a file that contains one line for each URL. In
the first column, we find the URL, and the second and third columns hold
the length of the URL's body when checked for the two last times.  Now,
we follow this plan:

  1. Read the URLs from the file and remember their most recent lengths

  2. Delete the contents of the file

  3. For each URL, check its new length and write it into the file

  4. If the most recent and the new length differ, tell the user

   It may seem a bit peculiar to read the URLs from a file together with
their two most recent lengths, but this approach has several advantages.
You can call the program again and again with the same file.  After
running the program, you can regenerate the changed URLs by extracting
those lines that differ in their second and third columns:

     BEGIN {
       if (ARGC != 2) {
         print "URLCHK - check if URLs have changed"
         print "IN:\n    the file with URLs as a command-line parameter"
         print "    file contains URL, old length, new length"
         print "PARAMS:\n    -v Proxy=MyProxy -v ProxyPort=8080"
         print "OUT:\n    same as file with URLs"
         print "JK 02.03.1998"
         exit
       }
       URLfile = ARGV[1]; ARGV[1] = ""
       if (Proxy     != "") Proxy     = " -v Proxy="     Proxy
       if (ProxyPort != "") ProxyPort = " -v ProxyPort=" ProxyPort
       while ((getline < URLfile) > 0)
          Length[$1] = $3 + 0
       close(URLfile)      # now, URLfile is read in and can be updated
       GetHeader = "gawk " Proxy ProxyPort " -v Method=\"HEAD\" -f geturl.awk "
       for (i in Length) {
         GetThisHeader = GetHeader i " 2>&1"
         while ((GetThisHeader | getline) > 0)
           if (toupper($0) ~ /CONTENT-LENGTH/) NewLength = $2 + 0
         close(GetThisHeader)
         print i, Length[i], NewLength > URLfile
         if (Length[i] != NewLength)  # report only changed URLs
           print i, Length[i], NewLength
       }
       close(URLfile)
     }

   Another thing that may look strange is the way GETURL is called.
Before calling GETURL, we have to check if the proxy variables need to
be passed on.  If so, we prepare strings that will become part of the
command line later.  In 'GetHeader', we store these strings together
with the longest part of the command line.  Later, in the loop over the
URLs, 'GetHeader' is appended with the URL and a redirection operator to
form the command that reads the URL's header over the Internet.  GETURL
always sends the headers to '/dev/stderr'.  That is the reason why we
need the redirection operator to have the header piped in.

   This program is not perfect because it assumes that changing URLs
results in changed lengths, which is not necessarily true.  A more
advanced approach is to look at some other header line that holds time
information.  But, as always when things get a bit more complicated,
this is left as an exercise to the reader.


File: gawkinet.info,  Node: WEBGRAB,  Next: STATIST,  Prev: URLCHK,  Up: Some Applications and Techniques

3.5 WEBGRAB: Extract Links from a Page
======================================

Sometimes it is necessary to extract links from web pages.  Browsers do
it, web robots do it, and sometimes even humans do it.  Since we have a
tool like GETURL at hand, we can solve this problem with some help from
the Bourne shell:

     BEGIN { RS = "https?://[#%&\\+\\-\\./0-9\\:;\\?A-Z_a-z\\~]*" }
     RT != "" {
        command = ("gawk -v Proxy=MyProxy -f geturl.awk " RT \
                    " > doc" NR ".html")
        print command
     }

   Notice that the regular expression for URLs is rather crude.  A
precise regular expression is much more complex.  But this one works
rather well.  One problem is that it is unable to find internal links of
an HTML document.  Another problem is that 'ftp', 'telnet', 'news',
'mailto', and other kinds of links are missing in the regular
expression.  However, it is straightforward to add them, if doing so is
necessary for other tasks.

   This program reads an HTML file and prints all the HTTP links that it
finds.  It relies on 'gawk''s ability to use regular expressions as the
record separator.  With 'RS' set to a regular expression that matches
links, the second action is executed each time a non-empty link is
found.  We can find the matching link itself in 'RT'.

   The action could use the 'system()' function to let another GETURL
retrieve the page, but here we use a different approach.  This simple
program prints shell commands that can be piped into 'sh' for execution.
This way it is possible to first extract the links, wrap shell commands
around them, and pipe all the shell commands into a file.  After editing
the file, execution of the file retrieves only those files that we
really need.  In case we do not want to edit, we can retrieve all the
pages like this:

     gawk -f geturl.awk http://www.suse.de | gawk -f webgrab.awk | sh

   After this, you will find the contents of all referenced documents in
files named 'doc*.html' even if they do not contain HTML code.  The most
annoying thing is that we always have to pass the proxy to GETURL. If
you do not like to see the headers of the web pages appear on the
screen, you can redirect them to '/dev/null'.  Watching the headers
appear can be quite interesting, because it reveals interesting details
such as which web server the companies use.  Now, it is clear how the
clever marketing people use web robots to determine the market shares of
Microsoft and Netscape in the web server market.

   Port 80 of any web server is like a small hole in a repellent
firewall.  After attaching a browser to port 80, we usually catch a
glimpse of the bright side of the server (its home page).  With a tool
like GETURL at hand, we are able to discover some of the more concealed
or even "indecent" services (i.e., lacking conformity to standards of
quality).  It can be exciting to see the fancy CGI scripts that lie
there, revealing the inner workings of the server, ready to be called:

   * With a command such as:

          gawk -f geturl.awk http://any.host.on.the.net/cgi-bin/

     some servers give you a directory listing of the CGI files.
     Knowing the names, you can try to call some of them and watch for
     useful results.  Sometimes there are executables in such
     directories (such as Perl interpreters) that you may call remotely.
     If there are subdirectories with configuration data of the web
     server, this can also be quite interesting to read.

   * The well-known Apache web server usually has its CGI files in the
     directory '/cgi-bin'.  There you can often find the scripts
     'test-cgi' and 'printenv'.  Both tell you some things about the
     current connection and the installation of the web server.  Just
     call:

          gawk -f geturl.awk http://any.host.on.the.net/cgi-bin/test-cgi
          gawk -f geturl.awk http://any.host.on.the.net/cgi-bin/printenv

   * Sometimes it is even possible to retrieve system files like the web
     server's log file--possibly containing customer data--or even the
     file '/etc/passwd'.  (We don't recommend this!)

   *Caution:* Although this may sound funny or simply irrelevant, we are
talking about severe security holes.  Try to explore your own system
this way and make sure that none of the above reveals too much
information about your system.


File: gawkinet.info,  Node: STATIST,  Next: MAZE,  Prev: WEBGRAB,  Up: Some Applications and Techniques

3.6 STATIST: Graphing a Statistical Distribution
================================================