1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
dnl AMD64 mpn_lshiftc -- mpn left shift with complement.
dnl Copyright 2003, 2005, 2006, 2009, 2011 Free Software Foundation, Inc.
dnl
dnl This file is part of the GNU MP Library.
dnl
dnl The GNU MP Library is free software; you can redistribute it and/or
dnl modify it under the terms of the GNU Lesser General Public License as
dnl published by the Free Software Foundation; either version 3 of the
dnl License, or (at your option) any later version.
dnl
dnl The GNU MP Library is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
dnl Lesser General Public License for more details.
dnl
dnl You should have received a copy of the GNU Lesser General Public License
dnl along with the GNU MP Library. If not, see http://www.gnu.org/licenses/.
include(`../config.m4')
C cycles/limb
C AMD K8,K9 2.75
C AMD K10 2.75
C Intel P4 ?
C Intel core2 ?
C Intel corei ?
C Intel atom ?
C VIA nano 3.75
C INPUT PARAMETERS
define(`rp', `%rdi')
define(`up', `%rsi')
define(`n', `%rdx')
define(`cnt', `%rcx')
ABI_SUPPORT(DOS64)
ABI_SUPPORT(ELF64)
ASM_START()
TEXT
ALIGN(32)
PROLOGUE(mpn_lshiftc)
DOS64_ENTRY(4)
neg R32(%rcx) C put rsh count in cl
mov -8(up,n,8), %rax
shr R8(%rcx), %rax C function return value
neg R32(%rcx) C put lsh count in cl
lea 1(n), R32(%r8)
and $3, R32(%r8)
je L(rlx) C jump for n = 3, 7, 11, ...
dec R32(%r8)
jne L(1)
C n = 4, 8, 12, ...
mov -8(up,n,8), %r10
shl R8(%rcx), %r10
neg R32(%rcx) C put rsh count in cl
mov -16(up,n,8), %r8
shr R8(%rcx), %r8
or %r8, %r10
not %r10
mov %r10, -8(rp,n,8)
dec n
jmp L(rll)
L(1): dec R32(%r8)
je L(1x) C jump for n = 1, 5, 9, 13, ...
C n = 2, 6, 10, 16, ...
mov -8(up,n,8), %r10
shl R8(%rcx), %r10
neg R32(%rcx) C put rsh count in cl
mov -16(up,n,8), %r8
shr R8(%rcx), %r8
or %r8, %r10
not %r10
mov %r10, -8(rp,n,8)
dec n
neg R32(%rcx) C put lsh count in cl
L(1x):
cmp $1, n
je L(ast)
mov -8(up,n,8), %r10
shl R8(%rcx), %r10
mov -16(up,n,8), %r11
shl R8(%rcx), %r11
neg R32(%rcx) C put rsh count in cl
mov -16(up,n,8), %r8
mov -24(up,n,8), %r9
shr R8(%rcx), %r8
or %r8, %r10
shr R8(%rcx), %r9
or %r9, %r11
not %r10
not %r11
mov %r10, -8(rp,n,8)
mov %r11, -16(rp,n,8)
sub $2, n
L(rll): neg R32(%rcx) C put lsh count in cl
L(rlx): mov -8(up,n,8), %r10
shl R8(%rcx), %r10
mov -16(up,n,8), %r11
shl R8(%rcx), %r11
sub $4, n C 4
jb L(end) C 2
ALIGN(16)
L(top):
C finish stuff from lsh block
neg R32(%rcx) C put rsh count in cl
mov 16(up,n,8), %r8
mov 8(up,n,8), %r9
shr R8(%rcx), %r8
or %r8, %r10
shr R8(%rcx), %r9
or %r9, %r11
not %r10
not %r11
mov %r10, 24(rp,n,8)
mov %r11, 16(rp,n,8)
C start two new rsh
mov 0(up,n,8), %r8
mov -8(up,n,8), %r9
shr R8(%rcx), %r8
shr R8(%rcx), %r9
C finish stuff from rsh block
neg R32(%rcx) C put lsh count in cl
mov 8(up,n,8), %r10
mov 0(up,n,8), %r11
shl R8(%rcx), %r10
or %r10, %r8
shl R8(%rcx), %r11
or %r11, %r9
not %r8
not %r9
mov %r8, 8(rp,n,8)
mov %r9, 0(rp,n,8)
C start two new lsh
mov -8(up,n,8), %r10
mov -16(up,n,8), %r11
shl R8(%rcx), %r10
shl R8(%rcx), %r11
sub $4, n
jae L(top) C 2
L(end):
neg R32(%rcx) C put rsh count in cl
mov 8(up), %r8
shr R8(%rcx), %r8
or %r8, %r10
mov (up), %r9
shr R8(%rcx), %r9
or %r9, %r11
not %r10
not %r11
mov %r10, 16(rp)
mov %r11, 8(rp)
neg R32(%rcx) C put lsh count in cl
L(ast): mov (up), %r10
shl R8(%rcx), %r10
not %r10
mov %r10, (rp)
DOS64_EXIT()
ret
EPILOGUE()
|
