summaryrefslogtreecommitdiff
path: root/git-gui
diff options
context:
space:
mode:
Diffstat (limited to 'git-gui')
-rw-r--r--git-gui/.gitignore5
-rwxr-xr-xgit-gui/GIT-VERSION-GEN80
-rw-r--r--git-gui/Makefile159
-rwxr-xr-xgit-gui/git-gui.sh2285
-rw-r--r--git-gui/lib/blame.tcl1005
-rw-r--r--git-gui/lib/branch.tcl574
-rw-r--r--git-gui/lib/branch_rename.tcl136
-rw-r--r--git-gui/lib/browser.tcl238
-rw-r--r--git-gui/lib/class.tcl171
-rw-r--r--git-gui/lib/commit.tcl410
-rw-r--r--git-gui/lib/console.tcl176
-rw-r--r--git-gui/lib/database.tcl89
-rw-r--r--git-gui/lib/diff.tcl336
-rw-r--r--git-gui/lib/error.tcl101
-rw-r--r--git-gui/lib/index.tcl409
-rw-r--r--git-gui/lib/merge.tcl313
-rw-r--r--git-gui/lib/option.tcl308
-rw-r--r--git-gui/lib/remote.tcl170
-rw-r--r--git-gui/lib/remote_branch_delete.tcl347
-rw-r--r--git-gui/lib/shortcut.tcl141
-rw-r--r--git-gui/lib/transport.tcl174
21 files changed, 7627 insertions, 0 deletions
diff --git a/git-gui/.gitignore b/git-gui/.gitignore
new file mode 100644
index 0000000000..020b86deae
--- /dev/null
+++ b/git-gui/.gitignore
@@ -0,0 +1,5 @@
+GIT-VERSION-FILE
+GIT-GUI-VARS
+git-citool
+git-gui
+lib/tclIndex
diff --git a/git-gui/GIT-VERSION-GEN b/git-gui/GIT-VERSION-GEN
new file mode 100755
index 0000000000..9770b0bc27
--- /dev/null
+++ b/git-gui/GIT-VERSION-GEN
@@ -0,0 +1,80 @@
+#!/bin/sh
+
+GVF=GIT-VERSION-FILE
+DEF_VER=0.8.GITGUI
+
+LF='
+'
+
+tree_search ()
+{
+ head=$1
+ tree=$2
+ for p in $(git rev-list --parents --max-count=1 $head 2>/dev/null)
+ do
+ test $tree = $(git rev-parse $p^{tree} 2>/dev/null) &&
+ vn=$(git describe --abbrev=4 $p 2>/dev/null) &&
+ case "$vn" in
+ gitgui-[0-9]*) echo $vn; break;;
+ esac
+ done
+}
+
+# Always use the tarball version file if found, just
+# in case we are somehow contained in a larger git
+# repository that doesn't actually track our state.
+# (At least one package manager is doing this.)
+#
+# We may be a subproject, so try looking for the merge
+# commit that supplied this directory content if we are
+# not at the toplevel. We probably will always be the
+# second parent in the commit, but we shouldn't rely on
+# that fact.
+#
+# If we are at the toplevel or the merge assumption fails
+# try looking for a gitgui-* tag.
+
+if test -f version &&
+ VN=$(cat version)
+then
+ : happy
+elif prefix="$(git rev-parse --show-prefix 2>/dev/null)"
+ test -n "$prefix" &&
+ head=$(git rev-list --max-count=1 HEAD -- . 2>/dev/null) &&
+ tree=$(git rev-parse --verify "HEAD:$prefix" 2>/dev/null) &&
+ VN=$(tree_search $head $tree)
+ case "$VN" in
+ gitgui-[0-9]*) : happy ;;
+ *) (exit 1) ;;
+ esac
+then
+ VN=$(echo "$VN" | sed -e 's/^gitgui-//;s/-/./g');
+elif VN=$(git describe --abbrev=4 HEAD 2>/dev/null) &&
+ case "$VN" in
+ gitgui-[0-9]*) : happy ;;
+ *) (exit 1) ;;
+ esac
+then
+ VN=$(echo "$VN" | sed -e 's/^gitgui-//;s/-/./g');
+else
+ VN="$DEF_VER"
+fi
+
+dirty=$(sh -c 'git diff-index --name-only HEAD' 2>/dev/null) || dirty=
+case "$dirty" in
+'')
+ ;;
+*)
+ VN="$VN-dirty" ;;
+esac
+
+if test -r $GVF
+then
+ VC=$(sed -e 's/^GITGUI_VERSION = //' <$GVF)
+else
+ VC=unset
+fi
+test "$VN" = "$VC" || {
+ echo >&2 "GITGUI_VERSION = $VN"
+ echo "GITGUI_VERSION = $VN" >$GVF
+}
diff --git a/git-gui/Makefile b/git-gui/Makefile
new file mode 100644
index 0000000000..1bac6fed46
--- /dev/null
+++ b/git-gui/Makefile
@@ -0,0 +1,159 @@
+all::
+
+# Define V=1 to have a more verbose compile.
+#
+
+GIT-VERSION-FILE: .FORCE-GIT-VERSION-FILE
+ @$(SHELL_PATH) ./GIT-VERSION-GEN
+-include GIT-VERSION-FILE
+
+uname_O := $(shell sh -c 'uname -o 2>/dev/null || echo not')
+
+SCRIPT_SH = git-gui.sh
+GITGUI_BUILT_INS = git-citool
+ALL_PROGRAMS = $(GITGUI_BUILT_INS) $(patsubst %.sh,%,$(SCRIPT_SH))
+ALL_LIBFILES = $(wildcard lib/*.tcl)
+PRELOAD_FILES = lib/class.tcl
+
+ifndef SHELL_PATH
+ SHELL_PATH = /bin/sh
+endif
+
+ifndef gitexecdir
+ gitexecdir := $(shell git --exec-path)
+endif
+
+ifndef sharedir
+ sharedir := $(dir $(gitexecdir))share
+endif
+
+ifndef INSTALL
+ INSTALL = install
+endif
+
+INSTALL_D0 = $(INSTALL) -d -m755 # space is required here
+INSTALL_D1 =
+INSTALL_R0 = $(INSTALL) -m644 # space is required here
+INSTALL_R1 =
+INSTALL_X0 = $(INSTALL) -m755 # space is required here
+INSTALL_X1 =
+INSTALL_L0 = rm -f # space is required here
+INSTALL_L1 = && ln # space is required here
+INSTALL_L2 =
+INSTALL_L3 =
+
+ifndef V
+ QUIET = @
+ QUIET_GEN = $(QUIET)echo ' ' GEN $@ &&
+ QUIET_BUILT_IN = $(QUIET)echo ' ' BUILTIN $@ &&
+ QUIET_INDEX = $(QUIET)echo ' ' INDEX $(dir $@) &&
+ QUIET_2DEVNULL = 2>/dev/null
+
+ INSTALL_D0 = dir=
+ INSTALL_D1 = && echo ' ' DEST $$dir && $(INSTALL) -d -m755 "$$dir"
+ INSTALL_R0 = src=
+ INSTALL_R1 = && echo ' ' INSTALL 644 `basename $$src` && $(INSTALL) -m644 $$src
+ INSTALL_X0 = src=
+ INSTALL_X1 = && echo ' ' INSTALL 755 `basename $$src` && $(INSTALL) -m755 $$src
+
+ INSTALL_L0 = dst=
+ INSTALL_L1 = && src=
+ INSTALL_L2 = && dst=
+ INSTALL_L3 = && echo ' ' 'LINK ' `basename "$$dst"` '->' `basename "$$src"` && rm -f "$$dst" && ln "$$src" "$$dst"
+endif
+
+TCL_PATH ?= tclsh
+TCLTK_PATH ?= wish
+
+ifeq ($(findstring $(MAKEFLAGS),s),s)
+QUIET_GEN =
+QUIET_BUILT_IN =
+endif
+
+DESTDIR_SQ = $(subst ','\'',$(DESTDIR))
+gitexecdir_SQ = $(subst ','\'',$(gitexecdir))
+SHELL_PATH_SQ = $(subst ','\'',$(SHELL_PATH))
+TCL_PATH_SQ = $(subst ','\'',$(TCL_PATH))
+TCLTK_PATH_SQ = $(subst ','\'',$(TCLTK_PATH))
+
+libdir ?= $(sharedir)/git-gui/lib
+libdir_SQ = $(subst ','\'',$(libdir))
+
+exedir = $(dir $(gitexecdir))share/git-gui/lib
+exedir_SQ = $(subst ','\'',$(exedir))
+
+$(patsubst %.sh,%,$(SCRIPT_SH)) : % : %.sh
+ $(QUIET_GEN)rm -f $@ $@+ && \
+ GITGUI_RELATIVE= && \
+ if test '$(exedir_SQ)' = '$(libdir_SQ)'; then \
+ if test "$(uname_O)" = Cygwin; \
+ then GITGUI_RELATIVE= ; \
+ else GITGUI_RELATIVE=1; \
+ fi; \
+ fi && \
+ sed -e '1s|#!.*/sh|#!$(SHELL_PATH_SQ)|' \
+ -e 's|^ exec wish "$$0"| exec $(subst |,'\|',$(TCLTK_PATH_SQ)) "$$0"|' \
+ -e 's/@@GITGUI_VERSION@@/$(GITGUI_VERSION)/g' \
+ -e 's|@@GITGUI_RELATIVE@@|'$$GITGUI_RELATIVE'|' \
+ -e $$GITGUI_RELATIVE's|@@GITGUI_LIBDIR@@|$(libdir_SQ)|' \
+ $@.sh >$@+ && \
+ chmod +x $@+ && \
+ mv $@+ $@
+
+$(GITGUI_BUILT_INS): git-gui
+ $(QUIET_BUILT_IN)rm -f $@ && ln git-gui $@
+
+lib/tclIndex: $(ALL_LIBFILES)
+ $(QUIET_INDEX)if echo \
+ $(foreach p,$(PRELOAD_FILES),source $p\;) \
+ auto_mkindex lib '*.tcl' \
+ | $(TCL_PATH) $(QUIET_2DEVNULL); then : ok; \
+ else \
+ echo 1>&2 " * $(TCL_PATH) failed; using unoptimized loading"; \
+ rm -f $@ ; \
+ echo '# Autogenerated by git-gui Makefile' >$@ && \
+ echo >>$@ && \
+ $(foreach p,$(PRELOAD_FILES) $(ALL_LIBFILES),echo '$(subst lib/,,$p)' >>$@ &&) \
+ echo >>$@ ; \
+ fi
+
+# These can record GITGUI_VERSION
+$(patsubst %.sh,%,$(SCRIPT_SH)): GIT-VERSION-FILE GIT-GUI-VARS
+lib/tclIndex: GIT-GUI-VARS
+
+TRACK_VARS = \
+ $(subst ','\'',SHELL_PATH='$(SHELL_PATH_SQ)') \
+ $(subst ','\'',TCL_PATH='$(TCL_PATH_SQ)') \
+ $(subst ','\'',TCLTK_PATH='$(TCLTK_PATH_SQ)') \
+ $(subst ','\'',gitexecdir='$(gitexecdir_SQ)') \
+ $(subst ','\'',libdir='$(libdir_SQ)') \
+#end TRACK_VARS
+
+GIT-GUI-VARS: .FORCE-GIT-GUI-VARS
+ @VARS='$(TRACK_VARS)'; \
+ if test x"$$VARS" != x"`cat $@ 2>/dev/null`" ; then \
+ echo 1>&2 " * new locations or Tcl/Tk interpreter"; \
+ echo 1>$@ "$$VARS"; \
+ fi
+
+all:: $(ALL_PROGRAMS) lib/tclIndex
+
+install: all
+ $(QUIET)$(INSTALL_D0)'$(DESTDIR_SQ)$(gitexecdir_SQ)' $(INSTALL_D1)
+ $(QUIET)$(INSTALL_X0)git-gui $(INSTALL_X1) '$(DESTDIR_SQ)$(gitexecdir_SQ)'
+ $(QUIET)$(foreach p,$(GITGUI_BUILT_INS), $(INSTALL_L0)'$(DESTDIR_SQ)$(gitexecdir_SQ)/$p' $(INSTALL_L1)'$(DESTDIR_SQ)$(gitexecdir_SQ)/git-gui' $(INSTALL_L2)'$(DESTDIR_SQ)$(gitexecdir_SQ)/$p' $(INSTALL_L3) &&) true
+ $(QUIET)$(INSTALL_D0)'$(DESTDIR_SQ)$(libdir_SQ)' $(INSTALL_D1)
+ $(QUIET)$(INSTALL_R0)lib/tclIndex $(INSTALL_R1) '$(DESTDIR_SQ)$(libdir_SQ)'
+ $(QUIET)$(foreach p,$(ALL_LIBFILES), $(INSTALL_R0)$p $(INSTALL_R1) '$(DESTDIR_SQ)$(libdir_SQ)' &&) true
+
+dist-version:
+ @mkdir -p $(TARDIR)
+ @echo $(GITGUI_VERSION) > $(TARDIR)/version
+
+clean::
+ rm -f $(ALL_PROGRAMS) lib/tclIndex
+ rm -f GIT-VERSION-FILE GIT-GUI-VARS
+
+.PHONY: all install dist-version clean
+.PHONY: .FORCE-GIT-VERSION-FILE
+.PHONY: .FORCE-GIT-GUI-VARS
diff --git a/git-gui/git-gui.sh b/git-gui/git-gui.sh
new file mode 100755
index 0000000000..9df2e47029
--- /dev/null
+++ b/git-gui/git-gui.sh
@@ -0,0 +1,2285 @@
+#!/bin/sh
+# Tcl ignores the next line -*- tcl -*- \
+ if test "z$*" = zversion \
+ || test "z$*" = z--version; \
+ then \
+ echo 'git-gui version @@GITGUI_VERSION@@'; \
+ exit; \
+ fi; \
+ exec wish "$0" -- "$@"
+
+set appvers {@@GITGUI_VERSION@@}
+set copyright {
+Copyright © 2006, 2007 Shawn Pearce, et. al.
+
+This program is free software; you can redistribute it and/or modify
+it under the terms of the GNU General Public License as published by
+the Free Software Foundation; either version 2 of the License, or
+(at your option) any later version.
+
+This program is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+GNU General Public License for more details.
+
+You should have received a copy of the GNU General Public License
+along with this program; if not, write to the Free Software
+Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA}
+
+######################################################################
+##
+## Tcl/Tk sanity check
+
+if {[catch {package require Tcl 8.4} err]
+ || [catch {package require Tk 8.4} err]
+} {
+ catch {wm withdraw .}
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title "git-gui: fatal error" \
+ -message $err
+ exit 1
+}
+
+######################################################################
+##
+## enable verbose loading?
+
+if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
+ unset _verbose
+ rename auto_load real__auto_load
+ proc auto_load {name args} {
+ puts stderr "auto_load $name"
+ return [uplevel 1 real__auto_load $name $args]
+ }
+ rename source real__source
+ proc source {name} {
+ puts stderr "source $name"
+ uplevel 1 real__source $name
+ }
+}
+
+######################################################################
+##
+## configure our library
+
+set oguilib {@@GITGUI_LIBDIR@@}
+set oguirel {@@GITGUI_RELATIVE@@}
+if {$oguirel eq {1}} {
+ set oguilib [file dirname [file dirname [file normalize $argv0]]]
+ set oguilib [file join $oguilib share git-gui lib]
+} elseif {[string match @@* $oguirel]} {
+ set oguilib [file join [file dirname [file normalize $argv0]] lib]
+}
+
+set idx [file join $oguilib tclIndex]
+if {[catch {set fd [open $idx r]} err]} {
+ catch {wm withdraw .}
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title "git-gui: fatal error" \
+ -message $err
+ exit 1
+}
+if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
+ set idx [list]
+ while {[gets $fd n] >= 0} {
+ if {$n ne {} && ![string match #* $n]} {
+ lappend idx $n
+ }
+ }
+} else {
+ set idx {}
+}
+close $fd
+
+if {$idx ne {}} {
+ set loaded [list]
+ foreach p $idx {
+ if {[lsearch -exact $loaded $p] >= 0} continue
+ source [file join $oguilib $p]
+ lappend loaded $p
+ }
+ unset loaded p
+} else {
+ set auto_path [concat [list $oguilib] $auto_path]
+}
+unset -nocomplain oguirel idx fd
+
+######################################################################
+##
+## read only globals
+
+set _appname [lindex [file split $argv0] end]
+set _gitdir {}
+set _gitexec {}
+set _reponame {}
+set _iscygwin {}
+
+proc appname {} {
+ global _appname
+ return $_appname
+}
+
+proc gitdir {args} {
+ global _gitdir
+ if {$args eq {}} {
+ return $_gitdir
+ }
+ return [eval [concat [list file join $_gitdir] $args]]
+}
+
+proc gitexec {args} {
+ global _gitexec
+ if {$_gitexec eq {}} {
+ if {[catch {set _gitexec [git --exec-path]} err]} {
+ error "Git not installed?\n\n$err"
+ }
+ }
+ if {$args eq {}} {
+ return $_gitexec
+ }
+ return [eval [concat [list file join $_gitexec] $args]]
+}
+
+proc reponame {} {
+ global _reponame
+ return $_reponame
+}
+
+proc is_MacOSX {} {
+ global tcl_platform tk_library
+ if {[tk windowingsystem] eq {aqua}} {
+ return 1
+ }
+ return 0
+}
+
+proc is_Windows {} {
+ global tcl_platform
+ if {$tcl_platform(platform) eq {windows}} {
+ return 1
+ }
+ return 0
+}
+
+proc is_Cygwin {} {
+ global tcl_platform _iscygwin
+ if {$_iscygwin eq {}} {
+ if {$tcl_platform(platform) eq {windows}} {
+ if {[catch {set p [exec cygpath --windir]} err]} {
+ set _iscygwin 0
+ } else {
+ set _iscygwin 1
+ }
+ } else {
+ set _iscygwin 0
+ }
+ }
+ return $_iscygwin
+}
+
+proc is_enabled {option} {
+ global enabled_options
+ if {[catch {set on $enabled_options($option)}]} {return 0}
+ return $on
+}
+
+proc enable_option {option} {
+ global enabled_options
+ set enabled_options($option) 1
+}
+
+proc disable_option {option} {
+ global enabled_options
+ set enabled_options($option) 0
+}
+
+######################################################################
+##
+## config
+
+proc is_many_config {name} {
+ switch -glob -- $name {
+ remote.*.fetch -
+ remote.*.push
+ {return 1}
+ *
+ {return 0}
+ }
+}
+
+proc is_config_true {name} {
+ global repo_config
+ if {[catch {set v $repo_config($name)}]} {
+ return 0
+ } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
+ return 1
+ } else {
+ return 0
+ }
+}
+
+proc get_config {name} {
+ global repo_config
+ if {[catch {set v $repo_config($name)}]} {
+ return {}
+ } else {
+ return $v
+ }
+}
+
+proc load_config {include_global} {
+ global repo_config global_config default_config
+
+ array unset global_config
+ if {$include_global} {
+ catch {
+ set fd_rc [open "| git config --global --list" r]
+ while {[gets $fd_rc line] >= 0} {
+ if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
+ if {[is_many_config $name]} {
+ lappend global_config($name) $value
+ } else {
+ set global_config($name) $value
+ }
+ }
+ }
+ close $fd_rc
+ }
+ }
+
+ array unset repo_config
+ catch {
+ set fd_rc [open "| git config --list" r]
+ while {[gets $fd_rc line] >= 0} {
+ if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
+ if {[is_many_config $name]} {
+ lappend repo_config($name) $value
+ } else {
+ set repo_config($name) $value
+ }
+ }
+ }
+ close $fd_rc
+ }
+
+ foreach name [array names default_config] {
+ if {[catch {set v $global_config($name)}]} {
+ set global_config($name) $default_config($name)
+ }
+ if {[catch {set v $repo_config($name)}]} {
+ set repo_config($name) $default_config($name)
+ }
+ }
+}
+
+######################################################################
+##
+## handy utils
+
+proc git {args} {
+ return [eval exec git $args]
+}
+
+proc current-branch {} {
+ set ref {}
+ set fd [open [gitdir HEAD] r]
+ if {[gets $fd ref] <16
+ || ![regsub {^ref: refs/heads/} $ref {} ref]} {
+ set ref {}
+ }
+ close $fd
+ return $ref
+}
+
+auto_load tk_optionMenu
+rename tk_optionMenu real__tkOptionMenu
+proc tk_optionMenu {w varName args} {
+ set m [eval real__tkOptionMenu $w $varName $args]
+ $m configure -font font_ui
+ $w configure -font font_ui
+ return $m
+}
+
+######################################################################
+##
+## version check
+
+set req_maj 1
+set req_min 5
+
+if {[catch {set v [git --version]} err]} {
+ catch {wm withdraw .}
+ error_popup "Cannot determine Git version:
+
+$err
+
+[appname] requires Git $req_maj.$req_min or later."
+ exit 1
+}
+if {[regexp {^git version (\d+)\.(\d+)} $v _junk act_maj act_min]} {
+ if {$act_maj < $req_maj
+ || ($act_maj == $req_maj && $act_min < $req_min)} {
+ catch {wm withdraw .}
+ error_popup "[appname] requires Git $req_maj.$req_min or later.
+
+You are using $v."
+ exit 1
+ }
+} else {
+ catch {wm withdraw .}
+ error_popup "Cannot parse Git version string:\n\n$v"
+ exit 1
+}
+unset -nocomplain v _junk act_maj act_min req_maj req_min
+
+######################################################################
+##
+## repository setup
+
+if {[catch {
+ set _gitdir $env(GIT_DIR)
+ set _prefix {}
+ }]
+ && [catch {
+ set _gitdir [git rev-parse --git-dir]
+ set _prefix [git rev-parse --show-prefix]
+ } err]} {
+ catch {wm withdraw .}
+ error_popup "Cannot find the git directory:\n\n$err"
+ exit 1
+}
+if {![file isdirectory $_gitdir] && [is_Cygwin]} {
+ catch {set _gitdir [exec cygpath --unix $_gitdir]}
+}
+if {![file isdirectory $_gitdir]} {
+ catch {wm withdraw .}
+ error_popup "Git directory not found:\n\n$_gitdir"
+ exit 1
+}
+if {[lindex [file split $_gitdir] end] ne {.git}} {
+ catch {wm withdraw .}
+ error_popup "Cannot use funny .git directory:\n\n$_gitdir"
+ exit 1
+}
+if {[catch {cd [file dirname $_gitdir]} err]} {
+ catch {wm withdraw .}
+ error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
+ exit 1
+}
+set _reponame [lindex [file split \
+ [file normalize [file dirname $_gitdir]]] \
+ end]
+
+######################################################################
+##
+## global init
+
+set current_diff_path {}
+set current_diff_side {}
+set diff_actions [list]
+set ui_status_value {Initializing...}
+
+set HEAD {}
+set PARENT {}
+set MERGE_HEAD [list]
+set commit_type {}
+set empty_tree {}
+set current_branch {}
+set current_diff_path {}
+set selected_commit_type new
+
+######################################################################
+##
+## task management
+
+set rescan_active 0
+set diff_active 0
+set last_clicked {}
+
+set disable_on_lock [list]
+set index_lock_type none
+
+proc lock_index {type} {
+ global index_lock_type disable_on_lock
+
+ if {$index_lock_type eq {none}} {
+ set index_lock_type $type
+ foreach w $disable_on_lock {
+ uplevel #0 $w disabled
+ }
+ return 1
+ } elseif {$index_lock_type eq "begin-$type"} {
+ set index_lock_type $type
+ return 1
+ }
+ return 0
+}
+
+proc unlock_index {} {
+ global index_lock_type disable_on_lock
+
+ set index_lock_type none
+ foreach w $disable_on_lock {
+ uplevel #0 $w normal
+ }
+}
+
+######################################################################
+##
+## status
+
+proc repository_state {ctvar hdvar mhvar} {
+ global current_branch
+ upvar $ctvar ct $hdvar hd $mhvar mh
+
+ set mh [list]
+
+ set current_branch [current-branch]
+ if {[catch {set hd [git rev-parse --verify HEAD]}]} {
+ set hd {}
+ set ct initial
+ return
+ }
+
+ set merge_head [gitdir MERGE_HEAD]
+ if {[file exists $merge_head]} {
+ set ct merge
+ set fd_mh [open $merge_head r]
+ while {[gets $fd_mh line] >= 0} {
+ lappend mh $line
+ }
+ close $fd_mh
+ return
+ }
+
+ set ct normal
+}
+
+proc PARENT {} {
+ global PARENT empty_tree
+
+ set p [lindex $PARENT 0]
+ if {$p ne {}} {
+ return $p
+ }
+ if {$empty_tree eq {}} {
+ set empty_tree [git mktree << {}]
+ }
+ return $empty_tree
+}
+
+proc rescan {after {honor_trustmtime 1}} {
+ global HEAD PARENT MERGE_HEAD commit_type
+ global ui_index ui_workdir ui_status_value ui_comm
+ global rescan_active file_states
+ global repo_config
+
+ if {$rescan_active > 0 || ![lock_index read]} return
+
+ repository_state newType newHEAD newMERGE_HEAD
+ if {[string match amend* $commit_type]
+ && $newType eq {normal}
+ && $newHEAD eq $HEAD} {
+ } else {
+ set HEAD $newHEAD
+ set PARENT $newHEAD
+ set MERGE_HEAD $newMERGE_HEAD
+ set commit_type $newType
+ }
+
+ array unset file_states
+
+ if {![$ui_comm edit modified]
+ || [string trim [$ui_comm get 0.0 end]] eq {}} {
+ if {[string match amend* $commit_type]} {
+ } elseif {[load_message GITGUI_MSG]} {
+ } elseif {[load_message MERGE_MSG]} {
+ } elseif {[load_message SQUASH_MSG]} {
+ }
+ $ui_comm edit reset
+ $ui_comm edit modified false
+ }
+
+ if {[is_enabled branch]} {
+ load_all_heads
+ populate_branch_menu
+ }
+
+ if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
+ rescan_stage2 {} $after
+ } else {
+ set rescan_active 1
+ set ui_status_value {Refreshing file status...}
+ set cmd [list git update-index]
+ lappend cmd -q
+ lappend cmd --unmerged
+ lappend cmd --ignore-missing
+ lappend cmd --refresh
+ set fd_rf [open "| $cmd" r]
+ fconfigure $fd_rf -blocking 0 -translation binary
+ fileevent $fd_rf readable \
+ [list rescan_stage2 $fd_rf $after]
+ }
+}
+
+proc rescan_stage2 {fd after} {
+ global ui_status_value
+ global rescan_active buf_rdi buf_rdf buf_rlo
+
+ if {$fd ne {}} {
+ read $fd
+ if {![eof $fd]} return
+ close $fd
+ }
+
+ set ls_others [list | git ls-files --others -z \
+ --exclude-per-directory=.gitignore]
+ set info_exclude [gitdir info exclude]
+ if {[file readable $info_exclude]} {
+ lappend ls_others "--exclude-from=$info_exclude"
+ }
+
+ set buf_rdi {}
+ set buf_rdf {}
+ set buf_rlo {}
+
+ set rescan_active 3
+ set ui_status_value {Scanning for modified files ...}
+ set fd_di [open "| git diff-index --cached -z [PARENT]" r]
+ set fd_df [open "| git diff-files -z" r]
+ set fd_lo [open $ls_others r]
+
+ fconfigure $fd_di -blocking 0 -translation binary -encoding binary
+ fconfigure $fd_df -blocking 0 -translation binary -encoding binary
+ fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
+ fileevent $fd_di readable [list read_diff_index $fd_di $after]
+ fileevent $fd_df readable [list read_diff_files $fd_df $after]
+ fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
+}
+
+proc load_message {file} {
+ global ui_comm
+
+ set f [gitdir $file]
+ if {[file isfile $f]} {
+ if {[catch {set fd [open $f r]}]} {
+ return 0
+ }
+ set content [string trim [read $fd]]
+ close $fd
+ regsub -all -line {[ \r\t]+$} $content {} content
+ $ui_comm delete 0.0 end
+ $ui_comm insert end $content
+ return 1
+ }
+ return 0
+}
+
+proc read_diff_index {fd after} {
+ global buf_rdi
+
+ append buf_rdi [read $fd]
+ set c 0
+ set n [string length $buf_rdi]
+ while {$c < $n} {
+ set z1 [string first "\0" $buf_rdi $c]
+ if {$z1 == -1} break
+ incr z1
+ set z2 [string first "\0" $buf_rdi $z1]
+ if {$z2 == -1} break
+
+ incr c
+ set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
+ set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
+ merge_state \
+ [encoding convertfrom $p] \
+ [lindex $i 4]? \
+ [list [lindex $i 0] [lindex $i 2]] \
+ [list]
+ set c $z2
+ incr c
+ }
+ if {$c < $n} {
+ set buf_rdi [string range $buf_rdi $c end]
+ } else {
+ set buf_rdi {}
+ }
+
+ rescan_done $fd buf_rdi $after
+}
+
+proc read_diff_files {fd after} {
+ global buf_rdf
+
+ append buf_rdf [read $fd]
+ set c 0
+ set n [string length $buf_rdf]
+ while {$c < $n} {
+ set z1 [string first "\0" $buf_rdf $c]
+ if {$z1 == -1} break
+ incr z1
+ set z2 [string first "\0" $buf_rdf $z1]
+ if {$z2 == -1} break
+
+ incr c
+ set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
+ set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
+ merge_state \
+ [encoding convertfrom $p] \
+ ?[lindex $i 4] \
+ [list] \
+ [list [lindex $i 0] [lindex $i 2]]
+ set c $z2
+ incr c
+ }
+ if {$c < $n} {
+ set buf_rdf [string range $buf_rdf $c end]
+ } else {
+ set buf_rdf {}
+ }
+
+ rescan_done $fd buf_rdf $after
+}
+
+proc read_ls_others {fd after} {
+ global buf_rlo
+
+ append buf_rlo [read $fd]
+ set pck [split $buf_rlo "\0"]
+ set buf_rlo [lindex $pck end]
+ foreach p [lrange $pck 0 end-1] {
+ merge_state [encoding convertfrom $p] ?O
+ }
+ rescan_done $fd buf_rlo $after
+}
+
+proc rescan_done {fd buf after} {
+ global rescan_active current_diff_path
+ global file_states repo_config
+ upvar $buf to_clear
+
+ if {![eof $fd]} return
+ set to_clear {}
+ close $fd
+ if {[incr rescan_active -1] > 0} return
+
+ prune_selection
+ unlock_index
+ display_all_files
+ if {$current_diff_path ne {}} reshow_diff
+ uplevel #0 $after
+}
+
+proc prune_selection {} {
+ global file_states selected_paths
+
+ foreach path [array names selected_paths] {
+ if {[catch {set still_here $file_states($path)}]} {
+ unset selected_paths($path)
+ }
+ }
+}
+
+######################################################################
+##
+## ui helpers
+
+proc mapicon {w state path} {
+ global all_icons
+
+ if {[catch {set r $all_icons($state$w)}]} {
+ puts "error: no icon for $w state={$state} $path"
+ return file_plain
+ }
+ return $r
+}
+
+proc mapdesc {state path} {
+ global all_descs
+
+ if {[catch {set r $all_descs($state)}]} {
+ puts "error: no desc for state={$state} $path"
+ return $state
+ }
+ return $r
+}
+
+proc escape_path {path} {
+ regsub -all {\\} $path "\\\\" path
+ regsub -all "\n" $path "\\n" path
+ return $path
+}
+
+proc short_path {path} {
+ return [escape_path [lindex [file split $path] end]]
+}
+
+set next_icon_id 0
+set null_sha1 [string repeat 0 40]
+
+proc merge_state {path new_state {head_info {}} {index_info {}}} {
+ global file_states next_icon_id null_sha1
+
+ set s0 [string index $new_state 0]
+ set s1 [string index $new_state 1]
+
+ if {[catch {set info $file_states($path)}]} {
+ set state __
+ set icon n[incr next_icon_id]
+ } else {
+ set state [lindex $info 0]
+ set icon [lindex $info 1]
+ if {$head_info eq {}} {set head_info [lindex $info 2]}
+ if {$index_info eq {}} {set index_info [lindex $info 3]}
+ }
+
+ if {$s0 eq {?}} {set s0 [string index $state 0]} \
+ elseif {$s0 eq {_}} {set s0 _}
+
+ if {$s1 eq {?}} {set s1 [string index $state 1]} \
+ elseif {$s1 eq {_}} {set s1 _}
+
+ if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
+ set head_info [list 0 $null_sha1]
+ } elseif {$s0 ne {_} && [string index $state 0] eq {_}
+ && $head_info eq {}} {
+ set head_info $index_info
+ }
+
+ set file_states($path) [list $s0$s1 $icon \
+ $head_info $index_info \
+ ]
+ return $state
+}
+
+proc display_file_helper {w path icon_name old_m new_m} {
+ global file_lists
+
+ if {$new_m eq {_}} {
+ set lno [lsearch -sorted -exact $file_lists($w) $path]
+ if {$lno >= 0} {
+ set file_lists($w) [lreplace $file_lists($w) $lno $lno]
+ incr lno
+ $w conf -state normal
+ $w delete $lno.0 [expr {$lno + 1}].0
+ $w conf -state disabled
+ }
+ } elseif {$old_m eq {_} && $new_m ne {_}} {
+ lappend file_lists($w) $path
+ set file_lists($w) [lsort -unique $file_lists($w)]
+ set lno [lsearch -sorted -exact $file_lists($w) $path]
+ incr lno
+ $w conf -state normal
+ $w image create $lno.0 \
+ -align center -padx 5 -pady 1 \
+ -name $icon_name \
+ -image [mapicon $w $new_m $path]
+ $w insert $lno.1 "[escape_path $path]\n"
+ $w conf -state disabled
+ } elseif {$old_m ne $new_m} {
+ $w conf -state normal
+ $w image conf $icon_name -image [mapicon $w $new_m $path]
+ $w conf -state disabled
+ }
+}
+
+proc display_file {path state} {
+ global file_states selected_paths
+ global ui_index ui_workdir
+
+ set old_m [merge_state $path $state]
+ set s $file_states($path)
+ set new_m [lindex $s 0]
+ set icon_name [lindex $s 1]
+
+ set o [string index $old_m 0]
+ set n [string index $new_m 0]
+ if {$o eq {U}} {
+ set o _
+ }
+ if {$n eq {U}} {
+ set n _
+ }
+ display_file_helper $ui_index $path $icon_name $o $n
+
+ if {[string index $old_m 0] eq {U}} {
+ set o U
+ } else {
+ set o [string index $old_m 1]
+ }
+ if {[string index $new_m 0] eq {U}} {
+ set n U
+ } else {
+ set n [string index $new_m 1]
+ }
+ display_file_helper $ui_workdir $path $icon_name $o $n
+
+ if {$new_m eq {__}} {
+ unset file_states($path)
+ catch {unset selected_paths($path)}
+ }
+}
+
+proc display_all_files_helper {w path icon_name m} {
+ global file_lists
+
+ lappend file_lists($w) $path
+ set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
+ $w image create end \
+ -align center -padx 5 -pady 1 \
+ -name $icon_name \
+ -image [mapicon $w $m $path]
+ $w insert end "[escape_path $path]\n"
+}
+
+proc display_all_files {} {
+ global ui_index ui_workdir
+ global file_states file_lists
+ global last_clicked
+
+ $ui_index conf -state normal
+ $ui_workdir conf -state normal
+
+ $ui_index delete 0.0 end
+ $ui_workdir delete 0.0 end
+ set last_clicked {}
+
+ set file_lists($ui_index) [list]
+ set file_lists($ui_workdir) [list]
+
+ foreach path [lsort [array names file_states]] {
+ set s $file_states($path)
+ set m [lindex $s 0]
+ set icon_name [lindex $s 1]
+
+ set s [string index $m 0]
+ if {$s ne {U} && $s ne {_}} {
+ display_all_files_helper $ui_index $path \
+ $icon_name $s
+ }
+
+ if {[string index $m 0] eq {U}} {
+ set s U
+ } else {
+ set s [string index $m 1]
+ }
+ if {$s ne {_}} {
+ display_all_files_helper $ui_workdir $path \
+ $icon_name $s
+ }
+ }
+
+ $ui_index conf -state disabled
+ $ui_workdir conf -state disabled
+}
+
+######################################################################
+##
+## icons
+
+set filemask {
+#define mask_width 14
+#define mask_height 15
+static unsigned char mask_bits[] = {
+ 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
+ 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
+ 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
+}
+
+image create bitmap file_plain -background white -foreground black -data {
+#define plain_width 14
+#define plain_height 15
+static unsigned char plain_bits[] = {
+ 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
+ 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
+ 0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+image create bitmap file_mod -background white -foreground blue -data {
+#define mod_width 14
+#define mod_height 15
+static unsigned char mod_bits[] = {
+ 0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
+ 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
+ 0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+image create bitmap file_fulltick -background white -foreground "#007000" -data {
+#define file_fulltick_width 14
+#define file_fulltick_height 15
+static unsigned char file_fulltick_bits[] = {
+ 0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
+ 0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
+ 0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+image create bitmap file_parttick -background white -foreground "#005050" -data {
+#define parttick_width 14
+#define parttick_height 15
+static unsigned char parttick_bits[] = {
+ 0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
+ 0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
+ 0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+image create bitmap file_question -background white -foreground black -data {
+#define file_question_width 14
+#define file_question_height 15
+static unsigned char file_question_bits[] = {
+ 0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
+ 0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
+ 0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+image create bitmap file_removed -background white -foreground red -data {
+#define file_removed_width 14
+#define file_removed_height 15
+static unsigned char file_removed_bits[] = {
+ 0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
+ 0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
+ 0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+image create bitmap file_merge -background white -foreground blue -data {
+#define file_merge_width 14
+#define file_merge_height 15
+static unsigned char file_merge_bits[] = {
+ 0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
+ 0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
+ 0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
+} -maskdata $filemask
+
+set file_dir_data {
+#define file_width 18
+#define file_height 18
+static unsigned char file_bits[] = {
+ 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xf8, 0x03, 0x00,
+ 0x0c, 0x03, 0x00, 0x04, 0xfe, 0x00, 0x06, 0x80, 0x00, 0xff, 0x9f, 0x00,
+ 0x03, 0x98, 0x00, 0x02, 0x90, 0x00, 0x06, 0xb0, 0x00, 0x04, 0xa0, 0x00,
+ 0x0c, 0xe0, 0x00, 0x08, 0xc0, 0x00, 0xf8, 0xff, 0x00, 0x00, 0x00, 0x00,
+ 0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
+}
+image create bitmap file_dir -background white -foreground blue \
+ -data $file_dir_data -maskdata $file_dir_data
+unset file_dir_data
+
+set file_uplevel_data {
+#define up_width 15
+#define up_height 15
+static unsigned char up_bits[] = {
+ 0x80, 0x00, 0xc0, 0x01, 0xe0, 0x03, 0xf0, 0x07, 0xf8, 0x0f, 0xfc, 0x1f,
+ 0xfe, 0x3f, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01,
+ 0xc0, 0x01, 0xc0, 0x01, 0x00, 0x00};
+}
+image create bitmap file_uplevel -background white -foreground red \
+ -data $file_uplevel_data -maskdata $file_uplevel_data
+unset file_uplevel_data
+
+set ui_index .vpane.files.index.list
+set ui_workdir .vpane.files.workdir.list
+
+set all_icons(_$ui_index) file_plain
+set all_icons(A$ui_index) file_fulltick
+set all_icons(M$ui_index) file_fulltick
+set all_icons(D$ui_index) file_removed
+set all_icons(U$ui_index) file_merge
+
+set all_icons(_$ui_workdir) file_plain
+set all_icons(M$ui_workdir) file_mod
+set all_icons(D$ui_workdir) file_question
+set all_icons(U$ui_workdir) file_merge
+set all_icons(O$ui_workdir) file_plain
+
+set max_status_desc 0
+foreach i {
+ {__ "Unmodified"}
+
+ {_M "Modified, not staged"}
+ {M_ "Staged for commit"}
+ {MM "Portions staged for commit"}
+ {MD "Staged for commit, missing"}
+
+ {_O "Untracked, not staged"}
+ {A_ "Staged for commit"}
+ {AM "Portions staged for commit"}
+ {AD "Staged for commit, missing"}
+
+ {_D "Missing"}
+ {D_ "Staged for removal"}
+ {DO "Staged for removal, still present"}
+
+ {U_ "Requires merge resolution"}
+ {UU "Requires merge resolution"}
+ {UM "Requires merge resolution"}
+ {UD "Requires merge resolution"}
+ } {
+ if {$max_status_desc < [string length [lindex $i 1]]} {
+ set max_status_desc [string length [lindex $i 1]]
+ }
+ set all_descs([lindex $i 0]) [lindex $i 1]
+}
+unset i
+
+######################################################################
+##
+## util
+
+proc bind_button3 {w cmd} {
+ bind $w <Any-Button-3> $cmd
+ if {[is_MacOSX]} {
+ bind $w <Control-Button-1> $cmd
+ }
+}
+
+proc scrollbar2many {list mode args} {
+ foreach w $list {eval $w $mode $args}
+}
+
+proc many2scrollbar {list mode sb top bottom} {
+ $sb set $top $bottom
+ foreach w $list {$w $mode moveto $top}
+}
+
+proc incr_font_size {font {amt 1}} {
+ set sz [font configure $font -size]
+ incr sz $amt
+ font configure $font -size $sz
+ font configure ${font}bold -size $sz
+ font configure ${font}italic -size $sz
+}
+
+######################################################################
+##
+## ui commands
+
+set starting_gitk_msg {Starting gitk... please wait...}
+
+proc do_gitk {revs} {
+ global env ui_status_value starting_gitk_msg
+
+ # -- Always start gitk through whatever we were loaded with. This
+ # lets us bypass using shell process on Windows systems.
+ #
+ set cmd [list [info nameofexecutable]]
+ lappend cmd [gitexec gitk]
+ if {$revs ne {}} {
+ append cmd { }
+ append cmd $revs
+ }
+
+ if {[catch {eval exec $cmd &} err]} {
+ error_popup "Failed to start gitk:\n\n$err"
+ } else {
+ set ui_status_value $starting_gitk_msg
+ after 10000 {
+ if {$ui_status_value eq $starting_gitk_msg} {
+ set ui_status_value {Ready.}
+ }
+ }
+ }
+}
+
+set is_quitting 0
+
+proc do_quit {} {
+ global ui_comm is_quitting repo_config commit_type
+
+ if {$is_quitting} return
+ set is_quitting 1
+
+ if {[winfo exists $ui_comm]} {
+ # -- Stash our current commit buffer.
+ #
+ set save [gitdir GITGUI_MSG]
+ set msg [string trim [$ui_comm get 0.0 end]]
+ regsub -all -line {[ \r\t]+$} $msg {} msg
+ if {(![string match amend* $commit_type]
+ || [$ui_comm edit modified])
+ && $msg ne {}} {
+ catch {
+ set fd [open $save w]
+ puts -nonewline $fd $msg
+ close $fd
+ }
+ } else {
+ catch {file delete $save}
+ }
+
+ # -- Stash our current window geometry into this repository.
+ #
+ set cfg_geometry [list]
+ lappend cfg_geometry [wm geometry .]
+ lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
+ lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
+ if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
+ set rc_geometry {}
+ }
+ if {$cfg_geometry ne $rc_geometry} {
+ catch {git config gui.geometry $cfg_geometry}
+ }
+ }
+
+ destroy .
+}
+
+proc do_rescan {} {
+ rescan {set ui_status_value {Ready.}}
+}
+
+proc do_commit {} {
+ commit_tree
+}
+
+proc toggle_or_diff {w x y} {
+ global file_states file_lists current_diff_path ui_index ui_workdir
+ global last_clicked selected_paths
+
+ set pos [split [$w index @$x,$y] .]
+ set lno [lindex $pos 0]
+ set col [lindex $pos 1]
+ set path [lindex $file_lists($w) [expr {$lno - 1}]]
+ if {$path eq {}} {
+ set last_clicked {}
+ return
+ }
+
+ set last_clicked [list $w $lno]
+ array unset selected_paths
+ $ui_index tag remove in_sel 0.0 end
+ $ui_workdir tag remove in_sel 0.0 end
+
+ if {$col == 0} {
+ if {$current_diff_path eq $path} {
+ set after {reshow_diff;}
+ } else {
+ set after {}
+ }
+ if {$w eq $ui_index} {
+ update_indexinfo \
+ "Unstaging [short_path $path] from commit" \
+ [list $path] \
+ [concat $after {set ui_status_value {Ready.}}]
+ } elseif {$w eq $ui_workdir} {
+ update_index \
+ "Adding [short_path $path]" \
+ [list $path] \
+ [concat $after {set ui_status_value {Ready.}}]
+ }
+ } else {
+ show_diff $path $w $lno
+ }
+}
+
+proc add_one_to_selection {w x y} {
+ global file_lists last_clicked selected_paths
+
+ set lno [lindex [split [$w index @$x,$y] .] 0]
+ set path [lindex $file_lists($w) [expr {$lno - 1}]]
+ if {$path eq {}} {
+ set last_clicked {}
+ return
+ }
+
+ if {$last_clicked ne {}
+ && [lindex $last_clicked 0] ne $w} {
+ array unset selected_paths
+ [lindex $last_clicked 0] tag remove in_sel 0.0 end
+ }
+
+ set last_clicked [list $w $lno]
+ if {[catch {set in_sel $selected_paths($path)}]} {
+ set in_sel 0
+ }
+ if {$in_sel} {
+ unset selected_paths($path)
+ $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
+ } else {
+ set selected_paths($path) 1
+ $w tag add in_sel $lno.0 [expr {$lno + 1}].0
+ }
+}
+
+proc add_range_to_selection {w x y} {
+ global file_lists last_clicked selected_paths
+
+ if {[lindex $last_clicked 0] ne $w} {
+ toggle_or_diff $w $x $y
+ return
+ }
+
+ set lno [lindex [split [$w index @$x,$y] .] 0]
+ set lc [lindex $last_clicked 1]
+ if {$lc < $lno} {
+ set begin $lc
+ set end $lno
+ } else {
+ set begin $lno
+ set end $lc
+ }
+
+ foreach path [lrange $file_lists($w) \
+ [expr {$begin - 1}] \
+ [expr {$end - 1}]] {
+ set selected_paths($path) 1
+ }
+ $w tag add in_sel $begin.0 [expr {$end + 1}].0
+}
+
+######################################################################
+##
+## config defaults
+
+set cursor_ptr arrow
+font create font_diff -family Courier -size 10
+font create font_ui
+catch {
+ label .dummy
+ eval font configure font_ui [font actual [.dummy cget -font]]
+ destroy .dummy
+}
+
+font create font_uiitalic
+font create font_uibold
+font create font_diffbold
+font create font_diffitalic
+
+foreach class {Button Checkbutton Entry Label
+ Labelframe Listbox Menu Message
+ Radiobutton Spinbox Text} {
+ option add *$class.font font_ui
+}
+unset class
+
+if {[is_Windows] || [is_MacOSX]} {
+ option add *Menu.tearOff 0
+}
+
+if {[is_MacOSX]} {
+ set M1B M1
+ set M1T Cmd
+} else {
+ set M1B Control
+ set M1T Ctrl
+}
+
+proc apply_config {} {
+ global repo_config font_descs
+
+ foreach option $font_descs {
+ set name [lindex $option 0]
+ set font [lindex $option 1]
+ if {[catch {
+ foreach {cn cv} $repo_config(gui.$name) {
+ font configure $font $cn $cv
+ }
+ } err]} {
+ error_popup "Invalid font specified in gui.$name:\n\n$err"
+ }
+ foreach {cn cv} [font configure $font] {
+ font configure ${font}bold $cn $cv
+ font configure ${font}italic $cn $cv
+ }
+ font configure ${font}bold -weight bold
+ font configure ${font}italic -slant italic
+ }
+}
+
+set default_config(merge.diffstat) true
+set default_config(merge.summary) false
+set default_config(merge.verbosity) 2
+set default_config(user.name) {}
+set default_config(user.email) {}
+
+set default_config(gui.pruneduringfetch) false
+set default_config(gui.trustmtime) false
+set default_config(gui.diffcontext) 5
+set default_config(gui.newbranchtemplate) {}
+set default_config(gui.fontui) [font configure font_ui]
+set default_config(gui.fontdiff) [font configure font_diff]
+set font_descs {
+ {fontui font_ui {Main Font}}
+ {fontdiff font_diff {Diff/Console Font}}
+}
+load_config 0
+apply_config
+
+######################################################################
+##
+## feature option selection
+
+if {[regexp {^git-(.+)$} [appname] _junk subcommand]} {
+ unset _junk
+} else {
+ set subcommand gui
+}
+if {$subcommand eq {gui.sh}} {
+ set subcommand gui
+}
+if {$subcommand eq {gui} && [llength $argv] > 0} {
+ set subcommand [lindex $argv 0]
+ set argv [lrange $argv 1 end]
+}
+
+enable_option multicommit
+enable_option branch
+enable_option transport
+
+switch -- $subcommand {
+browser -
+blame {
+ disable_option multicommit
+ disable_option branch
+ disable_option transport
+}
+citool {
+ enable_option singlecommit
+
+ disable_option multicommit
+ disable_option branch
+ disable_option transport
+}
+}
+
+######################################################################
+##
+## ui construction
+
+set ui_comm {}
+
+# -- Menu Bar
+#
+menu .mbar -tearoff 0
+.mbar add cascade -label Repository -menu .mbar.repository
+.mbar add cascade -label Edit -menu .mbar.edit
+if {[is_enabled branch]} {
+ .mbar add cascade -label Branch -menu .mbar.branch
+}
+if {[is_enabled multicommit] || [is_enabled singlecommit]} {
+ .mbar add cascade -label Commit -menu .mbar.commit
+}
+if {[is_enabled transport]} {
+ .mbar add cascade -label Merge -menu .mbar.merge
+ .mbar add cascade -label Fetch -menu .mbar.fetch
+ .mbar add cascade -label Push -menu .mbar.push
+}
+. configure -menu .mbar
+
+# -- Repository Menu
+#
+menu .mbar.repository
+
+.mbar.repository add command \
+ -label {Browse Current Branch} \
+ -command {browser::new $current_branch}
+trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Browse \$current_branch\" ;#"
+.mbar.repository add separator
+
+.mbar.repository add command \
+ -label {Visualize Current Branch} \
+ -command {do_gitk $current_branch}
+trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Visualize \$current_branch\" ;#"
+.mbar.repository add command \
+ -label {Visualize All Branches} \
+ -command {do_gitk --all}
+.mbar.repository add separator
+
+if {[is_enabled multicommit]} {
+ .mbar.repository add command -label {Database Statistics} \
+ -command do_stats
+
+ .mbar.repository add command -label {Compress Database} \
+ -command do_gc
+
+ .mbar.repository add command -label {Verify Database} \
+ -command do_fsck_objects
+
+ .mbar.repository add separator
+
+ if {[is_Cygwin]} {
+ .mbar.repository add command \
+ -label {Create Desktop Icon} \
+ -command do_cygwin_shortcut
+ } elseif {[is_Windows]} {
+ .mbar.repository add command \
+ -label {Create Desktop Icon} \
+ -command do_windows_shortcut
+ } elseif {[is_MacOSX]} {
+ .mbar.repository add command \
+ -label {Create Desktop Icon} \
+ -command do_macosx_app
+ }
+}
+
+.mbar.repository add command -label Quit \
+ -command do_quit \
+ -accelerator $M1T-Q
+
+# -- Edit Menu
+#
+menu .mbar.edit
+.mbar.edit add command -label Undo \
+ -command {catch {[focus] edit undo}} \
+ -accelerator $M1T-Z
+.mbar.edit add command -label Redo \
+ -command {catch {[focus] edit redo}} \
+ -accelerator $M1T-Y
+.mbar.edit add separator
+.mbar.edit add command -label Cut \
+ -command {catch {tk_textCut [focus]}} \
+ -accelerator $M1T-X
+.mbar.edit add command -label Copy \
+ -command {catch {tk_textCopy [focus]}} \
+ -accelerator $M1T-C
+.mbar.edit add command -label Paste \
+ -command {catch {tk_textPaste [focus]; [focus] see insert}} \
+ -accelerator $M1T-V
+.mbar.edit add command -label Delete \
+ -command {catch {[focus] delete sel.first sel.last}} \
+ -accelerator Del
+.mbar.edit add separator
+.mbar.edit add command -label {Select All} \
+ -command {catch {[focus] tag add sel 0.0 end}} \
+ -accelerator $M1T-A
+
+# -- Branch Menu
+#
+if {[is_enabled branch]} {
+ menu .mbar.branch
+
+ .mbar.branch add command -label {Create...} \
+ -command do_create_branch \
+ -accelerator $M1T-N
+ lappend disable_on_lock [list .mbar.branch entryconf \
+ [.mbar.branch index last] -state]
+
+ .mbar.branch add command -label {Rename...} \
+ -command branch_rename::dialog
+ lappend disable_on_lock [list .mbar.branch entryconf \
+ [.mbar.branch index last] -state]
+
+ .mbar.branch add command -label {Delete...} \
+ -command do_delete_branch
+ lappend disable_on_lock [list .mbar.branch entryconf \
+ [.mbar.branch index last] -state]
+
+ .mbar.branch add command -label {Reset...} \
+ -command merge::reset_hard
+ lappend disable_on_lock [list .mbar.branch entryconf \
+ [.mbar.branch index last] -state]
+}
+
+# -- Commit Menu
+#
+if {[is_enabled multicommit] || [is_enabled singlecommit]} {
+ menu .mbar.commit
+
+ .mbar.commit add radiobutton \
+ -label {New Commit} \
+ -command do_select_commit_type \
+ -variable selected_commit_type \
+ -value new
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add radiobutton \
+ -label {Amend Last Commit} \
+ -command do_select_commit_type \
+ -variable selected_commit_type \
+ -value amend
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add separator
+
+ .mbar.commit add command -label Rescan \
+ -command do_rescan \
+ -accelerator F5
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add command -label {Add To Commit} \
+ -command do_add_selection
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add command -label {Add Existing To Commit} \
+ -command do_add_all \
+ -accelerator $M1T-I
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add command -label {Unstage From Commit} \
+ -command do_unstage_selection
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add command -label {Revert Changes} \
+ -command do_revert_selection
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+
+ .mbar.commit add separator
+
+ .mbar.commit add command -label {Sign Off} \
+ -command do_signoff \
+ -accelerator $M1T-S
+
+ .mbar.commit add command -label Commit \
+ -command do_commit \
+ -accelerator $M1T-Return
+ lappend disable_on_lock \
+ [list .mbar.commit entryconf [.mbar.commit index last] -state]
+}
+
+# -- Merge Menu
+#
+if {[is_enabled branch]} {
+ menu .mbar.merge
+ .mbar.merge add command -label {Local Merge...} \
+ -command merge::dialog
+ lappend disable_on_lock \
+ [list .mbar.merge entryconf [.mbar.merge index last] -state]
+ .mbar.merge add command -label {Abort Merge...} \
+ -command merge::reset_hard
+ lappend disable_on_lock \
+ [list .mbar.merge entryconf [.mbar.merge index last] -state]
+
+}
+
+# -- Transport Menu
+#
+if {[is_enabled transport]} {
+ menu .mbar.fetch
+
+ menu .mbar.push
+ .mbar.push add command -label {Push...} \
+ -command do_push_anywhere
+ .mbar.push add command -label {Delete...} \
+ -command remote_branch_delete::dialog
+}
+
+if {[is_MacOSX]} {
+ # -- Apple Menu (Mac OS X only)
+ #
+ .mbar add cascade -label Apple -menu .mbar.apple
+ menu .mbar.apple
+
+ .mbar.apple add command -label "About [appname]" \
+ -command do_about
+ .mbar.apple add command -label "Options..." \
+ -command do_options
+} else {
+ # -- Edit Menu
+ #
+ .mbar.edit add separator
+ .mbar.edit add command -label {Options...} \
+ -command do_options
+
+ # -- Tools Menu
+ #
+ if {[is_Cygwin] && [file exists /usr/local/miga/lib/gui-miga]} {
+ proc do_miga {} {
+ global ui_status_value
+ if {![lock_index update]} return
+ set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
+ set miga_fd [open "|$cmd" r]
+ fconfigure $miga_fd -blocking 0
+ fileevent $miga_fd readable [list miga_done $miga_fd]
+ set ui_status_value {Running miga...}
+ }
+ proc miga_done {fd} {
+ read $fd 512
+ if {[eof $fd]} {
+ close $fd
+ unlock_index
+ rescan [list set ui_status_value {Ready.}]
+ }
+ }
+ .mbar add cascade -label Tools -menu .mbar.tools
+ menu .mbar.tools
+ .mbar.tools add command -label "Migrate" \
+ -command do_miga
+ lappend disable_on_lock \
+ [list .mbar.tools entryconf [.mbar.tools index last] -state]
+ }
+}
+
+# -- Help Menu
+#
+.mbar add cascade -label Help -menu .mbar.help
+menu .mbar.help
+
+if {![is_MacOSX]} {
+ .mbar.help add command -label "About [appname]" \
+ -command do_about
+}
+
+set browser {}
+catch {set browser $repo_config(instaweb.browser)}
+set doc_path [file dirname [gitexec]]
+set doc_path [file join $doc_path Documentation index.html]
+
+if {[is_Cygwin]} {
+ set doc_path [exec cygpath --mixed $doc_path]
+}
+
+if {$browser eq {}} {
+ if {[is_MacOSX]} {
+ set browser open
+ } elseif {[is_Cygwin]} {
+ set program_files [file dirname [exec cygpath --windir]]
+ set program_files [file join $program_files {Program Files}]
+ set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
+ set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
+ if {[file exists $firefox]} {
+ set browser $firefox
+ } elseif {[file exists $ie]} {
+ set browser $ie
+ }
+ unset program_files firefox ie
+ }
+}
+
+if {[file isfile $doc_path]} {
+ set doc_url "file:$doc_path"
+} else {
+ set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
+}
+
+if {$browser ne {}} {
+ .mbar.help add command -label {Online Documentation} \
+ -command [list exec $browser $doc_url &]
+}
+unset browser doc_path doc_url
+
+# -- Standard bindings
+#
+wm protocol . WM_DELETE_WINDOW do_quit
+bind all <$M1B-Key-q> do_quit
+bind all <$M1B-Key-Q> do_quit
+bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
+bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
+
+set subcommand_args {}
+proc usage {} {
+ puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
+ exit 1
+}
+
+# -- Not a normal commit type invocation? Do that instead!
+#
+switch -- $subcommand {
+browser {
+ set subcommand_args {rev?}
+ switch [llength $argv] {
+ 0 { set current_branch [current-branch] }
+ 1 { set current_branch [lindex $argv 0] }
+ default usage
+ }
+ browser::new $current_branch
+ return
+}
+blame {
+ set subcommand_args {rev? path?}
+ set head {}
+ set path {}
+ set is_path 0
+ foreach a $argv {
+ if {$is_path || [file exists $_prefix$a]} {
+ if {$path ne {}} usage
+ set path $_prefix$a
+ break
+ } elseif {$a eq {--}} {
+ if {$path ne {}} {
+ if {$head ne {}} usage
+ set head $path
+ set path {}
+ }
+ set is_path 1
+ } elseif {$head eq {}} {
+ if {$head ne {}} usage
+ set head $a
+ } else {
+ usage
+ }
+ }
+ unset is_path
+
+ if {$head eq {}} {
+ set current_branch [current-branch]
+ } else {
+ set current_branch $head
+ }
+
+ if {$path eq {}} usage
+ blame::new $head $path
+ return
+}
+citool -
+gui {
+ if {[llength $argv] != 0} {
+ puts -nonewline stderr "usage: $argv0"
+ if {$subcommand ne {gui} && [appname] ne "git-$subcommand"} {
+ puts -nonewline stderr " $subcommand"
+ }
+ puts stderr {}
+ exit 1
+ }
+ # fall through to setup UI for commits
+}
+default {
+ puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
+ exit 1
+}
+}
+
+# -- Branch Control
+#
+frame .branch \
+ -borderwidth 1 \
+ -relief sunken
+label .branch.l1 \
+ -text {Current Branch:} \
+ -anchor w \
+ -justify left
+label .branch.cb \
+ -textvariable current_branch \
+ -anchor w \
+ -justify left
+pack .branch.l1 -side left
+pack .branch.cb -side left -fill x
+pack .branch -side top -fill x
+
+# -- Main Window Layout
+#
+panedwindow .vpane -orient vertical
+panedwindow .vpane.files -orient horizontal
+.vpane add .vpane.files -sticky nsew -height 100 -width 200
+pack .vpane -anchor n -side top -fill both -expand 1
+
+# -- Index File List
+#
+frame .vpane.files.index -height 100 -width 200
+label .vpane.files.index.title -text {Staged Changes (Will Be Committed)} \
+ -background lightgreen
+text $ui_index -background white -borderwidth 0 \
+ -width 20 -height 10 \
+ -wrap none \
+ -cursor $cursor_ptr \
+ -xscrollcommand {.vpane.files.index.sx set} \
+ -yscrollcommand {.vpane.files.index.sy set} \
+ -state disabled
+scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
+scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
+pack .vpane.files.index.title -side top -fill x
+pack .vpane.files.index.sx -side bottom -fill x
+pack .vpane.files.index.sy -side right -fill y
+pack $ui_index -side left -fill both -expand 1
+.vpane.files add .vpane.files.index -sticky nsew
+
+# -- Working Directory File List
+#
+frame .vpane.files.workdir -height 100 -width 200
+label .vpane.files.workdir.title -text {Unstaged Changes (Will Not Be Committed)} \
+ -background lightsalmon
+text $ui_workdir -background white -borderwidth 0 \
+ -width 20 -height 10 \
+ -wrap none \
+ -cursor $cursor_ptr \
+ -xscrollcommand {.vpane.files.workdir.sx set} \
+ -yscrollcommand {.vpane.files.workdir.sy set} \
+ -state disabled
+scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
+scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
+pack .vpane.files.workdir.title -side top -fill x
+pack .vpane.files.workdir.sx -side bottom -fill x
+pack .vpane.files.workdir.sy -side right -fill y
+pack $ui_workdir -side left -fill both -expand 1
+.vpane.files add .vpane.files.workdir -sticky nsew
+
+foreach i [list $ui_index $ui_workdir] {
+ $i tag conf in_diff -background lightgray
+ $i tag conf in_sel -background lightgray
+}
+unset i
+
+# -- Diff and Commit Area
+#
+frame .vpane.lower -height 300 -width 400
+frame .vpane.lower.commarea
+frame .vpane.lower.diff -relief sunken -borderwidth 1
+pack .vpane.lower.commarea -side top -fill x
+pack .vpane.lower.diff -side bottom -fill both -expand 1
+.vpane add .vpane.lower -sticky nsew
+
+# -- Commit Area Buttons
+#
+frame .vpane.lower.commarea.buttons
+label .vpane.lower.commarea.buttons.l -text {} \
+ -anchor w \
+ -justify left
+pack .vpane.lower.commarea.buttons.l -side top -fill x
+pack .vpane.lower.commarea.buttons -side left -fill y
+
+button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
+ -command do_rescan
+pack .vpane.lower.commarea.buttons.rescan -side top -fill x
+lappend disable_on_lock \
+ {.vpane.lower.commarea.buttons.rescan conf -state}
+
+button .vpane.lower.commarea.buttons.incall -text {Add Existing} \
+ -command do_add_all
+pack .vpane.lower.commarea.buttons.incall -side top -fill x
+lappend disable_on_lock \
+ {.vpane.lower.commarea.buttons.incall conf -state}
+
+button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
+ -command do_signoff
+pack .vpane.lower.commarea.buttons.signoff -side top -fill x
+
+button .vpane.lower.commarea.buttons.commit -text {Commit} \
+ -command do_commit
+pack .vpane.lower.commarea.buttons.commit -side top -fill x
+lappend disable_on_lock \
+ {.vpane.lower.commarea.buttons.commit conf -state}
+
+# -- Commit Message Buffer
+#
+frame .vpane.lower.commarea.buffer
+frame .vpane.lower.commarea.buffer.header
+set ui_comm .vpane.lower.commarea.buffer.t
+set ui_coml .vpane.lower.commarea.buffer.header.l
+radiobutton .vpane.lower.commarea.buffer.header.new \
+ -text {New Commit} \
+ -command do_select_commit_type \
+ -variable selected_commit_type \
+ -value new
+lappend disable_on_lock \
+ [list .vpane.lower.commarea.buffer.header.new conf -state]
+radiobutton .vpane.lower.commarea.buffer.header.amend \
+ -text {Amend Last Commit} \
+ -command do_select_commit_type \
+ -variable selected_commit_type \
+ -value amend
+lappend disable_on_lock \
+ [list .vpane.lower.commarea.buffer.header.amend conf -state]
+label $ui_coml \
+ -anchor w \
+ -justify left
+proc trace_commit_type {varname args} {
+ global ui_coml commit_type
+ switch -glob -- $commit_type {
+ initial {set txt {Initial Commit Message:}}
+ amend {set txt {Amended Commit Message:}}
+ amend-initial {set txt {Amended Initial Commit Message:}}
+ amend-merge {set txt {Amended Merge Commit Message:}}
+ merge {set txt {Merge Commit Message:}}
+ * {set txt {Commit Message:}}
+ }
+ $ui_coml conf -text $txt
+}
+trace add variable commit_type write trace_commit_type
+pack $ui_coml -side left -fill x
+pack .vpane.lower.commarea.buffer.header.amend -side right
+pack .vpane.lower.commarea.buffer.header.new -side right
+
+text $ui_comm -background white -borderwidth 1 \
+ -undo true \
+ -maxundo 20 \
+ -autoseparators true \
+ -relief sunken \
+ -width 75 -height 9 -wrap none \
+ -font font_diff \
+ -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
+scrollbar .vpane.lower.commarea.buffer.sby \
+ -command [list $ui_comm yview]
+pack .vpane.lower.commarea.buffer.header -side top -fill x
+pack .vpane.lower.commarea.buffer.sby -side right -fill y
+pack $ui_comm -side left -fill y
+pack .vpane.lower.commarea.buffer -side left -fill y
+
+# -- Commit Message Buffer Context Menu
+#
+set ctxm .vpane.lower.commarea.buffer.ctxm
+menu $ctxm -tearoff 0
+$ctxm add command \
+ -label {Cut} \
+ -command {tk_textCut $ui_comm}
+$ctxm add command \
+ -label {Copy} \
+ -command {tk_textCopy $ui_comm}
+$ctxm add command \
+ -label {Paste} \
+ -command {tk_textPaste $ui_comm}
+$ctxm add command \
+ -label {Delete} \
+ -command {$ui_comm delete sel.first sel.last}
+$ctxm add separator
+$ctxm add command \
+ -label {Select All} \
+ -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
+$ctxm add command \
+ -label {Copy All} \
+ -command {
+ $ui_comm tag add sel 0.0 end
+ tk_textCopy $ui_comm
+ $ui_comm tag remove sel 0.0 end
+ }
+$ctxm add separator
+$ctxm add command \
+ -label {Sign Off} \
+ -command do_signoff
+bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
+
+# -- Diff Header
+#
+proc trace_current_diff_path {varname args} {
+ global current_diff_path diff_actions file_states
+ if {$current_diff_path eq {}} {
+ set s {}
+ set f {}
+ set p {}
+ set o disabled
+ } else {
+ set p $current_diff_path
+ set s [mapdesc [lindex $file_states($p) 0] $p]
+ set f {File:}
+ set p [escape_path $p]
+ set o normal
+ }
+
+ .vpane.lower.diff.header.status configure -text $s
+ .vpane.lower.diff.header.file configure -text $f
+ .vpane.lower.diff.header.path configure -text $p
+ foreach w $diff_actions {
+ uplevel #0 $w $o
+ }
+}
+trace add variable current_diff_path write trace_current_diff_path
+
+frame .vpane.lower.diff.header -background gold
+label .vpane.lower.diff.header.status \
+ -background gold \
+ -width $max_status_desc \
+ -anchor w \
+ -justify left
+label .vpane.lower.diff.header.file \
+ -background gold \
+ -anchor w \
+ -justify left
+label .vpane.lower.diff.header.path \
+ -background gold \
+ -anchor w \
+ -justify left
+pack .vpane.lower.diff.header.status -side left
+pack .vpane.lower.diff.header.file -side left
+pack .vpane.lower.diff.header.path -fill x
+set ctxm .vpane.lower.diff.header.ctxm
+menu $ctxm -tearoff 0
+$ctxm add command \
+ -label {Copy} \
+ -command {
+ clipboard clear
+ clipboard append \
+ -format STRING \
+ -type STRING \
+ -- $current_diff_path
+ }
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
+
+# -- Diff Body
+#
+frame .vpane.lower.diff.body
+set ui_diff .vpane.lower.diff.body.t
+text $ui_diff -background white -borderwidth 0 \
+ -width 80 -height 15 -wrap none \
+ -font font_diff \
+ -xscrollcommand {.vpane.lower.diff.body.sbx set} \
+ -yscrollcommand {.vpane.lower.diff.body.sby set} \
+ -state disabled
+scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
+ -command [list $ui_diff xview]
+scrollbar .vpane.lower.diff.body.sby -orient vertical \
+ -command [list $ui_diff yview]
+pack .vpane.lower.diff.body.sbx -side bottom -fill x
+pack .vpane.lower.diff.body.sby -side right -fill y
+pack $ui_diff -side left -fill both -expand 1
+pack .vpane.lower.diff.header -side top -fill x
+pack .vpane.lower.diff.body -side bottom -fill both -expand 1
+
+$ui_diff tag conf d_cr -elide true
+$ui_diff tag conf d_@ -foreground blue -font font_diffbold
+$ui_diff tag conf d_+ -foreground {#00a000}
+$ui_diff tag conf d_- -foreground red
+
+$ui_diff tag conf d_++ -foreground {#00a000}
+$ui_diff tag conf d_-- -foreground red
+$ui_diff tag conf d_+s \
+ -foreground {#00a000} \
+ -background {#e2effa}
+$ui_diff tag conf d_-s \
+ -foreground red \
+ -background {#e2effa}
+$ui_diff tag conf d_s+ \
+ -foreground {#00a000} \
+ -background ivory1
+$ui_diff tag conf d_s- \
+ -foreground red \
+ -background ivory1
+
+$ui_diff tag conf d<<<<<<< \
+ -foreground orange \
+ -font font_diffbold
+$ui_diff tag conf d======= \
+ -foreground orange \
+ -font font_diffbold
+$ui_diff tag conf d>>>>>>> \
+ -foreground orange \
+ -font font_diffbold
+
+$ui_diff tag raise sel
+
+# -- Diff Body Context Menu
+#
+set ctxm .vpane.lower.diff.body.ctxm
+menu $ctxm -tearoff 0
+$ctxm add command \
+ -label {Refresh} \
+ -command reshow_diff
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add command \
+ -label {Copy} \
+ -command {tk_textCopy $ui_diff}
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add command \
+ -label {Select All} \
+ -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add command \
+ -label {Copy All} \
+ -command {
+ $ui_diff tag add sel 0.0 end
+ tk_textCopy $ui_diff
+ $ui_diff tag remove sel 0.0 end
+ }
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add separator
+$ctxm add command \
+ -label {Apply/Reverse Hunk} \
+ -command {apply_hunk $cursorX $cursorY}
+set ui_diff_applyhunk [$ctxm index last]
+lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
+$ctxm add separator
+$ctxm add command \
+ -label {Decrease Font Size} \
+ -command {incr_font_size font_diff -1}
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add command \
+ -label {Increase Font Size} \
+ -command {incr_font_size font_diff 1}
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add separator
+$ctxm add command \
+ -label {Show Less Context} \
+ -command {if {$repo_config(gui.diffcontext) >= 1} {
+ incr repo_config(gui.diffcontext) -1
+ reshow_diff
+ }}
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add command \
+ -label {Show More Context} \
+ -command {if {$repo_config(gui.diffcontext) < 99} {
+ incr repo_config(gui.diffcontext)
+ reshow_diff
+ }}
+lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
+$ctxm add separator
+$ctxm add command -label {Options...} \
+ -command do_options
+bind_button3 $ui_diff "
+ set cursorX %x
+ set cursorY %y
+ if {\$ui_index eq \$current_diff_side} {
+ $ctxm entryconf $ui_diff_applyhunk -label {Unstage Hunk From Commit}
+ } else {
+ $ctxm entryconf $ui_diff_applyhunk -label {Stage Hunk For Commit}
+ }
+ tk_popup $ctxm %X %Y
+"
+unset ui_diff_applyhunk
+
+# -- Status Bar
+#
+label .status -textvariable ui_status_value \
+ -anchor w \
+ -justify left \
+ -borderwidth 1 \
+ -relief sunken
+pack .status -anchor w -side bottom -fill x
+
+# -- Load geometry
+#
+catch {
+set gm $repo_config(gui.geometry)
+wm geometry . [lindex $gm 0]
+.vpane sash place 0 \
+ [lindex [.vpane sash coord 0] 0] \
+ [lindex $gm 1]
+.vpane.files sash place 0 \
+ [lindex $gm 2] \
+ [lindex [.vpane.files sash coord 0] 1]
+unset gm
+}
+
+# -- Key Bindings
+#
+bind $ui_comm <$M1B-Key-Return> {do_commit;break}
+bind $ui_comm <$M1B-Key-i> {do_add_all;break}
+bind $ui_comm <$M1B-Key-I> {do_add_all;break}
+bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
+bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
+bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
+bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
+bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
+bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
+bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
+bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
+
+bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
+bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
+bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
+bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
+bind $ui_diff <$M1B-Key-v> {break}
+bind $ui_diff <$M1B-Key-V> {break}
+bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
+bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
+bind $ui_diff <Key-Up> {catch {%W yview scroll -1 units};break}
+bind $ui_diff <Key-Down> {catch {%W yview scroll 1 units};break}
+bind $ui_diff <Key-Left> {catch {%W xview scroll -1 units};break}
+bind $ui_diff <Key-Right> {catch {%W xview scroll 1 units};break}
+bind $ui_diff <Key-k> {catch {%W yview scroll -1 units};break}
+bind $ui_diff <Key-j> {catch {%W yview scroll 1 units};break}
+bind $ui_diff <Key-h> {catch {%W xview scroll -1 units};break}
+bind $ui_diff <Key-l> {catch {%W xview scroll 1 units};break}
+bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
+bind $ui_diff <Control-Key-f> {catch {%W yview scroll 1 pages};break}
+bind $ui_diff <Button-1> {focus %W}
+
+if {[is_enabled branch]} {
+ bind . <$M1B-Key-n> do_create_branch
+ bind . <$M1B-Key-N> do_create_branch
+}
+
+bind all <Key-F5> do_rescan
+bind all <$M1B-Key-r> do_rescan
+bind all <$M1B-Key-R> do_rescan
+bind . <$M1B-Key-s> do_signoff
+bind . <$M1B-Key-S> do_signoff
+bind . <$M1B-Key-i> do_add_all
+bind . <$M1B-Key-I> do_add_all
+bind . <$M1B-Key-Return> do_commit
+foreach i [list $ui_index $ui_workdir] {
+ bind $i <Button-1> "toggle_or_diff $i %x %y; break"
+ bind $i <$M1B-Button-1> "add_one_to_selection $i %x %y; break"
+ bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
+}
+unset i
+
+set file_lists($ui_index) [list]
+set file_lists($ui_workdir) [list]
+
+wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
+focus -force $ui_comm
+
+# -- Warn the user about environmental problems. Cygwin's Tcl
+# does *not* pass its env array onto any processes it spawns.
+# This means that git processes get none of our environment.
+#
+if {[is_Cygwin]} {
+ set ignored_env 0
+ set suggest_user {}
+ set msg "Possible environment issues exist.
+
+The following environment variables are probably
+going to be ignored by any Git subprocess run
+by [appname]:
+
+"
+ foreach name [array names env] {
+ switch -regexp -- $name {
+ {^GIT_INDEX_FILE$} -
+ {^GIT_OBJECT_DIRECTORY$} -
+ {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
+ {^GIT_DIFF_OPTS$} -
+ {^GIT_EXTERNAL_DIFF$} -
+ {^GIT_PAGER$} -
+ {^GIT_TRACE$} -
+ {^GIT_CONFIG$} -
+ {^GIT_CONFIG_LOCAL$} -
+ {^GIT_(AUTHOR|COMMITTER)_DATE$} {
+ append msg " - $name\n"
+ incr ignored_env
+ }
+ {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
+ append msg " - $name\n"
+ incr ignored_env
+ set suggest_user $name
+ }
+ }
+ }
+ if {$ignored_env > 0} {
+ append msg "
+This is due to a known issue with the
+Tcl binary distributed by Cygwin."
+
+ if {$suggest_user ne {}} {
+ append msg "
+
+A good replacement for $suggest_user
+is placing values for the user.name and
+user.email settings into your personal
+~/.gitconfig file.
+"
+ }
+ warn_popup $msg
+ }
+ unset ignored_env msg suggest_user name
+}
+
+# -- Only initialize complex UI if we are going to stay running.
+#
+if {[is_enabled transport]} {
+ load_all_remotes
+ load_all_heads
+
+ populate_branch_menu
+ populate_fetch_menu
+ populate_push_menu
+}
+
+# -- Only suggest a gc run if we are going to stay running.
+#
+if {[is_enabled multicommit]} {
+ set object_limit 2000
+ if {[is_Windows]} {set object_limit 200}
+ regexp {^([0-9]+) objects,} [git count-objects] _junk objects_current
+ if {$objects_current >= $object_limit} {
+ if {[ask_popup \
+ "This repository currently has $objects_current loose objects.
+
+To maintain optimal performance it is strongly recommended that you compress the database when more than $object_limit loose objects exist.
+
+Compress the database now?"] eq yes} {
+ do_gc
+ }
+ }
+ unset object_limit _junk objects_current
+}
+
+lock_index begin-read
+after 1 do_rescan
diff --git a/git-gui/lib/blame.tcl b/git-gui/lib/blame.tcl
new file mode 100644
index 0000000000..b523654815
--- /dev/null
+++ b/git-gui/lib/blame.tcl
@@ -0,0 +1,1005 @@
+# git-gui blame viewer
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+class blame {
+
+image create photo ::blame::img_back_arrow -data {R0lGODlhGAAYAIUAAPwCBEzKXFTSZIz+nGzmhGzqfGTidIT+nEzGXHTqhGzmfGzifFzadETCVES+VARWDFzWbHzyjAReDGTadFTOZDSyRDyyTCymPARaFGTedFzSbDy2TCyqRCyqPARaDAyCHES6VDy6VCyiPAR6HCSeNByWLARyFARiDARqFGTifARiFAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAYABgAAAajQIBwSCwaj8ikcsk0BppJwRPqHEypQwHBis0WDAdEFyBIKBaMAKLBdjQeSkFBYTBAIvgEoS6JmhUTEwIUDQ4VFhcMGEhyCgoZExoUaxsWHB0THkgfAXUGAhoBDSAVFR0XBnCbDRmgog0hpSIiDJpJIyEQhBUcJCIlwA22SSYVogknEg8eD82qSigdDSknY0IqJQXPYxIl1dZCGNvWw+Dm510GQQAh/mhDcmVhdGVkIGJ5IEJNUFRvR0lGIFBybyB2ZXJzaW9uIDIuNQ0KqSBEZXZlbENvciAxOTk3LDE5OTguIEFsbCByaWdodHMgcmVzZXJ2ZWQuDQpodHRwOi8vd3d3LmRldmVsY29yLmNvbQA7}
+
+# Persistant data (survives loads)
+#
+field history {}; # viewer history: {commit path}
+field header ; # array commit,key -> header field
+
+# Tk UI control paths
+#
+field w ; # top window in this viewer
+field w_back ; # our back button
+field w_path ; # label showing the current file path
+field w_columns ; # list of all column widgets in the viewer
+field w_line ; # text column: all line numbers
+field w_amov ; # text column: annotations + move tracking
+field w_asim ; # text column: annotations (simple computation)
+field w_file ; # text column: actual file data
+field w_cviewer ; # pane showing commit message
+field status ; # text variable bound to status bar
+field old_height ; # last known height of $w.file_pane
+
+# Tk UI colors
+#
+variable active_color #c0edc5
+variable group_colors {
+ #d6d6d6
+ #e1e1e1
+ #ececec
+}
+
+# Current blame data; cleared/reset on each load
+#
+field commit ; # input commit to blame
+field path ; # input filename to view in $commit
+
+field current_fd {} ; # background process running
+field highlight_line -1 ; # current line selected
+field highlight_column {} ; # current commit column selected
+field highlight_commit {} ; # sha1 of commit selected
+
+field total_lines 0 ; # total length of file
+field blame_lines 0 ; # number of lines computed
+field amov_data ; # list of {commit origfile origline}
+field asim_data ; # list of {commit origfile origline}
+
+field r_commit ; # commit currently being parsed
+field r_orig_line ; # original line number
+field r_final_line ; # final line number
+field r_line_count ; # lines in this region
+
+field tooltip_wm {} ; # Current tooltip toplevel, if open
+field tooltip_t {} ; # Text widget in $tooltip_wm
+field tooltip_timer {} ; # Current timer event for our tooltip
+field tooltip_commit {} ; # Commit(s) in tooltip
+
+constructor new {i_commit i_path} {
+ global cursor_ptr
+ variable active_color
+ variable group_colors
+
+ set commit $i_commit
+ set path $i_path
+
+ make_toplevel top w
+ wm title $top "[appname] ([reponame]): File Viewer"
+
+ frame $w.header -background gold
+ label $w.header.commit_l \
+ -text {Commit:} \
+ -background gold \
+ -anchor w \
+ -justify left
+ set w_back $w.header.commit_b
+ label $w_back \
+ -image ::blame::img_back_arrow \
+ -borderwidth 0 \
+ -relief flat \
+ -state disabled \
+ -background gold \
+ -activebackground gold
+ bind $w_back <Button-1> "
+ if {\[$w_back cget -state\] eq {normal}} {
+ [cb _history_menu]
+ }
+ "
+ label $w.header.commit \
+ -textvariable @commit \
+ -background gold \
+ -anchor w \
+ -justify left
+ label $w.header.path_l \
+ -text {File:} \
+ -background gold \
+ -anchor w \
+ -justify left
+ set w_path $w.header.path
+ label $w_path \
+ -background gold \
+ -anchor w \
+ -justify left
+ pack $w.header.commit_l -side left
+ pack $w_back -side left
+ pack $w.header.commit -side left
+ pack $w_path -fill x -side right
+ pack $w.header.path_l -side right
+
+ panedwindow $w.file_pane -orient vertical
+ frame $w.file_pane.out
+ frame $w.file_pane.cm
+ $w.file_pane add $w.file_pane.out \
+ -sticky nsew \
+ -minsize 100 \
+ -height 100 \
+ -width 100
+ $w.file_pane add $w.file_pane.cm \
+ -sticky nsew \
+ -minsize 25 \
+ -height 25 \
+ -width 100
+
+ set w_line $w.file_pane.out.linenumber_t
+ text $w_line \
+ -takefocus 0 \
+ -highlightthickness 0 \
+ -padx 0 -pady 0 \
+ -background white -borderwidth 0 \
+ -state disabled \
+ -wrap none \
+ -height 40 \
+ -width 6 \
+ -font font_diff
+ $w_line tag conf linenumber -justify right -rmargin 5
+
+ set w_amov $w.file_pane.out.amove_t
+ text $w_amov \
+ -takefocus 0 \
+ -highlightthickness 0 \
+ -padx 0 -pady 0 \
+ -background white -borderwidth 0 \
+ -state disabled \
+ -wrap none \
+ -height 40 \
+ -width 5 \
+ -font font_diff
+ $w_amov tag conf author_abbr -justify right -rmargin 5
+ $w_amov tag conf curr_commit
+ $w_amov tag conf prior_commit -foreground blue -underline 1
+ $w_amov tag bind prior_commit \
+ <Button-1> \
+ "[cb _load_commit $w_amov @amov_data @%x,%y];break"
+
+ set w_asim $w.file_pane.out.asimple_t
+ text $w_asim \
+ -takefocus 0 \
+ -highlightthickness 0 \
+ -padx 0 -pady 0 \
+ -background white -borderwidth 0 \
+ -state disabled \
+ -wrap none \
+ -height 40 \
+ -width 4 \
+ -font font_diff
+ $w_asim tag conf author_abbr -justify right
+ $w_asim tag conf curr_commit
+ $w_asim tag conf prior_commit -foreground blue -underline 1
+ $w_asim tag bind prior_commit \
+ <Button-1> \
+ "[cb _load_commit $w_asim @asim_data @%x,%y];break"
+
+ set w_file $w.file_pane.out.file_t
+ text $w_file \
+ -takefocus 0 \
+ -highlightthickness 0 \
+ -padx 0 -pady 0 \
+ -background white -borderwidth 0 \
+ -state disabled \
+ -wrap none \
+ -height 40 \
+ -width 80 \
+ -xscrollcommand [list $w.file_pane.out.sbx set] \
+ -font font_diff
+
+ set w_columns [list $w_amov $w_asim $w_line $w_file]
+
+ scrollbar $w.file_pane.out.sbx \
+ -orient h \
+ -command [list $w_file xview]
+ scrollbar $w.file_pane.out.sby \
+ -orient v \
+ -command [list scrollbar2many $w_columns yview]
+ eval grid $w_columns $w.file_pane.out.sby -sticky nsew
+ grid conf \
+ $w.file_pane.out.sbx \
+ -column [expr {[llength $w_columns] - 1}] \
+ -sticky we
+ grid columnconfigure \
+ $w.file_pane.out \
+ [expr {[llength $w_columns] - 1}] \
+ -weight 1
+ grid rowconfigure $w.file_pane.out 0 -weight 1
+
+ set w_cviewer $w.file_pane.cm.t
+ text $w_cviewer \
+ -background white -borderwidth 0 \
+ -state disabled \
+ -wrap none \
+ -height 10 \
+ -width 80 \
+ -xscrollcommand [list $w.file_pane.cm.sbx set] \
+ -yscrollcommand [list $w.file_pane.cm.sby set] \
+ -font font_diff
+ $w_cviewer tag conf still_loading \
+ -font font_uiitalic \
+ -justify center
+ $w_cviewer tag conf header_key \
+ -tabs {3c} \
+ -background $active_color \
+ -font font_uibold
+ $w_cviewer tag conf header_val \
+ -background $active_color \
+ -font font_ui
+ $w_cviewer tag raise sel
+ scrollbar $w.file_pane.cm.sbx \
+ -orient h \
+ -command [list $w_cviewer xview]
+ scrollbar $w.file_pane.cm.sby \
+ -orient v \
+ -command [list $w_cviewer yview]
+ pack $w.file_pane.cm.sby -side right -fill y
+ pack $w.file_pane.cm.sbx -side bottom -fill x
+ pack $w_cviewer -expand 1 -fill both
+
+ frame $w.status \
+ -borderwidth 1 \
+ -relief sunken
+ label $w.status.l \
+ -textvariable @status \
+ -anchor w \
+ -justify left
+ pack $w.status.l -side left
+
+ menu $w.ctxm -tearoff 0
+ $w.ctxm add command \
+ -label "Copy Commit" \
+ -command [cb _copycommit]
+
+ foreach i $w_columns {
+ for {set g 0} {$g < [llength $group_colors]} {incr g} {
+ $i tag conf color$g -background [lindex $group_colors $g]
+ }
+
+ $i conf -cursor $cursor_ptr
+ $i conf -yscrollcommand [list many2scrollbar \
+ $w_columns yview $w.file_pane.out.sby]
+ bind $i <Button-1> "
+ [cb _hide_tooltip]
+ [cb _click $i @%x,%y]
+ focus $i
+ "
+ bind $i <Any-Motion> [cb _show_tooltip $i @%x,%y]
+ bind $i <Any-Enter> [cb _hide_tooltip]
+ bind $i <Any-Leave> [cb _hide_tooltip]
+ bind_button3 $i "
+ [cb _hide_tooltip]
+ set cursorX %x
+ set cursorY %y
+ set cursorW %W
+ tk_popup $w.ctxm %X %Y
+ "
+ bind $i <Shift-Tab> "[list focus $w_cviewer];break"
+ bind $i <Tab> "[list focus $w_cviewer];break"
+ }
+
+ foreach i [concat $w_columns $w_cviewer] {
+ bind $i <Key-Up> {catch {%W yview scroll -1 units};break}
+ bind $i <Key-Down> {catch {%W yview scroll 1 units};break}
+ bind $i <Key-Left> {catch {%W xview scroll -1 units};break}
+ bind $i <Key-Right> {catch {%W xview scroll 1 units};break}
+ bind $i <Key-k> {catch {%W yview scroll -1 units};break}
+ bind $i <Key-j> {catch {%W yview scroll 1 units};break}
+ bind $i <Key-h> {catch {%W xview scroll -1 units};break}
+ bind $i <Key-l> {catch {%W xview scroll 1 units};break}
+ bind $i <Control-Key-b> {catch {%W yview scroll -1 pages};break}
+ bind $i <Control-Key-f> {catch {%W yview scroll 1 pages};break}
+ }
+
+ bind $w_cviewer <Shift-Tab> "[list focus $w_file];break"
+ bind $w_cviewer <Tab> "[list focus $w_file];break"
+ bind $w_cviewer <Button-1> [list focus $w_cviewer]
+ bind $w_file <Visibility> [list focus $w_file]
+
+ grid configure $w.header -sticky ew
+ grid configure $w.file_pane -sticky nsew
+ grid configure $w.status -sticky ew
+ grid columnconfigure $top 0 -weight 1
+ grid rowconfigure $top 0 -weight 0
+ grid rowconfigure $top 1 -weight 1
+ grid rowconfigure $top 2 -weight 0
+
+ set req_w [winfo reqwidth $top]
+ set req_h [winfo reqheight $top]
+ if {$req_w < 600} {set req_w 600}
+ if {$req_h < 400} {set req_h 400}
+ set g "${req_w}x${req_h}"
+ wm geometry $top $g
+ update
+
+ set old_height [winfo height $w.file_pane]
+ $w.file_pane sash place 0 \
+ [lindex [$w.file_pane sash coord 0] 0] \
+ [expr {int($old_height * 0.70)}]
+ bind $w.file_pane <Configure> \
+ "if {{$w.file_pane} eq {%W}} {[cb _resize %h]}"
+
+ _load $this {}
+}
+
+method _load {jump} {
+ variable group_colors
+
+ _hide_tooltip $this
+
+ if {$total_lines != 0 || $current_fd ne {}} {
+ if {$current_fd ne {}} {
+ catch {close $current_fd}
+ set current_fd {}
+ }
+
+ foreach i $w_columns {
+ $i conf -state normal
+ $i delete 0.0 end
+ foreach g [$i tag names] {
+ if {[regexp {^g[0-9a-f]{40}$} $g]} {
+ $i tag delete $g
+ }
+ }
+ $i conf -state disabled
+ }
+
+ $w_cviewer conf -state normal
+ $w_cviewer delete 0.0 end
+ $w_cviewer conf -state disabled
+
+ set highlight_line -1
+ set highlight_column {}
+ set highlight_commit {}
+ set total_lines 0
+ }
+
+ if {[winfo exists $w.status.c]} {
+ $w.status.c coords bar 0 0 0 20
+ } else {
+ canvas $w.status.c \
+ -width 100 \
+ -height [expr {int([winfo reqheight $w.status.l] * 0.6)}] \
+ -borderwidth 1 \
+ -relief groove \
+ -highlightt 0
+ $w.status.c create rectangle 0 0 0 20 -tags bar -fill navy
+ pack $w.status.c -side right
+ }
+
+ if {$history eq {}} {
+ $w_back conf -state disabled
+ } else {
+ $w_back conf -state normal
+ }
+
+ # Index 0 is always empty. There is never line 0 as
+ # we use only 1 based lines, as that matches both with
+ # git-blame output and with Tk's text widget.
+ #
+ set amov_data [list [list]]
+ set asim_data [list [list]]
+
+ set status "Loading $commit:[escape_path $path]..."
+ $w_path conf -text [escape_path $path]
+ if {$commit eq {}} {
+ set fd [open $path r]
+ } else {
+ set cmd [list git cat-file blob "$commit:$path"]
+ set fd [open "| $cmd" r]
+ }
+ fconfigure $fd -blocking 0 -translation lf -encoding binary
+ fileevent $fd readable [cb _read_file $fd $jump]
+ set current_fd $fd
+}
+
+method _history_menu {} {
+ set m $w.backmenu
+ if {[winfo exists $m]} {
+ $m delete 0 end
+ } else {
+ menu $m -tearoff 0
+ }
+
+ for {set i [expr {[llength $history] - 1}]
+ } {$i >= 0} {incr i -1} {
+ set e [lindex $history $i]
+ set c [lindex $e 0]
+ set f [lindex $e 1]
+
+ if {[regexp {^[0-9a-f]{40}$} $c]} {
+ set t [string range $c 0 8]...
+ } elseif {$c eq {}} {
+ set t {Working Directory}
+ } else {
+ set t $c
+ }
+ if {![catch {set summary $header($c,summary)}]} {
+ append t " $summary"
+ if {[string length $t] > 70} {
+ set t [string range $t 0 66]...
+ }
+ }
+
+ $m add command -label $t -command [cb _goback $i]
+ }
+ set X [winfo rootx $w_back]
+ set Y [expr {[winfo rooty $w_back] + [winfo height $w_back]}]
+ tk_popup $m $X $Y
+}
+
+method _goback {i} {
+ set dat [lindex $history $i]
+ set history [lrange $history 0 [expr {$i - 1}]]
+ set commit [lindex $dat 0]
+ set path [lindex $dat 1]
+ _load $this [lrange $dat 2 5]
+}
+
+method _read_file {fd jump} {
+ if {$fd ne $current_fd} {
+ catch {close $fd}
+ return
+ }
+
+ foreach i $w_columns {$i conf -state normal}
+ while {[gets $fd line] >= 0} {
+ regsub "\r\$" $line {} line
+ incr total_lines
+ lappend amov_data {}
+ lappend asim_data {}
+
+ if {$total_lines > 1} {
+ foreach i $w_columns {$i insert end "\n"}
+ }
+
+ $w_line insert end "$total_lines" linenumber
+ $w_file insert end "$line"
+ }
+
+ set ln_wc [expr {[string length $total_lines] + 2}]
+ if {[$w_line cget -width] < $ln_wc} {
+ $w_line conf -width $ln_wc
+ }
+
+ foreach i $w_columns {$i conf -state disabled}
+
+ if {[eof $fd]} {
+ close $fd
+
+ # If we don't force Tk to update the widgets *right now*
+ # none of our jump commands will cause a change in the UI.
+ #
+ update
+
+ if {[llength $jump] == 1} {
+ set highlight_line [lindex $jump 0]
+ $w_file see "$highlight_line.0"
+ } elseif {[llength $jump] == 4} {
+ set highlight_column [lindex $jump 0]
+ set highlight_line [lindex $jump 1]
+ $w_file xview moveto [lindex $jump 2]
+ $w_file yview moveto [lindex $jump 3]
+ }
+
+ _exec_blame $this $w_asim @asim_data \
+ [list] \
+ { copy/move tracking}
+ }
+} ifdeleted { catch {close $fd} }
+
+method _exec_blame {cur_w cur_d options cur_s} {
+ set cmd [list]
+ if {![is_Windows] || [is_Cygwin]} {
+ lappend cmd nice
+ }
+ lappend cmd git blame
+ set cmd [concat $cmd $options]
+ lappend cmd --incremental
+ if {$commit eq {}} {
+ lappend cmd --contents $path
+ } else {
+ lappend cmd $commit
+ }
+ lappend cmd -- $path
+ set fd [open "| $cmd" r]
+ fconfigure $fd -blocking 0 -translation lf -encoding binary
+ fileevent $fd readable [cb _read_blame $fd $cur_w $cur_d $cur_s]
+ set current_fd $fd
+ set blame_lines 0
+ _status $this $cur_s
+}
+
+method _read_blame {fd cur_w cur_d cur_s} {
+ upvar #0 $cur_d line_data
+ variable group_colors
+
+ if {$fd ne $current_fd} {
+ catch {close $fd}
+ return
+ }
+
+ $cur_w conf -state normal
+ while {[gets $fd line] >= 0} {
+ if {[regexp {^([a-z0-9]{40}) (\d+) (\d+) (\d+)$} $line line \
+ cmit original_line final_line line_count]} {
+ set r_commit $cmit
+ set r_orig_line $original_line
+ set r_final_line $final_line
+ set r_line_count $line_count
+ } elseif {[string match {filename *} $line]} {
+ set file [string range $line 9 end]
+ set n $r_line_count
+ set lno $r_final_line
+ set oln $r_orig_line
+ set cmit $r_commit
+
+ if {[regexp {^0{40}$} $cmit]} {
+ set commit_abbr work
+ set commit_type curr_commit
+ } elseif {$cmit eq $commit} {
+ set commit_abbr this
+ set commit_type curr_commit
+ } else {
+ set commit_type prior_commit
+ set commit_abbr [string range $cmit 0 3]
+ }
+
+ set author_abbr {}
+ set a_name {}
+ catch {set a_name $header($cmit,author)}
+ while {$a_name ne {}} {
+ if {![regexp {^([[:upper:]])} $a_name _a]} break
+ append author_abbr $_a
+ unset _a
+ if {![regsub \
+ {^[[:upper:]][^\s]*\s+} \
+ $a_name {} a_name ]} break
+ }
+ if {$author_abbr eq {}} {
+ set author_abbr { |}
+ } else {
+ set author_abbr [string range $author_abbr 0 3]
+ }
+ unset a_name
+
+ set first_lno $lno
+ while {
+ $first_lno > 1
+ && $cmit eq [lindex $line_data [expr {$first_lno - 1}] 0]
+ && $file eq [lindex $line_data [expr {$first_lno - 1}] 1]
+ } {
+ incr first_lno -1
+ }
+
+ set color {}
+ if {$first_lno < $lno} {
+ foreach g [$w_file tag names $first_lno.0] {
+ if {[regexp {^color[0-9]+$} $g]} {
+ set color $g
+ break
+ }
+ }
+ } else {
+ set i [lsort [concat \
+ [$w_file tag names "[expr {$first_lno - 1}].0"] \
+ [$w_file tag names "[expr {$lno + $n}].0"] \
+ ]]
+ for {set g 0} {$g < [llength $group_colors]} {incr g} {
+ if {[lsearch -sorted -exact $i color$g] == -1} {
+ set color color$g
+ break
+ }
+ }
+ }
+ if {$color eq {}} {
+ set color color0
+ }
+
+ while {$n > 0} {
+ set lno_e "$lno.0 lineend + 1c"
+ if {[lindex $line_data $lno] ne {}} {
+ set g [lindex $line_data $lno 0]
+ foreach i $w_columns {
+ $i tag remove g$g $lno.0 $lno_e
+ }
+ }
+ lset line_data $lno [list $cmit $file $oln]
+
+ $cur_w delete $lno.0 "$lno.0 lineend"
+ if {$lno == $first_lno} {
+ $cur_w insert $lno.0 $commit_abbr $commit_type
+ } elseif {$lno == [expr {$first_lno + 1}]} {
+ $cur_w insert $lno.0 $author_abbr author_abbr
+ } else {
+ $cur_w insert $lno.0 { |}
+ }
+
+ foreach i $w_columns {
+ if {$cur_w eq $w_amov} {
+ for {set g 0} \
+ {$g < [llength $group_colors]} \
+ {incr g} {
+ $i tag remove color$g $lno.0 $lno_e
+ }
+ $i tag add $color $lno.0 $lno_e
+ }
+ $i tag add g$cmit $lno.0 $lno_e
+ }
+
+ if {$highlight_column eq $cur_w} {
+ if {$highlight_line == -1
+ && [lindex [$w_file yview] 0] == 0} {
+ $w_file see $lno.0
+ set highlight_line $lno
+ }
+ if {$highlight_line == $lno} {
+ _showcommit $this $cur_w $lno
+ }
+ }
+
+ incr n -1
+ incr lno
+ incr oln
+ incr blame_lines
+ }
+
+ while {
+ $cmit eq [lindex $line_data $lno 0]
+ && $file eq [lindex $line_data $lno 1]
+ } {
+ $cur_w delete $lno.0 "$lno.0 lineend"
+
+ if {$lno == $first_lno} {
+ $cur_w insert $lno.0 $commit_abbr $commit_type
+ } elseif {$lno == [expr {$first_lno + 1}]} {
+ $cur_w insert $lno.0 $author_abbr author_abbr
+ } else {
+ $cur_w insert $lno.0 { |}
+ }
+
+ if {$cur_w eq $w_amov} {
+ foreach i $w_columns {
+ for {set g 0} \
+ {$g < [llength $group_colors]} \
+ {incr g} {
+ $i tag remove color$g $lno.0 $lno_e
+ }
+ $i tag add $color $lno.0 $lno_e
+ }
+ }
+
+ incr lno
+ }
+
+ } elseif {[regexp {^([a-z-]+) (.*)$} $line line key data]} {
+ set header($r_commit,$key) $data
+ }
+ }
+ $cur_w conf -state disabled
+
+ if {[eof $fd]} {
+ close $fd
+ if {$cur_w eq $w_asim} {
+ _exec_blame $this $w_amov @amov_data \
+ [list -M -C -C] \
+ { original location}
+ } else {
+ set current_fd {}
+ set status {Annotation complete.}
+ destroy $w.status.c
+ }
+ } else {
+ _status $this $cur_s
+ }
+} ifdeleted { catch {close $fd} }
+
+method _status {cur_s} {
+ set have $blame_lines
+ set total $total_lines
+ set pdone 0
+ if {$total} {set pdone [expr {100 * $have / $total}]}
+
+ set status [format \
+ "Loading%s annotations... %i of %i lines annotated (%2i%%)" \
+ $cur_s $have $total $pdone]
+ $w.status.c coords bar 0 0 $pdone 20
+}
+
+method _click {cur_w pos} {
+ set lno [lindex [split [$cur_w index $pos] .] 0]
+ _showcommit $this $cur_w $lno
+}
+
+method _load_commit {cur_w cur_d pos} {
+ upvar #0 $cur_d line_data
+ set lno [lindex [split [$cur_w index $pos] .] 0]
+ set dat [lindex $line_data $lno]
+ if {$dat ne {}} {
+ lappend history [list \
+ $commit $path \
+ $highlight_column \
+ $highlight_line \
+ [lindex [$w_file xview] 0] \
+ [lindex [$w_file yview] 0] \
+ ]
+ set commit [lindex $dat 0]
+ set path [lindex $dat 1]
+ _load $this [list [lindex $dat 2]]
+ }
+}
+
+method _showcommit {cur_w lno} {
+ global repo_config
+ variable active_color
+
+ if {$highlight_commit ne {}} {
+ foreach i $w_columns {
+ $i tag conf g$highlight_commit -background {}
+ $i tag lower g$highlight_commit
+ }
+ }
+
+ if {$cur_w eq $w_asim} {
+ set dat [lindex $asim_data $lno]
+ set highlight_column $w_asim
+ } else {
+ set dat [lindex $amov_data $lno]
+ set highlight_column $w_amov
+ }
+
+ $w_cviewer conf -state normal
+ $w_cviewer delete 0.0 end
+
+ if {$dat eq {}} {
+ set cmit {}
+ $w_cviewer insert end "Loading annotation..." still_loading
+ } else {
+ set cmit [lindex $dat 0]
+ set file [lindex $dat 1]
+
+ foreach i $w_columns {
+ $i tag conf g$cmit -background $active_color
+ $i tag raise g$cmit
+ }
+
+ set author_name {}
+ set author_email {}
+ set author_time {}
+ catch {set author_name $header($cmit,author)}
+ catch {set author_email $header($cmit,author-mail)}
+ catch {set author_time [clock format \
+ $header($cmit,author-time) \
+ -format {%Y-%m-%d %H:%M:%S}
+ ]}
+
+ set committer_name {}
+ set committer_email {}
+ set committer_time {}
+ catch {set committer_name $header($cmit,committer)}
+ catch {set committer_email $header($cmit,committer-mail)}
+ catch {set committer_time [clock format \
+ $header($cmit,committer-time) \
+ -format {%Y-%m-%d %H:%M:%S}
+ ]}
+
+ if {[catch {set msg $header($cmit,message)}]} {
+ set msg {}
+ catch {
+ set fd [open "| git cat-file commit $cmit" r]
+ fconfigure $fd -encoding binary -translation lf
+ if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
+ set enc utf-8
+ }
+ while {[gets $fd line] > 0} {
+ if {[string match {encoding *} $line]} {
+ set enc [string tolower [string range $line 9 end]]
+ }
+ }
+ set msg [encoding convertfrom $enc [read $fd]]
+ set msg [string trim $msg]
+ close $fd
+
+ set author_name [encoding convertfrom $enc $author_name]
+ set committer_name [encoding convertfrom $enc $committer_name]
+
+ set header($cmit,author) $author_name
+ set header($cmit,committer) $committer_name
+ }
+ set header($cmit,message) $msg
+ }
+
+ $w_cviewer insert end "commit $cmit\n" header_key
+ $w_cviewer insert end "Author:\t" header_key
+ $w_cviewer insert end "$author_name $author_email" header_val
+ $w_cviewer insert end " $author_time\n" header_val
+
+ $w_cviewer insert end "Committer:\t" header_key
+ $w_cviewer insert end "$committer_name $committer_email" header_val
+ $w_cviewer insert end " $committer_time\n" header_val
+
+ if {$file ne $path} {
+ $w_cviewer insert end "Original File:\t" header_key
+ $w_cviewer insert end "[escape_path $file]\n" header_val
+ }
+
+ $w_cviewer insert end "\n$msg"
+ }
+ $w_cviewer conf -state disabled
+
+ set highlight_line $lno
+ set highlight_commit $cmit
+
+ if {[lsearch -exact $tooltip_commit $highlight_commit] != -1} {
+ _hide_tooltip $this
+ }
+}
+
+method _copycommit {} {
+ set pos @$::cursorX,$::cursorY
+ set lno [lindex [split [$::cursorW index $pos] .] 0]
+ set dat [lindex $amov_data $lno]
+ if {$dat ne {}} {
+ clipboard clear
+ clipboard append \
+ -format STRING \
+ -type STRING \
+ -- [lindex $dat 0]
+ }
+}
+
+method _show_tooltip {cur_w pos} {
+ if {$tooltip_wm ne {}} {
+ _open_tooltip $this $cur_w
+ } elseif {$tooltip_timer eq {}} {
+ set tooltip_timer [after 1000 [cb _open_tooltip $cur_w]]
+ }
+}
+
+method _open_tooltip {cur_w} {
+ set tooltip_timer {}
+ set pos_x [winfo pointerx $cur_w]
+ set pos_y [winfo pointery $cur_w]
+ if {[winfo containing $pos_x $pos_y] ne $cur_w} {
+ _hide_tooltip $this
+ return
+ }
+
+ if {$tooltip_wm ne "$cur_w.tooltip"} {
+ _hide_tooltip $this
+
+ set tooltip_wm [toplevel $cur_w.tooltip -borderwidth 1]
+ wm overrideredirect $tooltip_wm 1
+ wm transient $tooltip_wm [winfo toplevel $cur_w]
+ set tooltip_t $tooltip_wm.label
+ text $tooltip_t \
+ -takefocus 0 \
+ -highlightthickness 0 \
+ -relief flat \
+ -borderwidth 0 \
+ -wrap none \
+ -background lightyellow \
+ -foreground black
+ $tooltip_t tag conf section_header -font font_uibold
+ pack $tooltip_t
+ } else {
+ $tooltip_t conf -state normal
+ $tooltip_t delete 0.0 end
+ }
+
+ set pos @[join [list \
+ [expr {$pos_x - [winfo rootx $cur_w]}] \
+ [expr {$pos_y - [winfo rooty $cur_w]}]] ,]
+ set lno [lindex [split [$cur_w index $pos] .] 0]
+ if {$cur_w eq $w_amov} {
+ set dat [lindex $amov_data $lno]
+ set org {}
+ } else {
+ set dat [lindex $asim_data $lno]
+ set org [lindex $amov_data $lno]
+ }
+
+ set cmit [lindex $dat 0]
+ set tooltip_commit [list $cmit]
+
+ set author_name {}
+ set summary {}
+ set author_time {}
+ catch {set author_name $header($cmit,author)}
+ catch {set summary $header($cmit,summary)}
+ catch {set author_time [clock format \
+ $header($cmit,author-time) \
+ -format {%Y-%m-%d %H:%M:%S}
+ ]}
+
+ $tooltip_t insert end "commit $cmit\n"
+ $tooltip_t insert end "$author_name $author_time\n"
+ $tooltip_t insert end "$summary"
+
+ if {$org ne {} && [lindex $org 0] ne $cmit} {
+ set save [$tooltip_t get 0.0 end]
+ $tooltip_t delete 0.0 end
+
+ set cmit [lindex $org 0]
+ set file [lindex $org 1]
+ lappend tooltip_commit $cmit
+
+ set author_name {}
+ set summary {}
+ set author_time {}
+ catch {set author_name $header($cmit,author)}
+ catch {set summary $header($cmit,summary)}
+ catch {set author_time [clock format \
+ $header($cmit,author-time) \
+ -format {%Y-%m-%d %H:%M:%S}
+ ]}
+
+ $tooltip_t insert end "Originally By:\n" section_header
+ $tooltip_t insert end "commit $cmit\n"
+ $tooltip_t insert end "$author_name $author_time\n"
+ $tooltip_t insert end "$summary\n"
+
+ if {$file ne $path} {
+ $tooltip_t insert end "In File: " section_header
+ $tooltip_t insert end "$file\n"
+ }
+
+ $tooltip_t insert end "\n"
+ $tooltip_t insert end "Copied Or Moved Here By:\n" section_header
+ $tooltip_t insert end $save
+ }
+
+ $tooltip_t conf -state disabled
+ _position_tooltip $this
+}
+
+method _position_tooltip {} {
+ set max_h [lindex [split [$tooltip_t index end] .] 0]
+ set max_w 0
+ for {set i 1} {$i <= $max_h} {incr i} {
+ set c [lindex [split [$tooltip_t index "$i.0 lineend"] .] 1]
+ if {$c > $max_w} {set max_w $c}
+ }
+ $tooltip_t conf -width $max_w -height $max_h
+
+ set req_w [winfo reqwidth $tooltip_t]
+ set req_h [winfo reqheight $tooltip_t]
+ set pos_x [expr {[winfo pointerx .] + 5}]
+ set pos_y [expr {[winfo pointery .] + 10}]
+
+ set g "${req_w}x${req_h}"
+ if {$pos_x >= 0} {append g +}
+ append g $pos_x
+ if {$pos_y >= 0} {append g +}
+ append g $pos_y
+
+ wm geometry $tooltip_wm $g
+ raise $tooltip_wm
+}
+
+method _hide_tooltip {} {
+ if {$tooltip_wm ne {}} {
+ destroy $tooltip_wm
+ set tooltip_wm {}
+ set tooltip_commit {}
+ }
+ if {$tooltip_timer ne {}} {
+ after cancel $tooltip_timer
+ set tooltip_timer {}
+ }
+}
+
+method _resize {new_height} {
+ set diff [expr {$new_height - $old_height}]
+ if {$diff == 0} return
+
+ set my [expr {[winfo height $w.file_pane] - 25}]
+ set o [$w.file_pane sash coord 0]
+ set ox [lindex $o 0]
+ set oy [expr {[lindex $o 1] + $diff}]
+ if {$oy < 0} {set oy 0}
+ if {$oy > $my} {set oy $my}
+ $w.file_pane sash place 0 $ox $oy
+
+ set old_height $new_height
+}
+
+}
diff --git a/git-gui/lib/branch.tcl b/git-gui/lib/branch.tcl
new file mode 100644
index 0000000000..4f648b2bc7
--- /dev/null
+++ b/git-gui/lib/branch.tcl
@@ -0,0 +1,574 @@
+# git-gui branch (create/delete) support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc load_all_heads {} {
+ global all_heads
+
+ set all_heads [list]
+ set fd [open "| git for-each-ref --format=%(refname) refs/heads" r]
+ while {[gets $fd line] > 0} {
+ if {[is_tracking_branch $line]} continue
+ if {![regsub ^refs/heads/ $line {} name]} continue
+ lappend all_heads $name
+ }
+ close $fd
+
+ set all_heads [lsort $all_heads]
+}
+
+proc load_all_tags {} {
+ set all_tags [list]
+ set fd [open "| git for-each-ref --format=%(refname) refs/tags" r]
+ while {[gets $fd line] > 0} {
+ if {![regsub ^refs/tags/ $line {} name]} continue
+ lappend all_tags $name
+ }
+ close $fd
+
+ return [lsort $all_tags]
+}
+
+proc populate_branch_menu {} {
+ global all_heads disable_on_lock
+
+ set m .mbar.branch
+ set last [$m index last]
+ for {set i 0} {$i <= $last} {incr i} {
+ if {[$m type $i] eq {separator}} {
+ $m delete $i last
+ set new_dol [list]
+ foreach a $disable_on_lock {
+ if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
+ lappend new_dol $a
+ }
+ }
+ set disable_on_lock $new_dol
+ break
+ }
+ }
+
+ if {$all_heads ne {}} {
+ $m add separator
+ }
+ foreach b $all_heads {
+ $m add radiobutton \
+ -label $b \
+ -command [list switch_branch $b] \
+ -variable current_branch \
+ -value $b
+ lappend disable_on_lock \
+ [list $m entryconf [$m index last] -state]
+ }
+}
+
+proc do_create_branch_action {w} {
+ global all_heads null_sha1 repo_config
+ global create_branch_checkout create_branch_revtype
+ global create_branch_head create_branch_trackinghead
+ global create_branch_name create_branch_revexp
+ global create_branch_tag
+
+ set newbranch $create_branch_name
+ if {$newbranch eq {}
+ || $newbranch eq $repo_config(gui.newbranchtemplate)} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Please supply a branch name."
+ focus $w.desc.name_t
+ return
+ }
+ if {![catch {git show-ref --verify -- "refs/heads/$newbranch"}]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Branch '$newbranch' already exists."
+ focus $w.desc.name_t
+ return
+ }
+ if {[catch {git check-ref-format "heads/$newbranch"}]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "We do not like '$newbranch' as a branch name."
+ focus $w.desc.name_t
+ return
+ }
+
+ set rev {}
+ switch -- $create_branch_revtype {
+ head {set rev $create_branch_head}
+ tracking {set rev $create_branch_trackinghead}
+ tag {set rev $create_branch_tag}
+ expression {set rev $create_branch_revexp}
+ }
+ if {[catch {set cmt [git rev-parse --verify "${rev}^0"]}]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Invalid starting revision: $rev"
+ return
+ }
+ if {[catch {
+ git update-ref \
+ -m "branch: Created from $rev" \
+ "refs/heads/$newbranch" \
+ $cmt \
+ $null_sha1
+ } err]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Failed to create '$newbranch'.\n\n$err"
+ return
+ }
+
+ lappend all_heads $newbranch
+ set all_heads [lsort $all_heads]
+ populate_branch_menu
+ destroy $w
+ if {$create_branch_checkout} {
+ switch_branch $newbranch
+ }
+}
+
+proc radio_selector {varname value args} {
+ upvar #0 $varname var
+ set var $value
+}
+
+trace add variable create_branch_head write \
+ [list radio_selector create_branch_revtype head]
+trace add variable create_branch_trackinghead write \
+ [list radio_selector create_branch_revtype tracking]
+trace add variable create_branch_tag write \
+ [list radio_selector create_branch_revtype tag]
+
+trace add variable delete_branch_head write \
+ [list radio_selector delete_branch_checktype head]
+trace add variable delete_branch_trackinghead write \
+ [list radio_selector delete_branch_checktype tracking]
+
+proc do_create_branch {} {
+ global all_heads current_branch repo_config
+ global create_branch_checkout create_branch_revtype
+ global create_branch_head create_branch_trackinghead
+ global create_branch_name create_branch_revexp
+ global create_branch_tag
+
+ set w .branch_editor
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ label $w.header -text {Create New Branch} \
+ -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.create -text Create \
+ -default active \
+ -command [list do_create_branch_action $w]
+ pack $w.buttons.create -side right
+ button $w.buttons.cancel -text {Cancel} \
+ -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ labelframe $w.desc -text {Branch Description}
+ label $w.desc.name_l -text {Name:}
+ entry $w.desc.name_t \
+ -borderwidth 1 \
+ -relief sunken \
+ -width 40 \
+ -textvariable create_branch_name \
+ -validate key \
+ -validatecommand {
+ if {%d == 1 && [regexp {[~^:?*\[\0- ]} %S]} {return 0}
+ return 1
+ }
+ grid $w.desc.name_l $w.desc.name_t -sticky we -padx {0 5}
+ grid columnconfigure $w.desc 1 -weight 1
+ pack $w.desc -anchor nw -fill x -pady 5 -padx 5
+
+ labelframe $w.from -text {Starting Revision}
+ if {$all_heads ne {}} {
+ radiobutton $w.from.head_r \
+ -text {Local Branch:} \
+ -value head \
+ -variable create_branch_revtype
+ eval tk_optionMenu $w.from.head_m create_branch_head $all_heads
+ grid $w.from.head_r $w.from.head_m -sticky w
+ }
+ set all_trackings [all_tracking_branches]
+ if {$all_trackings ne {}} {
+ set create_branch_trackinghead [lindex $all_trackings 0]
+ radiobutton $w.from.tracking_r \
+ -text {Tracking Branch:} \
+ -value tracking \
+ -variable create_branch_revtype
+ eval tk_optionMenu $w.from.tracking_m \
+ create_branch_trackinghead \
+ $all_trackings
+ grid $w.from.tracking_r $w.from.tracking_m -sticky w
+ }
+ set all_tags [load_all_tags]
+ if {$all_tags ne {}} {
+ set create_branch_tag [lindex $all_tags 0]
+ radiobutton $w.from.tag_r \
+ -text {Tag:} \
+ -value tag \
+ -variable create_branch_revtype
+ eval tk_optionMenu $w.from.tag_m create_branch_tag $all_tags
+ grid $w.from.tag_r $w.from.tag_m -sticky w
+ }
+ radiobutton $w.from.exp_r \
+ -text {Revision Expression:} \
+ -value expression \
+ -variable create_branch_revtype
+ entry $w.from.exp_t \
+ -borderwidth 1 \
+ -relief sunken \
+ -width 50 \
+ -textvariable create_branch_revexp \
+ -validate key \
+ -validatecommand {
+ if {%d == 1 && [regexp {\s} %S]} {return 0}
+ if {%d == 1 && [string length %S] > 0} {
+ set create_branch_revtype expression
+ }
+ return 1
+ }
+ grid $w.from.exp_r $w.from.exp_t -sticky we -padx {0 5}
+ grid columnconfigure $w.from 1 -weight 1
+ pack $w.from -anchor nw -fill x -pady 5 -padx 5
+
+ labelframe $w.postActions -text {Post Creation Actions}
+ checkbutton $w.postActions.checkout \
+ -text {Checkout after creation} \
+ -variable create_branch_checkout
+ pack $w.postActions.checkout -anchor nw
+ pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
+
+ set create_branch_checkout 1
+ set create_branch_head $current_branch
+ set create_branch_revtype head
+ set create_branch_name $repo_config(gui.newbranchtemplate)
+ set create_branch_revexp {}
+
+ bind $w <Visibility> "
+ grab $w
+ $w.desc.name_t icursor end
+ focus $w.desc.name_t
+ "
+ bind $w <Key-Escape> "destroy $w"
+ bind $w <Key-Return> "do_create_branch_action $w;break"
+ wm title $w "[appname] ([reponame]): Create Branch"
+ tkwait window $w
+}
+
+proc do_delete_branch_action {w} {
+ global all_heads
+ global delete_branch_checktype delete_branch_head delete_branch_trackinghead
+
+ set check_rev {}
+ switch -- $delete_branch_checktype {
+ head {set check_rev $delete_branch_head}
+ tracking {set check_rev $delete_branch_trackinghead}
+ always {set check_rev {:none}}
+ }
+ if {$check_rev eq {:none}} {
+ set check_cmt {}
+ } elseif {[catch {set check_cmt [git rev-parse --verify "${check_rev}^0"]}]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Invalid check revision: $check_rev"
+ return
+ }
+
+ set to_delete [list]
+ set not_merged [list]
+ foreach i [$w.list.l curselection] {
+ set b [$w.list.l get $i]
+ if {[catch {set o [git rev-parse --verify $b]}]} continue
+ if {$check_cmt ne {}} {
+ if {$b eq $check_rev} continue
+ if {[catch {set m [git merge-base $o $check_cmt]}]} continue
+ if {$o ne $m} {
+ lappend not_merged $b
+ continue
+ }
+ }
+ lappend to_delete [list $b $o]
+ }
+ if {$not_merged ne {}} {
+ set msg "The following branches are not completely merged into $check_rev:
+
+ - [join $not_merged "\n - "]"
+ tk_messageBox \
+ -icon info \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message $msg
+ }
+ if {$to_delete eq {}} return
+ if {$delete_branch_checktype eq {always}} {
+ set msg {Recovering deleted branches is difficult.
+
+Delete the selected branches?}
+ if {[tk_messageBox \
+ -icon warning \
+ -type yesno \
+ -title [wm title $w] \
+ -parent $w \
+ -message $msg] ne yes} {
+ return
+ }
+ }
+
+ set failed {}
+ foreach i $to_delete {
+ set b [lindex $i 0]
+ set o [lindex $i 1]
+ if {[catch {git update-ref -d "refs/heads/$b" $o} err]} {
+ append failed " - $b: $err\n"
+ } else {
+ set x [lsearch -sorted -exact $all_heads $b]
+ if {$x >= 0} {
+ set all_heads [lreplace $all_heads $x $x]
+ }
+ }
+ }
+
+ if {$failed ne {}} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Failed to delete branches:\n$failed"
+ }
+
+ set all_heads [lsort $all_heads]
+ populate_branch_menu
+ destroy $w
+}
+
+proc do_delete_branch {} {
+ global all_heads tracking_branches current_branch
+ global delete_branch_checktype delete_branch_head delete_branch_trackinghead
+
+ set w .branch_editor
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ label $w.header -text {Delete Local Branch} \
+ -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.create -text Delete \
+ -command [list do_delete_branch_action $w]
+ pack $w.buttons.create -side right
+ button $w.buttons.cancel -text {Cancel} \
+ -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ labelframe $w.list -text {Local Branches}
+ listbox $w.list.l \
+ -height 10 \
+ -width 70 \
+ -selectmode extended \
+ -yscrollcommand [list $w.list.sby set]
+ foreach h $all_heads {
+ if {$h ne $current_branch} {
+ $w.list.l insert end $h
+ }
+ }
+ scrollbar $w.list.sby -command [list $w.list.l yview]
+ pack $w.list.sby -side right -fill y
+ pack $w.list.l -side left -fill both -expand 1
+ pack $w.list -fill both -expand 1 -pady 5 -padx 5
+
+ labelframe $w.validate -text {Delete Only If}
+ radiobutton $w.validate.head_r \
+ -text {Merged Into Local Branch:} \
+ -value head \
+ -variable delete_branch_checktype
+ eval tk_optionMenu $w.validate.head_m delete_branch_head $all_heads
+ grid $w.validate.head_r $w.validate.head_m -sticky w
+ set all_trackings [all_tracking_branches]
+ if {$all_trackings ne {}} {
+ set delete_branch_trackinghead [lindex $all_trackings 0]
+ radiobutton $w.validate.tracking_r \
+ -text {Merged Into Tracking Branch:} \
+ -value tracking \
+ -variable delete_branch_checktype
+ eval tk_optionMenu $w.validate.tracking_m \
+ delete_branch_trackinghead \
+ $all_trackings
+ grid $w.validate.tracking_r $w.validate.tracking_m -sticky w
+ }
+ radiobutton $w.validate.always_r \
+ -text {Always (Do not perform merge checks)} \
+ -value always \
+ -variable delete_branch_checktype
+ grid $w.validate.always_r -columnspan 2 -sticky w
+ grid columnconfigure $w.validate 1 -weight 1
+ pack $w.validate -anchor nw -fill x -pady 5 -padx 5
+
+ set delete_branch_head $current_branch
+ set delete_branch_checktype head
+
+ bind $w <Visibility> "grab $w; focus $w"
+ bind $w <Key-Escape> "destroy $w"
+ wm title $w "[appname] ([reponame]): Delete Branch"
+ tkwait window $w
+}
+
+proc switch_branch {new_branch} {
+ global HEAD commit_type current_branch repo_config
+
+ if {![lock_index switch]} return
+
+ # -- Our in memory state should match the repository.
+ #
+ repository_state curType curHEAD curMERGE_HEAD
+ if {[string match amend* $commit_type]
+ && $curType eq {normal}
+ && $curHEAD eq $HEAD} {
+ } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
+ info_popup {Last scanned state does not match repository state.
+
+Another Git program has modified this repository since the last scan. A rescan must be performed before the current branch can be changed.
+
+The rescan will be automatically started now.
+}
+ unlock_index
+ rescan {set ui_status_value {Ready.}}
+ return
+ }
+
+ # -- Don't do a pointless switch.
+ #
+ if {$current_branch eq $new_branch} {
+ unlock_index
+ return
+ }
+
+ if {$repo_config(gui.trustmtime) eq {true}} {
+ switch_branch_stage2 {} $new_branch
+ } else {
+ set ui_status_value {Refreshing file status...}
+ set cmd [list git update-index]
+ lappend cmd -q
+ lappend cmd --unmerged
+ lappend cmd --ignore-missing
+ lappend cmd --refresh
+ set fd_rf [open "| $cmd" r]
+ fconfigure $fd_rf -blocking 0 -translation binary
+ fileevent $fd_rf readable \
+ [list switch_branch_stage2 $fd_rf $new_branch]
+ }
+}
+
+proc switch_branch_stage2 {fd_rf new_branch} {
+ global ui_status_value HEAD
+
+ if {$fd_rf ne {}} {
+ read $fd_rf
+ if {![eof $fd_rf]} return
+ close $fd_rf
+ }
+
+ set ui_status_value "Updating working directory to '$new_branch'..."
+ set cmd [list git read-tree]
+ lappend cmd -m
+ lappend cmd -u
+ lappend cmd --exclude-per-directory=.gitignore
+ lappend cmd $HEAD
+ lappend cmd $new_branch
+ set fd_rt [open "| $cmd" r]
+ fconfigure $fd_rt -blocking 0 -translation binary
+ fileevent $fd_rt readable \
+ [list switch_branch_readtree_wait $fd_rt $new_branch]
+}
+
+proc switch_branch_readtree_wait {fd_rt new_branch} {
+ global selected_commit_type commit_type HEAD MERGE_HEAD PARENT
+ global current_branch
+ global ui_comm ui_status_value
+
+ # -- We never get interesting output on stdout; only stderr.
+ #
+ read $fd_rt
+ fconfigure $fd_rt -blocking 1
+ if {![eof $fd_rt]} {
+ fconfigure $fd_rt -blocking 0
+ return
+ }
+
+ # -- The working directory wasn't in sync with the index and
+ # we'd have to overwrite something to make the switch. A
+ # merge is required.
+ #
+ if {[catch {close $fd_rt} err]} {
+ regsub {^fatal: } $err {} err
+ warn_popup "File level merge required.
+
+$err
+
+Staying on branch '$current_branch'."
+ set ui_status_value "Aborted checkout of '$new_branch' (file level merging is required)."
+ unlock_index
+ return
+ }
+
+ # -- Update the symbolic ref. Core git doesn't even check for failure
+ # here, it Just Works(tm). If it doesn't we are in some really ugly
+ # state that is difficult to recover from within git-gui.
+ #
+ if {[catch {git symbolic-ref HEAD "refs/heads/$new_branch"} err]} {
+ error_popup "Failed to set current branch.
+
+This working directory is only partially switched. We successfully updated your files, but failed to update an internal Git file.
+
+This should not have occurred. [appname] will now close and give up.
+
+$err"
+ do_quit
+ return
+ }
+
+ # -- Update our repository state. If we were previously in amend mode
+ # we need to toss the current buffer and do a full rescan to update
+ # our file lists. If we weren't in amend mode our file lists are
+ # accurate and we can avoid the rescan.
+ #
+ unlock_index
+ set selected_commit_type new
+ if {[string match amend* $commit_type]} {
+ $ui_comm delete 0.0 end
+ $ui_comm edit reset
+ $ui_comm edit modified false
+ rescan {set ui_status_value "Checked out branch '$current_branch'."}
+ } else {
+ repository_state commit_type HEAD MERGE_HEAD
+ set PARENT $HEAD
+ set ui_status_value "Checked out branch '$current_branch'."
+ }
+}
diff --git a/git-gui/lib/branch_rename.tcl b/git-gui/lib/branch_rename.tcl
new file mode 100644
index 0000000000..405101637f
--- /dev/null
+++ b/git-gui/lib/branch_rename.tcl
@@ -0,0 +1,136 @@
+# git-gui branch rename support
+# Copyright (C) 2007 Shawn Pearce
+
+class branch_rename {
+
+field w
+field oldname
+field newname
+
+constructor dialog {} {
+ global all_heads current_branch
+
+ make_toplevel top w
+ wm title $top "[appname] ([reponame]): Rename Branch"
+ if {$top ne {.}} {
+ wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
+ }
+
+ set oldname $current_branch
+ set newname [get_config gui.newbranchtemplate]
+
+ label $w.header -text {Rename Branch} -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.rename -text Rename \
+ -default active \
+ -command [cb _rename]
+ pack $w.buttons.rename -side right
+ button $w.buttons.cancel -text {Cancel} \
+ -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ frame $w.rename
+ label $w.rename.oldname_l -text {Branch:}
+ eval tk_optionMenu $w.rename.oldname_m @oldname $all_heads
+
+ label $w.rename.newname_l -text {New Name:}
+ entry $w.rename.newname_t \
+ -borderwidth 1 \
+ -relief sunken \
+ -width 40 \
+ -textvariable @newname \
+ -validate key \
+ -validatecommand {
+ if {%d == 1 && [regexp {[~^:?*\[\0- ]} %S]} {return 0}
+ return 1
+ }
+
+ grid $w.rename.oldname_l $w.rename.oldname_m -sticky w -padx {0 5}
+ grid $w.rename.newname_l $w.rename.newname_t -sticky we -padx {0 5}
+ grid columnconfigure $w.rename 1 -weight 1
+ pack $w.rename -anchor nw -fill x -pady 5 -padx 5
+
+ bind $w <Key-Return> [cb _rename]
+ bind $w <Key-Escape> [list destroy $w]
+ bind $w <Visibility> "
+ grab $w
+ $w.rename.newname_t icursor end
+ focus $w.rename.newname_t
+ "
+ tkwait window $w
+}
+
+method _rename {} {
+ global all_heads current_branch
+
+ if {$oldname eq {}} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Please select a branch to rename."
+ focus $w.rename.oldname_m
+ return
+ }
+ if {$newname eq {}
+ || $newname eq [get_config gui.newbranchtemplate]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Please supply a branch name."
+ focus $w.rename.newname_t
+ return
+ }
+ if {![catch {git show-ref --verify -- "refs/heads/$newname"}]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Branch '$newname' already exists."
+ focus $w.rename.newname_t
+ return
+ }
+ if {[catch {git check-ref-format "heads/$newname"}]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "We do not like '$newname' as a branch name."
+ focus $w.rename.newname_t
+ return
+ }
+
+ if {[catch {git branch -m $oldname $newname} err]} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Failed to rename '$oldname'.\n\n$err"
+ return
+ }
+
+ set oldidx [lsearch -exact -sorted $all_heads $oldname]
+ if {$oldidx >= 0} {
+ set all_heads [lreplace $all_heads $oldidx $oldidx]
+ }
+ lappend all_heads $newname
+ set all_heads [lsort $all_heads]
+ populate_branch_menu
+
+ if {$current_branch eq $oldname} {
+ set current_branch $newname
+ }
+
+ destroy $w
+}
+
+}
diff --git a/git-gui/lib/browser.tcl b/git-gui/lib/browser.tcl
new file mode 100644
index 0000000000..3d6341bcc5
--- /dev/null
+++ b/git-gui/lib/browser.tcl
@@ -0,0 +1,238 @@
+# git-gui tree browser
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+class browser {
+
+field w
+field browser_commit
+field browser_path
+field browser_files {}
+field browser_status {Starting...}
+field browser_stack {}
+field browser_busy 1
+
+constructor new {commit} {
+ global cursor_ptr M1B
+ make_toplevel top w
+ wm title $top "[appname] ([reponame]): File Browser"
+
+ set browser_commit $commit
+ set browser_path $browser_commit:
+
+ label $w.path \
+ -textvariable @browser_path \
+ -anchor w \
+ -justify left \
+ -borderwidth 1 \
+ -relief sunken \
+ -font font_uibold
+ pack $w.path -anchor w -side top -fill x
+
+ frame $w.list
+ set w_list $w.list.l
+ text $w_list -background white -borderwidth 0 \
+ -cursor $cursor_ptr \
+ -state disabled \
+ -wrap none \
+ -height 20 \
+ -width 70 \
+ -xscrollcommand [list $w.list.sbx set] \
+ -yscrollcommand [list $w.list.sby set]
+ $w_list tag conf in_sel \
+ -background [$w_list cget -foreground] \
+ -foreground [$w_list cget -background]
+ scrollbar $w.list.sbx -orient h -command [list $w_list xview]
+ scrollbar $w.list.sby -orient v -command [list $w_list yview]
+ pack $w.list.sbx -side bottom -fill x
+ pack $w.list.sby -side right -fill y
+ pack $w_list -side left -fill both -expand 1
+ pack $w.list -side top -fill both -expand 1
+
+ label $w.status \
+ -textvariable @browser_status \
+ -anchor w \
+ -justify left \
+ -borderwidth 1 \
+ -relief sunken
+ pack $w.status -anchor w -side bottom -fill x
+
+ bind $w_list <Button-1> "[cb _click 0 @%x,%y];break"
+ bind $w_list <Double-Button-1> "[cb _click 1 @%x,%y];break"
+ bind $w_list <$M1B-Up> "[cb _parent] ;break"
+ bind $w_list <$M1B-Left> "[cb _parent] ;break"
+ bind $w_list <Up> "[cb _move -1] ;break"
+ bind $w_list <Down> "[cb _move 1] ;break"
+ bind $w_list <$M1B-Right> "[cb _enter] ;break"
+ bind $w_list <Return> "[cb _enter] ;break"
+ bind $w_list <Prior> "[cb _page -1] ;break"
+ bind $w_list <Next> "[cb _page 1] ;break"
+ bind $w_list <Left> break
+ bind $w_list <Right> break
+
+ bind $w_list <Visibility> [list focus $w_list]
+ set w $w_list
+ _ls $this $browser_commit
+ return $this
+}
+
+method _move {dir} {
+ if {$browser_busy} return
+ set lno [lindex [split [$w index in_sel.first] .] 0]
+ incr lno $dir
+ if {[lindex $browser_files [expr {$lno - 1}]] ne {}} {
+ $w tag remove in_sel 0.0 end
+ $w tag add in_sel $lno.0 [expr {$lno + 1}].0
+ $w see $lno.0
+ }
+}
+
+method _page {dir} {
+ if {$browser_busy} return
+ $w yview scroll $dir pages
+ set lno [expr {int(
+ [lindex [$w yview] 0]
+ * [llength $browser_files]
+ + 1)}]
+ if {[lindex $browser_files [expr {$lno - 1}]] ne {}} {
+ $w tag remove in_sel 0.0 end
+ $w tag add in_sel $lno.0 [expr {$lno + 1}].0
+ $w see $lno.0
+ }
+}
+
+method _parent {} {
+ if {$browser_busy} return
+ set info [lindex $browser_files 0]
+ if {[lindex $info 0] eq {parent}} {
+ set parent [lindex $browser_stack end-1]
+ set browser_stack [lrange $browser_stack 0 end-2]
+ if {$browser_stack eq {}} {
+ regsub {:.*$} $browser_path {:} browser_path
+ } else {
+ regsub {/[^/]+$} $browser_path {} browser_path
+ }
+ set browser_status "Loading $browser_path..."
+ _ls $this [lindex $parent 0] [lindex $parent 1]
+ }
+}
+
+method _enter {} {
+ if {$browser_busy} return
+ set lno [lindex [split [$w index in_sel.first] .] 0]
+ set info [lindex $browser_files [expr {$lno - 1}]]
+ if {$info ne {}} {
+ switch -- [lindex $info 0] {
+ parent {
+ _parent $this
+ }
+ tree {
+ set name [lindex $info 2]
+ set escn [escape_path $name]
+ set browser_status "Loading $escn..."
+ append browser_path $escn
+ _ls $this [lindex $info 1] $name
+ }
+ blob {
+ set name [lindex $info 2]
+ set p {}
+ foreach n $browser_stack {
+ append p [lindex $n 1]
+ }
+ append p $name
+ blame::new $browser_commit $p
+ }
+ }
+ }
+}
+
+method _click {was_double_click pos} {
+ if {$browser_busy} return
+ set lno [lindex [split [$w index $pos] .] 0]
+ focus $w
+
+ if {[lindex $browser_files [expr {$lno - 1}]] ne {}} {
+ $w tag remove in_sel 0.0 end
+ $w tag add in_sel $lno.0 [expr {$lno + 1}].0
+ if {$was_double_click} {
+ _enter $this
+ }
+ }
+}
+
+method _ls {tree_id {name {}}} {
+ set browser_buffer {}
+ set browser_files {}
+ set browser_busy 1
+
+ $w conf -state normal
+ $w tag remove in_sel 0.0 end
+ $w delete 0.0 end
+ if {$browser_stack ne {}} {
+ $w image create end \
+ -align center -padx 5 -pady 1 \
+ -name icon0 \
+ -image file_uplevel
+ $w insert end {[Up To Parent]}
+ lappend browser_files parent
+ }
+ lappend browser_stack [list $tree_id $name]
+ $w conf -state disabled
+
+ set cmd [list git ls-tree -z $tree_id]
+ set fd [open "| $cmd" r]
+ fconfigure $fd -blocking 0 -translation binary -encoding binary
+ fileevent $fd readable [cb _read $fd]
+}
+
+method _read {fd} {
+ append browser_buffer [read $fd]
+ set pck [split $browser_buffer "\0"]
+ set browser_buffer [lindex $pck end]
+
+ set n [llength $browser_files]
+ $w conf -state normal
+ foreach p [lrange $pck 0 end-1] {
+ set info [split $p "\t"]
+ set path [lindex $info 1]
+ set info [split [lindex $info 0] { }]
+ set type [lindex $info 1]
+ set object [lindex $info 2]
+
+ switch -- $type {
+ blob {
+ set image file_mod
+ }
+ tree {
+ set image file_dir
+ append path /
+ }
+ default {
+ set image file_question
+ }
+ }
+
+ if {$n > 0} {$w insert end "\n"}
+ $w image create end \
+ -align center -padx 5 -pady 1 \
+ -name icon[incr n] \
+ -image $image
+ $w insert end [escape_path $path]
+ lappend browser_files [list $type $object $path]
+ }
+ $w conf -state disabled
+
+ if {[eof $fd]} {
+ close $fd
+ set browser_status Ready.
+ set browser_busy 0
+ unset browser_buffer
+ if {$n > 0} {
+ $w tag add in_sel 1.0 2.0
+ focus -force $w
+ }
+ }
+} ifdeleted {
+ catch {close $fd}
+}
+
+}
diff --git a/git-gui/lib/class.tcl b/git-gui/lib/class.tcl
new file mode 100644
index 0000000000..9d298d0dcc
--- /dev/null
+++ b/git-gui/lib/class.tcl
@@ -0,0 +1,171 @@
+# git-gui simple class/object fake-alike
+# Copyright (C) 2007 Shawn Pearce
+
+proc class {class body} {
+ if {[namespace exists $class]} {
+ error "class $class already declared"
+ }
+ namespace eval $class {
+ variable __nextid 0
+ variable __sealed 0
+ variable __field_list {}
+ variable __field_array
+
+ proc cb {name args} {
+ upvar this this
+ set args [linsert $args 0 $name $this]
+ return [uplevel [list namespace code $args]]
+ }
+ }
+ namespace eval $class $body
+}
+
+proc field {name args} {
+ set class [uplevel {namespace current}]
+ variable ${class}::__sealed
+ variable ${class}::__field_array
+
+ switch [llength $args] {
+ 0 { set new [list $name] }
+ 1 { set new [list $name [lindex $args 0]] }
+ default { error "wrong # args: field name value?" }
+ }
+
+ if {$__sealed} {
+ error "class $class is sealed (cannot add new fields)"
+ }
+
+ if {[catch {set old $__field_array($name)}]} {
+ variable ${class}::__field_list
+ lappend __field_list $new
+ set __field_array($name) 1
+ } else {
+ error "field $name already declared"
+ }
+}
+
+proc constructor {name params body} {
+ set class [uplevel {namespace current}]
+ set ${class}::__sealed 1
+ variable ${class}::__field_list
+ set mbodyc {}
+
+ append mbodyc {set this } $class
+ append mbodyc {::__o[incr } $class {::__nextid]} \;
+ append mbodyc {namespace eval $this {}} \;
+
+ if {$__field_list ne {}} {
+ append mbodyc {upvar #0}
+ foreach n $__field_list {
+ set n [lindex $n 0]
+ append mbodyc { ${this}::} $n { } $n
+ regsub -all @$n\\M $body "\${this}::$n" body
+ }
+ append mbodyc \;
+ foreach n $__field_list {
+ if {[llength $n] == 2} {
+ append mbodyc \
+ {set } [lindex $n 0] { } [list [lindex $n 1]] \;
+ }
+ }
+ }
+ append mbodyc $body
+ namespace eval $class [list proc $name $params $mbodyc]
+}
+
+proc method {name params body {deleted {}} {del_body {}}} {
+ set class [uplevel {namespace current}]
+ set ${class}::__sealed 1
+ variable ${class}::__field_list
+ set params [linsert $params 0 this]
+ set mbodyc {}
+
+ switch $deleted {
+ {} {}
+ ifdeleted {
+ append mbodyc {if {![namespace exists $this]} }
+ append mbodyc \{ $del_body \; return \} \;
+ }
+ default {
+ error "wrong # args: method name args body (ifdeleted body)?"
+ }
+ }
+
+ set decl {}
+ foreach n $__field_list {
+ set n [lindex $n 0]
+ if {[regexp -- $n\\M $body]} {
+ if { [regexp -all -- $n\\M $body] == 1
+ && [regexp -all -- \\\$$n\\M $body] == 1
+ && [regexp -all -- \\\$$n\\( $body] == 0} {
+ regsub -all \\\$$n\\M $body "\[set \${this}::$n\]" body
+ } else {
+ append decl { ${this}::} $n { } $n
+ regsub -all @$n\\M $body "\${this}::$n" body
+ }
+ }
+ }
+ if {$decl ne {}} {
+ append mbodyc {upvar #0} $decl \;
+ }
+ append mbodyc $body
+ namespace eval $class [list proc $name $params $mbodyc]
+}
+
+proc delete_this {{t {}}} {
+ if {$t eq {}} {
+ upvar this this
+ set t $this
+ }
+ if {[namespace exists $t]} {namespace delete $t}
+}
+
+proc make_toplevel {t w args} {
+ upvar $t top $w pfx this this
+
+ if {[llength $args] % 2} {
+ error "make_toplevel topvar winvar {options}"
+ }
+ set autodelete 1
+ foreach {name value} $args {
+ switch -exact -- $name {
+ -autodelete {set autodelete $value}
+ default {error "unsupported option $name"}
+ }
+ }
+
+ if {[winfo ismapped .]} {
+ regsub -all {::} $this {__} w
+ set top .$w
+ set pfx $top
+ toplevel $top
+ } else {
+ set top .
+ set pfx {}
+ }
+
+ if {$autodelete} {
+ wm protocol $top WM_DELETE_WINDOW "
+ [list delete_this $this]
+ [list destroy $top]
+ "
+ }
+}
+
+
+## auto_mkindex support for class/constructor/method
+##
+auto_mkindex_parser::command class {name body} {
+ variable parser
+ variable contextStack
+ set contextStack [linsert $contextStack 0 $name]
+ $parser eval [list _%@namespace eval $name] $body
+ set contextStack [lrange $contextStack 1 end]
+}
+auto_mkindex_parser::command constructor {name args} {
+ variable index
+ variable scriptFile
+ append index [list set auto_index([fullname $name])] \
+ [format { [list source [file join $dir %s]]} \
+ [file split $scriptFile]] "\n"
+}
diff --git a/git-gui/lib/commit.tcl b/git-gui/lib/commit.tcl
new file mode 100644
index 0000000000..f9791f64db
--- /dev/null
+++ b/git-gui/lib/commit.tcl
@@ -0,0 +1,410 @@
+# git-gui misc. commit reading/writing support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc load_last_commit {} {
+ global HEAD PARENT MERGE_HEAD commit_type ui_comm
+ global repo_config
+
+ if {[llength $PARENT] == 0} {
+ error_popup {There is nothing to amend.
+
+You are about to create the initial commit. There is no commit before this to amend.
+}
+ return
+ }
+
+ repository_state curType curHEAD curMERGE_HEAD
+ if {$curType eq {merge}} {
+ error_popup {Cannot amend while merging.
+
+You are currently in the middle of a merge that has not been fully completed. You cannot amend the prior commit unless you first abort the current merge activity.
+}
+ return
+ }
+
+ set msg {}
+ set parents [list]
+ if {[catch {
+ set fd [open "| git cat-file commit $curHEAD" r]
+ fconfigure $fd -encoding binary -translation lf
+ if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
+ set enc utf-8
+ }
+ while {[gets $fd line] > 0} {
+ if {[string match {parent *} $line]} {
+ lappend parents [string range $line 7 end]
+ } elseif {[string match {encoding *} $line]} {
+ set enc [string tolower [string range $line 9 end]]
+ }
+ }
+ set msg [encoding convertfrom $enc [read $fd]]
+ set msg [string trim $msg]
+ close $fd
+ } err]} {
+ error_popup "Error loading commit data for amend:\n\n$err"
+ return
+ }
+
+ set HEAD $curHEAD
+ set PARENT $parents
+ set MERGE_HEAD [list]
+ switch -- [llength $parents] {
+ 0 {set commit_type amend-initial}
+ 1 {set commit_type amend}
+ default {set commit_type amend-merge}
+ }
+
+ $ui_comm delete 0.0 end
+ $ui_comm insert end $msg
+ $ui_comm edit reset
+ $ui_comm edit modified false
+ rescan {set ui_status_value {Ready.}}
+}
+
+set GIT_COMMITTER_IDENT {}
+
+proc committer_ident {} {
+ global GIT_COMMITTER_IDENT
+
+ if {$GIT_COMMITTER_IDENT eq {}} {
+ if {[catch {set me [git var GIT_COMMITTER_IDENT]} err]} {
+ error_popup "Unable to obtain your identity:\n\n$err"
+ return {}
+ }
+ if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
+ $me me GIT_COMMITTER_IDENT]} {
+ error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
+ return {}
+ }
+ }
+
+ return $GIT_COMMITTER_IDENT
+}
+
+proc do_signoff {} {
+ global ui_comm
+
+ set me [committer_ident]
+ if {$me eq {}} return
+
+ set sob "Signed-off-by: $me"
+ set last [$ui_comm get {end -1c linestart} {end -1c}]
+ if {$last ne $sob} {
+ $ui_comm edit separator
+ if {$last ne {}
+ && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
+ $ui_comm insert end "\n"
+ }
+ $ui_comm insert end "\n$sob"
+ $ui_comm edit separator
+ $ui_comm see end
+ }
+}
+
+proc create_new_commit {} {
+ global commit_type ui_comm
+
+ set commit_type normal
+ $ui_comm delete 0.0 end
+ $ui_comm edit reset
+ $ui_comm edit modified false
+ rescan {set ui_status_value {Ready.}}
+}
+
+proc commit_tree {} {
+ global HEAD commit_type file_states ui_comm repo_config
+ global ui_status_value pch_error
+
+ if {[committer_ident] eq {}} return
+ if {![lock_index update]} return
+
+ # -- Our in memory state should match the repository.
+ #
+ repository_state curType curHEAD curMERGE_HEAD
+ if {[string match amend* $commit_type]
+ && $curType eq {normal}
+ && $curHEAD eq $HEAD} {
+ } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
+ info_popup {Last scanned state does not match repository state.
+
+Another Git program has modified this repository since the last scan. A rescan must be performed before another commit can be created.
+
+The rescan will be automatically started now.
+}
+ unlock_index
+ rescan {set ui_status_value {Ready.}}
+ return
+ }
+
+ # -- At least one file should differ in the index.
+ #
+ set files_ready 0
+ foreach path [array names file_states] {
+ switch -glob -- [lindex $file_states($path) 0] {
+ _? {continue}
+ A? -
+ D? -
+ M? {set files_ready 1}
+ U? {
+ error_popup "Unmerged files cannot be committed.
+
+File [short_path $path] has merge conflicts. You must resolve them and add the file before committing.
+"
+ unlock_index
+ return
+ }
+ default {
+ error_popup "Unknown file state [lindex $s 0] detected.
+
+File [short_path $path] cannot be committed by this program.
+"
+ }
+ }
+ }
+ if {!$files_ready && ![string match *merge $curType]} {
+ info_popup {No changes to commit.
+
+You must add at least 1 file before you can commit.
+}
+ unlock_index
+ return
+ }
+
+ # -- A message is required.
+ #
+ set msg [string trim [$ui_comm get 1.0 end]]
+ regsub -all -line {[ \t\r]+$} $msg {} msg
+ if {$msg eq {}} {
+ error_popup {Please supply a commit message.
+
+A good commit message has the following format:
+
+- First line: Describe in one sentance what you did.
+- Second line: Blank
+- Remaining lines: Describe why this change is good.
+}
+ unlock_index
+ return
+ }
+
+ # -- Run the pre-commit hook.
+ #
+ set pchook [gitdir hooks pre-commit]
+
+ # On Cygwin [file executable] might lie so we need to ask
+ # the shell if the hook is executable. Yes that's annoying.
+ #
+ if {[is_Cygwin] && [file isfile $pchook]} {
+ set pchook [list sh -c [concat \
+ "if test -x \"$pchook\";" \
+ "then exec \"$pchook\" 2>&1;" \
+ "fi"]]
+ } elseif {[file executable $pchook]} {
+ set pchook [list $pchook |& cat]
+ } else {
+ commit_writetree $curHEAD $msg
+ return
+ }
+
+ set ui_status_value {Calling pre-commit hook...}
+ set pch_error {}
+ set fd_ph [open "| $pchook" r]
+ fconfigure $fd_ph -blocking 0 -translation binary
+ fileevent $fd_ph readable \
+ [list commit_prehook_wait $fd_ph $curHEAD $msg]
+}
+
+proc commit_prehook_wait {fd_ph curHEAD msg} {
+ global pch_error ui_status_value
+
+ append pch_error [read $fd_ph]
+ fconfigure $fd_ph -blocking 1
+ if {[eof $fd_ph]} {
+ if {[catch {close $fd_ph}]} {
+ set ui_status_value {Commit declined by pre-commit hook.}
+ hook_failed_popup pre-commit $pch_error
+ unlock_index
+ } else {
+ commit_writetree $curHEAD $msg
+ }
+ set pch_error {}
+ return
+ }
+ fconfigure $fd_ph -blocking 0
+}
+
+proc commit_writetree {curHEAD msg} {
+ global ui_status_value
+
+ set ui_status_value {Committing changes...}
+ set fd_wt [open "| git write-tree" r]
+ fileevent $fd_wt readable \
+ [list commit_committree $fd_wt $curHEAD $msg]
+}
+
+proc commit_committree {fd_wt curHEAD msg} {
+ global HEAD PARENT MERGE_HEAD commit_type
+ global all_heads current_branch
+ global ui_status_value ui_comm selected_commit_type
+ global file_states selected_paths rescan_active
+ global repo_config
+
+ gets $fd_wt tree_id
+ if {$tree_id eq {} || [catch {close $fd_wt} err]} {
+ error_popup "write-tree failed:\n\n$err"
+ set ui_status_value {Commit failed.}
+ unlock_index
+ return
+ }
+
+ # -- Verify this wasn't an empty change.
+ #
+ if {$commit_type eq {normal}} {
+ set old_tree [git rev-parse "$PARENT^{tree}"]
+ if {$tree_id eq $old_tree} {
+ info_popup {No changes to commit.
+
+No files were modified by this commit and it was not a merge commit.
+
+A rescan will be automatically started now.
+}
+ unlock_index
+ rescan {set ui_status_value {No changes to commit.}}
+ return
+ }
+ }
+
+ # -- Build the message.
+ #
+ set msg_p [gitdir COMMIT_EDITMSG]
+ set msg_wt [open $msg_p w]
+ if {[catch {set enc $repo_config(i18n.commitencoding)}]} {
+ set enc utf-8
+ }
+ fconfigure $msg_wt -encoding binary -translation binary
+ puts -nonewline $msg_wt [encoding convertto $enc $msg]
+ close $msg_wt
+
+ # -- Create the commit.
+ #
+ set cmd [list commit-tree $tree_id]
+ foreach p [concat $PARENT $MERGE_HEAD] {
+ lappend cmd -p $p
+ }
+ lappend cmd <$msg_p
+ if {[catch {set cmt_id [eval git $cmd]} err]} {
+ error_popup "commit-tree failed:\n\n$err"
+ set ui_status_value {Commit failed.}
+ unlock_index
+ return
+ }
+
+ # -- Update the HEAD ref.
+ #
+ set reflogm commit
+ if {$commit_type ne {normal}} {
+ append reflogm " ($commit_type)"
+ }
+ set i [string first "\n" $msg]
+ if {$i >= 0} {
+ set subject [string range $msg 0 [expr {$i - 1}]]
+ } else {
+ set subject $msg
+ }
+ append reflogm {: } $subject
+ if {[catch {
+ git update-ref -m $reflogm HEAD $cmt_id $curHEAD
+ } err]} {
+ error_popup "update-ref failed:\n\n$err"
+ set ui_status_value {Commit failed.}
+ unlock_index
+ return
+ }
+
+ # -- Cleanup after ourselves.
+ #
+ catch {file delete $msg_p}
+ catch {file delete [gitdir MERGE_HEAD]}
+ catch {file delete [gitdir MERGE_MSG]}
+ catch {file delete [gitdir SQUASH_MSG]}
+ catch {file delete [gitdir GITGUI_MSG]}
+
+ # -- Let rerere do its thing.
+ #
+ if {[file isdirectory [gitdir rr-cache]]} {
+ catch {git rerere}
+ }
+
+ # -- Run the post-commit hook.
+ #
+ set pchook [gitdir hooks post-commit]
+ if {[is_Cygwin] && [file isfile $pchook]} {
+ set pchook [list sh -c [concat \
+ "if test -x \"$pchook\";" \
+ "then exec \"$pchook\";" \
+ "fi"]]
+ } elseif {![file executable $pchook]} {
+ set pchook {}
+ }
+ if {$pchook ne {}} {
+ catch {exec $pchook &}
+ }
+
+ $ui_comm delete 0.0 end
+ $ui_comm edit reset
+ $ui_comm edit modified false
+
+ if {[is_enabled singlecommit]} do_quit
+
+ # -- Make sure our current branch exists.
+ #
+ if {$commit_type eq {initial}} {
+ lappend all_heads $current_branch
+ set all_heads [lsort -unique $all_heads]
+ populate_branch_menu
+ }
+
+ # -- Update in memory status
+ #
+ set selected_commit_type new
+ set commit_type normal
+ set HEAD $cmt_id
+ set PARENT $cmt_id
+ set MERGE_HEAD [list]
+
+ foreach path [array names file_states] {
+ set s $file_states($path)
+ set m [lindex $s 0]
+ switch -glob -- $m {
+ _O -
+ _M -
+ _D {continue}
+ __ -
+ A_ -
+ M_ -
+ D_ {
+ unset file_states($path)
+ catch {unset selected_paths($path)}
+ }
+ DO {
+ set file_states($path) [list _O [lindex $s 1] {} {}]
+ }
+ AM -
+ AD -
+ MM -
+ MD {
+ set file_states($path) [list \
+ _[string index $m 1] \
+ [lindex $s 1] \
+ [lindex $s 3] \
+ {}]
+ }
+ }
+ }
+
+ display_all_files
+ unlock_index
+ reshow_diff
+ set ui_status_value \
+ "Created commit [string range $cmt_id 0 7]: $subject"
+}
diff --git a/git-gui/lib/console.tcl b/git-gui/lib/console.tcl
new file mode 100644
index 0000000000..ce25d92cac
--- /dev/null
+++ b/git-gui/lib/console.tcl
@@ -0,0 +1,176 @@
+# git-gui console support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+class console {
+
+field t_short
+field t_long
+field w
+field console_cr
+
+constructor new {short_title long_title} {
+ set t_short $short_title
+ set t_long $long_title
+ _init $this
+ return $this
+}
+
+method _init {} {
+ global M1B
+ make_toplevel top w -autodelete 0
+ wm title $top "[appname] ([reponame]): $t_short"
+ set console_cr 1.0
+
+ frame $w.m
+ label $w.m.l1 \
+ -textvariable @t_long \
+ -anchor w \
+ -justify left \
+ -font font_uibold
+ text $w.m.t \
+ -background white -borderwidth 1 \
+ -relief sunken \
+ -width 80 -height 10 \
+ -font font_diff \
+ -state disabled \
+ -yscrollcommand [list $w.m.sby set]
+ label $w.m.s -text {Working... please wait...} \
+ -anchor w \
+ -justify left \
+ -font font_uibold
+ scrollbar $w.m.sby -command [list $w.m.t yview]
+ pack $w.m.l1 -side top -fill x
+ pack $w.m.s -side bottom -fill x
+ pack $w.m.sby -side right -fill y
+ pack $w.m.t -side left -fill both -expand 1
+ pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
+
+ menu $w.ctxm -tearoff 0
+ $w.ctxm add command -label "Copy" \
+ -command "tk_textCopy $w.m.t"
+ $w.ctxm add command -label "Select All" \
+ -command "focus $w.m.t;$w.m.t tag add sel 0.0 end"
+ $w.ctxm add command -label "Copy All" \
+ -command "
+ $w.m.t tag add sel 0.0 end
+ tk_textCopy $w.m.t
+ $w.m.t tag remove sel 0.0 end
+ "
+
+ button $w.ok -text {Close} \
+ -state disabled \
+ -command "destroy $w"
+ pack $w.ok -side bottom -anchor e -pady 10 -padx 10
+
+ bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
+ bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
+ bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
+ bind $w <Visibility> "focus $w"
+}
+
+method exec {cmd {after {}}} {
+ # -- Cygwin's Tcl tosses the enviroment when we exec our child.
+ # But most users need that so we have to relogin. :-(
+ #
+ if {[is_Cygwin]} {
+ set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
+ }
+
+ # -- Tcl won't let us redirect both stdout and stderr to
+ # the same pipe. So pass it through cat...
+ #
+ set cmd [concat | $cmd |& cat]
+
+ set fd_f [open $cmd r]
+ fconfigure $fd_f -blocking 0 -translation binary
+ fileevent $fd_f readable [cb _read $fd_f $after]
+}
+
+method _read {fd after} {
+ set buf [read $fd]
+ if {$buf ne {}} {
+ if {![winfo exists $w.m.t]} {_init $this}
+ $w.m.t conf -state normal
+ set c 0
+ set n [string length $buf]
+ while {$c < $n} {
+ set cr [string first "\r" $buf $c]
+ set lf [string first "\n" $buf $c]
+ if {$cr < 0} {set cr [expr {$n + 1}]}
+ if {$lf < 0} {set lf [expr {$n + 1}]}
+
+ if {$lf < $cr} {
+ $w.m.t insert end [string range $buf $c $lf]
+ set console_cr [$w.m.t index {end -1c}]
+ set c $lf
+ incr c
+ } else {
+ $w.m.t delete $console_cr end
+ $w.m.t insert end "\n"
+ $w.m.t insert end [string range $buf $c $cr]
+ set c $cr
+ incr c
+ }
+ }
+ $w.m.t conf -state disabled
+ $w.m.t see end
+ }
+
+ fconfigure $fd -blocking 1
+ if {[eof $fd]} {
+ if {[catch {close $fd}]} {
+ set ok 0
+ } else {
+ set ok 1
+ }
+ if {$after ne {}} {
+ uplevel #0 $after $ok
+ } else {
+ done $this $ok
+ }
+ return
+ }
+ fconfigure $fd -blocking 0
+}
+
+method chain {cmdlist {ok 1}} {
+ if {$ok} {
+ if {[llength $cmdlist] == 0} {
+ done $this $ok
+ return
+ }
+
+ set cmd [lindex $cmdlist 0]
+ set cmdlist [lrange $cmdlist 1 end]
+
+ if {[lindex $cmd 0] eq {exec}} {
+ exec $this \
+ [lrange $cmd 1 end] \
+ [cb chain $cmdlist]
+ } else {
+ uplevel #0 $cmd [cb chain $cmdlist]
+ }
+ } else {
+ done $this $ok
+ }
+}
+
+method done {ok} {
+ if {$ok} {
+ if {[winfo exists $w.m.s]} {
+ $w.m.s conf -background green -text {Success}
+ $w.ok conf -state normal
+ focus $w.ok
+ }
+ } else {
+ if {![winfo exists $w.m.s]} {
+ _init $this
+ }
+ $w.m.s conf -background red -text {Error: Command Failed}
+ $w.ok conf -state normal
+ focus $w.ok
+ }
+ delete_this
+}
+
+}
diff --git a/git-gui/lib/database.tcl b/git-gui/lib/database.tcl
new file mode 100644
index 0000000000..43e4a289bb
--- /dev/null
+++ b/git-gui/lib/database.tcl
@@ -0,0 +1,89 @@
+# git-gui object database management support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc do_stats {} {
+ set fd [open "| git count-objects -v" r]
+ while {[gets $fd line] > 0} {
+ if {[regexp {^([^:]+): (\d+)$} $line _ name value]} {
+ set stats($name) $value
+ }
+ }
+ close $fd
+
+ set packed_sz 0
+ foreach p [glob -directory [gitdir objects pack] \
+ -type f \
+ -nocomplain -- *] {
+ incr packed_sz [file size $p]
+ }
+ if {$packed_sz > 0} {
+ set stats(size-pack) [expr {$packed_sz / 1024}]
+ }
+
+ set w .stats_view
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ label $w.header -text {Database Statistics}
+ pack $w.header -side top -fill x
+
+ frame $w.buttons -border 1
+ button $w.buttons.close -text Close \
+ -default active \
+ -command [list destroy $w]
+ button $w.buttons.gc -text {Compress Database} \
+ -default normal \
+ -command "destroy $w;do_gc"
+ pack $w.buttons.close -side right
+ pack $w.buttons.gc -side left
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ frame $w.stat -borderwidth 1 -relief solid
+ foreach s {
+ {count {Number of loose objects}}
+ {size {Disk space used by loose objects} { KiB}}
+ {in-pack {Number of packed objects}}
+ {packs {Number of packs}}
+ {size-pack {Disk space used by packed objects} { KiB}}
+ {prune-packable {Packed objects waiting for pruning}}
+ {garbage {Garbage files}}
+ } {
+ set name [lindex $s 0]
+ set label [lindex $s 1]
+ if {[catch {set value $stats($name)}]} continue
+ if {[llength $s] > 2} {
+ set value "$value[lindex $s 2]"
+ }
+
+ label $w.stat.l_$name -text "$label:" -anchor w
+ label $w.stat.v_$name -text $value -anchor w
+ grid $w.stat.l_$name $w.stat.v_$name -sticky we -padx {0 5}
+ }
+ pack $w.stat -pady 10 -padx 10
+
+ bind $w <Visibility> "grab $w; focus $w.buttons.close"
+ bind $w <Key-Escape> [list destroy $w]
+ bind $w <Key-Return> [list destroy $w]
+ wm title $w "[appname] ([reponame]): Database Statistics"
+ tkwait window $w
+}
+
+proc do_gc {} {
+ set w [console::new {gc} {Compressing the object database}]
+ console::chain $w {
+ {exec git pack-refs --prune}
+ {exec git reflog expire --all}
+ {exec git repack -a -d -l}
+ {exec git rerere gc}
+ }
+}
+
+proc do_fsck_objects {} {
+ set w [console::new {fsck-objects} \
+ {Verifying the object database with fsck-objects}]
+ set cmd [list git fsck-objects]
+ lappend cmd --full
+ lappend cmd --cache
+ lappend cmd --strict
+ console::exec $w $cmd
+}
diff --git a/git-gui/lib/diff.tcl b/git-gui/lib/diff.tcl
new file mode 100644
index 0000000000..29436b50cb
--- /dev/null
+++ b/git-gui/lib/diff.tcl
@@ -0,0 +1,336 @@
+# git-gui diff viewer
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc clear_diff {} {
+ global ui_diff current_diff_path current_diff_header
+ global ui_index ui_workdir
+
+ $ui_diff conf -state normal
+ $ui_diff delete 0.0 end
+ $ui_diff conf -state disabled
+
+ set current_diff_path {}
+ set current_diff_header {}
+
+ $ui_index tag remove in_diff 0.0 end
+ $ui_workdir tag remove in_diff 0.0 end
+}
+
+proc reshow_diff {} {
+ global ui_status_value file_states file_lists
+ global current_diff_path current_diff_side
+
+ set p $current_diff_path
+ if {$p eq {}} {
+ # No diff is being shown.
+ } elseif {$current_diff_side eq {}
+ || [catch {set s $file_states($p)}]
+ || [lsearch -sorted -exact $file_lists($current_diff_side) $p] == -1} {
+ clear_diff
+ } else {
+ show_diff $p $current_diff_side
+ }
+}
+
+proc handle_empty_diff {} {
+ global current_diff_path file_states file_lists
+
+ set path $current_diff_path
+ set s $file_states($path)
+ if {[lindex $s 0] ne {_M}} return
+
+ info_popup "No differences detected.
+
+[short_path $path] has no changes.
+
+The modification date of this file was updated by another application, but the content within the file was not changed.
+
+A rescan will be automatically started to find other files which may have the same state."
+
+ clear_diff
+ display_file $path __
+ rescan {set ui_status_value {Ready.}} 0
+}
+
+proc show_diff {path w {lno {}}} {
+ global file_states file_lists
+ global is_3way_diff diff_active repo_config
+ global ui_diff ui_status_value ui_index ui_workdir
+ global current_diff_path current_diff_side current_diff_header
+
+ if {$diff_active || ![lock_index read]} return
+
+ clear_diff
+ if {$lno == {}} {
+ set lno [lsearch -sorted -exact $file_lists($w) $path]
+ if {$lno >= 0} {
+ incr lno
+ }
+ }
+ if {$lno >= 1} {
+ $w tag add in_diff $lno.0 [expr {$lno + 1}].0
+ }
+
+ set s $file_states($path)
+ set m [lindex $s 0]
+ set is_3way_diff 0
+ set diff_active 1
+ set current_diff_path $path
+ set current_diff_side $w
+ set current_diff_header {}
+ set ui_status_value "Loading diff of [escape_path $path]..."
+
+ # - Git won't give us the diff, there's nothing to compare to!
+ #
+ if {$m eq {_O}} {
+ set max_sz [expr {128 * 1024}]
+ if {[catch {
+ set fd [open $path r]
+ set content [read $fd $max_sz]
+ close $fd
+ set sz [file size $path]
+ } err ]} {
+ set diff_active 0
+ unlock_index
+ set ui_status_value "Unable to display [escape_path $path]"
+ error_popup "Error loading file:\n\n$err"
+ return
+ }
+ $ui_diff conf -state normal
+ if {![catch {set type [exec file $path]}]} {
+ set n [string length $path]
+ if {[string equal -length $n $path $type]} {
+ set type [string range $type $n end]
+ regsub {^:?\s*} $type {} type
+ }
+ $ui_diff insert end "* $type\n" d_@
+ }
+ if {[string first "\0" $content] != -1} {
+ $ui_diff insert end \
+ "* Binary file (not showing content)." \
+ d_@
+ } else {
+ if {$sz > $max_sz} {
+ $ui_diff insert end \
+"* Untracked file is $sz bytes.
+* Showing only first $max_sz bytes.
+" d_@
+ }
+ $ui_diff insert end $content
+ if {$sz > $max_sz} {
+ $ui_diff insert end "
+* Untracked file clipped here by [appname].
+* To see the entire file, use an external editor.
+" d_@
+ }
+ }
+ $ui_diff conf -state disabled
+ set diff_active 0
+ unlock_index
+ set ui_status_value {Ready.}
+ return
+ }
+
+ set cmd [list | git]
+ if {$w eq $ui_index} {
+ lappend cmd diff-index
+ lappend cmd --cached
+ } elseif {$w eq $ui_workdir} {
+ if {[string index $m 0] eq {U}} {
+ lappend cmd diff
+ } else {
+ lappend cmd diff-files
+ }
+ }
+
+ lappend cmd -p
+ lappend cmd --no-color
+ if {$repo_config(gui.diffcontext) >= 0} {
+ lappend cmd "-U$repo_config(gui.diffcontext)"
+ }
+ if {$w eq $ui_index} {
+ lappend cmd [PARENT]
+ }
+ lappend cmd --
+ lappend cmd $path
+
+ if {[catch {set fd [open $cmd r]} err]} {
+ set diff_active 0
+ unlock_index
+ set ui_status_value "Unable to display [escape_path $path]"
+ error_popup "Error loading diff:\n\n$err"
+ return
+ }
+
+ fconfigure $fd \
+ -blocking 0 \
+ -encoding binary \
+ -translation binary
+ fileevent $fd readable [list read_diff $fd]
+}
+
+proc read_diff {fd} {
+ global ui_diff ui_status_value diff_active
+ global is_3way_diff current_diff_header
+
+ $ui_diff conf -state normal
+ while {[gets $fd line] >= 0} {
+ # -- Cleanup uninteresting diff header lines.
+ #
+ if { [string match {diff --git *} $line]
+ || [string match {diff --cc *} $line]
+ || [string match {diff --combined *} $line]
+ || [string match {--- *} $line]
+ || [string match {+++ *} $line]} {
+ append current_diff_header $line "\n"
+ continue
+ }
+ if {[string match {index *} $line]} continue
+ if {$line eq {deleted file mode 120000}} {
+ set line "deleted symlink"
+ }
+
+ # -- Automatically detect if this is a 3 way diff.
+ #
+ if {[string match {@@@ *} $line]} {set is_3way_diff 1}
+
+ if {[string match {mode *} $line]
+ || [string match {new file *} $line]
+ || [string match {deleted file *} $line]
+ || [string match {Binary files * and * differ} $line]
+ || $line eq {\ No newline at end of file}
+ || [regexp {^\* Unmerged path } $line]} {
+ set tags {}
+ } elseif {$is_3way_diff} {
+ set op [string range $line 0 1]
+ switch -- $op {
+ { } {set tags {}}
+ {@@} {set tags d_@}
+ { +} {set tags d_s+}
+ { -} {set tags d_s-}
+ {+ } {set tags d_+s}
+ {- } {set tags d_-s}
+ {--} {set tags d_--}
+ {++} {
+ if {[regexp {^\+\+([<>]{7} |={7})} $line _g op]} {
+ set line [string replace $line 0 1 { }]
+ set tags d$op
+ } else {
+ set tags d_++
+ }
+ }
+ default {
+ puts "error: Unhandled 3 way diff marker: {$op}"
+ set tags {}
+ }
+ }
+ } else {
+ set op [string index $line 0]
+ switch -- $op {
+ { } {set tags {}}
+ {@} {set tags d_@}
+ {-} {set tags d_-}
+ {+} {
+ if {[regexp {^\+([<>]{7} |={7})} $line _g op]} {
+ set line [string replace $line 0 0 { }]
+ set tags d$op
+ } else {
+ set tags d_+
+ }
+ }
+ default {
+ puts "error: Unhandled 2 way diff marker: {$op}"
+ set tags {}
+ }
+ }
+ }
+ $ui_diff insert end $line $tags
+ if {[string index $line end] eq "\r"} {
+ $ui_diff tag add d_cr {end - 2c}
+ }
+ $ui_diff insert end "\n" $tags
+ }
+ $ui_diff conf -state disabled
+
+ if {[eof $fd]} {
+ close $fd
+ set diff_active 0
+ unlock_index
+ set ui_status_value {Ready.}
+
+ if {[$ui_diff index end] eq {2.0}} {
+ handle_empty_diff
+ }
+ }
+}
+
+proc apply_hunk {x y} {
+ global current_diff_path current_diff_header current_diff_side
+ global ui_diff ui_index file_states
+
+ if {$current_diff_path eq {} || $current_diff_header eq {}} return
+ if {![lock_index apply_hunk]} return
+
+ set apply_cmd {git apply --cached --whitespace=nowarn}
+ set mi [lindex $file_states($current_diff_path) 0]
+ if {$current_diff_side eq $ui_index} {
+ set mode unstage
+ lappend apply_cmd --reverse
+ if {[string index $mi 0] ne {M}} {
+ unlock_index
+ return
+ }
+ } else {
+ set mode stage
+ if {[string index $mi 1] ne {M}} {
+ unlock_index
+ return
+ }
+ }
+
+ set s_lno [lindex [split [$ui_diff index @$x,$y] .] 0]
+ set s_lno [$ui_diff search -backwards -regexp ^@@ $s_lno.0 0.0]
+ if {$s_lno eq {}} {
+ unlock_index
+ return
+ }
+
+ set e_lno [$ui_diff search -forwards -regexp ^@@ "$s_lno + 1 lines" end]
+ if {$e_lno eq {}} {
+ set e_lno end
+ }
+
+ if {[catch {
+ set p [open "| $apply_cmd" w]
+ fconfigure $p -translation binary -encoding binary
+ puts -nonewline $p $current_diff_header
+ puts -nonewline $p [$ui_diff get $s_lno $e_lno]
+ close $p} err]} {
+ error_popup "Failed to $mode selected hunk.\n\n$err"
+ unlock_index
+ return
+ }
+
+ $ui_diff conf -state normal
+ $ui_diff delete $s_lno $e_lno
+ $ui_diff conf -state disabled
+
+ if {[$ui_diff get 1.0 end] eq "\n"} {
+ set o _
+ } else {
+ set o ?
+ }
+
+ if {$current_diff_side eq $ui_index} {
+ set mi ${o}M
+ } elseif {[string index $mi 0] eq {_}} {
+ set mi M$o
+ } else {
+ set mi ?$o
+ }
+ unlock_index
+ display_file $current_diff_path $mi
+ if {$o eq {_}} {
+ clear_diff
+ }
+}
diff --git a/git-gui/lib/error.tcl b/git-gui/lib/error.tcl
new file mode 100644
index 0000000000..d0253ae2ff
--- /dev/null
+++ b/git-gui/lib/error.tcl
@@ -0,0 +1,101 @@
+# git-gui branch (create/delete) support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc error_popup {msg} {
+ set title [appname]
+ if {[reponame] ne {}} {
+ append title " ([reponame])"
+ }
+ set cmd [list tk_messageBox \
+ -icon error \
+ -type ok \
+ -title "$title: error" \
+ -message $msg]
+ if {[winfo ismapped .]} {
+ lappend cmd -parent .
+ }
+ eval $cmd
+}
+
+proc warn_popup {msg} {
+ set title [appname]
+ if {[reponame] ne {}} {
+ append title " ([reponame])"
+ }
+ set cmd [list tk_messageBox \
+ -icon warning \
+ -type ok \
+ -title "$title: warning" \
+ -message $msg]
+ if {[winfo ismapped .]} {
+ lappend cmd -parent .
+ }
+ eval $cmd
+}
+
+proc info_popup {msg {parent .}} {
+ set title [appname]
+ if {[reponame] ne {}} {
+ append title " ([reponame])"
+ }
+ tk_messageBox \
+ -parent $parent \
+ -icon info \
+ -type ok \
+ -title $title \
+ -message $msg
+}
+
+proc ask_popup {msg} {
+ set title [appname]
+ if {[reponame] ne {}} {
+ append title " ([reponame])"
+ }
+ return [tk_messageBox \
+ -parent . \
+ -icon question \
+ -type yesno \
+ -title $title \
+ -message $msg]
+}
+
+proc hook_failed_popup {hook msg} {
+ set w .hookfail
+ toplevel $w
+
+ frame $w.m
+ label $w.m.l1 -text "$hook hook failed:" \
+ -anchor w \
+ -justify left \
+ -font font_uibold
+ text $w.m.t \
+ -background white -borderwidth 1 \
+ -relief sunken \
+ -width 80 -height 10 \
+ -font font_diff \
+ -yscrollcommand [list $w.m.sby set]
+ label $w.m.l2 \
+ -text {You must correct the above errors before committing.} \
+ -anchor w \
+ -justify left \
+ -font font_uibold
+ scrollbar $w.m.sby -command [list $w.m.t yview]
+ pack $w.m.l1 -side top -fill x
+ pack $w.m.l2 -side bottom -fill x
+ pack $w.m.sby -side right -fill y
+ pack $w.m.t -side left -fill both -expand 1
+ pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
+
+ $w.m.t insert 1.0 $msg
+ $w.m.t conf -state disabled
+
+ button $w.ok -text OK \
+ -width 15 \
+ -command "destroy $w"
+ pack $w.ok -side bottom -anchor e -pady 10 -padx 10
+
+ bind $w <Visibility> "grab $w; focus $w"
+ bind $w <Key-Return> "destroy $w"
+ wm title $w "[appname] ([reponame]): error"
+ tkwait window $w
+}
diff --git a/git-gui/lib/index.tcl b/git-gui/lib/index.tcl
new file mode 100644
index 0000000000..42742850ee
--- /dev/null
+++ b/git-gui/lib/index.tcl
@@ -0,0 +1,409 @@
+# git-gui index (add/remove) support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc update_indexinfo {msg pathList after} {
+ global update_index_cp ui_status_value
+
+ if {![lock_index update]} return
+
+ set update_index_cp 0
+ set pathList [lsort $pathList]
+ set totalCnt [llength $pathList]
+ set batch [expr {int($totalCnt * .01) + 1}]
+ if {$batch > 25} {set batch 25}
+
+ set ui_status_value [format \
+ "$msg... %i/%i files (%.2f%%)" \
+ $update_index_cp \
+ $totalCnt \
+ 0.0]
+ set fd [open "| git update-index -z --index-info" w]
+ fconfigure $fd \
+ -blocking 0 \
+ -buffering full \
+ -buffersize 512 \
+ -encoding binary \
+ -translation binary
+ fileevent $fd writable [list \
+ write_update_indexinfo \
+ $fd \
+ $pathList \
+ $totalCnt \
+ $batch \
+ $msg \
+ $after \
+ ]
+}
+
+proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
+ global update_index_cp ui_status_value
+ global file_states current_diff_path
+
+ if {$update_index_cp >= $totalCnt} {
+ close $fd
+ unlock_index
+ uplevel #0 $after
+ return
+ }
+
+ for {set i $batch} \
+ {$update_index_cp < $totalCnt && $i > 0} \
+ {incr i -1} {
+ set path [lindex $pathList $update_index_cp]
+ incr update_index_cp
+
+ set s $file_states($path)
+ switch -glob -- [lindex $s 0] {
+ A? {set new _O}
+ M? {set new _M}
+ D_ {set new _D}
+ D? {set new _?}
+ ?? {continue}
+ }
+ set info [lindex $s 2]
+ if {$info eq {}} continue
+
+ puts -nonewline $fd "$info\t[encoding convertto $path]\0"
+ display_file $path $new
+ }
+
+ set ui_status_value [format \
+ "$msg... %i/%i files (%.2f%%)" \
+ $update_index_cp \
+ $totalCnt \
+ [expr {100.0 * $update_index_cp / $totalCnt}]]
+}
+
+proc update_index {msg pathList after} {
+ global update_index_cp ui_status_value
+
+ if {![lock_index update]} return
+
+ set update_index_cp 0
+ set pathList [lsort $pathList]
+ set totalCnt [llength $pathList]
+ set batch [expr {int($totalCnt * .01) + 1}]
+ if {$batch > 25} {set batch 25}
+
+ set ui_status_value [format \
+ "$msg... %i/%i files (%.2f%%)" \
+ $update_index_cp \
+ $totalCnt \
+ 0.0]
+ set fd [open "| git update-index --add --remove -z --stdin" w]
+ fconfigure $fd \
+ -blocking 0 \
+ -buffering full \
+ -buffersize 512 \
+ -encoding binary \
+ -translation binary
+ fileevent $fd writable [list \
+ write_update_index \
+ $fd \
+ $pathList \
+ $totalCnt \
+ $batch \
+ $msg \
+ $after \
+ ]
+}
+
+proc write_update_index {fd pathList totalCnt batch msg after} {
+ global update_index_cp ui_status_value
+ global file_states current_diff_path
+
+ if {$update_index_cp >= $totalCnt} {
+ close $fd
+ unlock_index
+ uplevel #0 $after
+ return
+ }
+
+ for {set i $batch} \
+ {$update_index_cp < $totalCnt && $i > 0} \
+ {incr i -1} {
+ set path [lindex $pathList $update_index_cp]
+ incr update_index_cp
+
+ switch -glob -- [lindex $file_states($path) 0] {
+ AD {set new __}
+ ?D {set new D_}
+ _O -
+ AM {set new A_}
+ U? {
+ if {[file exists $path]} {
+ set new M_
+ } else {
+ set new D_
+ }
+ }
+ ?M {set new M_}
+ ?? {continue}
+ }
+ puts -nonewline $fd "[encoding convertto $path]\0"
+ display_file $path $new
+ }
+
+ set ui_status_value [format \
+ "$msg... %i/%i files (%.2f%%)" \
+ $update_index_cp \
+ $totalCnt \
+ [expr {100.0 * $update_index_cp / $totalCnt}]]
+}
+
+proc checkout_index {msg pathList after} {
+ global update_index_cp ui_status_value
+
+ if {![lock_index update]} return
+
+ set update_index_cp 0
+ set pathList [lsort $pathList]
+ set totalCnt [llength $pathList]
+ set batch [expr {int($totalCnt * .01) + 1}]
+ if {$batch > 25} {set batch 25}
+
+ set ui_status_value [format \
+ "$msg... %i/%i files (%.2f%%)" \
+ $update_index_cp \
+ $totalCnt \
+ 0.0]
+ set cmd [list git checkout-index]
+ lappend cmd --index
+ lappend cmd --quiet
+ lappend cmd --force
+ lappend cmd -z
+ lappend cmd --stdin
+ set fd [open "| $cmd " w]
+ fconfigure $fd \
+ -blocking 0 \
+ -buffering full \
+ -buffersize 512 \
+ -encoding binary \
+ -translation binary
+ fileevent $fd writable [list \
+ write_checkout_index \
+ $fd \
+ $pathList \
+ $totalCnt \
+ $batch \
+ $msg \
+ $after \
+ ]
+}
+
+proc write_checkout_index {fd pathList totalCnt batch msg after} {
+ global update_index_cp ui_status_value
+ global file_states current_diff_path
+
+ if {$update_index_cp >= $totalCnt} {
+ close $fd
+ unlock_index
+ uplevel #0 $after
+ return
+ }
+
+ for {set i $batch} \
+ {$update_index_cp < $totalCnt && $i > 0} \
+ {incr i -1} {
+ set path [lindex $pathList $update_index_cp]
+ incr update_index_cp
+ switch -glob -- [lindex $file_states($path) 0] {
+ U? {continue}
+ ?M -
+ ?D {
+ puts -nonewline $fd "[encoding convertto $path]\0"
+ display_file $path ?_
+ }
+ }
+ }
+
+ set ui_status_value [format \
+ "$msg... %i/%i files (%.2f%%)" \
+ $update_index_cp \
+ $totalCnt \
+ [expr {100.0 * $update_index_cp / $totalCnt}]]
+}
+
+proc unstage_helper {txt paths} {
+ global file_states current_diff_path
+
+ if {![lock_index begin-update]} return
+
+ set pathList [list]
+ set after {}
+ foreach path $paths {
+ switch -glob -- [lindex $file_states($path) 0] {
+ A? -
+ M? -
+ D? {
+ lappend pathList $path
+ if {$path eq $current_diff_path} {
+ set after {reshow_diff;}
+ }
+ }
+ }
+ }
+ if {$pathList eq {}} {
+ unlock_index
+ } else {
+ update_indexinfo \
+ $txt \
+ $pathList \
+ [concat $after {set ui_status_value {Ready.}}]
+ }
+}
+
+proc do_unstage_selection {} {
+ global current_diff_path selected_paths
+
+ if {[array size selected_paths] > 0} {
+ unstage_helper \
+ {Unstaging selected files from commit} \
+ [array names selected_paths]
+ } elseif {$current_diff_path ne {}} {
+ unstage_helper \
+ "Unstaging [short_path $current_diff_path] from commit" \
+ [list $current_diff_path]
+ }
+}
+
+proc add_helper {txt paths} {
+ global file_states current_diff_path
+
+ if {![lock_index begin-update]} return
+
+ set pathList [list]
+ set after {}
+ foreach path $paths {
+ switch -glob -- [lindex $file_states($path) 0] {
+ _O -
+ ?M -
+ ?D -
+ U? {
+ lappend pathList $path
+ if {$path eq $current_diff_path} {
+ set after {reshow_diff;}
+ }
+ }
+ }
+ }
+ if {$pathList eq {}} {
+ unlock_index
+ } else {
+ update_index \
+ $txt \
+ $pathList \
+ [concat $after {set ui_status_value {Ready to commit.}}]
+ }
+}
+
+proc do_add_selection {} {
+ global current_diff_path selected_paths
+
+ if {[array size selected_paths] > 0} {
+ add_helper \
+ {Adding selected files} \
+ [array names selected_paths]
+ } elseif {$current_diff_path ne {}} {
+ add_helper \
+ "Adding [short_path $current_diff_path]" \
+ [list $current_diff_path]
+ }
+}
+
+proc do_add_all {} {
+ global file_states
+
+ set paths [list]
+ foreach path [array names file_states] {
+ switch -glob -- [lindex $file_states($path) 0] {
+ U? {continue}
+ ?M -
+ ?D {lappend paths $path}
+ }
+ }
+ add_helper {Adding all changed files} $paths
+}
+
+proc revert_helper {txt paths} {
+ global file_states current_diff_path
+
+ if {![lock_index begin-update]} return
+
+ set pathList [list]
+ set after {}
+ foreach path $paths {
+ switch -glob -- [lindex $file_states($path) 0] {
+ U? {continue}
+ ?M -
+ ?D {
+ lappend pathList $path
+ if {$path eq $current_diff_path} {
+ set after {reshow_diff;}
+ }
+ }
+ }
+ }
+
+ set n [llength $pathList]
+ if {$n == 0} {
+ unlock_index
+ return
+ } elseif {$n == 1} {
+ set s "[short_path [lindex $pathList]]"
+ } else {
+ set s "these $n files"
+ }
+
+ set reply [tk_dialog \
+ .confirm_revert \
+ "[appname] ([reponame])" \
+ "Revert changes in $s?
+
+Any unadded changes will be permanently lost by the revert." \
+ question \
+ 1 \
+ {Do Nothing} \
+ {Revert Changes} \
+ ]
+ if {$reply == 1} {
+ checkout_index \
+ $txt \
+ $pathList \
+ [concat $after {set ui_status_value {Ready.}}]
+ } else {
+ unlock_index
+ }
+}
+
+proc do_revert_selection {} {
+ global current_diff_path selected_paths
+
+ if {[array size selected_paths] > 0} {
+ revert_helper \
+ {Reverting selected files} \
+ [array names selected_paths]
+ } elseif {$current_diff_path ne {}} {
+ revert_helper \
+ "Reverting [short_path $current_diff_path]" \
+ [list $current_diff_path]
+ }
+}
+
+proc do_select_commit_type {} {
+ global commit_type selected_commit_type
+
+ if {$selected_commit_type eq {new}
+ && [string match amend* $commit_type]} {
+ create_new_commit
+ } elseif {$selected_commit_type eq {amend}
+ && ![string match amend* $commit_type]} {
+ load_last_commit
+
+ # The amend request was rejected...
+ #
+ if {![string match amend* $commit_type]} {
+ set selected_commit_type new
+ }
+ }
+}
diff --git a/git-gui/lib/merge.tcl b/git-gui/lib/merge.tcl
new file mode 100644
index 0000000000..ae0389df5b
--- /dev/null
+++ b/git-gui/lib/merge.tcl
@@ -0,0 +1,313 @@
+# git-gui branch merge support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+namespace eval merge {
+
+proc _can_merge {} {
+ global HEAD commit_type file_states
+
+ if {[string match amend* $commit_type]} {
+ info_popup {Cannot merge while amending.
+
+You must finish amending this commit before starting any type of merge.
+}
+ return 0
+ }
+
+ if {[committer_ident] eq {}} {return 0}
+ if {![lock_index merge]} {return 0}
+
+ # -- Our in memory state should match the repository.
+ #
+ repository_state curType curHEAD curMERGE_HEAD
+ if {$commit_type ne $curType || $HEAD ne $curHEAD} {
+ info_popup {Last scanned state does not match repository state.
+
+Another Git program has modified this repository since the last scan. A rescan must be performed before a merge can be performed.
+
+The rescan will be automatically started now.
+}
+ unlock_index
+ rescan {set ui_status_value {Ready.}}
+ return 0
+ }
+
+ foreach path [array names file_states] {
+ switch -glob -- [lindex $file_states($path) 0] {
+ _O {
+ continue; # and pray it works!
+ }
+ U? {
+ error_popup "You are in the middle of a conflicted merge.
+
+File [short_path $path] has merge conflicts.
+
+You must resolve them, add the file, and commit to complete the current merge. Only then can you begin another merge.
+"
+ unlock_index
+ return 0
+ }
+ ?? {
+ error_popup "You are in the middle of a change.
+
+File [short_path $path] is modified.
+
+You should complete the current commit before starting a merge. Doing so will help you abort a failed merge, should the need arise.
+"
+ unlock_index
+ return 0
+ }
+ }
+ }
+
+ return 1
+}
+
+proc _refs {w list} {
+ set r {}
+ foreach i [$w.source.l curselection] {
+ lappend r [lindex [lindex $list $i] 0]
+ }
+ return $r
+}
+
+proc _visualize {w list} {
+ set revs [_refs $w $list]
+ if {$revs eq {}} return
+ lappend revs --not HEAD
+ do_gitk $revs
+}
+
+proc _start {w list} {
+ global HEAD ui_status_value current_branch
+
+ set cmd [list git merge]
+ set names [_refs $w $list]
+ set revcnt [llength $names]
+ append cmd { } $names
+
+ if {$revcnt == 0} {
+ return
+ } elseif {$revcnt == 1} {
+ set unit branch
+ } elseif {$revcnt <= 15} {
+ set unit branches
+
+ if {[tk_dialog \
+ $w.confirm_octopus \
+ [wm title $w] \
+ "Use octopus merge strategy?
+
+You are merging $revcnt branches at once. This requires using the octopus merge driver, which may not succeed if there are file-level conflicts.
+" \
+ question \
+ 0 \
+ {Cancel} \
+ {Use octopus} \
+ ] != 1} return
+ } else {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Too many branches selected.
+
+You have requested to merge $revcnt branches in an octopus merge. This exceeds Git's internal limit of 15 branches per merge.
+
+Please select fewer branches. To merge more than 15 branches, merge the branches in batches.
+"
+ return
+ }
+
+ set msg "Merging $current_branch, [join $names {, }]"
+ set ui_status_value "$msg..."
+ set cons [console::new "Merge" $msg]
+ console::exec $cons $cmd \
+ [namespace code [list _finish $revcnt $cons]]
+
+ wm protocol $w WM_DELETE_WINDOW {}
+ destroy $w
+}
+
+proc _finish {revcnt w ok} {
+ console::done $w $ok
+ if {$ok} {
+ set msg {Merge completed successfully.}
+ } else {
+ if {$revcnt != 1} {
+ info_popup "Octopus merge failed.
+
+Your merge of $revcnt branches has failed.
+
+There are file-level conflicts between the branches which must be resolved manually.
+
+The working directory will now be reset.
+
+You can attempt this merge again by merging only one branch at a time." $w
+
+ set fd [open "| git read-tree --reset -u HEAD" r]
+ fconfigure $fd -blocking 0 -translation binary
+ fileevent $fd readable \
+ [namespace code [list _reset_wait $fd]]
+ set ui_status_value {Aborting... please wait...}
+ return
+ }
+
+ set msg {Merge failed. Conflict resolution is required.}
+ }
+ unlock_index
+ rescan [list set ui_status_value $msg]
+}
+
+proc dialog {} {
+ global current_branch
+ global M1B
+
+ if {![_can_merge]} return
+
+ set fmt {list %(objectname) %(*objectname) %(refname) %(subject)}
+ set cmd [list git for-each-ref --tcl --format=$fmt]
+ lappend cmd refs/heads
+ lappend cmd refs/remotes
+ lappend cmd refs/tags
+ set fr_fd [open "| $cmd" r]
+ fconfigure $fr_fd -translation binary
+ while {[gets $fr_fd line] > 0} {
+ set line [eval $line]
+ set ref [lindex $line 2]
+ regsub ^refs/(heads|remotes|tags)/ $ref {} ref
+ set subj($ref) [lindex $line 3]
+ lappend sha1([lindex $line 0]) $ref
+ if {[lindex $line 1] ne {}} {
+ lappend sha1([lindex $line 1]) $ref
+ }
+ }
+ close $fr_fd
+
+ set to_show {}
+ set fr_fd [open "| git rev-list --all --not HEAD"]
+ while {[gets $fr_fd line] > 0} {
+ if {[catch {set ref $sha1($line)}]} continue
+ foreach n $ref {
+ lappend to_show [list $n $line]
+ }
+ }
+ close $fr_fd
+ set to_show [lsort -unique $to_show]
+
+ set w .merge_setup
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ set _visualize [namespace code [list _visualize $w $to_show]]
+ set _start [namespace code [list _start $w $to_show]]
+
+ label $w.header \
+ -text "Merge Into $current_branch" \
+ -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.visualize -text Visualize -command $_visualize
+ pack $w.buttons.visualize -side left
+ button $w.buttons.create -text Merge -command $_start
+ pack $w.buttons.create -side right
+ button $w.buttons.cancel -text {Cancel} -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ labelframe $w.source -text {Source Branches}
+ listbox $w.source.l \
+ -height 10 \
+ -width 70 \
+ -font font_diff \
+ -selectmode extended \
+ -yscrollcommand [list $w.source.sby set]
+ scrollbar $w.source.sby -command [list $w.source.l yview]
+ pack $w.source.sby -side right -fill y
+ pack $w.source.l -side left -fill both -expand 1
+ pack $w.source -fill both -expand 1 -pady 5 -padx 5
+
+ foreach ref $to_show {
+ set n [lindex $ref 0]
+ if {[string length $n] > 20} {
+ set n "[string range $n 0 16]..."
+ }
+ $w.source.l insert end [format {%s %-20s %s} \
+ [string range [lindex $ref 1] 0 5] \
+ $n \
+ $subj([lindex $ref 0])]
+ }
+
+ bind $w.source.l <Key-K> [list event generate %W <Shift-Key-Up>]
+ bind $w.source.l <Key-J> [list event generate %W <Shift-Key-Down>]
+ bind $w.source.l <Key-k> [list event generate %W <Key-Up>]
+ bind $w.source.l <Key-j> [list event generate %W <Key-Down>]
+ bind $w.source.l <Key-h> [list event generate %W <Key-Left>]
+ bind $w.source.l <Key-l> [list event generate %W <Key-Right>]
+ bind $w.source.l <Key-v> $_visualize
+
+ bind $w <$M1B-Key-Return> $_start
+ bind $w <Visibility> "grab $w; focus $w.source.l"
+ bind $w <Key-Escape> "unlock_index;destroy $w"
+ wm protocol $w WM_DELETE_WINDOW "unlock_index;destroy $w"
+ wm title $w "[appname] ([reponame]): Merge"
+ tkwait window $w
+}
+
+proc reset_hard {} {
+ global HEAD commit_type file_states
+
+ if {[string match amend* $commit_type]} {
+ info_popup {Cannot abort while amending.
+
+You must finish amending this commit.
+}
+ return
+ }
+
+ if {![lock_index abort]} return
+
+ if {[string match *merge* $commit_type]} {
+ set op merge
+ } else {
+ set op commit
+ }
+
+ if {[ask_popup "Abort $op?
+
+Aborting the current $op will cause *ALL* uncommitted changes to be lost.
+
+Continue with aborting the current $op?"] eq {yes}} {
+ set fd [open "| git read-tree --reset -u HEAD" r]
+ fconfigure $fd -blocking 0 -translation binary
+ fileevent $fd readable [namespace code [list _reset_wait $fd]]
+ set ui_status_value {Aborting... please wait...}
+ } else {
+ unlock_index
+ }
+}
+
+proc _reset_wait {fd} {
+ global ui_comm
+
+ read $fd
+ if {[eof $fd]} {
+ close $fd
+ unlock_index
+
+ $ui_comm delete 0.0 end
+ $ui_comm edit modified false
+
+ catch {file delete [gitdir MERGE_HEAD]}
+ catch {file delete [gitdir rr-cache MERGE_RR]}
+ catch {file delete [gitdir SQUASH_MSG]}
+ catch {file delete [gitdir MERGE_MSG]}
+ catch {file delete [gitdir GITGUI_MSG]}
+
+ rescan {set ui_status_value {Abort completed. Ready.}}
+ }
+}
+
+}
diff --git a/git-gui/lib/option.tcl b/git-gui/lib/option.tcl
new file mode 100644
index 0000000000..ae19a8f9cf
--- /dev/null
+++ b/git-gui/lib/option.tcl
@@ -0,0 +1,308 @@
+# git-gui options editor
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc save_config {} {
+ global default_config font_descs
+ global repo_config global_config
+ global repo_config_new global_config_new
+
+ foreach option $font_descs {
+ set name [lindex $option 0]
+ set font [lindex $option 1]
+ font configure $font \
+ -family $global_config_new(gui.$font^^family) \
+ -size $global_config_new(gui.$font^^size)
+ font configure ${font}bold \
+ -family $global_config_new(gui.$font^^family) \
+ -size $global_config_new(gui.$font^^size)
+ font configure ${font}italic \
+ -family $global_config_new(gui.$font^^family) \
+ -size $global_config_new(gui.$font^^size)
+ set global_config_new(gui.$name) [font configure $font]
+ unset global_config_new(gui.$font^^family)
+ unset global_config_new(gui.$font^^size)
+ }
+
+ foreach name [array names default_config] {
+ set value $global_config_new($name)
+ if {$value ne $global_config($name)} {
+ if {$value eq $default_config($name)} {
+ catch {git config --global --unset $name}
+ } else {
+ regsub -all "\[{}\]" $value {"} value
+ git config --global $name $value
+ }
+ set global_config($name) $value
+ if {$value eq $repo_config($name)} {
+ catch {git config --unset $name}
+ set repo_config($name) $value
+ }
+ }
+ }
+
+ foreach name [array names default_config] {
+ set value $repo_config_new($name)
+ if {$value ne $repo_config($name)} {
+ if {$value eq $global_config($name)} {
+ catch {git config --unset $name}
+ } else {
+ regsub -all "\[{}\]" $value {"} value
+ git config $name $value
+ }
+ set repo_config($name) $value
+ }
+ }
+}
+
+proc do_about {} {
+ global appvers copyright oguilib
+ global tcl_patchLevel tk_patchLevel
+
+ set w .about_dialog
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ label $w.header -text "About [appname]" \
+ -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.close -text {Close} \
+ -default active \
+ -command [list destroy $w]
+ pack $w.buttons.close -side right
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ label $w.desc \
+ -text "git-gui - a graphical user interface for Git.
+$copyright" \
+ -padx 5 -pady 5 \
+ -justify left \
+ -anchor w \
+ -borderwidth 1 \
+ -relief solid
+ pack $w.desc -side top -fill x -padx 5 -pady 5
+
+ set v {}
+ append v "git-gui version $appvers\n"
+ append v "[git version]\n"
+ append v "\n"
+ if {$tcl_patchLevel eq $tk_patchLevel} {
+ append v "Tcl/Tk version $tcl_patchLevel"
+ } else {
+ append v "Tcl version $tcl_patchLevel"
+ append v ", Tk version $tk_patchLevel"
+ }
+
+ set d {}
+ append d "git exec dir: [gitexec]\n"
+ append d "git-gui lib: $oguilib"
+
+ label $w.vers \
+ -text $v \
+ -padx 5 -pady 5 \
+ -justify left \
+ -anchor w \
+ -borderwidth 1 \
+ -relief solid
+ pack $w.vers -side top -fill x -padx 5 -pady 5
+
+ label $w.dirs \
+ -text $d \
+ -padx 5 -pady 5 \
+ -justify left \
+ -anchor w \
+ -borderwidth 1 \
+ -relief solid
+ pack $w.dirs -side top -fill x -padx 5 -pady 5
+
+ menu $w.ctxm -tearoff 0
+ $w.ctxm add command \
+ -label {Copy} \
+ -command "
+ clipboard clear
+ clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
+ "
+
+ bind $w <Visibility> "grab $w; focus $w.buttons.close"
+ bind $w <Key-Escape> "destroy $w"
+ bind $w <Key-Return> "destroy $w"
+ bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
+ wm title $w "About [appname]"
+ tkwait window $w
+}
+
+proc do_options {} {
+ global repo_config global_config font_descs
+ global repo_config_new global_config_new
+
+ array unset repo_config_new
+ array unset global_config_new
+ foreach name [array names repo_config] {
+ set repo_config_new($name) $repo_config($name)
+ }
+ load_config 1
+ foreach name [array names repo_config] {
+ switch -- $name {
+ gui.diffcontext {continue}
+ }
+ set repo_config_new($name) $repo_config($name)
+ }
+ foreach name [array names global_config] {
+ set global_config_new($name) $global_config($name)
+ }
+
+ set w .options_editor
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ label $w.header -text "Options" \
+ -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.restore -text {Restore Defaults} \
+ -default normal \
+ -command do_restore_defaults
+ pack $w.buttons.restore -side left
+ button $w.buttons.save -text Save \
+ -default active \
+ -command [list do_save_config $w]
+ pack $w.buttons.save -side right
+ button $w.buttons.cancel -text {Cancel} \
+ -default normal \
+ -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ labelframe $w.repo -text "[reponame] Repository"
+ labelframe $w.global -text {Global (All Repositories)}
+ pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
+ pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
+
+ set optid 0
+ foreach option {
+ {t user.name {User Name}}
+ {t user.email {Email Address}}
+
+ {b merge.summary {Summarize Merge Commits}}
+ {i-1..5 merge.verbosity {Merge Verbosity}}
+ {b merge.diffstat {Show Diffstat After Merge}}
+
+ {b gui.trustmtime {Trust File Modification Timestamps}}
+ {b gui.pruneduringfetch {Prune Tracking Branches During Fetch}}
+ {i-0..99 gui.diffcontext {Number of Diff Context Lines}}
+ {t gui.newbranchtemplate {New Branch Name Template}}
+ } {
+ set type [lindex $option 0]
+ set name [lindex $option 1]
+ set text [lindex $option 2]
+ incr optid
+ foreach f {repo global} {
+ switch -glob -- $type {
+ b {
+ checkbutton $w.$f.$optid -text $text \
+ -variable ${f}_config_new($name) \
+ -onvalue true \
+ -offvalue false
+ pack $w.$f.$optid -side top -anchor w
+ }
+ i-* {
+ regexp -- {-(\d+)\.\.(\d+)$} $type _junk min max
+ frame $w.$f.$optid
+ label $w.$f.$optid.l -text "$text:"
+ pack $w.$f.$optid.l -side left -anchor w -fill x
+ spinbox $w.$f.$optid.v \
+ -textvariable ${f}_config_new($name) \
+ -from $min \
+ -to $max \
+ -increment 1 \
+ -width [expr {1 + [string length $max]}]
+ bind $w.$f.$optid.v <FocusIn> {%W selection range 0 end}
+ pack $w.$f.$optid.v -side right -anchor e -padx 5
+ pack $w.$f.$optid -side top -anchor w -fill x
+ }
+ t {
+ frame $w.$f.$optid
+ label $w.$f.$optid.l -text "$text:"
+ entry $w.$f.$optid.v \
+ -borderwidth 1 \
+ -relief sunken \
+ -width 20 \
+ -textvariable ${f}_config_new($name)
+ pack $w.$f.$optid.l -side left -anchor w
+ pack $w.$f.$optid.v -side left -anchor w \
+ -fill x -expand 1 \
+ -padx 5
+ pack $w.$f.$optid -side top -anchor w -fill x
+ }
+ }
+ }
+ }
+
+ set all_fonts [lsort [font families]]
+ foreach option $font_descs {
+ set name [lindex $option 0]
+ set font [lindex $option 1]
+ set text [lindex $option 2]
+
+ set global_config_new(gui.$font^^family) \
+ [font configure $font -family]
+ set global_config_new(gui.$font^^size) \
+ [font configure $font -size]
+
+ frame $w.global.$name
+ label $w.global.$name.l -text "$text:"
+ pack $w.global.$name.l -side left -anchor w -fill x
+ eval tk_optionMenu $w.global.$name.family \
+ global_config_new(gui.$font^^family) \
+ $all_fonts
+ spinbox $w.global.$name.size \
+ -textvariable global_config_new(gui.$font^^size) \
+ -from 2 -to 80 -increment 1 \
+ -width 3
+ bind $w.global.$name.size <FocusIn> {%W selection range 0 end}
+ pack $w.global.$name.size -side right -anchor e
+ pack $w.global.$name.family -side right -anchor e
+ pack $w.global.$name -side top -anchor w -fill x
+ }
+
+ bind $w <Visibility> "grab $w; focus $w.buttons.save"
+ bind $w <Key-Escape> "destroy $w"
+ bind $w <Key-Return> [list do_save_config $w]
+ wm title $w "[appname] ([reponame]): Options"
+ tkwait window $w
+}
+
+proc do_restore_defaults {} {
+ global font_descs default_config repo_config
+ global repo_config_new global_config_new
+
+ foreach name [array names default_config] {
+ set repo_config_new($name) $default_config($name)
+ set global_config_new($name) $default_config($name)
+ }
+
+ foreach option $font_descs {
+ set name [lindex $option 0]
+ set repo_config(gui.$name) $default_config(gui.$name)
+ }
+ apply_config
+
+ foreach option $font_descs {
+ set name [lindex $option 0]
+ set font [lindex $option 1]
+ set global_config_new(gui.$font^^family) \
+ [font configure $font -family]
+ set global_config_new(gui.$font^^size) \
+ [font configure $font -size]
+ }
+}
+
+proc do_save_config {w} {
+ if {[catch {save_config} err]} {
+ error_popup "Failed to completely save options:\n\n$err"
+ }
+ reshow_diff
+ destroy $w
+}
diff --git a/git-gui/lib/remote.tcl b/git-gui/lib/remote.tcl
new file mode 100644
index 0000000000..b54824ab72
--- /dev/null
+++ b/git-gui/lib/remote.tcl
@@ -0,0 +1,170 @@
+# git-gui remote management
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc is_tracking_branch {name} {
+ global tracking_branches
+
+ if {![catch {set info $tracking_branches($name)}]} {
+ return 1
+ }
+ foreach t [array names tracking_branches] {
+ if {[string match {*/\*} $t] && [string match $t $name]} {
+ return 1
+ }
+ }
+ return 0
+}
+
+proc all_tracking_branches {} {
+ global tracking_branches
+
+ set all_trackings {}
+ set cmd {}
+ foreach name [array names tracking_branches] {
+ if {[regsub {/\*$} $name {} name]} {
+ lappend cmd $name
+ } else {
+ regsub ^refs/(heads|remotes)/ $name {} name
+ lappend all_trackings $name
+ }
+ }
+
+ if {$cmd ne {}} {
+ set fd [open "| git for-each-ref --format=%(refname) $cmd" r]
+ while {[gets $fd name] > 0} {
+ regsub ^refs/(heads|remotes)/ $name {} name
+ lappend all_trackings $name
+ }
+ close $fd
+ }
+
+ return [lsort -unique $all_trackings]
+}
+
+proc load_all_remotes {} {
+ global repo_config
+ global all_remotes tracking_branches
+
+ set all_remotes [list]
+ array unset tracking_branches
+
+ set rm_dir [gitdir remotes]
+ if {[file isdirectory $rm_dir]} {
+ set all_remotes [glob \
+ -types f \
+ -tails \
+ -nocomplain \
+ -directory $rm_dir *]
+
+ foreach name $all_remotes {
+ catch {
+ set fd [open [file join $rm_dir $name] r]
+ while {[gets $fd line] >= 0} {
+ if {![regexp {^Pull:[ ]*([^:]+):(.+)$} \
+ $line line src dst]} continue
+ if {![regexp ^refs/ $dst]} {
+ set dst "refs/heads/$dst"
+ }
+ set tracking_branches($dst) [list $name $src]
+ }
+ close $fd
+ }
+ }
+ }
+
+ foreach line [array names repo_config remote.*.url] {
+ if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
+ lappend all_remotes $name
+
+ if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
+ set fl {}
+ }
+ foreach line $fl {
+ if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
+ if {![regexp ^refs/ $dst]} {
+ set dst "refs/heads/$dst"
+ }
+ set tracking_branches($dst) [list $name $src]
+ }
+ }
+
+ set all_remotes [lsort -unique $all_remotes]
+}
+
+proc populate_fetch_menu {} {
+ global all_remotes repo_config
+
+ set m .mbar.fetch
+ set prune_list [list]
+ foreach r $all_remotes {
+ set enable 0
+ if {![catch {set a $repo_config(remote.$r.url)}]} {
+ if {![catch {set a $repo_config(remote.$r.fetch)}]} {
+ set enable 1
+ }
+ } else {
+ catch {
+ set fd [open [gitdir remotes $r] r]
+ while {[gets $fd n] >= 0} {
+ if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
+ set enable 1
+ break
+ }
+ }
+ close $fd
+ }
+ }
+
+ if {$enable} {
+ lappend prune_list $r
+ $m add command \
+ -label "Fetch from $r..." \
+ -command [list fetch_from $r]
+ }
+ }
+
+ if {$prune_list ne {}} {
+ $m add separator
+ }
+ foreach r $prune_list {
+ $m add command \
+ -label "Prune from $r..." \
+ -command [list prune_from $r]
+ }
+}
+
+proc populate_push_menu {} {
+ global all_remotes repo_config
+
+ set m .mbar.push
+ set fast_count 0
+ foreach r $all_remotes {
+ set enable 0
+ if {![catch {set a $repo_config(remote.$r.url)}]} {
+ if {![catch {set a $repo_config(remote.$r.push)}]} {
+ set enable 1
+ }
+ } else {
+ catch {
+ set fd [open [gitdir remotes $r] r]
+ while {[gets $fd n] >= 0} {
+ if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
+ set enable 1
+ break
+ }
+ }
+ close $fd
+ }
+ }
+
+ if {$enable} {
+ if {!$fast_count} {
+ $m add separator
+ }
+ $m add command \
+ -label "Push to $r..." \
+ -command [list push_to $r]
+ incr fast_count
+ }
+ }
+}
diff --git a/git-gui/lib/remote_branch_delete.tcl b/git-gui/lib/remote_branch_delete.tcl
new file mode 100644
index 0000000000..b83e1b6315
--- /dev/null
+++ b/git-gui/lib/remote_branch_delete.tcl
@@ -0,0 +1,347 @@
+# git-gui remote branch deleting support
+# Copyright (C) 2007 Shawn Pearce
+
+class remote_branch_delete {
+
+field w
+field head_m
+
+field urltype {url}
+field remote {}
+field url {}
+
+field checktype {head}
+field check_head {}
+
+field status {}
+field idle_id {}
+field full_list {}
+field head_list {}
+field active_ls {}
+field head_cache
+field full_cache
+field cached
+
+constructor dialog {} {
+ global all_remotes M1B
+
+ make_toplevel top w
+ wm title $top "[appname] ([reponame]): Delete Remote Branch"
+ if {$top ne {.}} {
+ wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
+ }
+
+ label $w.header -text {Delete Remote Branch} -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.delete -text Delete \
+ -default active \
+ -command [cb _delete]
+ pack $w.buttons.delete -side right
+ button $w.buttons.cancel -text {Cancel} \
+ -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ labelframe $w.dest -text {From Repository}
+ if {$all_remotes ne {}} {
+ radiobutton $w.dest.remote_r \
+ -text {Remote:} \
+ -value remote \
+ -variable @urltype
+ eval tk_optionMenu $w.dest.remote_m @remote $all_remotes
+ grid $w.dest.remote_r $w.dest.remote_m -sticky w
+ if {[lsearch -sorted -exact $all_remotes origin] != -1} {
+ set remote origin
+ } else {
+ set remote [lindex $all_remotes 0]
+ }
+ set urltype remote
+ trace add variable @remote write [cb _write_remote]
+ } else {
+ set urltype url
+ }
+ radiobutton $w.dest.url_r \
+ -text {Arbitrary URL:} \
+ -value url \
+ -variable @urltype
+ entry $w.dest.url_t \
+ -borderwidth 1 \
+ -relief sunken \
+ -width 50 \
+ -textvariable @url \
+ -validate key \
+ -validatecommand {
+ if {%d == 1 && [regexp {\s} %S]} {return 0}
+ return 1
+ }
+ trace add variable @url write [cb _write_url]
+ grid $w.dest.url_r $w.dest.url_t -sticky we -padx {0 5}
+ grid columnconfigure $w.dest 1 -weight 1
+ pack $w.dest -anchor nw -fill x -pady 5 -padx 5
+
+ labelframe $w.heads -text {Branches}
+ listbox $w.heads.l \
+ -height 10 \
+ -width 70 \
+ -listvariable @head_list \
+ -selectmode extended \
+ -yscrollcommand [list $w.heads.sby set]
+ scrollbar $w.heads.sby -command [list $w.heads.l yview]
+
+ frame $w.heads.footer
+ label $w.heads.footer.status \
+ -textvariable @status \
+ -anchor w \
+ -justify left
+ button $w.heads.footer.rescan \
+ -text {Rescan} \
+ -command [cb _rescan]
+ pack $w.heads.footer.status -side left -fill x -expand 1
+ pack $w.heads.footer.rescan -side right
+
+ pack $w.heads.footer -side bottom -fill x -expand 1
+ pack $w.heads.sby -side right -fill y
+ pack $w.heads.l -side left -fill both -expand 1
+ pack $w.heads -fill both -expand 1 -pady 5 -padx 5
+
+ labelframe $w.validate -text {Delete Only If}
+ radiobutton $w.validate.head_r \
+ -text {Merged Into:} \
+ -value head \
+ -variable @checktype
+ set head_m [tk_optionMenu $w.validate.head_m @check_head {}]
+ trace add variable @head_list write [cb _write_head_list]
+ trace add variable @check_head write [cb _write_check_head]
+ grid $w.validate.head_r $w.validate.head_m -sticky w
+ radiobutton $w.validate.always_r \
+ -text {Always (Do not perform merge checks)} \
+ -value always \
+ -variable @checktype
+ grid $w.validate.always_r -columnspan 2 -sticky w
+ grid columnconfigure $w.validate 1 -weight 1
+ pack $w.validate -anchor nw -fill x -pady 5 -padx 5
+
+ trace add variable @urltype write [cb _write_urltype]
+ _rescan $this
+
+ bind $w <Key-F5> [cb _rescan]
+ bind $w <$M1B-Key-r> [cb _rescan]
+ bind $w <$M1B-Key-R> [cb _rescan]
+ bind $w <Key-Return> [cb _delete]
+ bind $w <Key-Escape> [list destroy $w]
+ return $w
+}
+
+method _delete {} {
+ switch $urltype {
+ remote {set uri $remote}
+ url {set uri $url}
+ }
+
+ set cache $urltype:$uri
+ set crev {}
+ if {$checktype eq {head}} {
+ if {$check_head eq {}} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "A branch is required for 'Merged Into'."
+ return
+ }
+ set crev $full_cache("$cache\nrefs/heads/$check_head")
+ }
+
+ set not_merged [list]
+ set need_fetch 0
+ set have_selection 0
+ set push_cmd [list git push]
+ lappend push_cmd -v
+ lappend push_cmd $uri
+
+ foreach i [$w.heads.l curselection] {
+ set ref [lindex $full_list $i]
+ if {$crev ne {}} {
+ set obj $full_cache("$cache\n$ref")
+ if {[catch {set m [git merge-base $obj $crev]}]} {
+ set need_fetch 1
+ set m {}
+ }
+ if {$obj ne $m} {
+ lappend not_merged [lindex $head_list $i]
+ continue
+ }
+ }
+
+ lappend push_cmd :$ref
+ set have_selection 1
+ }
+
+ if {$not_merged ne {}} {
+ set msg "The following branches are not completely merged into $check_head:
+
+ - [join $not_merged "\n - "]"
+
+ if {$need_fetch} {
+ append msg "
+
+One or more of the merge tests failed because you have not fetched the necessary commits. Try fetching from $uri first."
+ }
+
+ tk_messageBox \
+ -icon info \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message $msg
+ if {!$have_selection} return
+ }
+
+ if {!$have_selection} {
+ tk_messageBox \
+ -icon error \
+ -type ok \
+ -title [wm title $w] \
+ -parent $w \
+ -message "Please select one or more branches to delete."
+ return
+ }
+
+ if {[tk_messageBox \
+ -icon warning \
+ -type yesno \
+ -title [wm title $w] \
+ -parent $w \
+ -message {Recovering deleted branches is difficult.
+
+Delete the selected branches?}] ne yes} {
+ return
+ }
+
+ destroy $w
+
+ set cons [console::new \
+ "push $uri" \
+ "Deleting branches from $uri"]
+ console::exec $cons $push_cmd
+}
+
+method _rescan {{force 1}} {
+ switch $urltype {
+ remote {set uri $remote}
+ url {set uri $url}
+ }
+
+ if {$force} {
+ unset -nocomplain cached($urltype:$uri)
+ }
+
+ if {$idle_id ne {}} {
+ after cancel $idle_id
+ set idle_id {}
+ }
+
+ _load $this $urltype:$uri $uri
+}
+
+method _write_remote {args} { set urltype remote }
+method _write_url {args} { set urltype url }
+method _write_check_head {args} { set checktype head }
+
+method _write_head_list {args} {
+ $head_m delete 0 end
+ foreach abr $head_list {
+ $head_m insert end radiobutton \
+ -label $abr \
+ -value $abr \
+ -variable @check_head
+ }
+ if {[lsearch -exact -sorted $head_list $check_head] < 0} {
+ set check_head {}
+ }
+}
+
+method _write_urltype {args} {
+ if {$urltype eq {url}} {
+ if {$idle_id ne {}} {
+ after cancel $idle_id
+ }
+ _load $this none: {}
+ set idle_id [after 1000 [cb _rescan 0]]
+ } else {
+ _rescan $this 0
+ }
+}
+
+method _load {cache uri} {
+ if {$active_ls ne {}} {
+ catch {close $active_ls}
+ }
+
+ if {$uri eq {}} {
+ $w.heads.l conf -state disabled
+ set head_list [list]
+ set full_list [list]
+ set status {No repository selected.}
+ return
+ }
+
+ if {[catch {set x $cached($cache)}]} {
+ set status "Scanning $uri..."
+ $w.heads.l conf -state disabled
+ set head_list [list]
+ set full_list [list]
+ set head_cache($cache) [list]
+ set full_cache($cache) [list]
+ set active_ls [open "| [list git ls-remote $uri]" r]
+ fconfigure $active_ls \
+ -blocking 0 \
+ -translation lf \
+ -encoding utf-8
+ fileevent $active_ls readable [cb _read $cache $active_ls]
+ } else {
+ set status {}
+ set full_list $full_cache($cache)
+ set head_list $head_cache($cache)
+ $w.heads.l conf -state normal
+ }
+}
+
+method _read {cache fd} {
+ if {$fd ne $active_ls} {
+ catch {close $fd}
+ return
+ }
+
+ while {[gets $fd line] >= 0} {
+ if {[string match {*^{}} $line]} continue
+ if {[regexp {^([0-9a-f]{40}) (.*)$} $line _junk obj ref]} {
+ if {[regsub ^refs/heads/ $ref {} abr]} {
+ lappend head_list $abr
+ lappend head_cache($cache) $abr
+ lappend full_list $ref
+ lappend full_cache($cache) $ref
+ set full_cache("$cache\n$ref") $obj
+ }
+ }
+ }
+
+ if {[eof $fd]} {
+ if {[catch {close $fd} err]} {
+ set status $err
+ set head_list [list]
+ set full_list [list]
+ } else {
+ set status {}
+ set cached($cache) 1
+ $w.heads.l conf -state normal
+ }
+ }
+} ifdeleted {
+ catch {close $fd}
+}
+
+}
diff --git a/git-gui/lib/shortcut.tcl b/git-gui/lib/shortcut.tcl
new file mode 100644
index 0000000000..ebf72e4452
--- /dev/null
+++ b/git-gui/lib/shortcut.tcl
@@ -0,0 +1,141 @@
+# git-gui desktop icon creators
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc do_windows_shortcut {} {
+ global argv0
+
+ set fn [tk_getSaveFile \
+ -parent . \
+ -title "[appname] ([reponame]): Create Desktop Icon" \
+ -initialfile "Git [reponame].bat"]
+ if {$fn != {}} {
+ if {[catch {
+ set fd [open $fn w]
+ puts $fd "@ECHO Entering [reponame]"
+ puts $fd "@ECHO Starting git-gui... please wait..."
+ puts $fd "@SET PATH=[file normalize [gitexec]];%PATH%"
+ puts $fd "@SET GIT_DIR=[file normalize [gitdir]]"
+ puts -nonewline $fd "@\"[info nameofexecutable]\""
+ puts $fd " \"[file normalize $argv0]\""
+ close $fd
+ } err]} {
+ error_popup "Cannot write script:\n\n$err"
+ }
+ }
+}
+
+proc do_cygwin_shortcut {} {
+ global argv0
+
+ if {[catch {
+ set desktop [exec cygpath \
+ --windows \
+ --absolute \
+ --long-name \
+ --desktop]
+ }]} {
+ set desktop .
+ }
+ set fn [tk_getSaveFile \
+ -parent . \
+ -title "[appname] ([reponame]): Create Desktop Icon" \
+ -initialdir $desktop \
+ -initialfile "Git [reponame].bat"]
+ if {$fn != {}} {
+ if {[catch {
+ set fd [open $fn w]
+ set sh [exec cygpath \
+ --windows \
+ --absolute \
+ /bin/sh]
+ set me [exec cygpath \
+ --unix \
+ --absolute \
+ $argv0]
+ set gd [exec cygpath \
+ --unix \
+ --absolute \
+ [gitdir]]
+ set gw [exec cygpath \
+ --windows \
+ --absolute \
+ [file dirname [gitdir]]]
+ regsub -all ' $me "'\\''" me
+ regsub -all ' $gd "'\\''" gd
+ puts $fd "@ECHO Entering $gw"
+ puts $fd "@ECHO Starting git-gui... please wait..."
+ puts -nonewline $fd "@\"$sh\" --login -c \""
+ puts -nonewline $fd "GIT_DIR='$gd'"
+ puts -nonewline $fd " '$me'"
+ puts $fd "&\""
+ close $fd
+ } err]} {
+ error_popup "Cannot write script:\n\n$err"
+ }
+ }
+}
+
+proc do_macosx_app {} {
+ global argv0 env
+
+ set fn [tk_getSaveFile \
+ -parent . \
+ -title "[appname] ([reponame]): Create Desktop Icon" \
+ -initialdir [file join $env(HOME) Desktop] \
+ -initialfile "Git [reponame].app"]
+ if {$fn != {}} {
+ if {[catch {
+ set Contents [file join $fn Contents]
+ set MacOS [file join $Contents MacOS]
+ set exe [file join $MacOS git-gui]
+
+ file mkdir $MacOS
+
+ set fd [open [file join $Contents Info.plist] w]
+ puts $fd {<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
+<plist version="1.0">
+<dict>
+ <key>CFBundleDevelopmentRegion</key>
+ <string>English</string>
+ <key>CFBundleExecutable</key>
+ <string>git-gui</string>
+ <key>CFBundleIdentifier</key>
+ <string>org.spearce.git-gui</string>
+ <key>CFBundleInfoDictionaryVersion</key>
+ <string>6.0</string>
+ <key>CFBundlePackageType</key>
+ <string>APPL</string>
+ <key>CFBundleSignature</key>
+ <string>????</string>
+ <key>CFBundleVersion</key>
+ <string>1.0</string>
+ <key>NSPrincipalClass</key>
+ <string>NSApplication</string>
+</dict>
+</plist>}
+ close $fd
+
+ set fd [open $exe w]
+ set gd [file normalize [gitdir]]
+ set ep [file normalize [gitexec]]
+ regsub -all ' $gd "'\\''" gd
+ regsub -all ' $ep "'\\''" ep
+ puts $fd "#!/bin/sh"
+ foreach name [array names env] {
+ if {[string match GIT_* $name]} {
+ regsub -all ' $env($name) "'\\''" v
+ puts $fd "export $name='$v'"
+ }
+ }
+ puts $fd "export PATH='$ep':\$PATH"
+ puts $fd "export GIT_DIR='$gd'"
+ puts $fd "exec [file normalize $argv0]"
+ close $fd
+
+ file attributes $exe -permissions u+x,g+x,o+x
+ } err]} {
+ error_popup "Cannot write icon:\n\n$err"
+ }
+ }
+}
diff --git a/git-gui/lib/transport.tcl b/git-gui/lib/transport.tcl
new file mode 100644
index 0000000000..e8ebc6eda0
--- /dev/null
+++ b/git-gui/lib/transport.tcl
@@ -0,0 +1,174 @@
+# git-gui transport (fetch/push) support
+# Copyright (C) 2006, 2007 Shawn Pearce
+
+proc fetch_from {remote} {
+ set w [console::new \
+ "fetch $remote" \
+ "Fetching new changes from $remote"]
+ set cmds [list]
+ lappend cmds [list exec git fetch $remote]
+ if {[is_config_true gui.pruneduringfetch]} {
+ lappend cmds [list exec git remote prune $remote]
+ }
+ console::chain $w $cmds
+}
+
+proc prune_from {remote} {
+ set w [console::new \
+ "remote prune $remote" \
+ "Pruning tracking branches deleted from $remote"]
+ console::exec $w [list git remote prune $remote]
+}
+
+proc push_to {remote} {
+ set w [console::new \
+ "push $remote" \
+ "Pushing changes to $remote"]
+ set cmd [list git push]
+ lappend cmd -v
+ lappend cmd $remote
+ console::exec $w $cmd
+}
+
+proc start_push_anywhere_action {w} {
+ global push_urltype push_remote push_url push_thin push_tags
+
+ set r_url {}
+ switch -- $push_urltype {
+ remote {set r_url $push_remote}
+ url {set r_url $push_url}
+ }
+ if {$r_url eq {}} return
+
+ set cmd [list git push]
+ lappend cmd -v
+ if {$push_thin} {
+ lappend cmd --thin
+ }
+ if {$push_tags} {
+ lappend cmd --tags
+ }
+ lappend cmd $r_url
+ set cnt 0
+ foreach i [$w.source.l curselection] {
+ set b [$w.source.l get $i]
+ lappend cmd "refs/heads/$b:refs/heads/$b"
+ incr cnt
+ }
+ if {$cnt == 0} {
+ return
+ } elseif {$cnt == 1} {
+ set unit branch
+ } else {
+ set unit branches
+ }
+
+ set cons [console::new \
+ "push $r_url" \
+ "Pushing $cnt $unit to $r_url"]
+ console::exec $cons $cmd
+ destroy $w
+}
+
+trace add variable push_remote write \
+ [list radio_selector push_urltype remote]
+
+proc do_push_anywhere {} {
+ global all_heads all_remotes current_branch
+ global push_urltype push_remote push_url push_thin push_tags
+
+ set w .push_setup
+ toplevel $w
+ wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
+
+ label $w.header -text {Push Branches} -font font_uibold
+ pack $w.header -side top -fill x
+
+ frame $w.buttons
+ button $w.buttons.create -text Push \
+ -default active \
+ -command [list start_push_anywhere_action $w]
+ pack $w.buttons.create -side right
+ button $w.buttons.cancel -text {Cancel} \
+ -default normal \
+ -command [list destroy $w]
+ pack $w.buttons.cancel -side right -padx 5
+ pack $w.buttons -side bottom -fill x -pady 10 -padx 10
+
+ labelframe $w.source -text {Source Branches}
+ listbox $w.source.l \
+ -height 10 \
+ -width 70 \
+ -selectmode extended \
+ -yscrollcommand [list $w.source.sby set]
+ foreach h $all_heads {
+ $w.source.l insert end $h
+ if {$h eq $current_branch} {
+ $w.source.l select set end
+ }
+ }
+ scrollbar $w.source.sby -command [list $w.source.l yview]
+ pack $w.source.sby -side right -fill y
+ pack $w.source.l -side left -fill both -expand 1
+ pack $w.source -fill both -expand 1 -pady 5 -padx 5
+
+ labelframe $w.dest -text {Destination Repository}
+ if {$all_remotes ne {}} {
+ radiobutton $w.dest.remote_r \
+ -text {Remote:} \
+ -value remote \
+ -variable push_urltype
+ eval tk_optionMenu $w.dest.remote_m push_remote $all_remotes
+ grid $w.dest.remote_r $w.dest.remote_m -sticky w
+ if {[lsearch -sorted -exact $all_remotes origin] != -1} {
+ set push_remote origin
+ } else {
+ set push_remote [lindex $all_remotes 0]
+ }
+ set push_urltype remote
+ } else {
+ set push_urltype url
+ }
+ radiobutton $w.dest.url_r \
+ -text {Arbitrary URL:} \
+ -value url \
+ -variable push_urltype
+ entry $w.dest.url_t \
+ -borderwidth 1 \
+ -relief sunken \
+ -width 50 \
+ -textvariable push_url \
+ -validate key \
+ -validatecommand {
+ if {%d == 1 && [regexp {\s} %S]} {return 0}
+ if {%d == 1 && [string length %S] > 0} {
+ set push_urltype url
+ }
+ return 1
+ }
+ grid $w.dest.url_r $w.dest.url_t -sticky we -padx {0 5}
+ grid columnconfigure $w.dest 1 -weight 1
+ pack $w.dest -anchor nw -fill x -pady 5 -padx 5
+
+ labelframe $w.options -text {Transfer Options}
+ checkbutton $w.options.thin \
+ -text {Use thin pack (for slow network connections)} \
+ -variable push_thin
+ grid $w.options.thin -columnspan 2 -sticky w
+ checkbutton $w.options.tags \
+ -text {Include tags} \
+ -variable push_tags
+ grid $w.options.tags -columnspan 2 -sticky w
+ grid columnconfigure $w.options 1 -weight 1
+ pack $w.options -anchor nw -fill x -pady 5 -padx 5
+
+ set push_url {}
+ set push_thin 0
+ set push_tags 0
+
+ bind $w <Visibility> "grab $w; focus $w.buttons.create"
+ bind $w <Key-Escape> "destroy $w"
+ bind $w <Key-Return> [list start_push_anywhere_action $w]
+ wm title $w "[appname] ([reponame]): Push"
+ tkwait window $w
+}
View Lorry Controller Status