1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
|
------------------------------------------------------------------------------
-- --
-- GNAT RUN-TIME COMPONENTS --
-- --
-- G N A T . M E M O R Y _ D U M P --
-- --
-- B o d y --
-- --
-- Copyright (C) 2003-2014, AdaCore --
-- --
-- GNAT is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
-- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
-- or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- GNAT was originally developed by the GNAT team at New York University. --
-- Extensive contributions were provided by Ada Core Technologies Inc. --
-- --
------------------------------------------------------------------------------
with System; use System;
with System.Img_BIU; use System.Img_BIU;
with System.Storage_Elements; use System.Storage_Elements;
with GNAT.IO; use GNAT.IO;
with GNAT.Debug_Utilities; use GNAT.Debug_Utilities;
with Ada.Unchecked_Conversion;
package body GNAT.Memory_Dump is
----------
-- Dump --
----------
procedure Dump
(Addr : Address;
Count : Natural)
is
begin
Dump (Addr, Count, Prefix => Absolute_Address);
end Dump;
procedure Dump
(Addr : Address;
Count : Natural;
Prefix : Prefix_Type)
is
Ctr : Natural := Count;
-- Count of bytes left to output
Offset_Buf : String (1 .. Standard'Address_Size / 4 + 4);
Offset_Last : Natural;
-- Buffer for prefix in Offset mode
Adr : Address := Addr;
-- Current address
N : Natural := 0;
-- Number of bytes output on current line
C : Character;
-- Character at current storage address
AIL : Natural;
-- Number of chars in prefix (including colon and space)
Line_Len : Natural;
-- Line length for entire line
Hex : constant array (0 .. 15) of Character := "0123456789ABCDEF";
type Char_Ptr is access all Character;
function To_Char_Ptr is new Ada.Unchecked_Conversion (Address, Char_Ptr);
begin
case Prefix is
when Absolute_Address =>
AIL := Address_Image_Length - 4 + 2;
when Offset =>
Offset_Last := Offset_Buf'First - 1;
Set_Image_Based_Integer (Ctr, 16, 0, Offset_Buf, Offset_Last);
AIL := Offset_Last - 4 + 2;
when None =>
AIL := 0;
end case;
Line_Len := AIL + 3 * 16 + 2 + 16;
declare
Line_Buf : String (1 .. Line_Len);
begin
while Ctr /= 0 loop
-- Start of line processing
if N = 0 then
case Prefix is
when Absolute_Address =>
declare
S : constant String := Image (Adr);
begin
Line_Buf (1 .. AIL) := S (4 .. S'Length - 1) & ": ";
end;
when Offset =>
declare
Last : Natural := 0;
Len : Natural;
begin
Set_Image_Based_Integer
(Count - Ctr, 16, 0, Offset_Buf, Last);
Len := Last - 4;
Line_Buf (1 .. AIL - Len - 2) := (others => '0');
Line_Buf (AIL - Len - 1 .. AIL - 2) :=
Offset_Buf (4 .. Last - 1);
Line_Buf (AIL - 1 .. AIL) := ": ";
end;
when None =>
null;
end case;
Line_Buf (AIL + 1 .. Line_Buf'Last) := (others => ' ');
Line_Buf (AIL + 3 * 16 + 1) := '"';
end if;
-- Add one character to current line
C := To_Char_Ptr (Adr).all;
Adr := Adr + 1;
Ctr := Ctr - 1;
Line_Buf (AIL + 3 * N + 1) := Hex (Character'Pos (C) / 16);
Line_Buf (AIL + 3 * N + 2) := Hex (Character'Pos (C) mod 16);
if C < ' ' or else C = Character'Val (16#7F#) then
C := '?';
end if;
Line_Buf (AIL + 3 * 16 + 2 + N) := C;
N := N + 1;
-- End of line processing
if N = 16 then
Line_Buf (Line_Buf'Last) := '"';
GNAT.IO.Put_Line (Line_Buf);
N := 0;
end if;
end loop;
-- Deal with possible last partial line
if N /= 0 then
Line_Buf (AIL + 3 * 16 + 2 + N) := '"';
GNAT.IO.Put_Line (Line_Buf (1 .. AIL + 3 * 16 + 2 + N));
end if;
end;
end Dump;
end GNAT.Memory_Dump;
|
