2003-10-21 Arnaud Charlet <charlet@act-europe.fr>

	* 3psoccon.ads, 3veacodu.adb, 3vexpect.adb, 3vsoccon.ads,
	3vsocthi.adb, 3vsocthi.ads, 3vtrasym.adb, 3zsoccon.ads,
	3zsocthi.adb, 3zsocthi.ads, 50system.ads, 51system.ads,
	55system.ads, 56osinte.adb, 56osinte.ads, 56taprop.adb,
	56taspri.ads, 56tpopsp.adb, 57system.ads, 58system.ads,
	59system.ads, 5aml-tgt.adb, 5bml-tgt.adb, 5csystem.ads,
	5dsystem.ads, 5fosinte.adb, 5gml-tgt.adb, 5hml-tgt.adb,
	5isystem.ads, 5lparame.adb, 5msystem.ads, 5psystem.ads,
	5sml-tgt.adb, 5sosprim.adb, 5stpopsp.adb, 5tsystem.ads,
	5usystem.ads, 5vml-tgt.adb, 5vsymbol.adb, 5vtraent.adb,
	5vtraent.ads, 5wml-tgt.adb, 5xparame.ads, 5xsystem.ads,
	5xvxwork.ads, 5yparame.ads, 5ytiitho.adb, 5zinit.adb,
	5zml-tgt.adb, 5zparame.ads, 5ztaspri.ads, 5ztfsetr.adb,
	5zthrini.adb, 5ztiitho.adb, 5ztpopsp.adb, 7stfsetr.adb,
	7straces.adb, 7strafor.adb, 7strafor.ads, 7stratas.adb,
	a-excach.adb, a-exexda.adb, a-exexpr.adb, a-exextr.adb,
	a-exstat.adb, a-strsup.adb, a-strsup.ads, a-stwisu.adb,
	a-stwisu.ads, bld.adb, bld.ads, bld-io.adb,
	bld-io.ads, clean.adb, clean.ads, ctrl_c.c,
	erroutc.adb, erroutc.ads, errutil.adb, errutil.ads,
	err_vars.ads, final.c, g-arrspl.adb, g-arrspl.ads,
	g-boubuf.adb, g-boubuf.ads, g-boumai.ads, g-bubsor.adb,
	g-bubsor.ads, g-comver.adb, g-comver.ads, g-ctrl_c.ads,
	g-dynhta.adb, g-dynhta.ads, g-eacodu.adb, g-excact.adb,
	g-excact.ads, g-heasor.adb, g-heasor.ads, g-memdum.adb,
	g-memdum.ads, gnatclean.adb, gnatsym.adb, g-pehage.adb,
	g-pehage.ads, g-perhas.ads, gpr2make.adb, gpr2make.ads,
	gprcmd.adb, gprep.adb, gprep.ads, g-semaph.adb,
	g-semaph.ads, g-string.adb, g-string.ads, g-strspl.ads,
	g-wistsp.ads, i-vthrea.adb, i-vthrea.ads, i-vxwoio.adb,
	i-vxwoio.ads, Makefile.generic, Makefile.prolog, Makefile.rtl,
	prep.adb, prep.ads, prepcomp.adb, prepcomp.ads,
	prj-err.adb, prj-err.ads, s-boarop.ads, s-carsi8.adb,
	s-carsi8.ads, s-carun8.adb, s-carun8.ads, s-casi16.adb,
	s-casi16.ads, s-casi32.adb, s-casi32.ads, s-casi64.adb,
	s-casi64.ads, s-casuti.adb, s-casuti.ads, s-caun16.adb,
	s-caun16.ads, s-caun32.adb, s-caun32.ads, s-caun64.adb,
	s-caun64.ads, scng.adb, scng.ads, s-exnint.adb,
	s-exnllf.adb, s-exnlli.adb, s-expint.adb, s-explli.adb,
	s-geveop.adb, s-geveop.ads, s-hibaen.ads, s-htable.adb,
	s-htable.ads, sinput-c.adb, sinput-c.ads, s-memcop.ads,
	socket.c, s-purexc.ads, s-scaval.adb, s-stopoo.adb,
	s-strcom.adb, s-strcom.ads, s-strxdr.adb, s-rident.ads,
	s-thread.adb, s-thread.ads, s-tpae65.adb, s-tpae65.ads,
	s-tporft.adb, s-traent.adb, s-traent.ads, styleg.adb,
	styleg.ads, styleg-c.adb, styleg-c.ads, s-veboop.adb,
	s-veboop.ads, s-vector.ads, symbols.adb, symbols.ads,
	tb-alvms.c, tb-alvxw.c, tempdir.adb, tempdir.ads,
	vms_conv.ads, vms_conv.adb, vms_data.ads,
	vxaddr2line.adb: Files added. Merge with ACT tree.

	* 4dintnam.ads, 4mintnam.ads, 4uintnam.ads, 52system.ads,
	5dosinte.ads, 5etpopse.adb, 5mosinte.ads, 5qosinte.adb,
	5qosinte.ads, 5qstache.adb, 5qtaprop.adb, 5qtaspri.ads,
	5stpopse.adb, 5uintman.adb, 5uosinte.ads, adafinal.c,
	g-enblsp.adb, io-aux.c, scn-nlit.adb, scn-slit.adb,
	s-exnflt.ads, s-exngen.adb, s-exngen.ads, s-exnlfl.ads,
	s-exnlin.ads, s-exnsfl.ads, s-exnsin.ads, s-exnssi.ads,
	s-expflt.ads, s-expgen.adb, s-expgen.ads, s-explfl.ads,
	s-explin.ads, s-expllf.ads, s-expsfl.ads, s-expsin.ads,
	s-expssi.ads, style.adb: Files removed. Merge with ACT tree.

	* 1ic.ads, 31soccon.ads, 31soliop.ads, 3asoccon.ads,
	3bsoccon.ads, 3gsoccon.ads, 3hsoccon.ads, 3ssoccon.ads,
	3ssoliop.ads, 3wsoccon.ads, 3wsocthi.adb, 3wsocthi.ads,
	3wsoliop.ads, 41intnam.ads, 42intnam.ads, 4aintnam.ads,
	4cintnam.ads, 4gintnam.ads, 4hexcpol.adb, 4hintnam.ads,
	4lintnam.ads, 4nintnam.ads, 4ointnam.ads, 4onumaux.ads,
	4pintnam.ads, 4sintnam.ads, 4vcaldel.adb, 4vcalend.adb,
	4vintnam.ads, 4wexcpol.adb, 4wintnam.ads, 4zintnam.ads,
	51osinte.adb, 51osinte.ads, 52osinte.adb, 52osinte.ads,
	53osinte.ads, 54osinte.ads, 5aosinte.adb, 5aosinte.ads,
	5asystem.ads, 5ataprop.adb, 5atasinf.ads, 5ataspri.ads,
	5atpopsp.adb, 5avxwork.ads, 5bosinte.adb, 5bosinte.ads,
	5bsystem.ads, 5cosinte.ads, 5esystem.ads, 5fintman.adb,
	5fosinte.ads, 5fsystem.ads, 5ftaprop.adb, 5ftasinf.ads,
	5ginterr.adb, 5gintman.adb, 5gmastop.adb, 5gosinte.ads,
	5gproinf.ads, 5gsystem.ads, 5gtaprop.adb, 5gtasinf.ads,
	5gtpgetc.adb, 5hosinte.adb, 5hosinte.ads, 5hsystem.ads,
	5htaprop.adb, 5htaspri.ads, 5htraceb.adb, 5iosinte.adb,
	5itaprop.adb, 5itaspri.ads, 5ksystem.ads, 5kvxwork.ads,
	5lintman.adb, 5lml-tgt.adb, 5losinte.ads, 5lsystem.ads,
	5mvxwork.ads, 5ninmaop.adb, 5nintman.adb, 5nosinte.ads,
	5ntaprop.adb, 5ntaspri.ads, 5ointerr.adb, 5omastop.adb,
	5oosinte.adb, 5oosinte.ads, 5oosprim.adb, 5oparame.adb,
	5osystem.ads, 5otaprop.adb, 5otaspri.ads, 5posinte.ads,
	5posprim.adb, 5pvxwork.ads, 5sintman.adb, 5sosinte.adb,
	5sosinte.ads, 5ssystem.ads, 5staprop.adb, 5stasinf.ads,
	5staspri.ads, 5svxwork.ads, 5tosinte.ads, 5vasthan.adb,
	5vinmaop.adb, 5vinterr.adb, 5vintman.adb, 5vintman.ads,
	5vmastop.adb, 5vosinte.adb, 5vosinte.ads, 5vosprim.adb,
	5vsystem.ads, 5vtaprop.adb, 5vtaspri.ads, 5vtpopde.adb,
	5vtpopde.ads, 5wgloloc.adb, 5wintman.adb, 5wmemory.adb,
	5wosprim.adb, 5wsystem.ads, 5wtaprop.adb, 5wtaspri.ads,
	5ysystem.ads, 5zinterr.adb, 5zintman.adb, 5zosinte.adb,
	5zosinte.ads, 5zosprim.adb, 5zsystem.ads, 5ztaprop.adb,
	6vcpp.adb, 6vcstrea.adb, 6vinterf.ads, 7sinmaop.adb,
	7sintman.adb, 7sosinte.adb, 7sosprim.adb, 7staprop.adb,
	7staspri.ads, 7stpopsp.adb, 7straceb.adb, 9drpc.adb,
	a-caldel.adb, a-caldel.ads, a-charac.ads, a-colien.ads,
	a-comlin.adb, adaint.c, adaint.h, ada-tree.def,
	a-diocst.adb, a-diocst.ads, a-direio.adb, a-except.adb,
	a-except.ads, a-excpol.adb, a-exctra.adb, a-exctra.ads,
	a-filico.adb, a-interr.adb, a-intsig.adb, a-intsig.ads,
	ali.adb, ali.ads, ali-util.adb, ali-util.ads,
	a-ngcefu.adb, a-ngcoty.adb, a-ngelfu.adb, a-nudira.adb,
	a-nudira.ads, a-nuflra.adb, a-nuflra.ads, a-reatim.adb,
	a-reatim.ads, a-retide.ads, a-sequio.adb, a-siocst.adb,
	a-siocst.ads, a-ssicst.adb, a-ssicst.ads, a-strbou.adb,
	a-strbou.ads, a-strfix.adb, a-strmap.adb, a-strsea.ads,
	a-strunb.adb, a-strunb.ads, a-ststio.adb, a-stunau.adb,
	a-stunau.ads, a-stwibo.adb, a-stwibo.ads, a-stwifi.adb,
	a-stwima.adb, a-stwiun.adb, a-stwiun.ads, a-tags.adb,
	a-tags.ads, a-tasatt.adb, a-taside.adb, a-teioed.adb,
	a-textio.adb, a-textio.ads, a-tienau.adb, a-tifiio.adb,
	a-tiflau.adb, a-tiflio.adb, a-tigeau.adb, a-tigeau.ads,
	a-tiinau.adb, a-timoau.adb, a-tiocst.adb, a-tiocst.ads,
	atree.adb, atree.ads, a-witeio.adb, a-witeio.ads,
	a-wtcstr.adb, a-wtcstr.ads, a-wtdeio.adb, a-wtedit.adb,
	a-wtenau.adb, a-wtflau.adb, a-wtinau.adb, a-wtmoau.adb,
	bcheck.adb, binde.adb, bindgen.adb, bindusg.adb,
	checks.adb, checks.ads, cio.c, comperr.adb,
	comperr.ads, csets.adb, cstand.adb, cstreams.c,
	debug_a.adb, debug_a.ads, debug.adb, decl.c,
	einfo.adb, einfo.ads, errout.adb, errout.ads,
	eval_fat.adb, eval_fat.ads, exp_aggr.adb, expander.adb,
	expander.ads, exp_attr.adb, exp_ch11.adb, exp_ch13.adb,
	exp_ch2.adb, exp_ch3.adb, exp_ch3.ads, exp_ch4.adb,
	exp_ch5.adb, exp_ch6.adb, exp_ch7.adb, exp_ch7.ads,
	exp_ch8.adb, exp_ch9.adb, exp_code.adb, exp_dbug.adb,
	exp_dbug.ads, exp_disp.adb, exp_dist.adb, expect.c,
	exp_fixd.adb, exp_imgv.adb, exp_intr.adb, exp_pakd.adb,
	exp_prag.adb, exp_strm.adb, exp_strm.ads, exp_tss.adb,
	exp_tss.ads, exp_util.adb, exp_util.ads, exp_vfpt.adb,
	fe.h, fmap.adb, fmap.ads, fname.adb,
	fname.ads, fname-uf.adb, fname-uf.ads, freeze.adb,
	freeze.ads, frontend.adb, g-awk.adb, g-awk.ads,
	g-busora.adb, g-busora.ads, g-busorg.adb, g-busorg.ads,
	g-casuti.adb, g-casuti.ads, g-catiio.adb, g-catiio.ads,
	g-cgi.adb, g-cgi.ads, g-cgicoo.adb, g-cgicoo.ads,
	g-cgideb.adb, g-cgideb.ads, g-comlin.adb, g-comlin.ads,
	g-crc32.adb, g-crc32.ads, g-debpoo.adb, g-debpoo.ads,
	g-debuti.adb, g-debuti.ads, g-diopit.adb, g-diopit.ads,
	g-dirope.adb, g-dirope.ads, g-dyntab.adb, g-dyntab.ads,
	g-except.ads, g-exctra.adb, g-exctra.ads, g-expect.adb,
	g-expect.ads, g-hesora.adb, g-hesora.ads, g-hesorg.adb,
	g-hesorg.ads, g-htable.adb, g-htable.ads, gigi.h,
	g-io.adb, g-io.ads, g-io_aux.adb, g-io_aux.ads,
	g-locfil.adb, g-locfil.ads, g-md5.adb, g-md5.ads,
	gmem.c, gnat1drv.adb, gnatbind.adb, gnatchop.adb,
	gnatcmd.adb, gnatfind.adb, gnatkr.adb, gnatlbr.adb,
	gnatlink.adb, gnatls.adb, gnatmake.adb, gnatmem.adb,
	gnatname.adb, gnatprep.adb, gnatprep.ads, gnatpsta.adb,
	gnatxref.adb, g-os_lib.adb, g-os_lib.ads, g-regexp.adb,
	g-regexp.ads, g-regist.adb, g-regist.ads, g-regpat.adb,
	g-regpat.ads, g-soccon.ads, g-socket.adb, g-socket.ads,
	g-socthi.adb, g-socthi.ads, g-soliop.ads, g-souinf.ads,
	g-speche.adb, g-speche.ads, g-spipat.adb, g-spipat.ads,
	g-spitbo.adb, g-spitbo.ads, g-sptabo.ads, g-sptain.ads,
	g-sptavs.ads, g-table.adb, g-table.ads, g-tasloc.adb,
	g-tasloc.ads, g-thread.adb, g-thread.ads, g-traceb.adb,
	g-traceb.ads, g-trasym.adb, g-trasym.ads, hostparm.ads,
	i-c.ads, i-cobol.adb, i-cpp.adb, i-cstrea.ads,
	i-cstrin.adb, i-cstrin.ads, impunit.adb, init.c,
	inline.adb, interfac.ads, i-pacdec.ads, itypes.adb,
	itypes.ads, i-vxwork.ads, lang.opt, lang-specs.h,
	layout.adb, lib.adb, lib.ads, lib-list.adb,
	lib-load.adb, lib-load.ads, lib-sort.adb, lib-util.adb,
	lib-writ.adb, lib-writ.ads, lib-xref.adb, lib-xref.ads,
	link.c, live.adb, make.adb, make.ads,
	Makefile.adalib, Makefile.in, Make-lang.in, makeusg.adb,
	mdll.adb, mdll-fil.adb, mdll-fil.ads, mdll-utl.adb,
	mdll-utl.ads, memroot.adb, memroot.ads, memtrack.adb,
	misc.c, mkdir.c, mlib.adb, mlib.ads,
	mlib-fil.adb, mlib-fil.ads, mlib-prj.adb, mlib-prj.ads,
	mlib-tgt.adb, mlib-tgt.ads, mlib-utl.adb, mlib-utl.ads,
	namet.adb, namet.ads, namet.h, nlists.ads,
	nlists.h, nmake.adt, opt.adb, opt.ads,
	osint.adb, osint.ads, osint-b.adb, osint-c.adb,
	par.adb, par-ch10.adb, par-ch11.adb, par-ch2.adb,
	par-ch3.adb, par-ch4.adb, par-ch5.adb, par-ch6.adb,
	par-ch9.adb, par-endh.adb, par-labl.adb, par-load.adb,
	par-prag.adb, par-sync.adb, par-tchk.adb, par-util.adb,
	prj.adb, prj.ads, prj-attr.adb, prj-attr.ads,
	prj-com.adb, prj-com.ads, prj-dect.adb, prj-dect.ads,
	prj-env.adb, prj-env.ads, prj-ext.adb, prj-ext.ads,
	prj-makr.adb, prj-makr.ads, prj-nmsc.adb, prj-nmsc.ads,
	prj-pars.adb, prj-pars.ads, prj-part.adb, prj-part.ads,
	prj-pp.adb, prj-pp.ads, prj-proc.adb, prj-proc.ads,
	prj-strt.adb, prj-strt.ads, prj-tree.adb, prj-tree.ads,
	prj-util.adb, prj-util.ads, raise.c, raise.h,
	repinfo.adb, repinfo.h, restrict.adb, restrict.ads,
	rident.ads, rtsfind.adb, rtsfind.ads, s-addima.ads,
	s-arit64.adb, s-assert.adb, s-assert.ads, s-atacco.adb,
	s-atacco.ads, s-auxdec.adb, s-auxdec.ads, s-bitops.adb,
	scans.ads, scn.adb, scn.ads, s-crc32.adb,
	s-crc32.ads, s-direio.adb, sem.adb, sem.ads,
	sem_aggr.adb, sem_attr.adb, sem_attr.ads, sem_case.adb,
	sem_case.ads, sem_cat.adb, sem_cat.ads, sem_ch10.adb,
	sem_ch11.adb, sem_ch12.adb, sem_ch12.ads, sem_ch13.adb,
	sem_ch13.ads, sem_ch3.adb, sem_ch3.ads, sem_ch4.adb,
	sem_ch5.adb, sem_ch5.ads, sem_ch6.adb, sem_ch6.ads,
	sem_ch7.adb, sem_ch7.ads, sem_ch8.adb, sem_ch8.ads,
	sem_ch9.adb, sem_disp.adb, sem_disp.ads, sem_dist.adb,
	sem_elab.adb, sem_eval.adb, sem_eval.ads, sem_intr.adb,
	sem_maps.adb, sem_mech.adb, sem_prag.adb, sem_prag.ads,
	sem_res.adb, sem_res.ads, sem_type.adb, sem_type.ads,
	sem_util.adb, sem_util.ads, sem_warn.adb, s-errrep.adb,
	s-errrep.ads, s-exctab.adb, s-exctab.ads, s-exnint.ads,
	s-exnllf.ads, s-exnlli.ads, s-expint.ads, s-explli.ads,
	s-expuns.ads, s-fatflt.ads, s-fatgen.adb, s-fatgen.ads,
	s-fatlfl.ads, s-fatllf.ads, s-fatsfl.ads, s-fileio.adb,
	s-fileio.ads, s-finimp.adb, s-finimp.ads, s-finroo.adb,
	s-finroo.ads, sfn_scan.adb, s-gloloc.adb, s-gloloc.ads,
	s-imgdec.adb, s-imgenu.adb, s-imgrea.adb, s-imgwch.adb,
	sinfo.adb, sinfo.ads, s-inmaop.ads, sinput.adb,
	sinput.ads, sinput-d.adb, sinput-l.adb, sinput-l.ads,
	sinput-p.adb, sinput-p.ads, s-interr.adb, s-interr.ads,
	s-intman.ads, s-maccod.ads, s-mastop.adb, s-mastop.ads,
	s-memory.adb, s-memory.ads, snames.adb, snames.ads,
	snames.h, s-osprim.ads, s-parame.ads, s-parint.ads,
	s-pooloc.adb, s-pooloc.ads, s-poosiz.adb, sprint.adb,
	s-proinf.ads, s-scaval.ads, s-secsta.adb, s-secsta.ads,
	s-sequio.adb, s-shasto.adb, s-shasto.ads, s-soflin.ads,
	s-stache.adb, s-stache.ads, s-stalib.adb, s-stalib.ads,
	s-stoele.ads, s-stopoo.ads, s-stratt.adb, s-stratt.ads,
	s-strops.adb, s-strops.ads, s-taasde.adb, s-taasde.ads,
	s-tadeca.adb, s-tadeca.ads, s-tadert.adb, s-tadert.ads,
	s-taenca.adb, s-taenca.ads, s-taprob.adb, s-taprob.ads,
	s-taprop.ads, s-tarest.adb, s-tarest.ads, s-tasdeb.adb,
	s-tasdeb.ads, s-tasinf.adb, s-tasinf.ads, s-tasini.adb,
	s-tasini.ads, s-taskin.adb, s-taskin.ads, s-tasque.adb,
	s-tasque.ads, s-tasren.adb, s-tasren.ads, s-tasres.ads,
	s-tassta.adb, s-tassta.ads, s-tasuti.adb, s-tasuti.ads,
	s-tataat.adb, s-tataat.ads, s-tpinop.adb, s-tpinop.ads,
	s-tpoben.adb, s-tpoben.ads, s-tpobop.adb, s-tpobop.ads,
	s-tposen.adb, s-tposen.ads, s-traceb.adb, s-traceb.ads,
	stringt.adb, stringt.ads, stringt.h, style.ads,
	stylesw.adb, stylesw.ads, s-unstyp.ads, s-vaflop.ads,
	s-valrea.adb, s-valuti.adb, s-vercon.adb, s-vmexta.adb,
	s-wchcnv.ads, s-wchcon.ads, s-widcha.adb, switch.adb,
	switch.ads, switch-b.adb, switch-c.adb, switch-m.adb,
	s-wwdcha.adb, s-wwdwch.adb, sysdep.c, system.ads,
	table.adb, table.ads, targparm.adb, targparm.ads,
	targtyps.c, tbuild.adb, tbuild.ads, tracebak.c,
	trans.c, tree_io.adb, treepr.adb, treeprs.adt,
	ttypes.ads, types.ads, types.h, uintp.adb,
	uintp.ads, uintp.h, uname.adb, urealp.adb,
	urealp.ads, urealp.h, usage.adb, utils2.c,
	utils.c, validsw.adb, validsw.ads, widechar.adb,
	xeinfo.adb, xnmake.adb, xref_lib.adb, xref_lib.ads,
	xr_tabls.adb, xr_tabls.ads, xtreeprs.adb, xsnames.adb,
	einfo.h, sinfo.h, treeprs.ads, nmake.ads, nmake.adb,
	gnatvsn.ads: Merge with ACT tree.

	* gnatvsn.adb: Rewritten in a simpler and more efficient way.


git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@72751 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 526 insertions, 0 deletions

diff --git a/gcc/ada/a-exexda.adb b/gcc/ada/a-exexda.adb
new file mode 100644
index 00000000000..b88d643092f
--- /dev/null
+++ b/gcc/ada/a-exexda.adb
@@ -0,0 +1,526 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT COMPILER COMPONENTS                         --
+--                                                                          --
+--                       ADA.EXCEPTIONS.EXCEPTION_DATA                      --
+--                                                                          --
+--                                 B o d y                                  --
+--                                                                          --
+--          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
+--                                                                          --
+-- GNAT is free software;  you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
+-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
+-- for  more details.  You should have  received  a copy of the GNU General --
+-- Public License  distributed with GNAT;  see file COPYING.  If not, write --
+-- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
+-- MA 02111-1307, USA.                                                      --
+--                                                                          --
+-- As a special exception,  if other files  instantiate  generics from this --
+-- unit, or you link  this unit with other files  to produce an executable, --
+-- this  unit  does not  by itself cause  the resulting  executable  to  be --
+-- covered  by the  GNU  General  Public  License.  This exception does not --
+-- however invalidate  any other reasons why  the executable file  might be --
+-- covered by the  GNU Public License.                                      --
+--                                                                          --
+-- GNAT was originally developed  by the GNAT team at  New York University. --
+-- Extensive contributions were provided by Ada Core Technologies Inc.      --
+--                                                                          --
+------------------------------------------------------------------------------
+
+with System.Storage_Elements; use System.Storage_Elements;
+
+separate (Ada.Exceptions)
+package body Exception_Data is
+
+   -----------------------
+   -- Local Subprograms --
+   -----------------------
+
+   function Address_Image (A : System.Address) return String;
+   --  Returns at string of the form 0xhhhhhhhhh for 32-bit addresses
+   --  or 0xhhhhhhhhhhhhhhhh for 64-bit addresses. Hex characters are
+   --  in lower case.
+
+   procedure Append_Info_Nat
+     (N    : Natural;
+      Info : in out String;
+      Ptr  : in out Natural);
+   --  Append the image of N at the end of the provided information string
+
+   procedure Append_Info_NL
+     (Info : in out String;
+      Ptr  : in out Natural);
+   --  Append a LF at the end of the provided information string
+
+   procedure Append_Info_String
+     (S    : String;
+      Info : in out String;
+      Ptr  : in out Natural);
+   --  Append a string at the end of the provided information string
+
+   --  To build Exception_Information and Tailored_Exception_Information,
+   --  we then use three intermediate functions :
+
+   function Basic_Exception_Information
+     (X    : Exception_Occurrence)
+      return String;
+   --  Returns the basic exception information string associated with a
+   --  given exception occurrence. This is the common part shared by both
+   --  Exception_Information and Tailored_Exception_Infomation.
+
+   function Basic_Exception_Traceback
+     (X    : Exception_Occurrence)
+      return String;
+   --  Returns an image of the complete call chain associated with an
+   --  exception occurence in its most basic form, that is as a raw sequence
+   --  of hexadecimal binary addresses.
+
+   function Tailored_Exception_Traceback
+     (X    : Exception_Occurrence)
+      return String;
+   --  Returns an image of the complete call chain associated with an
+   --  exception occurrence, either in its basic form if no decorator is
+   --  in place, or as formatted by the decorator otherwise.
+
+   --  The overall organization of the exception information related code
+   --  is summarized below :
+   --
+   --           Exception_Information
+   --                    |
+   --            +-------+--------+
+   --            |                |
+   --     Basic_Exc_Info & Basic_Exc_Tback
+   --
+   --
+   --       Tailored_Exception_Information
+   --                    |
+   --         +----------+----------+
+   --         |                     |
+   --  Basic_Exc_Info    &  Tailored_Exc_Tback
+   --                               |
+   --                   +-----------+------------+
+   --                   |                        |
+   --            Basic_Exc_Tback    Or    Tback_Decorator
+   --          if no decorator set           otherwise
+
+   -------------------
+   -- Address_Image --
+   -------------------
+
+   function Address_Image (A : Address) return String is
+      S : String (1 .. 18);
+      P : Natural;
+      N : Integer_Address;
+
+      H : constant array (Integer range 0 .. 15) of Character :=
+                                                         "0123456789abcdef";
+   begin
+      P := S'Last;
+      N := To_Integer (A);
+      while N /= 0 loop
+         S (P) := H (Integer (N mod 16));
+         P := P - 1;
+         N := N / 16;
+      end loop;
+
+      S (P - 1) := '0';
+      S (P) := 'x';
+      return S (P - 1 .. S'Last);
+   end Address_Image;
+
+   ---------------------
+   -- Append_Info_Nat --
+   ---------------------
+
+   procedure Append_Info_Nat
+     (N    : Natural;
+      Info : in out String;
+      Ptr  : in out Natural)
+   is
+   begin
+      if N > 9 then
+         Append_Info_Nat (N / 10, Info, Ptr);
+      end if;
+
+      Ptr := Ptr + 1;
+      Info (Ptr) := Character'Val (Character'Pos ('0') + N mod 10);
+   end Append_Info_Nat;
+
+   --------------------
+   -- Append_Info_NL --
+   --------------------
+
+   procedure Append_Info_NL
+     (Info : in out String;
+      Ptr  : in out Natural)
+   is
+   begin
+      Ptr := Ptr + 1;
+      Info (Ptr) := ASCII.LF;
+   end Append_Info_NL;
+
+   ------------------------
+   -- Append_Info_String --
+   ------------------------
+
+   procedure Append_Info_String
+     (S    : String;
+      Info : in out String;
+      Ptr  : in out Natural)
+   is
+      Last : constant Natural := Integer'Min (Ptr + S'Length, Info'Last);
+
+   begin
+      Info (Ptr + 1 .. Last) := S;
+      Ptr := Last;
+   end Append_Info_String;
+
+   ---------------------------------
+   -- Basic_Exception_Information --
+   ---------------------------------
+
+   function Basic_Exception_Information
+     (X    : Exception_Occurrence)
+      return String
+   is
+      Name : constant String := Exception_Name (X);
+      Msg  : constant String := Exception_Message (X);
+      --  Exception name and message that are going to be included in the
+      --  information to return, if not empty.
+
+      Name_Len : constant Natural := Name'Length;
+      Msg_Len  : constant Natural := Msg'Length;
+      --  Length of these strings, useful to compute the size of the string
+      --  we have to allocate for the complete result as well as in the body
+      --  of this procedure.
+
+      Info_Maxlen : constant Natural := 50 + Name_Len + Msg_Len;
+      --  Maximum length of the information string we will build, with :
+      --
+      --  50 =    16 + 2   for the text associated with the name
+      --        +  9 + 2   for the text associated with the message
+      --        +  5 + 2   for the text associated with the pid
+      --        + 14       for the text image of the pid itself and a margin.
+      --
+      --  This is indeed a maximum since some data may not appear at all if
+      --  not relevant. For example, nothing related to the exception message
+      --  will be there if this message is empty.
+      --
+      --  WARNING : Do not forget to update these numbers if anything
+      --  involved in the computation changes.
+
+      Info : String (1 .. Info_Maxlen);
+      --  Information string we are going to build, containing the common
+      --  part shared by Exc_Info and Tailored_Exc_Info.
+
+      Ptr  : Natural := 0;
+
+   begin
+      --  Output exception name and message except for _ABORT_SIGNAL, where
+      --  these two lines are omitted (see discussion above).
+
+      if Name (1) /= '_' then
+         Append_Info_String ("Exception name: ", Info, Ptr);
+         Append_Info_String (Name, Info, Ptr);
+         Append_Info_NL (Info, Ptr);
+
+         if Msg_Len /= 0 then
+            Append_Info_String ("Message: ", Info, Ptr);
+            Append_Info_String (Msg, Info, Ptr);
+            Append_Info_NL (Info, Ptr);
+         end if;
+      end if;
+
+      --  Output PID line if non-zero
+
+      if X.Pid /= 0 then
+         Append_Info_String ("PID: ", Info, Ptr);
+         Append_Info_Nat (X.Pid, Info, Ptr);
+         Append_Info_NL (Info, Ptr);
+      end if;
+
+      return Info (1 .. Ptr);
+   end Basic_Exception_Information;
+
+   -------------------------------
+   -- Basic_Exception_Traceback --
+   -------------------------------
+
+   function Basic_Exception_Traceback
+     (X    : Exception_Occurrence)
+      return String
+   is
+      Info_Maxlen : constant Natural := 35 + X.Num_Tracebacks * 19;
+      --  Maximum length of the information string we are building, with :
+      --  33 = 31 + 4      for the text before and after the traceback, and
+      --  19 =  2 + 16 + 1 for each address ("0x" + HHHH + " ")
+      --
+      --  WARNING : Do not forget to update these numbers if anything
+      --  involved in the computation changes.
+
+      Info : String (1 .. Info_Maxlen);
+      --  Information string we are going to build, containing an image
+      --  of the call chain associated with the exception occurrence in its
+      --  most basic form, that is as a sequence of binary addresses.
+
+      Ptr  : Natural := 0;
+
+   begin
+      if X.Num_Tracebacks > 0 then
+         Append_Info_String ("Call stack traceback locations:", Info, Ptr);
+         Append_Info_NL (Info, Ptr);
+
+         for J in 1 .. X.Num_Tracebacks loop
+            Append_Info_String
+              (Address_Image (TBE.PC_For (X.Tracebacks (J))), Info, Ptr);
+            exit when J = X.Num_Tracebacks;
+            Append_Info_String (" ", Info, Ptr);
+         end loop;
+
+         Append_Info_NL (Info, Ptr);
+      end if;
+
+      return Info (1 .. Ptr);
+   end Basic_Exception_Traceback;
+
+   ---------------------------
+   -- Exception_Information --
+   ---------------------------
+
+   --  The format of the string is:
+
+   --    Exception_Name: nnnnn
+   --    Message: mmmmm
+   --    PID: ppp
+   --    Call stack traceback locations:
+   --    0xhhhh 0xhhhh 0xhhhh ... 0xhhh
+
+   --  where
+
+   --    nnnn is the fully qualified name of the exception in all upper
+   --    case letters. This line is always present.
+
+   --    mmmm is the message (this line present only if message is non-null)
+
+   --    ppp is the Process Id value as a decimal integer (this line is
+   --    present only if the Process Id is non-zero). Currently we are
+   --    not making use of this field.
+
+   --    The Call stack traceback locations line and the following values
+   --    are present only if at least one traceback location was recorded.
+   --    the values are given in C style format, with lower case letters
+   --    for a-f, and only as many digits present as are necessary.
+
+   --  The line terminator sequence at the end of each line, including the
+   --  last line is a CR-LF sequence (16#0D# followed by 16#0A#).
+
+   --  The Exception_Name and Message lines are omitted in the abort
+   --  signal case, since this is not really an exception, and the only
+   --  use of this routine is internal for printing termination output.
+
+   --  WARNING: if the format of the generated string is changed, please note
+   --  that an equivalent modification to the routine String_To_EO must be
+   --  made to preserve proper functioning of the stream attributes.
+
+   function Exception_Information (X : Exception_Occurrence) return String is
+
+      --  This information is now built using the circuitry introduced in
+      --  association with the support of traceback decorators, as the
+      --  catenation of the exception basic information and the call chain
+      --  backtrace in its basic form.
+
+      Basic_Info : constant String  := Basic_Exception_Information (X);
+      Tback_Info : constant String  := Basic_Exception_Traceback (X);
+
+      Basic_Len  : constant Natural := Basic_Info'Length;
+      Tback_Len  : constant Natural := Tback_Info'Length;
+
+      Info : String (1 .. Basic_Len + Tback_Len);
+      Ptr  : Natural := 0;
+
+   begin
+      Append_Info_String (Basic_Info, Info, Ptr);
+      Append_Info_String (Tback_Info, Info, Ptr);
+
+      return Info;
+   end Exception_Information;
+
+
+   -------------------------
+   -- Set_Exception_C_Msg --
+   -------------------------
+
+   procedure Set_Exception_C_Msg
+     (Id   : Exception_Id;
+      Msg1 : Big_String_Ptr;
+      Line : Integer        := 0;
+      Msg2 : Big_String_Ptr := null)
+   is
+      Excep  : constant EOA := Get_Current_Excep.all;
+      Val    : Integer := Line;
+      Remind : Integer;
+      Size   : Integer := 1;
+      Ptr    : Natural;
+
+   begin
+      Exception_Propagation.Setup_Exception (Excep, Excep);
+      Excep.Exception_Raised := False;
+      Excep.Id               := Id;
+      Excep.Num_Tracebacks   := 0;
+      Excep.Pid              := Local_Partition_ID;
+      Excep.Msg_Length       := 0;
+      Excep.Cleanup_Flag     := False;
+
+      while Msg1 (Excep.Msg_Length + 1) /= ASCII.NUL
+        and then Excep.Msg_Length < Exception_Msg_Max_Length
+      loop
+         Excep.Msg_Length := Excep.Msg_Length + 1;
+         Excep.Msg (Excep.Msg_Length) := Msg1 (Excep.Msg_Length);
+      end loop;
+
+      --  Append line number if present
+
+      if Line > 0 then
+
+         --  Compute the number of needed characters
+
+         while Val > 0 loop
+            Val := Val / 10;
+            Size := Size + 1;
+         end loop;
+
+         --  If enough characters are available, put the line number
+
+         if Excep.Msg_Length <= Exception_Msg_Max_Length - Size then
+            Excep.Msg (Excep.Msg_Length + 1) := ':';
+            Excep.Msg_Length := Excep.Msg_Length + Size;
+            Val := Line;
+            Size := 0;
+
+            while Val > 0 loop
+               Remind := Val rem 10;
+               Val := Val / 10;
+               Excep.Msg (Excep.Msg_Length - Size) :=
+                 Character'Val (Remind + Character'Pos ('0'));
+               Size := Size + 1;
+            end loop;
+         end if;
+      end if;
+
+      --  Append second message if present
+
+      if Msg2 /= null
+        and then Excep.Msg_Length + 1 < Exception_Msg_Max_Length
+      then
+         Excep.Msg_Length := Excep.Msg_Length + 1;
+         Excep.Msg (Excep.Msg_Length) := ' ';
+
+         Ptr := 1;
+         while Msg2 (Ptr) /= ASCII.NUL
+           and then Excep.Msg_Length < Exception_Msg_Max_Length
+         loop
+            Excep.Msg_Length := Excep.Msg_Length + 1;
+            Excep.Msg (Excep.Msg_Length) := Msg2 (Ptr);
+            Ptr := Ptr + 1;
+         end loop;
+      end if;
+   end Set_Exception_C_Msg;
+
+   -----------------------
+   -- Set_Exception_Msg --
+   -----------------------
+
+   procedure Set_Exception_Msg
+     (Id      : Exception_Id;
+      Message : String)
+   is
+      Len   : constant Natural :=
+                Natural'Min (Message'Length, Exception_Msg_Max_Length);
+      First : constant Integer := Message'First;
+      Excep  : constant EOA := Get_Current_Excep.all;
+
+   begin
+      Exception_Propagation.Setup_Exception (Excep, Excep);
+      Excep.Exception_Raised := False;
+      Excep.Msg_Length       := Len;
+      Excep.Msg (1 .. Len)   := Message (First .. First + Len - 1);
+      Excep.Id               := Id;
+      Excep.Num_Tracebacks   := 0;
+      Excep.Pid              := Local_Partition_ID;
+      Excep.Cleanup_Flag     := False;
+
+   end Set_Exception_Msg;
+
+   ----------------------------------
+   -- Tailored_Exception_Traceback --
+   ----------------------------------
+
+   function Tailored_Exception_Traceback
+     (X    : Exception_Occurrence)
+      return String
+   is
+      --  We indeed reference the decorator *wrapper* from here and not the
+      --  decorator itself. The purpose of the local variable Wrapper is to
+      --  prevent a potential crash by race condition in the code below. The
+      --  atomicity of this assignment is enforced by pragma Atomic in
+      --  System.Soft_Links.
+
+      --  The potential race condition here, if no local variable was used,
+      --  relates to the test upon the wrapper's value and the call, which
+      --  are not performed atomically. With the local variable, potential
+      --  changes of the wrapper's global value between the test and the
+      --  call become inoffensive.
+
+      Wrapper : constant Traceback_Decorator_Wrapper_Call :=
+                  Traceback_Decorator_Wrapper;
+
+   begin
+      if Wrapper = null then
+         return Basic_Exception_Traceback (X);
+      else
+         return Wrapper.all (X.Tracebacks'Address, X.Num_Tracebacks);
+      end if;
+   end Tailored_Exception_Traceback;
+
+   ------------------------------------
+   -- Tailored_Exception_Information --
+   ------------------------------------
+
+   function Tailored_Exception_Information
+     (X    : Exception_Occurrence)
+      return String
+   is
+      --  The tailored exception information is simply the basic information
+      --  associated with the tailored call chain backtrace.
+
+      Basic_Info : constant String  := Basic_Exception_Information (X);
+      Tback_Info : constant String  := Tailored_Exception_Traceback (X);
+
+      Basic_Len  : constant Natural := Basic_Info'Length;
+      Tback_Len  : constant Natural := Tback_Info'Length;
+
+      Info : String (1 .. Basic_Len + Tback_Len);
+      Ptr  : Natural := 0;
+
+   begin
+      Append_Info_String (Basic_Info, Info, Ptr);
+      Append_Info_String (Tback_Info, Info, Ptr);
+
+      return Info;
+   end Tailored_Exception_Information;
+
+   procedure Tailored_Exception_Information
+     (X    : Exception_Occurrence;
+      Buff : in out String;
+      Last : in out Integer)
+   is
+   begin
+      Append_Info_String (Basic_Exception_Information (X), Buff, Last);
+      Append_Info_String (Tailored_Exception_Traceback (X), Buff, Last);
+   end Tailored_Exception_Information;
+
+end Exception_Data;