2004-01-09 Kelley Cook <kcook@gcc.gnu.org>

	* configure.in: Rename file to ...
	* configure.ac: ... this.  Add in AC_PREREQ(2.57)
	* config.h.in: Regenerate.
	* aclocal.m4: Regenerate.
	* Makefile.in: Regenerate.


git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@75621 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 82 insertions, 0 deletions

diff --git a/fastjar/configure.ac b/fastjar/configure.ac
new file mode 100644
index 00000000000..93630345eec
--- /dev/null
+++ b/fastjar/configure.ac
@@ -0,0 +1,82 @@
+dnl Process this file with autoconf to produce a configure script.
+AC_PREREQ(2.57)
+AC_INIT(jartool.h)
+AM_INIT_AUTOMAKE(fastjar, 0.92-gcc)
+AM_CONFIG_HEADER(config.h)
+
+dnl Checks for programs.
+AC_PROG_CC
+AC_PROG_INSTALL
+AC_PATH_PROG(RM, rm, /bin/rm, $PATH:/bin:/usr/bin:/usr/local/bin)
+AC_PATH_PROG(CP, cp, /bin/cp, $PATH:/bin:/usr/bin:/usr/local/bin)
+AC_PATH_PROG(STRIP, strip, /usr/bin/strip, $PATH:/bin:/usr/bin:/usr/local/bin)
+AC_PATH_PROG(CHMOD, chmod, /bin/chmod, $PATH:/bin:/usr/bin:/usr/local/bin)
+AC_EXEEXT
+
+AM_MAINTAINER_MODE
+
+dnl Add warning flags if we are using gcc.
+if test "$GCC" = yes; then
+  fastjar_warn_cflags='-W -Wall -pedantic -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings'
+fi
+AC_SUBST(fastjar_warn_cflags)
+
+dnl Checks for header files.
+AC_HEADER_DIRENT
+AC_HEADER_STDC
+AC_STRUCT_TM
+AC_CHECK_HEADERS(fcntl.h unistd.h sys/param.h stdlib.h limits.h)
+
+dnl Checks for typedefs, structures, and compiler characteristics.
+AC_TYPE_OFF_T
+AC_STRUCT_TM
+
+# mkdir takes a single argument on some systems.
+gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
+
+dnl Check for type-widths
+AC_COMPILE_CHECK_SIZEOF(char)
+AC_COMPILE_CHECK_SIZEOF(short)
+AC_COMPILE_CHECK_SIZEOF(int)
+AC_COMPILE_CHECK_SIZEOF(long)
+AC_COMPILE_CHECK_SIZEOF(long long)
+
+dnl Check byte order
+AC_C_BIGENDIAN_CROSS
+
+AC_ARG_WITH(system-zlib,
+[  --with-system-zlib      use installed libz])
+
+ZLIBS=
+ZDEPS=
+ZINCS=
+use_zlib=maybe
+if test "$with_system_zlib" = yes; then
+   AC_CHECK_LIB(z, deflate, ZLIBS=-lz, use_zlib=no)
+else
+   use_zlib=no
+fi
+
+if test "$use_zlib" = no; then
+   # Brain dead way to find tree's zlib.
+   ZDEPS='$(top_builddir)/../zlib/libz.a'
+   ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
+   ZINCS='-I$(top_srcdir)/../zlib'
+fi
+AC_SUBST(ZLIBS)
+AC_SUBST(ZDEPS)
+AC_SUBST(ZINCS)
+
+# Get the version trigger filename from the toplevel
+if test "${with_gcc_version_trigger+set}" = set; then
+   gcc_version_trigger=$with_gcc_version_trigger
+else
+   gcc_version_trigger=${srcdir}/version.c
+fi
+changequote(,)dnl
+gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
+gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
+changequote([,])dnl
+AC_SUBST(gcc_version)
+
+AC_OUTPUT(Makefile install-defs.sh)