1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
|
<?xml version='1.0' encoding='UTF-8'?><!-- -*- indent-tabs-mode: nil -*- -->
<!--
This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free
Software Foundation; either version 2 of the License, or (at your option) any
later version.
This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more
details.
You should have received a copy of the GNU Lesser General Public License
along with this program; see the file COPYING.LGPL. If not, write to the
Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
02111-1307, USA.
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:mal="http://www.gnome.org/~shaunm/mallard"
version="1.0">
<!--!!==========================================================================
Mallard Links
-->
<!--@@==========================================================================
mal.cache.file
The location of the cache file
-->
<xsl:param name="mal.cache.file"/>
<xsl:variable name="mal.cache" select="document($mal.cache.file)"/>
<xsl:key name="mal.cache.key" match="mal:page | mal:section" use="@id"/>
<!--**==========================================================================
mal.link.content
Generates the content for a #{link} element
$link: The #{link} or other element creating the link
$xref: The #{xref} attribute of ${link}
$href: The #{href} attribute of ${link}
-->
<xsl:template name="mal.link.content">
<xsl:param name="link" select="."/>
<xsl:param name="xref" select="$link/@xref"/>
<xsl:param name="href" select="$link/@href"/>
<xsl:choose>
<xsl:when test="contains($xref, '/')">
<!--
This is a link to another document, which we don't handle in these
stylesheets. Extensions such as library or yelp should override
this template to provide this functionality.
-->
<xsl:choose>
<xsl:when test="$href">
<xsl:value-of select="$href"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$xref"/>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:variable name="fullid">
<xsl:choose>
<xsl:when test="contains($xref, '#')">
<xsl:variable name="pageid" select="substring-before($xref, '#')"/>
<xsl:variable name="sectionid" select="substring-after($xref, '#')"/>
<xsl:if test="$pageid = ''">
<xsl:value-of select="$link/ancestor::mal:page/@id"/>
</xsl:if>
<xsl:value-of select="concat($pageid, '#', $sectionid)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$xref"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:for-each select="$mal.cache">
<xsl:apply-templates mode="mal.link.content.mode"
select="key('mal.cache.key', $fullid)
/mal:info/mal:title[@type = 'link']/node()"/>
</xsl:for-each>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!--%%==========================================================================
mal.link.content.mode
Renders the content of a link from a title
This mode is applied to the contents of a #{title} element by *{mal.link.content}.
By default, it returns the string value of its input. Stylesheets that import
this module should override this to call their inline mode.
-->
<xsl:template mode="mal.link.content.mode" match="* | text()">
<xsl:value-of select="."/>
</xsl:template>
<!--**==========================================================================
mal.link.target
Generates the target for a #{link} element
$link: The #{link} or other element creating the link
$xref: The #{xref} attribute of ${link}
$href: The #{href} attribute of ${link}
-->
<xsl:template name="mal.link.target">
<xsl:param name="link" select="."/>
<xsl:param name="xref" select="$link/@xref"/>
<xsl:param name="href" select="$link/@href"/>
<xsl:choose>
<xsl:when test="string($xref) = ''">
<xsl:value-of select="$href"/>
</xsl:when>
<xsl:when test="contains($xref, '/')">
<!--
This is a link to another document, which we don't handle in these
stylesheets. Extensions such as library or yelp should override
this template to provide this functionality.
-->
<xsl:value-of select="$href"/>
</xsl:when>
<xsl:when test="contains($xref, '#')">
<xsl:variable name="pageid" select="substring-before($xref, '#')"/>
<xsl:variable name="sectionid" select="substring-after($xref, '#')"/>
<xsl:if test="$pageid != ''">
<xsl:value-of select="concat($pageid, $mal.chunk.extension)"/>
</xsl:if>
<xsl:value-of select="concat('#', $sectionid)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat($xref, $mal.chunk.extension)"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!--**==========================================================================
mal.link.tooltip
Generates the tooltip for a #{link} or other linking element
$link: The #{link} or other element creating the link
$xref: The #{xref} attribute of ${link}
$href: The #{href} attribute of ${link}
-->
<xsl:template name="mal.link.tooltip">
<xsl:param name="link" select="."/>
<xsl:param name="xref" select="$link/@xref"/>
<xsl:param name="href" select="$link/@href"/>
<xsl:choose>
<xsl:when test="string($xref) != ''">
<!-- FIXME -->
</xsl:when>
<xsl:when test="starts-with($href, 'mailto:')">
<xsl:variable name="address" select="substring-after($href, 'mailto:')"/>
<xsl:call-template name="l10n.gettext">
<xsl:with-param name="msgid" select="'email.tooltip'"/>
<xsl:with-param name="string" select="$address"/>
<xsl:with-param name="format" select="true()"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="normalize-space($href)"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
|
