2003-10-21 Arnaud Charlet <charlet@act-europe.fr>

	* 3psoccon.ads, 3veacodu.adb, 3vexpect.adb, 3vsoccon.ads,
	3vsocthi.adb, 3vsocthi.ads, 3vtrasym.adb, 3zsoccon.ads,
	3zsocthi.adb, 3zsocthi.ads, 50system.ads, 51system.ads,
	55system.ads, 56osinte.adb, 56osinte.ads, 56taprop.adb,
	56taspri.ads, 56tpopsp.adb, 57system.ads, 58system.ads,
	59system.ads, 5aml-tgt.adb, 5bml-tgt.adb, 5csystem.ads,
	5dsystem.ads, 5fosinte.adb, 5gml-tgt.adb, 5hml-tgt.adb,
	5isystem.ads, 5lparame.adb, 5msystem.ads, 5psystem.ads,
	5sml-tgt.adb, 5sosprim.adb, 5stpopsp.adb, 5tsystem.ads,
	5usystem.ads, 5vml-tgt.adb, 5vsymbol.adb, 5vtraent.adb,
	5vtraent.ads, 5wml-tgt.adb, 5xparame.ads, 5xsystem.ads,
	5xvxwork.ads, 5yparame.ads, 5ytiitho.adb, 5zinit.adb,
	5zml-tgt.adb, 5zparame.ads, 5ztaspri.ads, 5ztfsetr.adb,
	5zthrini.adb, 5ztiitho.adb, 5ztpopsp.adb, 7stfsetr.adb,
	7straces.adb, 7strafor.adb, 7strafor.ads, 7stratas.adb,
	a-excach.adb, a-exexda.adb, a-exexpr.adb, a-exextr.adb,
	a-exstat.adb, a-strsup.adb, a-strsup.ads, a-stwisu.adb,
	a-stwisu.ads, bld.adb, bld.ads, bld-io.adb,
	bld-io.ads, clean.adb, clean.ads, ctrl_c.c,
	erroutc.adb, erroutc.ads, errutil.adb, errutil.ads,
	err_vars.ads, final.c, g-arrspl.adb, g-arrspl.ads,
	g-boubuf.adb, g-boubuf.ads, g-boumai.ads, g-bubsor.adb,
	g-bubsor.ads, g-comver.adb, g-comver.ads, g-ctrl_c.ads,
	g-dynhta.adb, g-dynhta.ads, g-eacodu.adb, g-excact.adb,
	g-excact.ads, g-heasor.adb, g-heasor.ads, g-memdum.adb,
	g-memdum.ads, gnatclean.adb, gnatsym.adb, g-pehage.adb,
	g-pehage.ads, g-perhas.ads, gpr2make.adb, gpr2make.ads,
	gprcmd.adb, gprep.adb, gprep.ads, g-semaph.adb,
	g-semaph.ads, g-string.adb, g-string.ads, g-strspl.ads,
	g-wistsp.ads, i-vthrea.adb, i-vthrea.ads, i-vxwoio.adb,
	i-vxwoio.ads, Makefile.generic, Makefile.prolog, Makefile.rtl,
	prep.adb, prep.ads, prepcomp.adb, prepcomp.ads,
	prj-err.adb, prj-err.ads, s-boarop.ads, s-carsi8.adb,
	s-carsi8.ads, s-carun8.adb, s-carun8.ads, s-casi16.adb,
	s-casi16.ads, s-casi32.adb, s-casi32.ads, s-casi64.adb,
	s-casi64.ads, s-casuti.adb, s-casuti.ads, s-caun16.adb,
	s-caun16.ads, s-caun32.adb, s-caun32.ads, s-caun64.adb,
	s-caun64.ads, scng.adb, scng.ads, s-exnint.adb,
	s-exnllf.adb, s-exnlli.adb, s-expint.adb, s-explli.adb,
	s-geveop.adb, s-geveop.ads, s-hibaen.ads, s-htable.adb,
	s-htable.ads, sinput-c.adb, sinput-c.ads, s-memcop.ads,
	socket.c, s-purexc.ads, s-scaval.adb, s-stopoo.adb,
	s-strcom.adb, s-strcom.ads, s-strxdr.adb, s-rident.ads,
	s-thread.adb, s-thread.ads, s-tpae65.adb, s-tpae65.ads,
	s-tporft.adb, s-traent.adb, s-traent.ads, styleg.adb,
	styleg.ads, styleg-c.adb, styleg-c.ads, s-veboop.adb,
	s-veboop.ads, s-vector.ads, symbols.adb, symbols.ads,
	tb-alvms.c, tb-alvxw.c, tempdir.adb, tempdir.ads,
	vms_conv.ads, vms_conv.adb, vms_data.ads,
	vxaddr2line.adb: Files added. Merge with ACT tree.

	* 4dintnam.ads, 4mintnam.ads, 4uintnam.ads, 52system.ads,
	5dosinte.ads, 5etpopse.adb, 5mosinte.ads, 5qosinte.adb,
	5qosinte.ads, 5qstache.adb, 5qtaprop.adb, 5qtaspri.ads,
	5stpopse.adb, 5uintman.adb, 5uosinte.ads, adafinal.c,
	g-enblsp.adb, io-aux.c, scn-nlit.adb, scn-slit.adb,
	s-exnflt.ads, s-exngen.adb, s-exngen.ads, s-exnlfl.ads,
	s-exnlin.ads, s-exnsfl.ads, s-exnsin.ads, s-exnssi.ads,
	s-expflt.ads, s-expgen.adb, s-expgen.ads, s-explfl.ads,
	s-explin.ads, s-expllf.ads, s-expsfl.ads, s-expsin.ads,
	s-expssi.ads, style.adb: Files removed. Merge with ACT tree.

	* 1ic.ads, 31soccon.ads, 31soliop.ads, 3asoccon.ads,
	3bsoccon.ads, 3gsoccon.ads, 3hsoccon.ads, 3ssoccon.ads,
	3ssoliop.ads, 3wsoccon.ads, 3wsocthi.adb, 3wsocthi.ads,
	3wsoliop.ads, 41intnam.ads, 42intnam.ads, 4aintnam.ads,
	4cintnam.ads, 4gintnam.ads, 4hexcpol.adb, 4hintnam.ads,
	4lintnam.ads, 4nintnam.ads, 4ointnam.ads, 4onumaux.ads,
	4pintnam.ads, 4sintnam.ads, 4vcaldel.adb, 4vcalend.adb,
	4vintnam.ads, 4wexcpol.adb, 4wintnam.ads, 4zintnam.ads,
	51osinte.adb, 51osinte.ads, 52osinte.adb, 52osinte.ads,
	53osinte.ads, 54osinte.ads, 5aosinte.adb, 5aosinte.ads,
	5asystem.ads, 5ataprop.adb, 5atasinf.ads, 5ataspri.ads,
	5atpopsp.adb, 5avxwork.ads, 5bosinte.adb, 5bosinte.ads,
	5bsystem.ads, 5cosinte.ads, 5esystem.ads, 5fintman.adb,
	5fosinte.ads, 5fsystem.ads, 5ftaprop.adb, 5ftasinf.ads,
	5ginterr.adb, 5gintman.adb, 5gmastop.adb, 5gosinte.ads,
	5gproinf.ads, 5gsystem.ads, 5gtaprop.adb, 5gtasinf.ads,
	5gtpgetc.adb, 5hosinte.adb, 5hosinte.ads, 5hsystem.ads,
	5htaprop.adb, 5htaspri.ads, 5htraceb.adb, 5iosinte.adb,
	5itaprop.adb, 5itaspri.ads, 5ksystem.ads, 5kvxwork.ads,
	5lintman.adb, 5lml-tgt.adb, 5losinte.ads, 5lsystem.ads,
	5mvxwork.ads, 5ninmaop.adb, 5nintman.adb, 5nosinte.ads,
	5ntaprop.adb, 5ntaspri.ads, 5ointerr.adb, 5omastop.adb,
	5oosinte.adb, 5oosinte.ads, 5oosprim.adb, 5oparame.adb,
	5osystem.ads, 5otaprop.adb, 5otaspri.ads, 5posinte.ads,
	5posprim.adb, 5pvxwork.ads, 5sintman.adb, 5sosinte.adb,
	5sosinte.ads, 5ssystem.ads, 5staprop.adb, 5stasinf.ads,
	5staspri.ads, 5svxwork.ads, 5tosinte.ads, 5vasthan.adb,
	5vinmaop.adb, 5vinterr.adb, 5vintman.adb, 5vintman.ads,
	5vmastop.adb, 5vosinte.adb, 5vosinte.ads, 5vosprim.adb,
	5vsystem.ads, 5vtaprop.adb, 5vtaspri.ads, 5vtpopde.adb,
	5vtpopde.ads, 5wgloloc.adb, 5wintman.adb, 5wmemory.adb,
	5wosprim.adb, 5wsystem.ads, 5wtaprop.adb, 5wtaspri.ads,
	5ysystem.ads, 5zinterr.adb, 5zintman.adb, 5zosinte.adb,
	5zosinte.ads, 5zosprim.adb, 5zsystem.ads, 5ztaprop.adb,
	6vcpp.adb, 6vcstrea.adb, 6vinterf.ads, 7sinmaop.adb,
	7sintman.adb, 7sosinte.adb, 7sosprim.adb, 7staprop.adb,
	7staspri.ads, 7stpopsp.adb, 7straceb.adb, 9drpc.adb,
	a-caldel.adb, a-caldel.ads, a-charac.ads, a-colien.ads,
	a-comlin.adb, adaint.c, adaint.h, ada-tree.def,
	a-diocst.adb, a-diocst.ads, a-direio.adb, a-except.adb,
	a-except.ads, a-excpol.adb, a-exctra.adb, a-exctra.ads,
	a-filico.adb, a-interr.adb, a-intsig.adb, a-intsig.ads,
	ali.adb, ali.ads, ali-util.adb, ali-util.ads,
	a-ngcefu.adb, a-ngcoty.adb, a-ngelfu.adb, a-nudira.adb,
	a-nudira.ads, a-nuflra.adb, a-nuflra.ads, a-reatim.adb,
	a-reatim.ads, a-retide.ads, a-sequio.adb, a-siocst.adb,
	a-siocst.ads, a-ssicst.adb, a-ssicst.ads, a-strbou.adb,
	a-strbou.ads, a-strfix.adb, a-strmap.adb, a-strsea.ads,
	a-strunb.adb, a-strunb.ads, a-ststio.adb, a-stunau.adb,
	a-stunau.ads, a-stwibo.adb, a-stwibo.ads, a-stwifi.adb,
	a-stwima.adb, a-stwiun.adb, a-stwiun.ads, a-tags.adb,
	a-tags.ads, a-tasatt.adb, a-taside.adb, a-teioed.adb,
	a-textio.adb, a-textio.ads, a-tienau.adb, a-tifiio.adb,
	a-tiflau.adb, a-tiflio.adb, a-tigeau.adb, a-tigeau.ads,
	a-tiinau.adb, a-timoau.adb, a-tiocst.adb, a-tiocst.ads,
	atree.adb, atree.ads, a-witeio.adb, a-witeio.ads,
	a-wtcstr.adb, a-wtcstr.ads, a-wtdeio.adb, a-wtedit.adb,
	a-wtenau.adb, a-wtflau.adb, a-wtinau.adb, a-wtmoau.adb,
	bcheck.adb, binde.adb, bindgen.adb, bindusg.adb,
	checks.adb, checks.ads, cio.c, comperr.adb,
	comperr.ads, csets.adb, cstand.adb, cstreams.c,
	debug_a.adb, debug_a.ads, debug.adb, decl.c,
	einfo.adb, einfo.ads, errout.adb, errout.ads,
	eval_fat.adb, eval_fat.ads, exp_aggr.adb, expander.adb,
	expander.ads, exp_attr.adb, exp_ch11.adb, exp_ch13.adb,
	exp_ch2.adb, exp_ch3.adb, exp_ch3.ads, exp_ch4.adb,
	exp_ch5.adb, exp_ch6.adb, exp_ch7.adb, exp_ch7.ads,
	exp_ch8.adb, exp_ch9.adb, exp_code.adb, exp_dbug.adb,
	exp_dbug.ads, exp_disp.adb, exp_dist.adb, expect.c,
	exp_fixd.adb, exp_imgv.adb, exp_intr.adb, exp_pakd.adb,
	exp_prag.adb, exp_strm.adb, exp_strm.ads, exp_tss.adb,
	exp_tss.ads, exp_util.adb, exp_util.ads, exp_vfpt.adb,
	fe.h, fmap.adb, fmap.ads, fname.adb,
	fname.ads, fname-uf.adb, fname-uf.ads, freeze.adb,
	freeze.ads, frontend.adb, g-awk.adb, g-awk.ads,
	g-busora.adb, g-busora.ads, g-busorg.adb, g-busorg.ads,
	g-casuti.adb, g-casuti.ads, g-catiio.adb, g-catiio.ads,
	g-cgi.adb, g-cgi.ads, g-cgicoo.adb, g-cgicoo.ads,
	g-cgideb.adb, g-cgideb.ads, g-comlin.adb, g-comlin.ads,
	g-crc32.adb, g-crc32.ads, g-debpoo.adb, g-debpoo.ads,
	g-debuti.adb, g-debuti.ads, g-diopit.adb, g-diopit.ads,
	g-dirope.adb, g-dirope.ads, g-dyntab.adb, g-dyntab.ads,
	g-except.ads, g-exctra.adb, g-exctra.ads, g-expect.adb,
	g-expect.ads, g-hesora.adb, g-hesora.ads, g-hesorg.adb,
	g-hesorg.ads, g-htable.adb, g-htable.ads, gigi.h,
	g-io.adb, g-io.ads, g-io_aux.adb, g-io_aux.ads,
	g-locfil.adb, g-locfil.ads, g-md5.adb, g-md5.ads,
	gmem.c, gnat1drv.adb, gnatbind.adb, gnatchop.adb,
	gnatcmd.adb, gnatfind.adb, gnatkr.adb, gnatlbr.adb,
	gnatlink.adb, gnatls.adb, gnatmake.adb, gnatmem.adb,
	gnatname.adb, gnatprep.adb, gnatprep.ads, gnatpsta.adb,
	gnatxref.adb, g-os_lib.adb, g-os_lib.ads, g-regexp.adb,
	g-regexp.ads, g-regist.adb, g-regist.ads, g-regpat.adb,
	g-regpat.ads, g-soccon.ads, g-socket.adb, g-socket.ads,
	g-socthi.adb, g-socthi.ads, g-soliop.ads, g-souinf.ads,
	g-speche.adb, g-speche.ads, g-spipat.adb, g-spipat.ads,
	g-spitbo.adb, g-spitbo.ads, g-sptabo.ads, g-sptain.ads,
	g-sptavs.ads, g-table.adb, g-table.ads, g-tasloc.adb,
	g-tasloc.ads, g-thread.adb, g-thread.ads, g-traceb.adb,
	g-traceb.ads, g-trasym.adb, g-trasym.ads, hostparm.ads,
	i-c.ads, i-cobol.adb, i-cpp.adb, i-cstrea.ads,
	i-cstrin.adb, i-cstrin.ads, impunit.adb, init.c,
	inline.adb, interfac.ads, i-pacdec.ads, itypes.adb,
	itypes.ads, i-vxwork.ads, lang.opt, lang-specs.h,
	layout.adb, lib.adb, lib.ads, lib-list.adb,
	lib-load.adb, lib-load.ads, lib-sort.adb, lib-util.adb,
	lib-writ.adb, lib-writ.ads, lib-xref.adb, lib-xref.ads,
	link.c, live.adb, make.adb, make.ads,
	Makefile.adalib, Makefile.in, Make-lang.in, makeusg.adb,
	mdll.adb, mdll-fil.adb, mdll-fil.ads, mdll-utl.adb,
	mdll-utl.ads, memroot.adb, memroot.ads, memtrack.adb,
	misc.c, mkdir.c, mlib.adb, mlib.ads,
	mlib-fil.adb, mlib-fil.ads, mlib-prj.adb, mlib-prj.ads,
	mlib-tgt.adb, mlib-tgt.ads, mlib-utl.adb, mlib-utl.ads,
	namet.adb, namet.ads, namet.h, nlists.ads,
	nlists.h, nmake.adt, opt.adb, opt.ads,
	osint.adb, osint.ads, osint-b.adb, osint-c.adb,
	par.adb, par-ch10.adb, par-ch11.adb, par-ch2.adb,
	par-ch3.adb, par-ch4.adb, par-ch5.adb, par-ch6.adb,
	par-ch9.adb, par-endh.adb, par-labl.adb, par-load.adb,
	par-prag.adb, par-sync.adb, par-tchk.adb, par-util.adb,
	prj.adb, prj.ads, prj-attr.adb, prj-attr.ads,
	prj-com.adb, prj-com.ads, prj-dect.adb, prj-dect.ads,
	prj-env.adb, prj-env.ads, prj-ext.adb, prj-ext.ads,
	prj-makr.adb, prj-makr.ads, prj-nmsc.adb, prj-nmsc.ads,
	prj-pars.adb, prj-pars.ads, prj-part.adb, prj-part.ads,
	prj-pp.adb, prj-pp.ads, prj-proc.adb, prj-proc.ads,
	prj-strt.adb, prj-strt.ads, prj-tree.adb, prj-tree.ads,
	prj-util.adb, prj-util.ads, raise.c, raise.h,
	repinfo.adb, repinfo.h, restrict.adb, restrict.ads,
	rident.ads, rtsfind.adb, rtsfind.ads, s-addima.ads,
	s-arit64.adb, s-assert.adb, s-assert.ads, s-atacco.adb,
	s-atacco.ads, s-auxdec.adb, s-auxdec.ads, s-bitops.adb,
	scans.ads, scn.adb, scn.ads, s-crc32.adb,
	s-crc32.ads, s-direio.adb, sem.adb, sem.ads,
	sem_aggr.adb, sem_attr.adb, sem_attr.ads, sem_case.adb,
	sem_case.ads, sem_cat.adb, sem_cat.ads, sem_ch10.adb,
	sem_ch11.adb, sem_ch12.adb, sem_ch12.ads, sem_ch13.adb,
	sem_ch13.ads, sem_ch3.adb, sem_ch3.ads, sem_ch4.adb,
	sem_ch5.adb, sem_ch5.ads, sem_ch6.adb, sem_ch6.ads,
	sem_ch7.adb, sem_ch7.ads, sem_ch8.adb, sem_ch8.ads,
	sem_ch9.adb, sem_disp.adb, sem_disp.ads, sem_dist.adb,
	sem_elab.adb, sem_eval.adb, sem_eval.ads, sem_intr.adb,
	sem_maps.adb, sem_mech.adb, sem_prag.adb, sem_prag.ads,
	sem_res.adb, sem_res.ads, sem_type.adb, sem_type.ads,
	sem_util.adb, sem_util.ads, sem_warn.adb, s-errrep.adb,
	s-errrep.ads, s-exctab.adb, s-exctab.ads, s-exnint.ads,
	s-exnllf.ads, s-exnlli.ads, s-expint.ads, s-explli.ads,
	s-expuns.ads, s-fatflt.ads, s-fatgen.adb, s-fatgen.ads,
	s-fatlfl.ads, s-fatllf.ads, s-fatsfl.ads, s-fileio.adb,
	s-fileio.ads, s-finimp.adb, s-finimp.ads, s-finroo.adb,
	s-finroo.ads, sfn_scan.adb, s-gloloc.adb, s-gloloc.ads,
	s-imgdec.adb, s-imgenu.adb, s-imgrea.adb, s-imgwch.adb,
	sinfo.adb, sinfo.ads, s-inmaop.ads, sinput.adb,
	sinput.ads, sinput-d.adb, sinput-l.adb, sinput-l.ads,
	sinput-p.adb, sinput-p.ads, s-interr.adb, s-interr.ads,
	s-intman.ads, s-maccod.ads, s-mastop.adb, s-mastop.ads,
	s-memory.adb, s-memory.ads, snames.adb, snames.ads,
	snames.h, s-osprim.ads, s-parame.ads, s-parint.ads,
	s-pooloc.adb, s-pooloc.ads, s-poosiz.adb, sprint.adb,
	s-proinf.ads, s-scaval.ads, s-secsta.adb, s-secsta.ads,
	s-sequio.adb, s-shasto.adb, s-shasto.ads, s-soflin.ads,
	s-stache.adb, s-stache.ads, s-stalib.adb, s-stalib.ads,
	s-stoele.ads, s-stopoo.ads, s-stratt.adb, s-stratt.ads,
	s-strops.adb, s-strops.ads, s-taasde.adb, s-taasde.ads,
	s-tadeca.adb, s-tadeca.ads, s-tadert.adb, s-tadert.ads,
	s-taenca.adb, s-taenca.ads, s-taprob.adb, s-taprob.ads,
	s-taprop.ads, s-tarest.adb, s-tarest.ads, s-tasdeb.adb,
	s-tasdeb.ads, s-tasinf.adb, s-tasinf.ads, s-tasini.adb,
	s-tasini.ads, s-taskin.adb, s-taskin.ads, s-tasque.adb,
	s-tasque.ads, s-tasren.adb, s-tasren.ads, s-tasres.ads,
	s-tassta.adb, s-tassta.ads, s-tasuti.adb, s-tasuti.ads,
	s-tataat.adb, s-tataat.ads, s-tpinop.adb, s-tpinop.ads,
	s-tpoben.adb, s-tpoben.ads, s-tpobop.adb, s-tpobop.ads,
	s-tposen.adb, s-tposen.ads, s-traceb.adb, s-traceb.ads,
	stringt.adb, stringt.ads, stringt.h, style.ads,
	stylesw.adb, stylesw.ads, s-unstyp.ads, s-vaflop.ads,
	s-valrea.adb, s-valuti.adb, s-vercon.adb, s-vmexta.adb,
	s-wchcnv.ads, s-wchcon.ads, s-widcha.adb, switch.adb,
	switch.ads, switch-b.adb, switch-c.adb, switch-m.adb,
	s-wwdcha.adb, s-wwdwch.adb, sysdep.c, system.ads,
	table.adb, table.ads, targparm.adb, targparm.ads,
	targtyps.c, tbuild.adb, tbuild.ads, tracebak.c,
	trans.c, tree_io.adb, treepr.adb, treeprs.adt,
	ttypes.ads, types.ads, types.h, uintp.adb,
	uintp.ads, uintp.h, uname.adb, urealp.adb,
	urealp.ads, urealp.h, usage.adb, utils2.c,
	utils.c, validsw.adb, validsw.ads, widechar.adb,
	xeinfo.adb, xnmake.adb, xref_lib.adb, xref_lib.ads,
	xr_tabls.adb, xr_tabls.ads, xtreeprs.adb, xsnames.adb,
	einfo.h, sinfo.h, treeprs.ads, nmake.ads, nmake.adb,
	gnatvsn.ads: Merge with ACT tree.

	* gnatvsn.adb: Rewritten in a simpler and more efficient way.


git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@72751 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 1807 insertions, 0 deletions

diff --git a/gcc/ada/a-strsup.adb b/gcc/ada/a-strsup.adb
new file mode 100644
index 00000000000..8ae039336d9
--- /dev/null
+++ b/gcc/ada/a-strsup.adb
@@ -0,0 +1,1807 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT RUNTIME COMPONENTS                          --
+--                                                                          --
+--             A D A . S T R I N G S . S U P E R B O U N D E D              --
+--                                                                          --
+--                                 B o d y                                  --
+--                                                                          --
+--          Copyright (C) 2003 Free Software Foundation, Inc.               --
+--                                                                          --
+-- GNAT is free software;  you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
+-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
+-- for  more details.  You should have  received  a copy of the GNU General --
+-- Public License  distributed with GNAT;  see file COPYING.  If not, write --
+-- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
+-- MA 02111-1307, USA.                                                      --
+--                                                                          --
+-- As a special exception,  if other files  instantiate  generics from this --
+-- unit, or you link  this unit with other files  to produce an executable, --
+-- this  unit  does not  by itself cause  the resulting  executable  to  be --
+-- covered  by the  GNU  General  Public  License.  This exception does not --
+-- however invalidate  any other reasons why  the executable file  might be --
+-- covered by the  GNU Public License.                                      --
+--                                                                          --
+-- GNAT was originally developed  by the GNAT team at  New York University. --
+-- Extensive contributions were provided by Ada Core Technologies Inc.      --
+--                                                                          --
+------------------------------------------------------------------------------
+
+with Ada.Strings.Maps;   use Ada.Strings.Maps;
+with Ada.Strings.Search;
+
+package body Ada.Strings.Superbounded is
+
+   ------------
+   -- Concat --
+   ------------
+
+   function Concat
+     (Left  : Super_String;
+      Right : Super_String)
+      return  Super_String
+   is
+      Result : Super_String (Left.Max_Length);
+      Llen   : constant Natural := Left.Current_Length;
+      Rlen   : constant Natural := Right.Current_Length;
+      Nlen   : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen > Left.Max_Length then
+         raise Ada.Strings.Length_Error;
+      else
+         Result.Current_Length := Nlen;
+         Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+         Result.Data (Llen + 1 .. Nlen) := Right.Data (1 .. Rlen);
+      end if;
+
+      return Result;
+   end Concat;
+
+   function Concat
+     (Left  : Super_String;
+      Right : String)
+      return  Super_String
+   is
+      Result : Super_String (Left.Max_Length);
+      Llen   : constant Natural := Left.Current_Length;
+
+      Nlen   : constant Natural := Llen + Right'Length;
+
+   begin
+      if Nlen > Left.Max_Length then
+         raise Ada.Strings.Length_Error;
+      else
+         Result.Current_Length := Nlen;
+         Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+         Result.Data (Llen + 1 .. Nlen) := Right;
+      end if;
+      return Result;
+   end Concat;
+
+   function Concat
+     (Left  : String;
+      Right : Super_String)
+      return  Super_String
+   is
+      Result : Super_String (Right.Max_Length);
+      Llen   : constant Natural := Left'Length;
+      Rlen   : constant Natural := Right.Current_Length;
+      Nlen   : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen > Right.Max_Length then
+         raise Ada.Strings.Length_Error;
+      else
+         Result.Current_Length := Nlen;
+         Result.Data (1 .. Llen) := Left;
+         Result.Data (Llen + 1 .. Nlen) := Right.Data (1 .. Rlen);
+      end if;
+
+      return Result;
+   end Concat;
+
+   function Concat
+     (Left  : Super_String;
+      Right : Character)
+      return  Super_String
+   is
+      Result : Super_String (Left.Max_Length);
+      Llen   : constant Natural := Left.Current_Length;
+
+   begin
+      if Llen = Left.Max_Length then
+         raise Ada.Strings.Length_Error;
+      else
+         Result.Current_Length := Llen + 1;
+         Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+         Result.Data (Result.Current_Length) := Right;
+      end if;
+
+      return Result;
+   end Concat;
+
+   function Concat
+     (Left  : Character;
+      Right : Super_String)
+      return  Super_String
+   is
+      Result : Super_String (Right.Max_Length);
+      Rlen   : constant Natural := Right.Current_Length;
+
+   begin
+      if Rlen = Right.Max_Length then
+         raise Ada.Strings.Length_Error;
+      else
+         Result.Current_Length := Rlen + 1;
+         Result.Data (1) := Left;
+         Result.Data (2 .. Result.Current_Length) := Right.Data (1 .. Rlen);
+      end if;
+
+      return Result;
+   end Concat;
+
+   -----------
+   -- Equal --
+   -----------
+
+   function "=" (Left, Right : Super_String) return Boolean is
+   begin
+      return Left.Current_Length = Right.Current_Length
+        and then Left.Data (1 .. Left.Current_Length) =
+                   Right.Data (1 .. Right.Current_Length);
+   end "=";
+
+   function Equal (Left : Super_String; Right : String)
+                   return Boolean is
+   begin
+      return Left.Current_Length = Right'Length
+        and then Left.Data (1 .. Left.Current_Length) = Right;
+   end Equal;
+
+   function Equal (Left : String; Right : Super_String)
+                   return Boolean is
+   begin
+      return Left'Length = Right.Current_Length
+        and then Left = Right.Data (1 .. Right.Current_Length);
+   end Equal;
+
+   -------------
+   -- Greater --
+   -------------
+
+   function Greater (Left, Right : Super_String) return Boolean is
+   begin
+      return Left.Data (1 .. Left.Current_Length) >
+               Right.Data (1 .. Right.Current_Length);
+   end Greater;
+
+   function Greater
+     (Left  : Super_String;
+      Right : String)
+      return  Boolean
+   is
+   begin
+      return Left.Data (1 .. Left.Current_Length) > Right;
+   end Greater;
+
+   function Greater
+     (Left  : String;
+      Right : Super_String)
+      return  Boolean
+   is
+   begin
+      return Left > Right.Data (1 .. Right.Current_Length);
+   end Greater;
+
+   ----------------------
+   -- Greater_Or_Equal --
+   ----------------------
+
+   function Greater_Or_Equal (Left, Right : Super_String) return Boolean is
+   begin
+      return Left.Data (1 .. Left.Current_Length) >=
+               Right.Data (1 .. Right.Current_Length);
+   end Greater_Or_Equal;
+
+   function Greater_Or_Equal
+     (Left  : Super_String;
+      Right : String)
+      return  Boolean
+   is
+   begin
+      return Left.Data (1 .. Left.Current_Length) >= Right;
+   end Greater_Or_Equal;
+
+   function Greater_Or_Equal
+     (Left  : String;
+      Right : Super_String)
+      return  Boolean
+   is
+   begin
+      return Left >= Right.Data (1 .. Right.Current_Length);
+   end Greater_Or_Equal;
+
+   ----------
+   -- Less --
+   ----------
+
+   function Less (Left, Right : Super_String) return Boolean is
+   begin
+      return Left.Data (1 .. Left.Current_Length) <
+               Right.Data (1 .. Right.Current_Length);
+   end Less;
+
+   function Less
+     (Left  : Super_String;
+      Right : String)
+      return  Boolean
+   is
+   begin
+      return Left.Data (1 .. Left.Current_Length) < Right;
+   end Less;
+
+   function Less
+     (Left  : String;
+      Right : Super_String)
+      return  Boolean
+   is
+   begin
+      return Left < Right.Data (1 .. Right.Current_Length);
+   end Less;
+
+   -------------------
+   -- Less_Or_Equal --
+   -------------------
+
+   function Less_Or_Equal (Left, Right : Super_String) return Boolean is
+   begin
+      return Left.Data (1 .. Left.Current_Length) <=
+               Right.Data (1 .. Right.Current_Length);
+   end Less_Or_Equal;
+
+   function Less_Or_Equal
+     (Left  : Super_String;
+      Right : String)
+      return  Boolean
+   is
+   begin
+      return Left.Data (1 .. Left.Current_Length) <= Right;
+   end Less_Or_Equal;
+
+   function Less_Or_Equal
+     (Left  : String;
+      Right : Super_String)
+      return  Boolean
+   is
+   begin
+      return Left <= Right.Data (1 .. Right.Current_Length);
+   end Less_Or_Equal;
+
+   ------------------
+   -- Super_Append --
+   ------------------
+
+   --  Case of Super_String and Super_String
+
+   function Super_Append
+     (Left, Right : Super_String;
+      Drop        : Strings.Truncation  := Strings.Error)
+      return        Super_String
+   is
+      Max_Length : constant Positive := Left.Max_Length;
+      Result : Super_String (Max_Length);
+      Llen   : constant Natural := Left.Current_Length;
+      Rlen   : constant Natural := Right.Current_Length;
+      Nlen   : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen <= Max_Length then
+         Result.Current_Length := Nlen;
+         Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+         Result.Data (Llen + 1 .. Nlen) := Right.Data (1 .. Rlen);
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Llen >= Max_Length then -- only case is Llen = Max_Length
+                  Result.Data := Left.Data;
+
+               else
+                  Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+                  Result.Data (Llen + 1 .. Max_Length) :=
+                    Right.Data (1 .. Max_Length - Llen);
+               end if;
+
+            when Strings.Left =>
+               if Rlen >= Max_Length then -- only case is Rlen = Max_Length
+                  Result.Data := Right.Data;
+
+               else
+                  Result.Data (1 .. Max_Length - Rlen) :=
+                    Left.Data (Llen - (Max_Length - Rlen - 1) .. Llen);
+                  Result.Data (Max_Length - Rlen + 1 .. Max_Length) :=
+                    Right.Data (1 .. Rlen);
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Append;
+
+   procedure Super_Append
+     (Source   : in out Super_String;
+      New_Item : Super_String;
+      Drop     : Truncation  := Error)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Llen       : constant Natural := Source.Current_Length;
+      Rlen       : constant Natural := New_Item.Current_Length;
+      Nlen       : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen <= Max_Length then
+         Source.Current_Length := Nlen;
+         Source.Data (Llen + 1 .. Nlen) := New_Item.Data (1 .. Rlen);
+
+      else
+         Source.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Llen < Max_Length then
+                  Source.Data (Llen + 1 .. Max_Length) :=
+                    New_Item.Data (1 .. Max_Length - Llen);
+               end if;
+
+            when Strings.Left =>
+               if Rlen >= Max_Length then -- only case is Rlen = Max_Length
+                  Source.Data := New_Item.Data;
+
+               else
+                  Source.Data (1 .. Max_Length - Rlen) :=
+                    Source.Data (Llen - (Max_Length - Rlen - 1) .. Llen);
+                  Source.Data (Max_Length - Rlen + 1 .. Max_Length) :=
+                    New_Item.Data (1 .. Rlen);
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+   end Super_Append;
+
+   --  Case of Super_String and String
+
+   function Super_Append
+     (Left  : Super_String;
+      Right : String;
+      Drop  : Strings.Truncation := Strings.Error)
+      return  Super_String
+   is
+      Max_Length : constant Positive := Left.Max_Length;
+      Result : Super_String (Max_Length);
+      Llen   : constant Natural := Left.Current_Length;
+      Rlen   : constant Natural := Right'Length;
+      Nlen   : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen <= Max_Length then
+         Result.Current_Length := Nlen;
+         Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+         Result.Data (Llen + 1 .. Nlen) := Right;
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Llen >= Max_Length then -- only case is Llen = Max_Length
+                  Result.Data := Left.Data;
+
+               else
+                  Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+                  Result.Data (Llen + 1 .. Max_Length) :=
+                    Right (Right'First .. Right'First - 1 +
+                             Max_Length - Llen);
+
+               end if;
+
+            when Strings.Left =>
+               if Rlen >= Max_Length then
+                  Result.Data (1 .. Max_Length) :=
+                    Right (Right'Last - (Max_Length - 1) .. Right'Last);
+
+               else
+                  Result.Data (1 .. Max_Length - Rlen) :=
+                    Left.Data (Llen - (Max_Length - Rlen - 1) .. Llen);
+                  Result.Data (Max_Length - Rlen + 1 .. Max_Length) :=
+                    Right;
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Append;
+
+   procedure Super_Append
+     (Source   : in out Super_String;
+      New_Item : String;
+      Drop     : Truncation  := Error)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Llen   : constant Natural := Source.Current_Length;
+      Rlen   : constant Natural := New_Item'Length;
+      Nlen   : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen <= Max_Length then
+         Source.Current_Length := Nlen;
+         Source.Data (Llen + 1 .. Nlen) := New_Item;
+
+      else
+         Source.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Llen < Max_Length then
+                  Source.Data (Llen + 1 .. Max_Length) :=
+                    New_Item (New_Item'First ..
+                                New_Item'First - 1 + Max_Length - Llen);
+               end if;
+
+            when Strings.Left =>
+               if Rlen >= Max_Length then
+                  Source.Data (1 .. Max_Length) :=
+                    New_Item (New_Item'Last - (Max_Length - 1) ..
+                                New_Item'Last);
+
+               else
+                  Source.Data (1 .. Max_Length - Rlen) :=
+                    Source.Data (Llen - (Max_Length - Rlen - 1) .. Llen);
+                  Source.Data (Max_Length - Rlen + 1 .. Max_Length) :=
+                    New_Item;
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+   end Super_Append;
+
+   --  Case of String and Super_String
+
+   function Super_Append
+     (Left  : String;
+      Right : Super_String;
+      Drop  : Strings.Truncation := Strings.Error)
+      return  Super_String
+   is
+      Max_Length : constant Positive := Right.Max_Length;
+      Result     : Super_String (Max_Length);
+      Llen       : constant Natural := Left'Length;
+      Rlen       : constant Natural := Right.Current_Length;
+      Nlen       : constant Natural := Llen + Rlen;
+
+   begin
+      if Nlen <= Max_Length then
+         Result.Current_Length := Nlen;
+         Result.Data (1 .. Llen) := Left;
+         Result.Data (Llen + 1 .. Llen + Rlen) := Right.Data (1 .. Rlen);
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Llen >= Max_Length then
+                  Result.Data (1 .. Max_Length) :=
+                    Left (Left'First .. Left'First + (Max_Length - 1));
+
+               else
+                  Result.Data (1 .. Llen) := Left;
+                  Result.Data (Llen + 1 .. Max_Length) :=
+                    Right.Data (1 .. Max_Length - Llen);
+               end if;
+
+            when Strings.Left =>
+               if Rlen >= Max_Length then
+                  Result.Data (1 .. Max_Length) :=
+                    Right.Data (Rlen - (Max_Length - 1) .. Rlen);
+
+               else
+                  Result.Data (1 .. Max_Length - Rlen) :=
+                    Left (Left'Last - (Max_Length - Rlen - 1) .. Left'Last);
+                  Result.Data (Max_Length - Rlen + 1 .. Max_Length) :=
+                    Right.Data (1 .. Rlen);
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Append;
+
+   --  Case of Super_String and Character
+
+   function Super_Append
+     (Left  : Super_String;
+      Right : Character;
+      Drop  : Strings.Truncation := Strings.Error)
+      return  Super_String
+   is
+      Max_Length : constant Positive := Left.Max_Length;
+      Result     : Super_String (Max_Length);
+      Llen       : constant Natural := Left.Current_Length;
+
+   begin
+      if Llen  < Max_Length then
+         Result.Current_Length := Llen + 1;
+         Result.Data (1 .. Llen) := Left.Data (1 .. Llen);
+         Result.Data (Llen + 1) := Right;
+         return Result;
+
+      else
+         case Drop is
+            when Strings.Right =>
+               return Left;
+
+            when Strings.Left =>
+               Result.Current_Length := Max_Length;
+               Result.Data (1 .. Max_Length - 1) :=
+                 Left.Data (2 .. Max_Length);
+               Result.Data (Max_Length) := Right;
+               return Result;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+   end Super_Append;
+
+   procedure Super_Append
+     (Source   : in out Super_String;
+      New_Item : Character;
+      Drop     : Truncation  := Error)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Llen       : constant Natural  := Source.Current_Length;
+
+   begin
+      if Llen  < Max_Length then
+         Source.Current_Length := Llen + 1;
+         Source.Data (Llen + 1) := New_Item;
+
+      else
+         Source.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               null;
+
+            when Strings.Left =>
+               Source.Data (1 .. Max_Length - 1) :=
+                 Source.Data (2 .. Max_Length);
+               Source.Data (Max_Length) := New_Item;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+   end Super_Append;
+
+   --  Case of Character and Super_String
+
+   function Super_Append
+     (Left  : Character;
+      Right : Super_String;
+      Drop  : Strings.Truncation := Strings.Error)
+      return  Super_String
+   is
+      Max_Length : constant Positive := Right.Max_Length;
+      Result : Super_String (Max_Length);
+      Rlen   : constant Natural := Right.Current_Length;
+
+   begin
+      if Rlen < Max_Length then
+         Result.Current_Length := Rlen + 1;
+         Result.Data (1) := Left;
+         Result.Data (2 .. Rlen + 1) := Right.Data (1 .. Rlen);
+         return Result;
+
+      else
+         case Drop is
+            when Strings.Right =>
+               Result.Current_Length := Max_Length;
+               Result.Data (1) := Left;
+               Result.Data (2 .. Max_Length) :=
+                 Right.Data (1 .. Max_Length - 1);
+               return Result;
+
+            when Strings.Left =>
+               return Right;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+   end Super_Append;
+
+   -----------------
+   -- Super_Count --
+   -----------------
+
+   function Super_Count
+     (Source   : Super_String;
+      Pattern  : String;
+      Mapping  : Maps.Character_Mapping := Maps.Identity)
+      return     Natural
+   is
+   begin
+      return
+        Search.Count
+          (Source.Data (1 .. Source.Current_Length), Pattern, Mapping);
+   end Super_Count;
+
+   function Super_Count
+     (Source   : Super_String;
+      Pattern  : String;
+      Mapping  : Maps.Character_Mapping_Function)
+      return     Natural
+   is
+   begin
+      return
+        Search.Count
+          (Source.Data (1 .. Source.Current_Length), Pattern, Mapping);
+   end Super_Count;
+
+   function Super_Count
+     (Source : Super_String;
+      Set    : Maps.Character_Set)
+      return   Natural
+   is
+   begin
+      return Search.Count (Source.Data (1 .. Source.Current_Length), Set);
+   end Super_Count;
+
+   ------------------
+   -- Super_Delete --
+   ------------------
+
+   function Super_Delete
+     (Source  : Super_String;
+      From    : Positive;
+      Through : Natural)
+      return    Super_String
+   is
+      Result     : Super_String (Source.Max_Length);
+      Slen       : constant Natural := Source.Current_Length;
+      Num_Delete : constant Integer := Through - From + 1;
+
+   begin
+      if Num_Delete <= 0 then
+         return Source;
+
+      elsif From > Slen + 1 then
+         raise Ada.Strings.Index_Error;
+
+      elsif Through >= Slen then
+         Result.Current_Length := From - 1;
+         Result.Data (1 .. From - 1) := Source.Data (1 .. From - 1);
+         return Result;
+
+      else
+         Result.Current_Length := Slen - Num_Delete;
+         Result.Data (1 .. From - 1) := Source.Data (1 .. From - 1);
+         Result.Data (From .. Result.Current_Length) :=
+           Source.Data (Through + 1 .. Slen);
+         return Result;
+      end if;
+   end Super_Delete;
+
+   procedure Super_Delete
+     (Source  : in out Super_String;
+      From    : Positive;
+      Through : Natural)
+   is
+      Slen       : constant Natural := Source.Current_Length;
+      Num_Delete : constant Integer := Through - From + 1;
+
+   begin
+      if Num_Delete <= 0 then
+         return;
+
+      elsif From > Slen + 1 then
+         raise Ada.Strings.Index_Error;
+
+      elsif Through >= Slen then
+         Source.Current_Length := From - 1;
+
+      else
+         Source.Current_Length := Slen - Num_Delete;
+         Source.Data (From .. Source.Current_Length) :=
+           Source.Data (Through + 1 .. Slen);
+      end if;
+   end Super_Delete;
+
+   -------------------
+   -- Super_Element --
+   -------------------
+
+   function Super_Element
+     (Source : Super_String;
+      Index  : Positive)
+      return   Character
+   is
+   begin
+      if Index in 1 .. Source.Current_Length then
+         return Source.Data (Index);
+      else
+         raise Strings.Index_Error;
+      end if;
+   end Super_Element;
+
+   ----------------------
+   -- Super_Find_Token --
+   ----------------------
+
+   procedure Super_Find_Token
+     (Source : Super_String;
+      Set    : Maps.Character_Set;
+      Test   : Strings.Membership;
+      First  : out Positive;
+      Last   : out Natural)
+   is
+   begin
+      Search.Find_Token
+        (Source.Data (1 .. Source.Current_Length), Set, Test, First, Last);
+   end Super_Find_Token;
+
+   ----------------
+   -- Super_Head --
+   ----------------
+
+   function Super_Head
+     (Source : Super_String;
+      Count  : Natural;
+      Pad    : Character := Space;
+      Drop   : Strings.Truncation := Strings.Error)
+      return   Super_String
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Result     : Super_String (Max_Length);
+      Slen       : constant Natural := Source.Current_Length;
+      Npad       : constant Integer := Count - Slen;
+
+   begin
+      if Npad <= 0 then
+         Result.Current_Length := Count;
+         Result.Data (1 .. Count) := Source.Data (1 .. Count);
+
+      elsif Count <= Max_Length then
+         Result.Current_Length := Count;
+         Result.Data (1 .. Slen) := Source.Data (1 .. Slen);
+         Result.Data (Slen + 1 .. Count) := (others => Pad);
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               Result.Data (1 .. Slen) := Source.Data (1 .. Slen);
+               Result.Data (Slen + 1 .. Max_Length) := (others => Pad);
+
+            when Strings.Left =>
+               if Npad >= Max_Length then
+                  Result.Data := (others => Pad);
+
+               else
+                  Result.Data (1 .. Max_Length - Npad) :=
+                    Source.Data (Count - Max_Length + 1 .. Slen);
+                  Result.Data (Max_Length - Npad + 1 .. Max_Length) :=
+                    (others => Pad);
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Head;
+
+   procedure Super_Head
+     (Source : in out Super_String;
+      Count  : Natural;
+      Pad    : Character  := Space;
+      Drop   : Truncation := Error)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Slen       : constant Natural  := Source.Current_Length;
+      Npad       : constant Integer  := Count - Slen;
+      Temp       : String (1 .. Max_Length);
+
+   begin
+      if Npad <= 0 then
+         Source.Current_Length := Count;
+
+      elsif Count <= Max_Length then
+         Source.Current_Length := Count;
+         Source.Data (Slen + 1 .. Count) := (others => Pad);
+
+      else
+         Source.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               Source.Data (Slen + 1 .. Max_Length) := (others => Pad);
+
+            when Strings.Left =>
+               if Npad > Max_Length then
+                  Source.Data := (others => Pad);
+
+               else
+                  Temp := Source.Data;
+                  Source.Data (1 .. Max_Length - Npad) :=
+                    Temp (Count - Max_Length + 1 .. Slen);
+
+                  for J in Max_Length - Npad + 1 .. Max_Length loop
+                     Source.Data (J) := Pad;
+                  end loop;
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+   end Super_Head;
+
+   -----------------
+   -- Super_Index --
+   -----------------
+
+   function Super_Index
+     (Source   : Super_String;
+      Pattern  : String;
+      Going    : Strings.Direction := Strings.Forward;
+      Mapping  : Maps.Character_Mapping := Maps.Identity)
+      return     Natural
+   is
+   begin
+      return Search.Index
+        (Source.Data (1 .. Source.Current_Length), Pattern, Going, Mapping);
+   end Super_Index;
+
+   function Super_Index
+     (Source   : Super_String;
+      Pattern  : String;
+      Going    : Direction := Forward;
+      Mapping  : Maps.Character_Mapping_Function)
+      return     Natural
+   is
+   begin
+      return Search.Index
+        (Source.Data (1 .. Source.Current_Length), Pattern, Going, Mapping);
+   end Super_Index;
+
+   function Super_Index
+     (Source : Super_String;
+      Set    : Maps.Character_Set;
+      Test   : Strings.Membership := Strings.Inside;
+      Going  : Strings.Direction  := Strings.Forward)
+      return   Natural
+   is
+   begin
+      return Search.Index
+        (Source.Data (1 .. Source.Current_Length), Set, Test, Going);
+   end Super_Index;
+
+   ---------------------------
+   -- Super_Index_Non_Blank --
+   ---------------------------
+
+   function Super_Index_Non_Blank
+     (Source : Super_String;
+      Going  : Strings.Direction := Strings.Forward)
+      return   Natural
+   is
+   begin
+      return
+        Search.Index_Non_Blank
+          (Source.Data (1 .. Source.Current_Length), Going);
+   end Super_Index_Non_Blank;
+
+   ------------------
+   -- Super_Insert --
+   ------------------
+
+   function Super_Insert
+     (Source   : Super_String;
+      Before   : Positive;
+      New_Item : String;
+      Drop     : Strings.Truncation := Strings.Error)
+      return     Super_String
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Result     : Super_String (Max_Length);
+      Slen       : constant Natural := Source.Current_Length;
+      Nlen       : constant Natural := New_Item'Length;
+      Tlen       : constant Natural := Slen + Nlen;
+      Blen       : constant Natural := Before - 1;
+      Alen       : constant Integer := Slen - Blen;
+      Droplen    : constant Integer := Tlen - Max_Length;
+
+      --  Tlen is the length of the total string before possible truncation.
+      --  Blen, Alen are the lengths of the before and after pieces of the
+      --  source string.
+
+   begin
+      if Alen < 0 then
+         raise Ada.Strings.Index_Error;
+
+      elsif Droplen <= 0 then
+         Result.Current_Length := Tlen;
+         Result.Data (1 .. Blen) := Source.Data (1 .. Blen);
+         Result.Data (Before .. Before + Nlen - 1) := New_Item;
+         Result.Data (Before + Nlen .. Tlen) :=
+           Source.Data (Before .. Slen);
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               Result.Data (1 .. Blen) := Source.Data (1 .. Blen);
+
+               if Droplen > Alen then
+                  Result.Data (Before .. Max_Length) :=
+                    New_Item (New_Item'First
+                                .. New_Item'First + Max_Length - Before);
+               else
+                  Result.Data (Before .. Before + Nlen - 1) := New_Item;
+                  Result.Data (Before + Nlen .. Max_Length) :=
+                    Source.Data (Before .. Slen - Droplen);
+               end if;
+
+            when Strings.Left =>
+               Result.Data (Max_Length - (Alen - 1) .. Max_Length) :=
+                 Source.Data (Before .. Slen);
+
+               if Droplen >= Blen then
+                  Result.Data (1 .. Max_Length - Alen) :=
+                    New_Item (New_Item'Last - (Max_Length - Alen) + 1
+                                .. New_Item'Last);
+               else
+                  Result.Data
+                    (Blen - Droplen + 1 .. Max_Length - Alen) :=
+                    New_Item;
+                  Result.Data (1 .. Blen - Droplen) :=
+                    Source.Data (Droplen + 1 .. Blen);
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Insert;
+
+   procedure Super_Insert
+     (Source   : in out Super_String;
+      Before   : Positive;
+      New_Item : String;
+      Drop     : Strings.Truncation := Strings.Error)
+   is
+   begin
+      --  We do a double copy here because this is one of the situations
+      --  in which we move data to the right, and at least at the moment,
+      --  GNAT is not handling such cases correctly ???
+
+      Source := Super_Insert (Source, Before, New_Item, Drop);
+   end Super_Insert;
+
+   ------------------
+   -- Super_Length --
+   ------------------
+
+   function Super_Length (Source : Super_String) return Natural is
+   begin
+      return Source.Current_Length;
+   end Super_Length;
+
+   ---------------------
+   -- Super_Overwrite --
+   ---------------------
+
+   function Super_Overwrite
+     (Source    : Super_String;
+      Position  : Positive;
+      New_Item  : String;
+      Drop      : Strings.Truncation := Strings.Error)
+      return      Super_String
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Result     : Super_String (Max_Length);
+      Endpos     : constant Natural  := Position + New_Item'Length - 1;
+      Slen       : constant Natural  := Source.Current_Length;
+      Droplen    : Natural;
+
+   begin
+      if Position > Slen + 1 then
+         raise Ada.Strings.Index_Error;
+
+      elsif New_Item'Length = 0 then
+         return Source;
+
+      elsif Endpos <= Slen then
+         Result.Current_Length := Source.Current_Length;
+         Result.Data (1 .. Slen) := Source.Data (1 .. Slen);
+         Result.Data (Position .. Endpos) := New_Item;
+         return Result;
+
+      elsif Endpos <= Max_Length then
+         Result.Current_Length := Endpos;
+         Result.Data (1 .. Position - 1) := Source.Data (1 .. Position - 1);
+         Result.Data (Position .. Endpos) := New_Item;
+         return Result;
+
+      else
+         Result.Current_Length := Max_Length;
+         Droplen := Endpos - Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               Result.Data (1 .. Position - 1) :=
+                 Source.Data (1 .. Position - 1);
+
+               Result.Data (Position .. Max_Length) :=
+                 New_Item (New_Item'First .. New_Item'Last - Droplen);
+               return Result;
+
+            when Strings.Left =>
+               if New_Item'Length >= Max_Length then
+                  Result.Data (1 .. Max_Length) :=
+                    New_Item (New_Item'Last - Max_Length + 1 ..
+                                New_Item'Last);
+                  return Result;
+
+               else
+                  Result.Data (1 .. Max_Length - New_Item'Length) :=
+                    Source.Data (Droplen + 1 .. Position - 1);
+                  Result.Data
+                    (Max_Length - New_Item'Length + 1 .. Max_Length) :=
+                    New_Item;
+                  return Result;
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+   end Super_Overwrite;
+
+   procedure Super_Overwrite
+     (Source    : in out Super_String;
+      Position  : Positive;
+      New_Item  : String;
+      Drop      : Strings.Truncation := Strings.Error)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Endpos     : constant Positive := Position + New_Item'Length - 1;
+      Slen       : constant Natural  := Source.Current_Length;
+      Droplen    : Natural;
+
+   begin
+      if Position > Slen + 1 then
+         raise Ada.Strings.Index_Error;
+
+      elsif Endpos <= Slen then
+         Source.Data (Position .. Endpos) := New_Item;
+
+      elsif Endpos <= Max_Length then
+         Source.Data (Position .. Endpos) := New_Item;
+         Source.Current_Length := Endpos;
+
+      else
+         Source.Current_Length := Max_Length;
+         Droplen := Endpos - Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               Source.Data (Position .. Max_Length) :=
+                 New_Item (New_Item'First .. New_Item'Last - Droplen);
+
+            when Strings.Left =>
+               if New_Item'Length > Max_Length then
+                  Source.Data (1 .. Max_Length) :=
+                    New_Item (New_Item'Last - Max_Length + 1 ..
+                                New_Item'Last);
+
+               else
+                  Source.Data (1 .. Max_Length - New_Item'Length) :=
+                    Source.Data (Droplen + 1 .. Position - 1);
+
+                  Source.Data
+                    (Max_Length - New_Item'Length + 1 .. Max_Length) :=
+                    New_Item;
+               end if;
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+   end Super_Overwrite;
+
+   ---------------------------
+   -- Super_Replace_Element --
+   ---------------------------
+
+   procedure Super_Replace_Element
+     (Source : in out Super_String;
+      Index  : Positive;
+      By     : Character)
+   is
+   begin
+      if Index <= Source.Current_Length then
+         Source.Data (Index) := By;
+      else
+         raise Ada.Strings.Index_Error;
+      end if;
+   end Super_Replace_Element;
+
+   -------------------------
+   -- Super_Replace_Slice --
+   -------------------------
+
+   function Super_Replace_Slice
+     (Source   : Super_String;
+      Low      : Positive;
+      High     : Natural;
+      By       : String;
+      Drop     : Strings.Truncation := Strings.Error)
+      return     Super_String
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Slen       : constant Natural  := Source.Current_Length;
+
+   begin
+      if Low > Slen + 1 then
+         raise Strings.Index_Error;
+
+      elsif High < Low then
+         return Super_Insert (Source, Low, By, Drop);
+
+      else
+         declare
+            Blen    : constant Natural := Natural'Max (0, Low - 1);
+            Alen    : constant Natural := Natural'Max (0, Slen - High);
+            Tlen    : constant Natural := Blen + By'Length + Alen;
+            Droplen : constant Integer := Tlen - Max_Length;
+            Result  : Super_String (Max_Length);
+
+            --  Tlen is the total length of the result string before any
+            --  truncation. Blen and Alen are the lengths of the pieces
+            --  of the original string that end up in the result string
+            --  before and after the replaced slice.
+
+         begin
+            if Droplen <= 0 then
+               Result.Current_Length := Tlen;
+               Result.Data (1 .. Blen) := Source.Data (1 .. Blen);
+               Result.Data (Low .. Low + By'Length - 1) := By;
+               Result.Data (Low + By'Length .. Tlen) :=
+                 Source.Data (High + 1 .. Slen);
+
+            else
+               Result.Current_Length := Max_Length;
+
+               case Drop is
+                  when Strings.Right =>
+                     Result.Data (1 .. Blen) := Source.Data (1 .. Blen);
+
+                     if Droplen > Alen then
+                        Result.Data (Low .. Max_Length) :=
+                          By (By'First .. By'First + Max_Length - Low);
+                     else
+                        Result.Data (Low .. Low + By'Length - 1) := By;
+                        Result.Data (Low + By'Length .. Max_Length) :=
+                          Source.Data (High + 1 .. Slen - Droplen);
+                     end if;
+
+                  when Strings.Left =>
+                     Result.Data (Max_Length - (Alen - 1) .. Max_Length) :=
+                       Source.Data (High + 1 .. Slen);
+
+                     if Droplen >= Blen then
+                        Result.Data (1 .. Max_Length - Alen) :=
+                          By (By'Last - (Max_Length - Alen) + 1 .. By'Last);
+                     else
+                        Result.Data
+                          (Blen - Droplen + 1 .. Max_Length - Alen) := By;
+                        Result.Data (1 .. Blen - Droplen) :=
+                          Source.Data (Droplen + 1 .. Blen);
+                     end if;
+
+                  when Strings.Error =>
+                     raise Ada.Strings.Length_Error;
+               end case;
+            end if;
+
+            return Result;
+         end;
+      end if;
+   end Super_Replace_Slice;
+
+   procedure Super_Replace_Slice
+     (Source   : in out Super_String;
+      Low      : Positive;
+      High     : Natural;
+      By       : String;
+      Drop     : Strings.Truncation := Strings.Error)
+   is
+   begin
+      --  We do a double copy here because this is one of the situations
+      --  in which we move data to the right, and at least at the moment,
+      --  GNAT is not handling such cases correctly ???
+
+      Source := Super_Replace_Slice (Source, Low, High, By, Drop);
+   end Super_Replace_Slice;
+
+   ---------------------
+   -- Super_Replicate --
+   ---------------------
+
+   function Super_Replicate
+     (Count      : Natural;
+      Item       : Character;
+      Drop       : Truncation := Error;
+      Max_Length : Positive)
+      return       Super_String
+   is
+      Result : Super_String (Max_Length);
+
+   begin
+      if Count <= Max_Length then
+         Result.Current_Length := Count;
+
+      elsif Drop = Strings.Error then
+         raise Ada.Strings.Length_Error;
+
+      else
+         Result.Current_Length := Max_Length;
+      end if;
+
+      Result.Data (1 .. Result.Current_Length) := (others => Item);
+      return Result;
+   end Super_Replicate;
+
+   function Super_Replicate
+     (Count      : Natural;
+      Item       : String;
+      Drop       : Truncation := Error;
+      Max_Length : Positive)
+      return       Super_String
+   is
+      Length : constant Integer := Count * Item'Length;
+      Result : Super_String (Max_Length);
+      Indx   : Positive;
+
+   begin
+      if Length <= Max_Length then
+         Result.Current_Length := Length;
+
+         if Length > 0 then
+            Indx := 1;
+
+            for J in 1 .. Count loop
+               Result.Data (Indx .. Indx + Item'Length - 1) := Item;
+               Indx := Indx + Item'Length;
+            end loop;
+         end if;
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               Indx := 1;
+
+               while Indx + Item'Length <= Max_Length + 1 loop
+                  Result.Data (Indx .. Indx + Item'Length - 1) := Item;
+                  Indx := Indx + Item'Length;
+               end loop;
+
+               Result.Data (Indx .. Max_Length) :=
+                 Item (Item'First .. Item'First + Max_Length - Indx);
+
+            when Strings.Left =>
+               Indx := Max_Length;
+
+               while Indx - Item'Length >= 1 loop
+                  Result.Data (Indx - (Item'Length - 1) .. Indx) := Item;
+                  Indx := Indx - Item'Length;
+               end loop;
+
+               Result.Data (1 .. Indx) :=
+                 Item (Item'Last - Indx + 1 .. Item'Last);
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Replicate;
+
+   function Super_Replicate
+     (Count : Natural;
+      Item  : Super_String;
+      Drop  : Strings.Truncation := Strings.Error)
+      return  Super_String
+   is
+   begin
+      return
+        Super_Replicate
+          (Count,
+           Item.Data (1 .. Item.Current_Length),
+           Drop,
+           Item.Max_Length);
+   end Super_Replicate;
+
+   -----------------
+   -- Super_Slice --
+   -----------------
+
+   function Super_Slice
+     (Source : Super_String;
+      Low    : Positive;
+      High   : Natural)
+      return   String
+   is
+   begin
+      --  Note: test of High > Length is in accordance with AI95-00128
+
+      if Low > Source.Current_Length + 1
+        or else High > Source.Current_Length
+      then
+         raise Index_Error;
+      else
+         return Source.Data (Low .. High);
+      end if;
+   end Super_Slice;
+
+   ----------------
+   -- Super_Tail --
+   ----------------
+
+   function Super_Tail
+     (Source : Super_String;
+      Count  : Natural;
+      Pad    : Character := Space;
+      Drop   : Strings.Truncation := Strings.Error)
+      return   Super_String
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Result     : Super_String (Max_Length);
+      Slen       : constant Natural := Source.Current_Length;
+      Npad       : constant Integer := Count - Slen;
+
+   begin
+      if Npad <= 0 then
+         Result.Current_Length := Count;
+         Result.Data (1 .. Count) :=
+           Source.Data (Slen - (Count - 1) .. Slen);
+
+      elsif Count <= Max_Length then
+         Result.Current_Length := Count;
+         Result.Data (1 .. Npad) := (others => Pad);
+         Result.Data (Npad + 1 .. Count) := Source.Data (1 .. Slen);
+
+      else
+         Result.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Npad >= Max_Length then
+                  Result.Data := (others => Pad);
+
+               else
+                  Result.Data (1 .. Npad) := (others => Pad);
+                  Result.Data (Npad + 1 .. Max_Length) :=
+                    Source.Data (1 .. Max_Length - Npad);
+               end if;
+
+            when Strings.Left =>
+               Result.Data (1 .. Max_Length - Slen) := (others => Pad);
+               Result.Data (Max_Length - Slen + 1 .. Max_Length) :=
+                 Source.Data (1 .. Slen);
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end Super_Tail;
+
+   procedure Super_Tail
+     (Source : in out Super_String;
+      Count  : Natural;
+      Pad    : Character  := Space;
+      Drop   : Truncation := Error)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Slen       : constant Natural  := Source.Current_Length;
+      Npad       : constant Integer  := Count - Slen;
+
+      Temp : constant String (1 .. Max_Length) := Source.Data;
+
+   begin
+      if Npad <= 0 then
+         Source.Current_Length := Count;
+         Source.Data (1 .. Count) :=
+           Temp (Slen - (Count - 1) .. Slen);
+
+      elsif Count <= Max_Length then
+         Source.Current_Length := Count;
+         Source.Data (1 .. Npad) := (others => Pad);
+         Source.Data (Npad + 1 .. Count) := Temp (1 .. Slen);
+
+      else
+         Source.Current_Length := Max_Length;
+
+         case Drop is
+            when Strings.Right =>
+               if Npad >= Max_Length then
+                  Source.Data := (others => Pad);
+
+               else
+                  Source.Data (1 .. Npad) := (others => Pad);
+                  Source.Data (Npad + 1 .. Max_Length) :=
+                    Temp (1 .. Max_Length - Npad);
+               end if;
+
+            when Strings.Left =>
+               for J in 1 .. Max_Length - Slen loop
+                  Source.Data (J) := Pad;
+               end loop;
+
+               Source.Data (Max_Length - Slen + 1 .. Max_Length) :=
+                 Temp (1 .. Slen);
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+   end Super_Tail;
+
+   ---------------------
+   -- Super_To_String --
+   ---------------------
+
+   function Super_To_String (Source : in Super_String) return String is
+   begin
+      return Source.Data (1 .. Source.Current_Length);
+   end Super_To_String;
+
+   ---------------------
+   -- Super_Translate --
+   ---------------------
+
+   function Super_Translate
+     (Source  : Super_String;
+      Mapping : Maps.Character_Mapping)
+      return    Super_String
+   is
+      Result : Super_String (Source.Max_Length);
+
+   begin
+      Result.Current_Length := Source.Current_Length;
+
+      for J in 1 .. Source.Current_Length loop
+         Result.Data (J) := Value (Mapping, Source.Data (J));
+      end loop;
+
+      return Result;
+   end Super_Translate;
+
+   procedure Super_Translate
+     (Source  : in out Super_String;
+      Mapping : Maps.Character_Mapping)
+   is
+   begin
+      for J in 1 .. Source.Current_Length loop
+         Source.Data (J) := Value (Mapping, Source.Data (J));
+      end loop;
+   end Super_Translate;
+
+   function Super_Translate
+     (Source  : Super_String;
+      Mapping : Maps.Character_Mapping_Function)
+      return    Super_String
+   is
+      Result : Super_String (Source.Max_Length);
+
+   begin
+      Result.Current_Length := Source.Current_Length;
+
+      for J in 1 .. Source.Current_Length loop
+         Result.Data (J) := Mapping.all (Source.Data (J));
+      end loop;
+
+      return Result;
+   end Super_Translate;
+
+   procedure Super_Translate
+     (Source  : in out Super_String;
+      Mapping : Maps.Character_Mapping_Function)
+   is
+   begin
+      for J in 1 .. Source.Current_Length loop
+         Source.Data (J) := Mapping.all (Source.Data (J));
+      end loop;
+   end Super_Translate;
+
+   ----------------
+   -- Super_Trim --
+   ----------------
+
+   function Super_Trim (Source : Super_String; Side : Trim_End)
+                        return   Super_String
+   is
+      Result : Super_String (Source.Max_Length);
+      Last   : Natural := Source.Current_Length;
+      First  : Positive := 1;
+
+   begin
+      if Side = Left or else Side = Both then
+         while First <= Last and then Source.Data (First) = ' ' loop
+            First := First + 1;
+         end loop;
+      end if;
+
+      if Side = Right or else Side = Both then
+         while Last >= First and then Source.Data (Last) = ' ' loop
+            Last := Last - 1;
+         end loop;
+      end if;
+
+      Result.Current_Length := Last - First + 1;
+      Result.Data (1 .. Result.Current_Length) := Source.Data (First .. Last);
+      return Result;
+   end Super_Trim;
+
+   procedure Super_Trim
+     (Source : in out Super_String;
+      Side   : Trim_End)
+   is
+      Max_Length : constant Positive := Source.Max_Length;
+      Last       : Natural           := Source.Current_Length;
+      First      : Positive          := 1;
+      Temp       : String (1 .. Max_Length);
+
+   begin
+      Temp (1 .. Last) := Source.Data (1 .. Last);
+
+      if Side = Left or else Side = Both then
+         while First <= Last and then Temp (First) = ' ' loop
+            First := First + 1;
+         end loop;
+      end if;
+
+      if Side = Right or else Side = Both then
+         while Last >= First and then Temp (Last) = ' ' loop
+            Last := Last - 1;
+         end loop;
+      end if;
+
+      Source.Data := (others => ASCII.NUL);
+      Source.Current_Length := Last - First + 1;
+      Source.Data (1 .. Source.Current_Length) := Temp (First .. Last);
+   end Super_Trim;
+
+   function Super_Trim
+     (Source : Super_String;
+      Left   : Maps.Character_Set;
+      Right  : Maps.Character_Set)
+      return   Super_String
+   is
+      Result : Super_String (Source.Max_Length);
+
+   begin
+      for First in 1 .. Source.Current_Length loop
+         if not Is_In (Source.Data (First), Left) then
+            for Last in reverse First .. Source.Current_Length loop
+               if not Is_In (Source.Data (Last), Right) then
+                  Result.Current_Length := Last - First + 1;
+                  Result.Data (1 .. Result.Current_Length) :=
+                    Source.Data (First .. Last);
+                  return Result;
+               end if;
+            end loop;
+         end if;
+      end loop;
+
+      Result.Current_Length := 0;
+      return Result;
+   end Super_Trim;
+
+   procedure Super_Trim
+     (Source : in out Super_String;
+      Left   : Maps.Character_Set;
+      Right  : Maps.Character_Set)
+   is
+   begin
+      for First in 1 .. Source.Current_Length loop
+         if not Is_In (Source.Data (First), Left) then
+            for Last in reverse First .. Source.Current_Length loop
+               if not Is_In (Source.Data (Last), Right) then
+                  if First = 1 then
+                     Source.Current_Length := Last;
+                     return;
+                  else
+                     Source.Current_Length := Last - First + 1;
+                     Source.Data (1 .. Source.Current_Length) :=
+                       Source.Data (First .. Last);
+
+                     for J in Source.Current_Length + 1 ..
+                                Source.Max_Length
+                     loop
+                        Source.Data (J) := ASCII.NUL;
+                     end loop;
+
+                     return;
+                  end if;
+               end if;
+            end loop;
+
+            Source.Current_Length := 0;
+            return;
+         end if;
+      end loop;
+
+      Source.Current_Length := 0;
+   end Super_Trim;
+
+   -----------
+   -- Times --
+   -----------
+
+   function Times
+     (Left       : Natural;
+      Right      : Character;
+      Max_Length : Positive)
+      return  Super_String
+   is
+      Result : Super_String (Max_Length);
+
+   begin
+      if Left > Max_Length then
+         raise Ada.Strings.Length_Error;
+
+      else
+         Result.Current_Length := Left;
+
+         for J in 1 .. Left loop
+            Result.Data (J) := Right;
+         end loop;
+      end if;
+
+      return Result;
+   end Times;
+
+   function Times
+     (Left       : Natural;
+      Right      : String;
+      Max_Length : Positive)
+      return  Super_String
+   is
+      Result : Super_String (Max_Length);
+      Pos    : Positive         := 1;
+      Rlen   : constant Natural := Right'Length;
+      Nlen   : constant Natural := Left * Rlen;
+
+   begin
+      if Nlen > Max_Length then
+         raise Ada.Strings.Index_Error;
+
+      else
+         Result.Current_Length := Nlen;
+
+         if Nlen > 0 then
+            for J in 1 .. Left loop
+               Result.Data (Pos .. Pos + Rlen - 1) := Right;
+               Pos := Pos + Rlen;
+            end loop;
+         end if;
+      end if;
+
+      return Result;
+   end Times;
+
+   function Times
+     (Left  : Natural;
+      Right : Super_String)
+      return  Super_String
+   is
+      Result : Super_String (Right.Max_Length);
+      Pos    : Positive := 1;
+      Rlen   : constant Natural := Right.Current_Length;
+      Nlen   : constant Natural := Left * Rlen;
+
+   begin
+      if Nlen > Right.Max_Length then
+         raise Ada.Strings.Length_Error;
+
+      else
+         Result.Current_Length := Nlen;
+
+         if Nlen > 0 then
+            for J in 1 .. Left loop
+               Result.Data (Pos .. Pos + Rlen - 1) :=
+                 Right.Data (1 .. Rlen);
+               Pos := Pos + Rlen;
+            end loop;
+         end if;
+      end if;
+
+      return Result;
+   end Times;
+
+   ---------------------
+   -- To_Super_String --
+   ---------------------
+
+   function To_Super_String
+     (Source     : String;
+      Max_Length : Natural;
+      Drop       : Truncation := Error)
+      return       Super_String
+   is
+      Result : Super_String (Max_Length);
+      Slen   : constant Natural := Source'Length;
+
+   begin
+      if Slen <= Max_Length then
+         Result.Current_Length := Slen;
+         Result.Data (1 .. Slen) := Source;
+
+      else
+         case Drop is
+            when Strings.Right =>
+               Result.Current_Length := Max_Length;
+               Result.Data (1 .. Max_Length) :=
+                 Source (Source'First .. Source'First - 1 + Max_Length);
+
+            when Strings.Left =>
+               Result.Current_Length := Max_Length;
+               Result.Data (1 .. Max_Length) :=
+                 Source (Source'Last - (Max_Length - 1) .. Source'Last);
+
+            when Strings.Error =>
+               raise Ada.Strings.Length_Error;
+         end case;
+      end if;
+
+      return Result;
+   end To_Super_String;
+
+end Ada.Strings.Superbounded;