1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
dnl x86-64 mpn_lshift optimized for Pentium 4.
dnl Copyright 2003, 2005, 2007 Free Software Foundation, Inc.
dnl
dnl This file is part of the GNU MP Library.
dnl
dnl The GNU MP Library is free software; you can redistribute it and/or
dnl modify it under the terms of the GNU Lesser General Public License as
dnl published by the Free Software Foundation; either version 2.1 of the
dnl License, or (at your option) any later version.
dnl
dnl The GNU MP Library is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
dnl Lesser General Public License for more details.
dnl
dnl You should have received a copy of the GNU Lesser General Public
dnl License along with the GNU MP Library; see the file COPYING.LIB. If
dnl not, write to the Free Software Foundation, Inc., 51 Franklin Street,
dnl Fifth Floor, Boston, MA 02110-1301, USA.
include(`../config.m4')
C cycles/limb
C K8: 2.5
C Prescott/Nocona: 3.29
C P6-15: 2.1 (fluctuates, presumably cache related)
C INPUT PARAMETERS
define(`rp',`%rdi')
define(`up',`%rsi')
define(`n',`%rdx')
define(`cnt',`%cl')
ASM_START()
TEXT
ALIGN(32)
PROLOGUE(mpn_lshift)
mov -8(up,n,8), %rax
movd %ecx, %mm4
neg %ecx C put rsh count in cl
and $63, %ecx
movd %ecx, %mm5
lea 1(n), %r8d
shr %cl, %rax C function return value
and $3, %r8d
je .Lrolx C jump for n = 3, 7, 11, ...
dec %r8d
jne .L1
C n = 4, 8, 12, ...
movq -8(up,n,8), %mm2
psllq %mm4, %mm2
movq -16(up,n,8), %mm0
psrlq %mm5, %mm0
por %mm0, %mm2
movq %mm2, -8(rp,n,8)
dec n
jmp .Lroll
.L1: dec %r8d
je .L1x C jump for n = 1, 5, 9, 13, ...
C n = 2, 6, 10, 16, ...
movq -8(up,n,8), %mm2
psllq %mm4, %mm2
movq -16(up,n,8), %mm0
psrlq %mm5, %mm0
por %mm0, %mm2
movq %mm2, -8(rp,n,8)
dec n
.L1x:
cmp $1, n
je .Last
movq -8(up,n,8), %mm2
psllq %mm4, %mm2
movq -16(up,n,8), %mm3
psllq %mm4, %mm3
movq -16(up,n,8), %mm0
movq -24(up,n,8), %mm1
psrlq %mm5, %mm0
por %mm0, %mm2
psrlq %mm5, %mm1
por %mm1, %mm3
movq %mm2, -8(rp,n,8)
movq %mm3, -16(rp,n,8)
sub $2, n
.Lroll:
.Lrolx: movq -8(up,n,8), %mm2
psllq %mm4, %mm2
movq -16(up,n,8), %mm3
psllq %mm4, %mm3
sub $4, n C 4
jb .Lend C 2
ALIGN(32)
.Loop:
C finish stuff from lsh block
movq 16(up,n,8), %mm0
movq 8(up,n,8), %mm1
psrlq %mm5, %mm0
por %mm0, %mm2
psrlq %mm5, %mm1
movq (up,n,8), %mm0
por %mm1, %mm3
movq -8(up,n,8), %mm1
movq %mm2, 24(rp,n,8)
movq %mm3, 16(rp,n,8)
C start two new rsh
psrlq %mm5, %mm0
psrlq %mm5, %mm1
C finish stuff from rsh block
movq 8(up,n,8), %mm2
movq (up,n,8), %mm3
psllq %mm4, %mm2
por %mm2, %mm0
psllq %mm4, %mm3
movq -8(up,n,8), %mm2
por %mm3, %mm1
movq -16(up,n,8), %mm3
movq %mm0, 8(rp,n,8)
movq %mm1, (rp,n,8)
C start two new lsh
sub $4, n
psllq %mm4, %mm2
psllq %mm4, %mm3
jae .Loop C 2
.Lend:
movq 16(up,n,8), %mm0
psrlq %mm5, %mm0
por %mm0, %mm2
movq 8(up,n,8), %mm1
psrlq %mm5, %mm1
por %mm1, %mm3
movq %mm2, 24(rp,n,8)
movq %mm3, 16(rp,n,8)
.Last: movq (up), %mm2
psllq %mm4, %mm2
movq %mm2, (rp)
emms
ret
EPILOGUE()
|
