Remove stray m4 directory

The Autotools build was dropped, we don't need m4 macros any more.

2 files changed, 0 insertions, 210 deletions

diff --git a/m4/ax_config_dir.m4 b/m4/ax_config_dir.m4
deleted file mode 100644
index 0ba313f..0000000
--- a/m4/ax_config_dir.m4
+++ /dev/null
@@ -1,109 +0,0 @@
-dnl Copied from Audacity 1.3.10 which itself is licensed under the GPL v2 or
-dnl any later version
-
-dnl Function to configure a sub-library now, because we need to know the result
-dnl of the configuration now in order to take decisions.
-dnl We don't worry about whether the configuration worked or not - it is
-dnl assumed that the next thing after this will be a package-specific check to
-dnl see if the package is actually available. (Hint: use pkg-config and
-dnl -uninstalled.pc files if available).
-dnl code based on a simplification of _AC_OUTPUT_SUBDIRS in 
-dnl /usr/share/autoconf/autoconf/status.m4 which implements part of 
-dnl AC_CONFIG_SUBDIRS
-
-AC_DEFUN([AX_CONFIG_DIR],
-[AC_REQUIRE([AC_DISABLE_OPTION_CHECKING])]
-[m4_append([_AC_LIST_SUBDIRS], [$1], [])]
-[
-  # Remove --cache-file and --srcdir arguments so they do not pile up.
-  ax_sub_configure_args=
-  ax_prev=
-  eval "set x $ac_configure_args"
-  shift
-  for ax_arg
-  do
-    if test -n "$ax_prev"; then
-      ax_prev=
-      continue
-    fi
-    case $ax_arg in
-    -cache-file | --cache-file | --cache-fil | --cache-fi \
-    | --cache-f | --cache- | --cache | --cach | --cac | --ca | --c)
-      ax_prev=cache_file ;;
-    -cache-file=* | --cache-file=* | --cache-fil=* | --cache-fi=* \
-    | --cache-f=* | --cache-=* | --cache=* | --cach=* | --cac=* | --ca=* \
-    | --c=*)
-      ;;
-    --config-cache | -C)
-      ;;
-    -srcdir | --srcdir | --srcdi | --srcd | --src | --sr)
-      ax_prev=srcdir ;;
-    -srcdir=* | --srcdir=* | --srcdi=* | --srcd=* | --src=* | --sr=*)
-      ;;
-    -prefix | --prefix | --prefi | --pref | --pre | --pr | --p)
-      ax_prev=prefix ;;
-    -prefix=* | --prefix=* | --prefi=* | --pref=* | --pre=* | --pr=* | --p=*)
-      ;;
-    *)
-      case $ax_arg in
-      *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
-      esac
-      ax_sub_configure_args="$ax_sub_configure_args '$ax_arg'" ;;
-    esac
-  done
-
-  # Always prepend --prefix to ensure using the same prefix
-  # in subdir configurations.
-  ax_arg="--prefix=$prefix"
-  case $ax_arg in
-  *\'*) ax_arg=`echo "$ax_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
-  esac
-  ax_sub_configure_args="'$ax_arg' $ax_sub_configure_args"
-
-  # Pass --silent
-  if test "$silent" = yes; then
-    ax_sub_configure_args="--silent $ax_sub_configure_args"
-  fi
-
-  ax_popdir=`pwd`
-  AC_MSG_NOTICE([Configuring sources in $1])
-  dnl for out-of-place builds srcdir and builddir will be different, and
-  dnl builddir may not exist, so we must create it
-  AS_MKDIR_P(["$1"])
-  dnl and also set the variables. As this isn't autoconf, the following may be
-  dnl risky:
-  _AC_SRCDIRS(["$1"])
-  cd "$1"
-
-  # Check for guested configure; otherwise get Cygnus style configure.
-  if test -f "configure.gnu"; then
-    ax_sub_configure=$ac_srcdir/configure.gnu
-  elif test -f "$ac_srcdir/configure"; then
-    ax_sub_configure=$ac_srcdir/configure
-  elif test -f "$ac_srcdir/configure.in"; then
-    # This should be Cygnus configure.
-	ax_sub_configure=$ac_aux_dir/configure
-  else
-    AC_MSG_WARN([no configuration information is in $1])
-    ax_sub_configure=
-  fi
-
-  # The recursion is here.
-  if test -n "$ax_sub_configure"; then
-    # Make the cache file name correct relative to the subdirectory.
-    case $cache_file in
-    [[\\/]]* | ?:[[\\/]]* ) ax_sub_cache_file=$cache_file ;;
-    *) # Relative name.
-	ax_sub_cache_file=$ac_top_build_prefix$cache_file ;;
-    esac
-
-    AC_MSG_NOTICE([running $SHELL $ax_sub_configure $ax_sub_configure_args --cache-file=$ax_sub_cache_file --srcdir=$ac_srcdir])
-    # The eval makes quoting arguments work.
-    eval "\$SHELL \"\$ax_sub_configure\" $ax_sub_configure_args \
-	   --cache-file=\"\$ax_sub_cache_file\" --srcdir=\"\$ax_srcdir\""
-  fi
-
-  cd "$ax_popdir"
-  AC_MSG_NOTICE([Done configuring in $1])
-])
-
diff --git a/m4/vapigen.m4 b/m4/vapigen.m4
deleted file mode 100644
index 2c435e7..0000000
--- a/m4/vapigen.m4
+++ /dev/null
@@ -1,101 +0,0 @@
-dnl vapigen.m4
-dnl
-dnl Copyright 2012 Evan Nemerson
-dnl
-dnl This library is free software; you can redistribute it and/or
-dnl modify it under the terms of the GNU Lesser General Public
-dnl License as published by the Free Software Foundation; either
-dnl version 2.1 of the License, or (at your option) any later version.
-dnl
-dnl This library is distributed in the hope that it will be useful,
-dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
-dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-dnl Lesser General Public License for more details.
-dnl
-dnl You should have received a copy of the GNU Lesser General Public
-dnl License along with this library; if not, write to the Free Software
-dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA
-
-# VAPIGEN_CHECK([VERSION], [API_VERSION], [FOUND_INTROSPECTION], [DEFAULT])
-# --------------------------------------
-# Check vapigen existence and version
-#
-# See http://live.gnome.org/Vala/UpstreamGuide for detailed documentation
-AC_DEFUN([VAPIGEN_CHECK],
-[
-  AS_IF([test "x$3" != "xyes"], [
-      m4_provide_if([GOBJECT_INTROSPECTION_CHECK], [], [
-          m4_provide_if([GOBJECT_INTROSPECTION_REQUIRE], [], [
-              AC_MSG_ERROR([[You must call GOBJECT_INTROSPECTION_CHECK or GOBJECT_INTROSPECTION_REQUIRE before using VAPIGEN_CHECK unless using the FOUND_INTROSPECTION argument is "yes"]])
-            ])
-        ])
-    ])
-
-  AC_ARG_ENABLE([vala],
-    [AS_HELP_STRING([--enable-vala[=@<:@no/auto/yes@:>@]],[build Vala bindings @<:@default=]ifelse($4,,auto,$4)[@:>@])],,[
-      AS_IF([test "x$4" = "x"], [
-          enable_vala=auto
-        ], [
-          enable_vala=$4
-        ])
-    ])
-
-  AS_CASE([$enable_vala], [no], [enable_vala=no],
-      [yes], [
-        AS_IF([test "x$3" != "xyes" -a "x$found_introspection" != "xyes"], [
-            AC_MSG_ERROR([Vala bindings require GObject Introspection])
-          ])
-      ], [auto], [
-        AS_IF([test "x$3" != "xyes" -a "x$found_introspection" != "xyes"], [
-            enable_vala=no
-          ])
-      ], [
-        AC_MSG_ERROR([Invalid argument passed to --enable-vala, should be one of @<:@no/auto/yes@:>@])
-      ])
-
-  AS_IF([test "x$2" = "x"], [
-      vapigen_pkg_name=vapigen
-    ], [
-      vapigen_pkg_name=vapigen-$2
-    ])
-  AS_IF([test "x$1" = "x"], [
-      vapigen_pkg="$vapigen_pkg_name"
-    ], [
-      vapigen_pkg="$vapigen_pkg_name >= $1"
-    ])
-
-  PKG_PROG_PKG_CONFIG
-
-  PKG_CHECK_EXISTS([$vapigen_pkg], [
-      AS_IF([test "$enable_vala" = "auto"], [
-          enable_vala=yes
-        ])
-    ], [
-      AS_CASE([$enable_vala], [yes], [
-          AC_MSG_ERROR([$vapigen_pkg not found])
-        ], [auto], [
-          enable_vala=no
-        ])
-    ])
-
-  AC_MSG_CHECKING([for vapigen])
-
-  AS_CASE([$enable_vala],
-    [yes], [
-      VAPIGEN=`$PKG_CONFIG --variable=vapigen $vapigen_pkg_name`
-      VAPIGEN_MAKEFILE=`$PKG_CONFIG --variable=datadir $vapigen_pkg_name`/vala/Makefile.vapigen
-      AS_IF([test "x$2" = "x"], [
-          VAPIGEN_VAPIDIR=`$PKG_CONFIG --variable=vapidir $vapigen_pkg_name`
-        ], [
-          VAPIGEN_VAPIDIR=`$PKG_CONFIG --variable=vapidir_versioned $vapigen_pkg_name`
-        ])
-    ])
-
-  AC_MSG_RESULT([$enable_vala])
-
-  AC_SUBST([VAPIGEN])
-  AC_SUBST([VAPIGEN_VAPIDIR])
-  AC_SUBST([VAPIGEN_MAKEFILE])
-
-  AM_CONDITIONAL(ENABLE_VAPIGEN, test "x$enable_vala" = "xyes")
-])