1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
dnl AMD64 mpn_copyd -- copy limb vector, decrementing.
dnl Copyright 2003, 2005, 2007, 2011 Free Software Foundation, Inc.
dnl This file is part of the GNU MP Library.
dnl The GNU MP Library is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU Lesser General Public License as published
dnl by the Free Software Foundation; either version 3 of the License, or (at
dnl your option) any later version.
dnl The GNU MP Library is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
dnl License for more details.
dnl You should have received a copy of the GNU Lesser General Public License
dnl along with the GNU MP Library. If not, see http://www.gnu.org/licenses/.
include(`../config.m4')
C cycles/limb
C AMD K8,K9 1
C AMD K10 1
C Intel P4 2.8
C Intel core2 1
C Intel corei 1
C Intel atom 2
C VIA nano 2.14
C INPUT PARAMETERS
C rp rdi
C up rsi
C n rdx
define(`rp',`%rdi')
define(`up',`%rsi')
define(`n',`%rdx')
ABI_SUPPORT(DOS64)
ABI_SUPPORT(ELF64)
ASM_START()
TEXT
ALIGN(16)
PROLOGUE(mpn_copyd)
DOS64_ENTRY(3)
leaq -8(up,n,8), up
leaq (rp,n,8), rp
subq $4, n
jc L(end)
ALIGN(16)
L(oop): movq (up), %r8
movq -8(up), %r9
leaq -32(rp), rp
movq -16(up), %r10
movq -24(up), %r11
leaq -32(up), up
movq %r8, 24(rp)
movq %r9, 16(rp)
subq $4, n
movq %r10, 8(rp)
movq %r11, (rp)
jnc L(oop)
L(end): shrl R32(%rdx) C edx = lowpart(n)
jnc 1f
movq (up), %r8
movq %r8, -8(rp)
leaq -8(rp), rp
leaq -8(up), up
1: shrl R32(%rdx) C edx = lowpart(n)
jnc 1f
movq (up), %r8
movq -8(up), %r9
movq %r8, -8(rp)
movq %r9, -16(rp)
1: DOS64_EXIT()
ret
EPILOGUE()
|