Renaming of target specific files for clarity

        * Makefile.in: Rename GNAT target specific files.

	* 31soccon.ads, 31soliop.ads 35soccon.ads, 3asoccon.ads,
	3bsoccon.ads, 3gsoccon.ads, 3hsoccon.ads, 3psoccon.ads,
	3ssoccon.ads, 3ssoliop.ads, 3veacodu.adb, 3vexpect.adb,
	3vsoccon.ads, 3vsocthi.adb, 3vsocthi.ads, 3vtrasym.adb,
	3wsoccon.ads, 3wsocthi.adb, 3wsocthi.ads, 3wsoliop.ads,
	3zsoccon.ads, 3zsocthi.adb, 3zsocthi.ads, 41intnam.ads,
	42intnam.ads, 45intnam.ads, 4aintnam.ads, 4cintnam.ads,
	4gintnam.ads, 4hexcpol.adb, 4hintnam.ads, 4lintnam.ads,
	4nintnam.ads, 4ointnam.ads, 4onumaux.ads, 4pintnam.ads,
	4sintnam.ads, 4vcaldel.adb, 4vcalend.adb, 4vcalend.ads,
	4vintnam.ads, 4wcalend.adb, 4wexcpol.adb, 4wintnam.ads,
	4zintnam.ads, 4znumaux.ads, 4zsytaco.adb, 4zsytaco.ads,
	51osinte.adb, 51osinte.ads, 51system.ads,
	52osinte.adb, 52osinte.ads, 53osinte.ads, 54osinte.ads,
	55osinte.adb, 55osinte.ads, 55system.ads, 56osinte.adb,
	56osinte.ads, 56system.ads, 56taprop.adb, 56taspri.ads,
	56tpopsp.adb, 57system.ads, 58system.ads,
	5amastop.adb, 5aml-tgt.adb, 5aosinte.adb, 5aosinte.ads,
	5asystem.ads, 5ataprop.adb, 5atasinf.ads, 5ataspri.ads,
	5atpopsp.adb, 5avxwork.ads, 5bml-tgt.adb, 5bosinte.adb,
	5bosinte.ads, 5bsystem.ads, 5cosinte.ads, 5csystem.ads,
	5dsystem.ads, 5esystem.ads, 5fintman.adb, 5fosinte.adb,
	5fosinte.ads, 5fsystem.ads, 5ftaprop.adb, 5ftasinf.ads,
	5ginterr.adb, 5gintman.adb, 5gmastop.adb, 5gml-tgt.adb,
	5gosinte.ads, 5gproinf.adb, 5gproinf.ads, 5gsystem.ads,
	5gtaprop.adb, 5gtasinf.adb, 5gtasinf.ads, 5gtpgetc.adb,
	5hml-tgt.adb, 5hosinte.adb, 5hosinte.ads, 5hparame.ads,
	5hsystem.ads, 5htaprop.adb, 5htaspri.ads, 5htraceb.adb,
	5iosinte.adb, 5iosinte.ads, 5itaprop.adb, 5itaspri.ads,
	5ksystem.ads, 5kvxwork.ads, 5lml-tgt.adb, 5losinte.ads,
	5lparame.adb, 5lsystem.ads, 5msystem.ads, 5mvxwork.ads,
	5ninmaop.adb, 5nintman.adb, 5nosinte.ads, 5nsystem.ads,
	5ntaprop.adb, 5ntaspri.ads, 5ointerr.adb, 5omastop.adb,
	5oosinte.adb, 5oosinte.ads, 5oosprim.adb, 5oparame.adb,
	5osystem.ads, 5otaprop.adb, 5otaspri.ads, 5posinte.ads,
	5posprim.adb, 5psystem.ads, 5pvxwork.ads, 5sintman.adb,
	5sml-tgt.adb, 5sosinte.adb, 5sosinte.ads, 5sosprim.adb,
	5sparame.adb, 5ssystem.ads, 5staprop.adb, 5stasinf.adb,
	5stasinf.ads, 5staspri.ads, 5stpopsp.adb, 5svxwork.ads,
	5tosinte.ads, 5usystem.ads, 5vasthan.adb, 5vdirval.adb,
	5vinmaop.adb, 5vinterr.adb, 5vintman.adb, 5vintman.ads,
	5vmastop.adb, 5vml-tgt.adb, 5vosinte.adb, 5vosinte.ads,
	5vosprim.adb, 5vosprim.ads, 5vparame.ads, 5vsymbol.adb,
	5vsystem.ads, 5vtaprop.adb, 5vtaspri.ads, 5vtpopde.adb,
	5vtpopde.ads, 5vtraent.adb, 5vtraent.ads, 5vvaflop.adb,
	5wdirval.adb, 5wgloloc.adb, 5wintman.adb, 5wmemory.adb,
	5wml-tgt.adb, 5wosinte.ads, 5wosprim.adb, 5wsystem.ads,
	5wtaprop.adb, 5wtaspri.ads, 5xparame.ads, 5xsystem.ads,
	5xvxwork.ads, 5yparame.ads, 5ysystem.ads, 5zinterr.adb,
	5zintman.adb, 5zintman.ads, 5zml-tgt.adb, 5zosinte.adb,
	5zosinte.ads, 5zosprim.adb, 5zparame.ads, 5zstchop.adb,
	5zsystem.ads, 5ztaprop.adb, 5ztaspri.ads, 5ztfsetr.adb,
	5ztpopsp.adb, 6vcpp.adb, 6vcstrea.adb, 6vinterf.ads,
	7sinmaop.adb, 7sintman.adb, 7sosinte.adb, 7sosprim.adb,
	7staprop.adb, 7staspri.ads, 7stfsetr.adb, 7stpopsp.adb,
	7straceb.adb, 7straces.adb, 7strafor.adb, 7strafor.ads,
	7stratas.adb, 86numaux.adb, 86numaux.ads: Replaced by files below.

	* a-caldel-vms.adb, a-calend-mingw.adb, a-calend-vms.adb,
	a-calend-vms.ads, a-dirval-mingw.adb, a-dirval-vms.adb,
	a-excpol-abort.adb, a-excpol-interix.adb, a-intnam-aix.ads,
	a-intnam-dummy.ads, a-intnam-freebsd.ads, a-intnam-hpux.ads,
	a-intnam-interix.ads, a-intnam-irix.ads, a-intnam-linux.ads,
	a-intnam-lynxos.ads, a-intnam-mingw.ads, a-intnam-os2.ads,
	a-intnam-solaris.ads, a-intnam-tru64.ads, a-intnam-unixware.ads,
	a-intnam-vms.ads, a-intnam-vxworks.ads, a-numaux-libc-x86.ads,
	a-numaux-vxworks.ads, a-numaux-x86.adb, a-numaux-x86.ads,
	a-sytaco-vxworks.adb, a-sytaco-vxworks.ads, g-eacodu-vms.adb,
	g-expect-vms.adb, g-soccon-aix.ads, g-soccon-freebsd.ads,
	g-soccon-hpux.ads, g-soccon-interix.ads, g-soccon-irix.ads,
	g-soccon-mingw.ads, g-soccon-solaris.ads, g-soccon-tru64.ads,
	g-soccon-unixware.ads, g-soccon-vms.adb, g-soccon-vxworks.ads,
	g-socthi-mingw.adb, g-socthi-mingw.ads, g-socthi-vms.adb,
	g-socthi-vms.ads, g-socthi-vxworks.adb, g-socthi-vxworks.ads,
	g-soliop-mingw.ads, g-soliop-solaris.ads, g-soliop-unixware.ads,
	g-trasym-vms.adb, i-cpp-vms.adb, i-cstrea-vms.adb,
	interfac-vms.ads, mlib-tgt-aix.adb, mlib-tgt-hpux.adb,
	mlib-tgt-irix.adb, mlib-tgt-linux.adb, mlib-tgt-mingw.adb,
	mlib-tgt-solaris.adb, mlib-tgt-tru64.adb, mlib-tgt-vms.adb,
	mlib-tgt-vxworks.adb, s-asthan-vms.adb, s-gloloc-mingw.adb,
	s-inmaop-dummy.adb, s-inmaop-posix.adb, s-inmaop-vms.adb,
	s-interr-dummy.adb, s-interr-sigaction.adb, s-interr-vms.adb,
	s-interr-vxworks.adb, s-intman-dummy.adb, s-intman-irix.adb,
	s-intman-irix-athread.adb, s-intman-mingw.adb, s-intman-posix.adb,
	s-intman-solaris.adb, s-intman-vms.adb, s-intman-vms.ads,
	s-intman-vxworks.adb, s-intman-vxworks.ads, s-mastop-irix.adb,
	s-mastop-tru64.adb, s-mastop-vms.adb, s-mastop-x86.adb,
	s-memory-mingw.adb, s-osinte-aix.adb, s-osinte-aix.ads,
	s-osinte-aix-fsu.ads, s-osinte-dummy.ads, s-osinte-freebsd.adb,
	s-osinte-freebsd.ads, s-osinte-fsu.adb, s-osinte-hpux.ads,
	s-osinte-hpux-dce.adb, s-osinte-hpux-dce.ads, s-osinte-interix.ads,
	s-osinte-irix.adb, s-osinte-irix.ads, s-osinte-irix-athread.ads,
	s-osinte-linux.ads, s-osinte-linux-fsu.ads, s-osinte-linux-ia64.ads,
	s-osinte-lynxos-3.adb, s-osinte-lynxos-3.ads, s-osinte-lynxos.adb,
	s-osinte-lynxos.ads, s-osinte-mingw.ads, s-osinte-os2.adb,
	s-osinte-os2.ads, s-osinte-posix.adb, s-osinte-solaris.adb,
	s-osinte-solaris.ads, s-osinte-solaris-fsu.ads,
	s-osinte-solaris-posix.ads, s-osinte-tru64.adb, s-osinte-tru64.ads,
	s-osinte-unixware.adb, s-osinte-unixware.ads, s-osinte-vms.adb,
	s-osinte-vms.ads, s-osinte-vxworks.adb,
	s-osinte-vxworks.ads, s-osprim-mingw.adb,
	s-osprim-os2.adb, s-osprim-posix.adb, s-osprim-solaris.adb,
	s-osprim-unix.adb, s-osprim-vms.adb, s-osprim-vms.ads,
	s-osprim-vxworks.adb, s-parame-ae653.ads, s-parame-hpux.ads,
	s-parame-linux.adb, s-parame-os2.adb, s-parame-solaris.adb,
	s-parame-vms.ads, s-parame-vms-restrict.ads, s-parame-vxworks.ads,
	s-proinf-irix-athread.adb, s-proinf-irix-athread.ads,
	s-stchop-vxworks.adb, s-taprop-dummy.adb,
	s-taprop-hpux-dce.adb, s-taprop-irix.adb,
	s-taprop-irix-athread.adb, s-taprop-linux.adb, s-taprop-lynxos.adb,
	s-taprop-mingw.adb, s-taprop-os2.adb, s-taprop-posix.adb,
	s-taprop-solaris.adb, s-taprop-tru64.adb, s-taprop-vms.adb,
	s-taprop-vxworks.adb, s-tasinf-irix.ads, s-tasinf-irix-athread.adb,
	s-tasinf-irix-athread.ads, s-tasinf-solaris.adb, s-tasinf-solaris.ads,
	s-tasinf-tru64.ads, s-taspri-dummy.ads, s-taspri-hpux-dce.ads,
	s-taspri-linux.ads, s-taspri-lynxos.ads, s-taspri-mingw.ads,
	s-taspri-os2.ads, s-taspri-posix.ads, s-taspri-solaris.ads,
	s-taspri-tru64.ads, s-taspri-vms.ads, s-taspri-vxworks.ads,
	s-tfsetr-default.adb, s-tfsetr-vxworks.adb, s-tpopde-vms.adb,
	s-tpopde-vms.ads, s-tpopsp-lynxos.adb, s-tpopsp-posix.adb,
	s-tpopsp-posix-foreign.adb, s-tpopsp-solaris.adb, s-tpopsp-vxworks.adb,
	s-traceb-hpux.adb, s-traceb-mastop.adb, s-traces-default.adb,
	s-traent-vms.adb, s-traent-vms.ads, s-trafor-default.adb,
	s-trafor-default.ads, s-tratas-default.adb, s-vaflop-vms.adb,
	s-vxwork-alpha.ads, s-vxwork-m68k.ads, s-vxwork-mips.ads,
	s-vxwork-ppc.ads, s-vxwork-sparcv9.ads, s-vxwork-xscale.ads,
	symbols-vms.adb, system-aix.ads, system-freebsd-x86.ads,
	system-hpux.ads, system-interix.ads, system-irix-n32.ads,
	system-irix-o32.ads, system-linux-x86_64.ads,
	system-linux-x86.ads, system-lynxos-ppc.ads, system-lynxos-x86.ads,
	system-mingw.ads, system-os2.ads, system-solaris-sparc.ads,
	system-solaris-sparcv9.ads, system-solaris-x86.ads, system-tru64.ads,
	system-unixware.ads, system-vms.ads, system-vms-zcx.ads,
	system-vxworks-alpha.ads, system-vxworks-m68k.ads,
	system-vxworks-mips.ads, system-vxworks-ppc.ads,
	system-vxworks-sparcv9.ads, system-vxworks-xscale.ads: Replace files
	above.


git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@81834 138bc75d-0d04-0410-961f-82ee72b054a4

1 files changed, 339 insertions, 0 deletions

diff --git a/gcc/ada/s-mastop-vms.adb b/gcc/ada/s-mastop-vms.adb
new file mode 100644
index 00000000000..5bb3f8a1eff
--- /dev/null
+++ b/gcc/ada/s-mastop-vms.adb
@@ -0,0 +1,339 @@
+------------------------------------------------------------------------------
+--                                                                          --
+--                         GNAT COMPILER COMPONENTS                         --
+--                                                                          --
+--                     SYSTEM.MACHINE_STATE_OPERATIONS                      --
+--                                                                          --
+--                                 B o d y                                  --
+--                         (Version for Alpha/VMS)                          --
+--                                                                          --
+--          Copyright (C) 2001-2002 Ada Core Technologies, Inc.             --
+--                                                                          --
+-- GNAT is free software;  you can  redistribute it  and/or modify it under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 2,  or (at your option) any later ver- --
+-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
+-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
+-- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
+-- for  more details.  You should have  received  a copy of the GNU General --
+-- Public License  distributed with GNAT;  see file COPYING.  If not, write --
+-- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
+-- MA 02111-1307, USA.                                                      --
+--                                                                          --
+-- As a special exception,  if other files  instantiate  generics from this --
+-- unit, or you link  this unit with other files  to produce an executable, --
+-- this  unit  does not  by itself cause  the resulting  executable  to  be --
+-- covered  by the  GNU  General  Public  License.  This exception does not --
+-- however invalidate  any other reasons why  the executable file  might be --
+-- covered by the  GNU Public License.                                      --
+--                                                                          --
+-- GNAT was originally developed  by the GNAT team at  New York University. --
+-- Extensive contributions were provided by Ada Core Technologies Inc.      --
+--                                                                          --
+------------------------------------------------------------------------------
+
+--  This version of System.Machine_State_Operations is for use on
+--  Alpha systems running VMS.
+
+with System.Memory;
+with System.Aux_DEC; use System.Aux_DEC;
+with Unchecked_Conversion;
+
+package body System.Machine_State_Operations is
+
+   use System.Exceptions;
+   subtype Cond_Value_Type is Unsigned_Longword;
+
+   --  Record layouts copied from Starlet.
+
+   type ICB_Fflags_Bits_Type is record
+      Exception_Frame : Boolean;
+      Ast_Frame       : Boolean;
+      Bottom_Of_Stack : Boolean;
+      Base_Frame      : Boolean;
+      Filler_1        : Unsigned_20;
+   end record;
+
+   for ICB_Fflags_Bits_Type use record
+      Exception_Frame at 0 range 0 .. 0;
+      Ast_Frame       at 0 range 1 .. 1;
+      Bottom_Of_Stack at 0 range 2 .. 2;
+      Base_Frame      at 0 range 3 .. 3;
+      Filler_1        at 0 range 4 .. 23;
+   end record;
+   for ICB_Fflags_Bits_Type'Size use 24;
+
+   type ICB_Hdr_Quad_Type is record
+      Context_Length : Unsigned_Longword;
+      Fflags_Bits    : ICB_Fflags_Bits_Type;
+      Block_Version  : Unsigned_Byte;
+   end record;
+
+   for ICB_Hdr_Quad_Type use record
+      Context_Length at 0 range 0 .. 31;
+      Fflags_Bits    at 4 range 0 .. 23;
+      Block_Version  at 7 range 0 .. 7;
+   end record;
+   for ICB_Hdr_Quad_Type'Size use 64;
+
+   type Invo_Context_Blk_Type is record
+
+      Hdr_Quad : ICB_Hdr_Quad_Type;
+      --  The first quadword contains:
+      --    o  The length of the structure in bytes (a longword field)
+      --    o  The frame flags (a 3 byte field of bits)
+      --    o  The version number (a 1 byte field)
+
+      Procedure_Descriptor : Unsigned_Quadword;
+      --  The address of the procedure descriptor for the procedure
+
+      Program_Counter : Integer_64;
+      --  The current PC of a given procedure invocation
+
+      Processor_Status : Integer_64;
+      --  The current PS of a given procedure invocation
+
+      Ireg : Unsigned_Quadword_Array (0 .. 30);
+      Freg : Unsigned_Quadword_Array (0 .. 30);
+      --  The register contents areas. 31 for scalars, 31 for float.
+
+      System_Defined : Unsigned_Quadword_Array (0 .. 1);
+      --  The following is an "internal" area that's reserved for use by
+      --  the operating system. It's size may vary over time.
+
+      --  Chfctx_Addr : Unsigned_Quadword;
+      --  Defined as a comment since it overlaps other fields
+
+      Filler_1             : String (1 .. 0);
+      --  Align to octaword
+   end record;
+
+   for Invo_Context_Blk_Type use record
+      Hdr_Quad             at   0 range 0 .. 63;
+      Procedure_Descriptor at   8 range 0 .. 63;
+      Program_Counter      at  16 range 0 .. 63;
+      Processor_Status     at  24 range 0 .. 63;
+      Ireg                 at  32 range 0 .. 1983;
+      Freg                 at 280 range 0 .. 1983;
+      System_Defined       at 528 range 0 .. 127;
+
+      --  Component representation spec(s) below are defined as
+      --  comments since they overlap other fields
+
+      --  Chfctx_Addr at 528 range 0 .. 63;
+
+      Filler_1 at 544 range 0 .. -1;
+   end record;
+   for Invo_Context_Blk_Type'Size use 4352;
+
+   subtype Invo_Handle_Type is Unsigned_Longword;
+
+   type Invo_Handle_Access_Type is access all Invo_Handle_Type;
+
+   function Fetch is new Fetch_From_Address (Code_Loc);
+
+   function To_Invo_Handle_Access is new Unchecked_Conversion
+     (Machine_State, Invo_Handle_Access_Type);
+
+   function To_Machine_State is new Unchecked_Conversion
+     (System.Address, Machine_State);
+
+   ----------------------------
+   -- Allocate_Machine_State --
+   ----------------------------
+
+   function Allocate_Machine_State return Machine_State is
+   begin
+      return To_Machine_State
+        (Memory.Alloc (Invo_Handle_Type'Max_Size_In_Storage_Elements));
+   end Allocate_Machine_State;
+
+   -------------------
+   -- Enter_Handler --
+   -------------------
+
+   procedure Enter_Handler (M : Machine_State; Handler : Handler_Loc) is
+      procedure Get_Invo_Context (
+         Result       : out Unsigned_Longword; -- return value
+         Invo_Handle  : Invo_Handle_Type;
+         Invo_Context : out Invo_Context_Blk_Type);
+
+      pragma Interface (External, Get_Invo_Context);
+
+      pragma Import_Valued_Procedure (Get_Invo_Context, "LIB$GET_INVO_CONTEXT",
+         (Unsigned_Longword, Invo_Handle_Type, Invo_Context_Blk_Type),
+         (Value, Value, Reference));
+
+      ICB : Invo_Context_Blk_Type;
+
+      procedure Goto_Unwind (
+         Status      : out Cond_Value_Type; -- return value
+         Target_Invo : Address := Address_Zero;
+         Target_PC   : Address := Address_Zero;
+         New_R0      : Unsigned_Quadword := Unsigned_Quadword'Null_Parameter;
+         New_R1      : Unsigned_Quadword := Unsigned_Quadword'Null_Parameter);
+
+      pragma Interface (External, Goto_Unwind);
+
+      pragma Import_Valued_Procedure
+        (Goto_Unwind, "SYS$GOTO_UNWIND",
+         (Cond_Value_Type, Address, Address,
+          Unsigned_Quadword, Unsigned_Quadword),
+         (Value, Reference, Reference,
+          Reference, Reference));
+
+      Status : Cond_Value_Type;
+
+   begin
+      Get_Invo_Context (Status, To_Invo_Handle_Access (M).all, ICB);
+      Goto_Unwind
+        (Status, System.Address (To_Invo_Handle_Access (M).all), Handler);
+   end Enter_Handler;
+
+   ----------------
+   -- Fetch_Code --
+   ----------------
+
+   function Fetch_Code (Loc : Code_Loc) return Code_Loc is
+   begin
+      --  The starting address is in the second longword pointed to by Loc.
+
+      return Fetch (System.Aux_DEC."+" (Loc, 8));
+   end Fetch_Code;
+
+   ------------------------
+   -- Free_Machine_State --
+   ------------------------
+
+   procedure Free_Machine_State (M : in out Machine_State) is
+   begin
+      Memory.Free (Address (M));
+      M := Machine_State (Null_Address);
+   end Free_Machine_State;
+
+   ------------------
+   -- Get_Code_Loc --
+   ------------------
+
+   function Get_Code_Loc (M : Machine_State) return Code_Loc is
+      procedure Get_Invo_Context (
+         Result       : out Unsigned_Longword; -- return value
+         Invo_Handle  : in  Invo_Handle_Type;
+         Invo_Context : out Invo_Context_Blk_Type);
+
+      pragma Interface (External, Get_Invo_Context);
+
+      pragma Import_Valued_Procedure (Get_Invo_Context, "LIB$GET_INVO_CONTEXT",
+         (Unsigned_Longword, Invo_Handle_Type, Invo_Context_Blk_Type),
+         (Value, Value, Reference));
+
+      Asm_Call_Size : constant := 4;
+      --  Under VMS a call
+      --  asm instruction takes 4 bytes. So we must remove this amount.
+
+      ICB : Invo_Context_Blk_Type;
+      Status : Cond_Value_Type;
+
+   begin
+      Get_Invo_Context (Status, To_Invo_Handle_Access (M).all, ICB);
+
+      if (Status and 1) /= 1 then
+         return Code_Loc (System.Null_Address);
+      end if;
+
+      return Code_Loc (ICB.Program_Counter - Asm_Call_Size);
+   end Get_Code_Loc;
+
+   --------------------------
+   -- Machine_State_Length --
+   --------------------------
+
+   function Machine_State_Length
+     return System.Storage_Elements.Storage_Offset
+   is
+      use System.Storage_Elements;
+
+   begin
+      return Invo_Handle_Type'Size / 8;
+   end Machine_State_Length;
+
+   ---------------
+   -- Pop_Frame --
+   ---------------
+
+   procedure Pop_Frame
+     (M    : Machine_State;
+      Info : Subprogram_Info_Type)
+   is
+      pragma Warnings (Off, Info);
+
+      procedure Get_Prev_Invo_Handle (
+         Result : out Invo_Handle_Type; -- return value
+         ICB    : in  Invo_Handle_Type);
+
+      pragma Interface (External, Get_Prev_Invo_Handle);
+
+      pragma Import_Valued_Procedure
+        (Get_Prev_Invo_Handle, "LIB$GET_PREV_INVO_HANDLE",
+         (Invo_Handle_Type, Invo_Handle_Type),
+         (Value, Value));
+
+      Prev_Handle : aliased Invo_Handle_Type;
+
+   begin
+      Get_Prev_Invo_Handle (Prev_Handle, To_Invo_Handle_Access (M).all);
+      To_Invo_Handle_Access (M).all := Prev_Handle;
+   end Pop_Frame;
+
+   -----------------------
+   -- Set_Machine_State --
+   -----------------------
+
+   procedure Set_Machine_State (M : Machine_State) is
+
+      procedure Get_Curr_Invo_Context
+        (Invo_Context : out Invo_Context_Blk_Type);
+
+      pragma Interface (External, Get_Curr_Invo_Context);
+
+      pragma Import_Valued_Procedure
+        (Get_Curr_Invo_Context, "LIB$GET_CURR_INVO_CONTEXT",
+         (Invo_Context_Blk_Type),
+         (Reference));
+
+      procedure Get_Invo_Handle (
+         Result       : out Invo_Handle_Type; -- return value
+         Invo_Context : in Invo_Context_Blk_Type);
+
+      pragma Interface (External, Get_Invo_Handle);
+
+      pragma Import_Valued_Procedure (Get_Invo_Handle, "LIB$GET_INVO_HANDLE",
+         (Invo_Handle_Type, Invo_Context_Blk_Type),
+         (Value, Reference));
+
+      ICB : Invo_Context_Blk_Type;
+      Invo_Handle : aliased Invo_Handle_Type;
+
+   begin
+      Get_Curr_Invo_Context (ICB);
+      Get_Invo_Handle (Invo_Handle, ICB);
+      To_Invo_Handle_Access (M).all := Invo_Handle;
+      Pop_Frame (M, System.Null_Address);
+   end Set_Machine_State;
+
+   ------------------------------
+   -- Set_Signal_Machine_State --
+   ------------------------------
+
+   procedure Set_Signal_Machine_State
+     (M       : Machine_State;
+      Context : System.Address)
+   is
+      pragma Warnings (Off, M);
+      pragma Warnings (Off, Context);
+
+   begin
+      null;
+   end Set_Signal_Machine_State;
+
+end System.Machine_State_Operations;