1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
libgkm_gnome2_store_sources = files(
'gkm-gnome2-file.c',
'gkm-gnome2-module.c',
'gkm-gnome2-private-key.c',
'gkm-gnome2-public-key.c',
'gkm-gnome2-storage.c',
)
libgkm_gnome2_store_deps = [
glib_dep,
gobject_dep,
libgcrypt_dep,
libegg_dep,
libgkm_dep,
]
libgkm_gnome2_store = library('gkm-gnome2-store',
libgkm_gnome2_store_sources,
dependencies: libgkm_gnome2_store_deps,
include_directories: config_h_inc,
install: true,
install_dir: gkr_pkglibdir,
)
libgkm_gnome2_store_dep = declare_dependency(
link_with: libgkm_gnome2_store,
)
# Tests
libgkm_gnome2_store_tests = [
{
'name': 'test-gnome2-file',
'needs-mock': false,
},
{
'name': 'test-gnome2-storage',
'needs-mock': true,
},
{
'name': 'test-gnome2-private-key',
'needs-mock': true,
},
{
'name': 'test-import',
'needs-mock': false,
},
]
libgkm_gnome2_store_tests_deps = [
gck_dep,
gcr_base_dep,
libgkm_gnome2_store_deps,
libgkm_gnome2_store_dep,
]
libgkm_gnome2_store_tests_cflags = [
'-DSRCDIR="@0@"'.format(source_root),
]
foreach _test : libgkm_gnome2_store_tests
test_name = _test['name']
test_sources = [ '@0@.c'.format(test_name) ]
if _test['needs-mock']
test_sources += 'mock-gnome2-module.c'
endif
test_bin = executable(test_name,
test_sources,
dependencies: libgkm_gnome2_store_tests_deps,
c_args: libgkm_gnome2_store_tests_cflags,
include_directories: config_h_inc,
)
test(test_name, test_bin,
suite: 'gkm::gnome2-store',
)
endforeach
|
