1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
|
dnl AMD64 mpn_redc_1 -- Montgomery reduction with a one-limb modular inverse.
dnl Copyright 2004, 2008, 2011 Free Software Foundation, Inc.
dnl
dnl This file is part of the GNU MP Library.
dnl
dnl The GNU MP Library is free software; you can redistribute it and/or
dnl modify it under the terms of the GNU Lesser General Public License as
dnl published by the Free Software Foundation; either version 3 of the
dnl License, or (at your option) any later version.
dnl
dnl The GNU MP Library is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
dnl Lesser General Public License for more details.
dnl
dnl You should have received a copy of the GNU Lesser General Public License
dnl along with the GNU MP Library. If not, see http://www.gnu.org/licenses/.
include(`../config.m4')
C cycles/limb
C cycles/limb
C AMD K8,K9 2.5
C AMD K10 2.5
C Intel P4 ?
C Intel core2 5.3
C Intel corei ?
C Intel atom ?
C VIA nano ?
C TODO
C * Handle certain sizes, e.g., 1, 2, 3, 4, 8, with single-loop code.
C The code for 1, 2, 3, 4 should perhaps be completely register based.
C * Perhaps align outer loops.
C * We could software pipeline the IMUL stuff, by putting it before the
C outer loops and before the end of the outer loops. The last outer
C loop iteration would then compute an unneeded product, but it is at
C least not a stray read from up[], since it is at up[n].
C INPUT PARAMETERS
define(`up', `%rdi')
define(`mp', `%rsi')
define(`n_param', `%rdx')
define(`invm', `%rcx')
define(`n', `%r13')
define(`i', `%r11')
define(`nneg', `%r12')
ABI_SUPPORT(DOS64)
ABI_SUPPORT(ELF64)
ASM_START()
TEXT
ALIGN(32)
PROLOGUE(mpn_redc_1)
DOS64_ENTRY(4)
push %rbp
push %rbx
push %r12
push %r13
push %r14
lea (mp,n_param,8), mp C mp += n
lea (up,n_param,8), up C up += n
mov n_param, nneg
mov n_param, n
neg nneg
mov R32(n), R32(%rax)
and $3, R32(%rax)
jz L(b0)
cmp $2, R32(%rax)
jz L(b2)
jg L(b3)
L(b1): C lea (mp), mp
lea -16(up), up
L(o1): mov nneg, i
mov 16(up,nneg,8), %rbp C up[0]
imul invm, %rbp
mov (mp,i,8), %rax
xor R32(%rbx), R32(%rbx)
mul %rbp
add $1, i
jnz 1f
add %rax, 8(up,i,8)
adc $0, %rdx
mov %rdx, %r14
jmp L(n1)
1: mov %rax, %r9
mov (mp,i,8), %rax
mov %rdx, %r14
jmp L(mi1)
ALIGN(16)
L(lo1): add %r10, (up,i,8)
adc %rax, %r9
mov (mp,i,8), %rax
adc %rdx, %r14
L(mi1): xor R32(%r10), R32(%r10)
mul %rbp
add %r9, 8(up,i,8)
adc %rax, %r14
adc %rdx, %rbx
mov 8(mp,i,8), %rax
mul %rbp
add %r14, 16(up,i,8)
adc %rax, %rbx
adc %rdx, %r10
mov 16(mp,i,8), %rax
mul %rbp
xor R32(%r9), R32(%r9)
xor R32(%r14), R32(%r14)
add %rbx, 24(up,i,8)
adc %rax, %r10
mov 24(mp,i,8), %rax
adc %rdx, %r9
xor R32(%rbx), R32(%rbx)
mul %rbp
add $4, i
js L(lo1)
L(ed1): add %r10, (up)
adc %rax, %r9
adc %rdx, %r14
xor R32(%r10), R32(%r10)
add %r9, 8(up)
adc $0, %r14
L(n1): mov %r14, 16(up,nneg,8) C up[0]
add $8, up
dec n
jnz L(o1)
jmp L(ret)
L(b0): C lea (mp), mp
lea -16(up), up
L(o0): mov nneg, i
mov 16(up,nneg,8), %rbp C up[0]
imul invm, %rbp
mov (mp,i,8), %rax
xor R32(%r10), R32(%r10)
mul %rbp
mov %rax, %r14
mov %rdx, %rbx
jmp L(mi0)
ALIGN(16)
L(lo0): add %r10, (up,i,8)
adc %rax, %r9
mov (mp,i,8), %rax
adc %rdx, %r14
xor R32(%r10), R32(%r10)
mul %rbp
add %r9, 8(up,i,8)
adc %rax, %r14
adc %rdx, %rbx
L(mi0): mov 8(mp,i,8), %rax
mul %rbp
add %r14, 16(up,i,8)
adc %rax, %rbx
adc %rdx, %r10
mov 16(mp,i,8), %rax
mul %rbp
xor R32(%r9), R32(%r9)
xor R32(%r14), R32(%r14)
add %rbx, 24(up,i,8)
adc %rax, %r10
mov 24(mp,i,8), %rax
adc %rdx, %r9
xor R32(%rbx), R32(%rbx)
mul %rbp
add $4, i
js L(lo0)
L(ed0): add %r10, (up)
adc %rax, %r9
adc %rdx, %r14
xor R32(%r10), R32(%r10)
add %r9, 8(up)
adc $0, %r14
mov %r14, 16(up,nneg,8) C up[0]
add $8, up
dec n
jnz L(o0)
jmp L(ret)
L(b3): lea -8(mp), mp
lea -24(up), up
L(o3): mov nneg, i
mov 24(up,nneg,8), %rbp C up[0]
imul invm, %rbp
mov 8(mp,i,8), %rax
mul %rbp
mov %rax, %rbx
mov %rdx, %r10
jmp L(mi3)
ALIGN(16)
L(lo3): add %r10, (up,i,8)
adc %rax, %r9
mov (mp,i,8), %rax
adc %rdx, %r14
xor R32(%r10), R32(%r10)
mul %rbp
add %r9, 8(up,i,8)
adc %rax, %r14
adc %rdx, %rbx
mov 8(mp,i,8), %rax
mul %rbp
add %r14, 16(up,i,8)
adc %rax, %rbx
adc %rdx, %r10
L(mi3): mov 16(mp,i,8), %rax
mul %rbp
xor R32(%r9), R32(%r9)
xor R32(%r14), R32(%r14)
add %rbx, 24(up,i,8)
adc %rax, %r10
mov 24(mp,i,8), %rax
adc %rdx, %r9
xor R32(%rbx), R32(%rbx)
mul %rbp
add $4, i
js L(lo3)
L(ed3): add %r10, 8(up)
adc %rax, %r9
adc %rdx, %r14
xor R32(%r10), R32(%r10)
add %r9, 16(up)
adc $0, %r14
mov %r14, 24(up,nneg,8) C up[0]
add $8, up
dec n
jnz L(o3)
jmp L(ret)
L(b2): lea -16(mp), mp
lea -32(up), up
L(o2): mov nneg, i
mov 32(up,nneg,8), %rbp C up[0]
imul invm, %rbp
mov 16(mp,i,8), %rax
mul %rbp
xor R32(%r14), R32(%r14)
mov %rax, %r10
mov 24(mp,i,8), %rax
mov %rdx, %r9
jmp L(mi2)
ALIGN(16)
L(lo2): add %r10, (up,i,8)
adc %rax, %r9
mov (mp,i,8), %rax
adc %rdx, %r14
xor R32(%r10), R32(%r10)
mul %rbp
add %r9, 8(up,i,8)
adc %rax, %r14
adc %rdx, %rbx
mov 8(mp,i,8), %rax
mul %rbp
add %r14, 16(up,i,8)
adc %rax, %rbx
adc %rdx, %r10
mov 16(mp,i,8), %rax
mul %rbp
xor R32(%r9), R32(%r9)
xor R32(%r14), R32(%r14)
add %rbx, 24(up,i,8)
adc %rax, %r10
mov 24(mp,i,8), %rax
adc %rdx, %r9
L(mi2): xor R32(%rbx), R32(%rbx)
mul %rbp
add $4, i
js L(lo2)
L(ed2): add %r10, 16(up)
adc %rax, %r9
adc %rdx, %r14
xor R32(%r10), R32(%r10)
add %r9, 24(up)
adc $0, %r14
mov %r14, 32(up,nneg,8) C up[0]
add $8, up
dec n
jnz L(o2)
L(ret): pop %r14
pop %r13
pop %r12
pop %rbx
pop %rbp
DOS64_EXIT()
ret
EPILOGUE()
|
