1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
|
dnl AMD64 mpn_mul_basecase.
dnl Copyright 2003, 2004, 2005, 2007 Free Software Foundation, Inc.
dnl This file is part of the GNU MP Library.
dnl The GNU MP Library is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU Lesser General Public License as published
dnl by the Free Software Foundation; either version 2.1 of the License, or (at
dnl your option) any later version.
dnl The GNU MP Library is distributed in the hope that it will be useful, but
dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
dnl License for more details.
dnl You should have received a copy of the GNU Lesser General Public License
dnl along with the GNU MP Library; see the file COPYING.LIB. If not, write
dnl to the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
dnl Boston, MA 02110-1301, USA.
include(`../config.m4')
C cycles/limb
C K8: 2.86 (3.14 at 20x20)
C P4: 13.65
C P6-15: 4.67
C Outline of algorithm:
C
C if (vn & 1)
C {
C rp[] = mpn_mul_1 (rp, up, un, vp[0]);
C rp++, vp++, vn--;
C }
C else
C {
C rp[] = mpn_mul_2 (rp, up, un, vp);
C rp += 2, vp += 2, vn -= 2;
C }
C if (vn == 0)
C return;
C switch (un % 3)
C {
C case 0:
C do
C {
C rp[un + 1] = _0_mpn_addmul_2 (rp, up, un, vp);
C rp += 2, vp += 2, vn -= 2;
C }
C while (vn != 0);
C break;
C case 1:
C do
C {
C rp[un + 1] = _1_mpn_addmul_2 (rp, up, un, vp);
C rp += 2, vp += 2, vn -= 2;
C }
C while (vn != 0);
C break;
C case 2:
C do
C {
C rp[un + 1] = _2_mpn_addmul_2 (rp, up, un, vp);
C rp += 2, vp += 2, vn -= 2;
C }
C while (vn != 0);
C break;
C }
C STATUS
C * This is fairly raw, the code could surely take some polishing. Perhaps a
C register or two less could be used.
C * This code is slower than the old, plain code for vn<=3, in particular for
C vn=3. The best way of improving it might be writing some sort of mul_3 or
C addmul_3 building block. That block might very well become faster than
C out present addmul_2, and should then be made the main worker.
C INPUT PARAMETERS
define(`rp', `%rdi')
define(`up', `%rsi')
define(`un', `%rdx')
define(`vp', `%rcx')
define(`vn', `%r8')
TEXT
ALIGN(16)
ASM_START()
PROLOGUE(mpn_mul_basecase)
push %rbx
push %rbp
push %r12
push %r13
push %r14
lea (up,un,8), up C
lea (rp,un,8), rp C
lea (vp), %r14 C
define(`vp', `%r14')
mov un, %r11 C move away from rdx
define(`un', `%r11')
test $1, vn C vn odd?
je .Luse_mul_2
.Luse_mul_1:
mov (vp), %rbp C read vp[0]
lea 8(vp), vp C vp += 1
dec vn C vn -= 1
mov un, %rbx C mul_1
neg %rbx C mul_1
xor %ecx, %ecx C clear carry limb mul_1
add $3, %rbx C mul_1
jb .Led1 C jump for n = 1, 2, 3 mul_1
.Llp1: mov -24(up,%rbx,8), %rax C mul_1
mul %rbp C mul_1
xor %r9, %r9 C mul_1
add %rax, %rcx C mul_1
adc %rdx, %r9 C mul_1
mov -16(up,%rbx,8), %rax C mul_1
mul %rbp C mul_1
xor %r10, %r10 C mul_1
add %rax, %r9 C mul_1
adc %rdx, %r10 C mul_1
mov %rcx, -24(rp,%rbx,8) C mul_1
mov %r9, -16(rp,%rbx,8) C mul_1
mov -8(up,%rbx,8), %rax C mul_1
mul %rbp C mul_1
xor %r9, %r9 C mul_1
add %rax, %r10 C mul_1
adc %rdx, %r9 C mul_1
mov (up,%rbx,8), %rax C mul_1
mul %rbp C mul_1
xor %rcx, %rcx C mul_1
add %rax, %r9 C mul_1
adc %rdx, %rcx C mul_1
mov %r10, -8(rp,%rbx,8) C mul_1
mov %r9, (rp,%rbx,8) C mul_1
add $4, %rbx C mul_1
jae .Llp1 C mul_1
cmp $3, %ebx C mul_1
jne .Led1 C mul_1
mov %rcx, (rp) C mul_1
lea 8(rp), rp C rp += 1 mul_1
jmp .Ljn1 C mul_1
.Led1: mov -24(up,%rbx,8), %rax C mul_1
mul %rbp C mul_1
xor %r9, %r9 C mul_1
add %rax, %rcx C mul_1
adc %rdx, %r9 C mul_1
cmp $2, %ebx C mul_1
jne .L1 C mul_1
mov %rcx, -8(rp) C mul_1
mov %r9, (rp) C mul_1
lea 8(rp), rp C rp += 1 mul_1
jmp .Ljn1 C mul_1
.L1: mov -16(up,%rbx,8), %rax C mul_1
mul %rbp C mul_1
xor %r10, %r10 C mul_1
add %rax, %r9 C mul_1
adc %rdx, %r10 C mul_1
cmp $1, %ebx C mul_1
jne .L2 C mul_1
mov %rcx, -16(rp) C mul_1
mov %r9, -8(rp) C mul_1
mov %r10, (rp) C mul_1
lea 8(rp), rp C rp += 1 mul_1
jmp .Ljn1 C mul_1
.L2: mov -8(up), %rax C mul_1
mul %rbp C mul_1
xor %rbx, %rbx C mul_1
add %rax, %r10 C mul_1
adc %rdx, %rbx C mul_1
mov %rcx, -24(rp) C mul_1
mov %r9, -16(rp) C mul_1
mov %r10, -8(rp) C mul_1
mov %rbx, (rp) C mul_1
lea 8(rp), rp C rp += 1 mul_1
jmp .Ljn1 C mul_1
.Luse_mul_2:
define(`v0', `%r9') define(`v1', `%r10')
define(`j',`%r13')
mov (vp), v0 C mul_2
mov 8(vp), v1 C mul_2
lea 16(vp), vp C vp += 2
sub $2, vn C vn -= 2
mov un, j C mul_2
neg j C mul_2
xor %ebx, %ebx C mul_2
xor %ecx, %ecx C mul_2
xor %rbp, %rbp C mul_2
mov (up,j,8), %r12 C mul_2
mov %r12, %rax C mul_2
add $3, j C mul_2
jns .Led2 C <= 4 iterations
ALIGN(32)
.Llp2: mul v0 C mul_2
add %rax, %rbx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rcx C mul_2
adc $0, %ebp C mul_2
mul v1 C mul_2
mov %rbx, -24(rp,j,8) C mul_2
mov -16(up,j,8), %r12 C mul_2
mov $0, %ebx C mul_2
add %rax, %rcx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbp C mul_2
mul v0 C mul_2
add %rax, %rcx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbp C mul_2
adc $0, %ebx C mul_2
mul v1 C mul_2
mov %rcx, -16(rp,j,8) C mul_2
mov -8(up,j,8), %r12 C mul_2
mov $0, %ecx C mul_2
add %rax, %rbp C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbx C mul_2
mul v0 C mul_2
add %rax, %rbp C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbx C mul_2
adc $0, %ecx C mul_2
mul v1 C mul_2
mov %rbp, -8(rp,j,8) C mul_2
mov (up,j,8), %r12 C mul_2
mov $0, %ebp C mul_2
add %rax, %rbx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rcx C mul_2
add $3, j C mul_2
jns .Led2 C mul_2
mul v0 C mul_2
add %rax, %rbx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rcx C mul_2
adc $0, %ebp C mul_2
mul v1 C mul_2
mov %rbx, -24(rp,j,8) C mul_2
mov -16(up,j,8), %r12 C mul_2
mov $0, %ebx C mul_2
add %rax, %rcx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbp C mul_2
mul v0 C mul_2
add %rax, %rcx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbp C mul_2
adc $0, %ebx C mul_2
mul v1 C mul_2
mov %rcx, -16(rp,j,8) C mul_2
mov -8(up,j,8), %r12 C mul_2
mov $0, %ecx C mul_2
add %rax, %rbp C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbx C mul_2
mul v0 C mul_2
add %rax, %rbp C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rbx C mul_2
adc $0, %ecx C mul_2
mul v1 C mul_2
mov %rbp, -8(rp,j,8) C mul_2
mov (up,j,8), %r12 C mul_2
mov $0, %ebp C mul_2
add %rax, %rbx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rcx C mul_2
add $3, j C mul_2
js .Llp2 C mul_2
.Led2: jne .Ln3 C mul_2
mul v0 C mul_2
add %rax, %rbx C mul_2
mov %r12, %rax C mul_2
adc %rdx, %rcx C mul_2
adc $0, %ebp C mul_2
mul v1 C mul_2
mov %rbx, -24(rp) C mul_2
mov $0, %ebx C mul_2
add %rax, %rcx C mul_2
mov -16(up), %rax C mul_2
adc %rdx, %rbp C mul_2
mul v0 C mul_2
add %rax, %rcx C mul_2
mov -16(up), %rax C mul_2
adc %rdx, %rbp C mul_2
adc $0, %ebx C mul_2
mul v1 C mul_2
mov %rcx, -16(rp) C mul_2
mov $0, %ecx C mul_2
add %rax, %rbp C mul_2
mov -8(up), %rax C mul_2
adc %rdx, %rbx C mul_2
mul v0 C mul_2
add %rax, %rbp C mul_2
mov -8(up), %rax C mul_2
adc %rdx, %rbx C mul_2
adc $0, %ecx C mul_2
mul v1 C mul_2
mov %rbp, -8(rp) C mul_2
add %rax, %rbx C mul_2
adc %rdx, %rcx C mul_2
mov %rbx, (rp) C mul_2
mov %rcx, 8(rp) C mul_2
lea 16(rp), rp C rp += 2
jmp .Ljn1 C mul_2
.Ln3: cmp $1, j C mul_2
jne .Ln2 C mul_2
mul v0 C mul_2
add %rax, %rbx C mul_2
mov -16(up), %rax C mul_2
adc %rdx, %rcx C mul_2
adc $0, %ebp C mul_2
mul v1 C mul_2
mov %rbx, -16(rp) C mul_2
mov $0, %ebx C mul_2
add %rax, %rcx C mul_2
mov -8(up), %rax C mul_2
adc %rdx, %rbp C mul_2
mul v0 C mul_2
add %rax, %rcx C mul_2
mov -8(up), %rax C mul_2
adc %rdx, %rbp C mul_2
adc $0, %ebx C mul_2
mul v1 C mul_2
mov %rcx, -8(rp) C mul_2
add %rax, %rbp C mul_2
adc %rdx, %rbx C mul_2
mov %rbp, (rp) C mul_2
mov %rbx, 8(rp) C mul_2
lea 16(rp), rp C rp += 2
jmp .Ljn1 C mul_2
.Ln2: mul v0 C mul_2
add %rax, %rbx C mul_2
mov -8(up), %rax C mul_2
adc %rdx, %rcx C mul_2
adc $0, %ebp C mul_2
mul v1 C mul_2
mov %rbx, -8(rp) C mul_2
add %rax, %rcx C mul_2
adc %rdx, %rbp C mul_2
mov %rcx, (rp) C mul_2
mov %rbp, 8(rp) C mul_2
lea 16(rp), rp C rp += 2
C jmp .Ljn1 C mul_2
.Ljn1: test vn, vn
je .Lolex
C In order to choose the right variant of code, compute un mod 3.
movabs $0x5555555555555555, %rdx
mov un, %rax
mul %rdx C rdx = un / 3 (for relevant un)
lea 2(%rdx,%rdx,2), %rdx
sub un, %rdx C rdx = -(un mod 3) FIXME
js .LM0
je .LM2
define(`v0', `%r9') define(`v1', `%r10')
define(`j',`%r13')
.LM1:
.LM1_lpo:
mov (vp), v0 C LM1
mov 8(vp), v1 C LM1
lea 16(vp), vp C vp += 2
mov un, j C LM1
neg j C LM1
xor %ebx, %ebx C LM1
xor %ecx, %ecx C LM1
xor %ebp, %ebp C LM1
mov (up,j,8), %r12 C LM1
mov %r12, %rax C LM1
add $3, j C LM1
jns .LM1_lpie C <= 4 iterations
ALIGN(16)
.LM1_lpi:
mul v0 C LM1
add %rax, %rbx C LM1
mov %r12, %rax C LM1
adc %rdx, %rcx C LM1
adc $0, %ebp C LM1
mul v1 C LM1
add %rbx, -24(rp,j,8) C LM1
mov -16(up,j,8), %r12 C LM1
mov $0, %ebx C LM1
adc %rax, %rcx C LM1
mov %r12, %rax C LM1
adc %rdx, %rbp C LM1
mul v0 C LM1
add %rax, %rcx C LM1
mov %r12, %rax C LM1
adc %rdx, %rbp C LM1
adc $0, %ebx C LM1
mul v1 C LM1
add %rcx, -16(rp,j,8) C LM1
mov -8(up,j,8), %r12 C LM1
mov $0, %ecx C LM1
adc %rax, %rbp C LM1
mov %r12, %rax C LM1
adc %rdx, %rbx C LM1
mul v0 C LM1
add %rax, %rbp C LM1
mov %r12, %rax C LM1
adc %rdx, %rbx C LM1
adc $0, %ecx C LM1
mul v1 C LM1
add %rbp, -8(rp,j,8) C LM1
mov (up,j,8), %r12 C LM1
mov $0, %ebp C LM1
adc %rax, %rbx C LM1
mov %r12, %rax C LM1
adc %rdx, %rcx C LM1
add $3, j C LM1
jns .LM1_lpie C LM1
mul v0 C LM1
add %rax, %rbx C LM1
mov %r12, %rax C LM1
adc %rdx, %rcx C LM1
adc $0, %ebp C LM1
mul v1 C LM1
add %rbx, -24(rp,j,8) C LM1
mov -16(up,j,8), %r12 C LM1
mov $0, %ebx C LM1
adc %rax, %rcx C LM1
mov %r12, %rax C LM1
adc %rdx, %rbp C LM1
mul v0 C LM1
add %rax, %rcx C LM1
mov %r12, %rax C LM1
adc %rdx, %rbp C LM1
adc $0, %ebx C LM1
mul v1 C LM1
add %rcx, -16(rp,j,8) C LM1
mov -8(up,j,8), %r12 C LM1
mov $0, %ecx C LM1
adc %rax, %rbp C LM1
mov %r12, %rax C LM1
adc %rdx, %rbx C LM1
mul v0 C LM1
add %rax, %rbp C LM1
mov %r12, %rax C LM1
adc %rdx, %rbx C LM1
adc $0, %ecx C LM1
mul v1 C LM1
add %rbp, -8(rp,j,8) C LM1
mov (up,j,8), %r12 C LM1
mov $0, %ebp C LM1
adc %rax, %rbx C LM1
mov %r12, %rax C LM1
adc %rdx, %rcx C LM1
add $3, j C LM1
js .LM1_lpi C LM1
.LM1_lpie:
mul v0 C LM1
add %rax, %rbx C LM1
mov %r12, %rax C LM1
adc %rdx, %rcx C LM1
adc $0, %ebp C LM1
mul v1 C LM1
add %rbx, -8(rp) C LM1
adc %rax, %rcx C LM1
adc %rdx, %rbp C LM1
mov %rcx, (rp) C LM1
mov %rbp, 8(rp) C LM1
lea 16(rp), rp C rp += 2 LM1
sub $2, vn C vn -= 2 LM1
jne .LM1_lpo C LM1
jmp .Lolex C LM1
.LM2:
.LM2_lpo:
mov (vp), v0 C LM2
mov 8(vp), v1 C LM2
lea 16(vp), vp C vp += 2
mov un, j C LM2
neg j C LM2
xor %ebx, %ebx C LM2
xor %ecx, %ecx C LM2
xor %ebp, %ebp C LM2
mov (up,j,8), %r12 C LM2
mov %r12, %rax C LM2
add $3, j C LM2
jns .LM2_lpie C <= 4 iterations
ALIGN(16)
.LM2_lpi:
mul v0 C LM2
add %rax, %rbx C LM2
mov %r12, %rax C LM2
adc %rdx, %rcx C LM2
adc $0, %ebp C LM2
mul v1 C LM2
add %rbx, -24(rp,j,8) C LM2
mov -16(up,j,8), %r12 C LM2
mov $0, %ebx C LM2
adc %rax, %rcx C LM2
mov %r12, %rax C LM2
adc %rdx, %rbp C LM2
mul v0 C LM2
add %rax, %rcx C LM2
mov %r12, %rax C LM2
adc %rdx, %rbp C LM2
adc $0, %ebx C LM2
mul v1 C LM2
add %rcx, -16(rp,j,8) C LM2
mov -8(up,j,8), %r12 C LM2
mov $0, %ecx C LM2
adc %rax, %rbp C LM2
mov %r12, %rax C LM2
adc %rdx, %rbx C LM2
mul v0 C LM2
add %rax, %rbp C LM2
mov %r12, %rax C LM2
adc %rdx, %rbx C LM2
adc $0, %ecx C LM2
mul v1 C LM2
add %rbp, -8(rp,j,8) C LM2
mov (up,j,8), %r12 C LM2
mov $0, %ebp C LM2
adc %rax, %rbx C LM2
mov %r12, %rax C LM2
adc %rdx, %rcx C LM2
add $3, j C LM2
jns .LM2_lpie C LM2
mul v0 C LM2
add %rax, %rbx C LM2
mov %r12, %rax C LM2
adc %rdx, %rcx C LM2
adc $0, %ebp C LM2
mul v1 C LM2
add %rbx, -24(rp,j,8) C LM2
mov -16(up,j,8), %r12 C LM2
mov $0, %ebx C LM2
adc %rax, %rcx C LM2
mov %r12, %rax C LM2
adc %rdx, %rbp C LM2
mul v0 C LM2
add %rax, %rcx C LM2
mov %r12, %rax C LM2
adc %rdx, %rbp C LM2
adc $0, %ebx C LM2
mul v1 C LM2
add %rcx, -16(rp,j,8) C LM2
mov -8(up,j,8), %r12 C LM2
mov $0, %ecx C LM2
adc %rax, %rbp C LM2
mov %r12, %rax C LM2
adc %rdx, %rbx C LM2
mul v0 C LM2
add %rax, %rbp C LM2
mov %r12, %rax C LM2
adc %rdx, %rbx C LM2
adc $0, %ecx C LM2
mul v1 C LM2
add %rbp, -8(rp,j,8) C LM2
mov (up,j,8), %r12 C LM2
mov $0, %ebp C LM2
adc %rax, %rbx C LM2
mov %r12, %rax C LM2
adc %rdx, %rcx C LM2
add $3, j C LM2
js .LM2_lpi C LM2
.LM2_lpie:
mul v0 C LM2
add %rax, %rbx C LM2
mov %r12, %rax C LM2
adc %rdx, %rcx C LM2
adc $0, %ebp C LM2
mul v1 C LM2
add %rbx, -16(rp) C LM2
mov -8(up), %r12 C LM2
mov $0, %ebx C LM2
adc %rax, %rcx C LM2
mov %r12, %rax C LM2
adc %rdx, %rbp C LM2
mul v0 C LM2
add %rax, %rcx C LM2
mov %r12, %rax C LM2
adc %rdx, %rbp C LM2
adc $0, %ebx C LM2
mul v1 C LM2
add %rcx, -8(rp) C LM2
adc %rax, %rbp C LM2
adc %rdx, %rbx C LM2
mov %rbp, (rp) C LM2
mov %rbx, 8(rp) C LM2
lea 16(rp), rp C rp += 2 LM2
sub $2, vn C vn -= 2 LM2
jne .LM2_lpo C LM2
jmp .Lolex C LM2
.LM0:
.LM0_lpo:
mov (vp), v0 C LM0
mov 8(vp), v1 C LM0
lea 16(vp), vp C vp += 2
mov un, j C LM0
neg j C LM0
xor %ebx, %ebx C LM0
xor %ecx, %ecx C LM0
xor %ebp, %ebp C LM0
mov (up,j,8), %r12 C LM0
mov %r12, %rax C LM0
add $3, j C LM0
jns .LM0_lpie C <= 4 iterations
ALIGN(16)
.LM0_lpi:
mul v0 C LM0
add %rax, %rbx C LM0
mov %r12, %rax C LM0
adc %rdx, %rcx C LM0
adc $0, %ebp C LM0
mul v1 C LM0
add %rbx, -24(rp,j,8) C LM0
mov -16(up,j,8), %r12 C LM0
mov $0, %ebx C LM0
adc %rax, %rcx C LM0
mov %r12, %rax C LM0
adc %rdx, %rbp C LM0
mul v0 C LM0
add %rax, %rcx C LM0
mov %r12, %rax C LM0
adc %rdx, %rbp C LM0
adc $0, %ebx C LM0
mul v1 C LM0
add %rcx, -16(rp,j,8) C LM0
mov -8(up,j,8), %r12 C LM0
mov $0, %ecx C LM0
adc %rax, %rbp C LM0
mov %r12, %rax C LM0
adc %rdx, %rbx C LM0
mul v0 C LM0
add %rax, %rbp C LM0
mov %r12, %rax C LM0
adc %rdx, %rbx C LM0
adc $0, %ecx C LM0
mul v1 C LM0
add %rbp, -8(rp,j,8) C LM0
mov (up,j,8), %r12 C LM0
mov $0, %ebp C LM0
adc %rax, %rbx C LM0
mov %r12, %rax C LM0
adc %rdx, %rcx C LM0
add $3, j C LM0
jns .LM0_lpie C LM0
mul v0 C LM0
add %rax, %rbx C LM0
mov %r12, %rax C LM0
adc %rdx, %rcx C LM0
adc $0, %ebp C LM0
mul v1 C LM0
add %rbx, -24(rp,j,8) C LM0
mov -16(up,j,8), %r12 C LM0
mov $0, %ebx C LM0
adc %rax, %rcx C LM0
mov %r12, %rax C LM0
adc %rdx, %rbp C LM0
mul v0 C LM0
add %rax, %rcx C LM0
mov %r12, %rax C LM0
adc %rdx, %rbp C LM0
adc $0, %ebx C LM0
mul v1 C LM0
add %rcx, -16(rp,j,8) C LM0
mov -8(up,j,8), %r12 C LM0
mov $0, %ecx C LM0
adc %rax, %rbp C LM0
mov %r12, %rax C LM0
adc %rdx, %rbx C LM0
mul v0 C LM0
add %rax, %rbp C LM0
mov %r12, %rax C LM0
adc %rdx, %rbx C LM0
adc $0, %ecx C LM0
mul v1 C LM0
add %rbp, -8(rp,j,8) C LM0
mov (up,j,8), %r12 C LM0
mov $0, %ebp C LM0
adc %rax, %rbx C LM0
mov %r12, %rax C LM0
adc %rdx, %rcx C LM0
add $3, j C LM0
js .LM0_lpi C LM0
.LM0_lpie:
mul v0 C LM0
add %rax, %rbx C LM0
mov %r12, %rax C LM0
adc %rdx, %rcx C LM0
adc $0, %ebp C LM0
mul v1 C LM0
add %rbx, -24(rp) C LM0
mov -16(up), %r12 C LM0
mov $0, %ebx C LM0
adc %rax, %rcx C LM0
mov %r12, %rax C LM0
adc %rdx, %rbp C LM0
mul v0 C LM0
add %rax, %rcx C LM0
mov %r12, %rax C LM0
adc %rdx, %rbp C LM0
adc $0, %ebx C LM0
mul v1 C LM0
add %rcx, -16(rp) C LM0
mov -8(up), %r12 C LM0
mov $0, %ecx C LM0
adc %rax, %rbp C LM0
mov %r12, %rax C LM0
adc %rdx, %rbx C LM0
mul v0 C LM0
add %rax, %rbp C LM0
mov %r12, %rax C LM0
adc %rdx, %rbx C LM0
adc $0, %ecx C LM0
mul v1 C LM0
add %rbp, -8(rp) C LM0
adc %rax, %rbx C LM0
adc %rdx, %rcx C LM0
mov %rbx, (rp) C LM0
mov %rcx, 8(rp) C LM0
lea 16(rp), rp C rp += 2 LM0
sub $2, vn C vn -= 2 LM0
jne .LM0_lpo C LM0
.Lolex: pop %r14
pop %r13
pop %r12
pop %rbp
pop %rbx
ret
EPILOGUE()
|