AC_PREREQ([2.64])
AC_INIT([gupnp-vala],
        [0.10.5],
        [http://bugzilla.gnome.org/enter_bug.cgi?product=gupnp&component=gupnp-vala],
        [gupnp-vala],
        [http://www.gupnp.org])

AC_CONFIG_HEADERS([config.h])
AC_CONFIG_SRCDIR([README])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET

AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-xz])
AM_MAINTAINER_MODE([enable])

AM_SILENT_RULES([enable])

VALA_REQUIRED=0.11.3

AM_PROG_VALAC([$VALA_REQUIRED])
if test "x$VALAC" = "x"; then
        AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
fi

AC_PATH_PROG(VAPIGEN, vapigen, no)
if test "x$VAPIGEN" = "xno"; then
	AC_MSG_ERROR([Cannot find the "vapigen" binary in your PATH])
fi

AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
if test "x$PKG_CONFIG" = "xno"; then
	AC_MSG_ERROR([Cannot find the "pkg-config" program in your PATH])
fi

dnl check if we have gssdp >= 0.12.2 which carries its own vapi
PKG_CHECK_MODULES(NEW_GSSDP, [gssdp-1.0 >= 0.11.0 gssdp-1.0 < 0.12.2],
                  [
                   has_gssdp=yes
                  ],
                  [
                   has_gssdp=no
                  ])
AM_CONDITIONAL(WITH_GSSDP, [test "x$has_gssdp" = "xyes"])

PKG_CHECK_MODULES(GUPNP, [gupnp-1.0 >= 0.18.0 gupnp-1.0 < 0.19.0],
                  has_gupnp=yes,
                  has_gupnp=no)
AM_CONDITIONAL(WITH_GUPNP, [test "x$has_gupnp" = "xyes"])

PKG_CHECK_MODULES(GUPNP_AV, [gupnp-av-1.0 >= 0.9.0 gupnp-av-1.0 < 0.11.0],
                  has_gupnp_av=yes,
                  has_gupnp_av=no)
AM_CONDITIONAL(WITH_GUPNP_AV, [test "x$has_gupnp_av" = "xyes"])

PKG_CHECK_MODULES(GUPNP_DLNA, [gupnp-dlna-1.0 >= 0.5.1],
                  has_gupnp_dlna=yes,
                  has_gupnp_dlna=no)
AM_CONDITIONAL(WITH_GUPNP_DLNA, [test "x$has_gupnp_dlna" = "xyes"])

VAPIDIR=`echo ${datadir}/vala/vapi`
AC_SUBST(VAPIDIR)

AC_CONFIG_FILES([
	Makefile
	gupnp-vala-1.0.pc
	tests/Makefile
])
AC_OUTPUT

echo ""
echo "     GUPnP Vala bindings"
echo ""
echo "       vapidir: ${VAPIDIR}"
echo ""
echo "           gssdp: ${has_gssdp}"
echo "           gupnp: ${has_gupnp}"
echo "        gupnp-av: ${has_gupnp_av}"
echo "      gupnp-dlna: ${has_gupnp_dlna}"
echo ""