From 440e8f59ea9b9ca4c3fae71606f6ff99751dcd88 Mon Sep 17 00:00:00 2001
From: Lubomir Rintel <lkundrak@v3.sk>
Date: Wed, 18 Mar 2015 19:02:29 +0100
Subject: build: disable warnings that trigger known clang problems

Fixes build with clang 3.5 on Fedora 21.

Taken from NetworkManager, commit f0740aff88a83c228aa22cfd4c567e31e36bb504.
---
 m4/compiler_warnings.m4 | 80 +++++++++++++++++++++++++++++++++++++++----------
 1 file changed, 64 insertions(+), 16 deletions(-)

(limited to 'm4')

diff --git a/m4/compiler_warnings.m4 b/m4/compiler_warnings.m4
index 97897e44..21e5c88c 100644
--- a/m4/compiler_warnings.m4
+++ b/m4/compiler_warnings.m4
@@ -1,3 +1,24 @@
+dnl Check whether a particular compiler flag works with code provided,
+dnl disable it in CFLAGS if the check fails.
+AC_DEFUN([NM_COMPILER_WARNING], [
+	CFLAGS_SAVED="$CFLAGS"
+	CFLAGS="$CFLAGS -Werror -W$1"
+	AC_MSG_CHECKING(whether -W$1 works)
+
+	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])], [
+		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[$2]])], [
+			AC_MSG_RESULT(yes)
+			CFLAGS="$CFLAGS_SAVED -W$1"
+		],[
+			AC_MSG_RESULT(no)
+			CFLAGS="$CFLAGS_SAVED -Wno-$1"
+		])
+	],[
+		AC_MSG_RESULT(not supported)
+		CFLAGS="$CFLAGS_SAVED"
+	])
+])
+
 AC_DEFUN([NM_COMPILER_WARNINGS],
 [AC_ARG_ENABLE(more-warnings,
 	AS_HELP_STRING([--enable-more-warnings], [Possible values: no/yes/error]),
@@ -5,22 +26,26 @@ AC_DEFUN([NM_COMPILER_WARNINGS],
 AC_MSG_CHECKING(for more warnings)
 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 	AC_MSG_RESULT(yes)
+
+	dnl This is enabled in clang by default, makes little sense,
+	dnl and causes the build to abort with -Werror.
 	CFLAGS_SAVED="$CFLAGS"
-	CFLAGS_MORE_WARNINGS="-Wall -std=gnu89"
+	CFLAGS="$CFLAGS -Qunused-arguments"
+	AC_COMPILE_IFELSE([AC_LANG_SOURCE([])], [], CFLAGS="$CFLAGS_SAVED")
+	unset CFLAGS_SAVED
 
 	dnl clang only warns about unknown warnings, unless
 	dnl called with "-Werror=unknown-warning-option"
 	dnl Test if the compiler supports that, and if it does
 	dnl attach it to the CFLAGS.
-	CFLAGS_EXTRA="-Werror=unknown-warning-option"
-	CFLAGS="$CFLAGS_MORE_WARNINGS $CFLAGS_EXTRA $CFLAGS_SAVED"
-	AC_TRY_COMPILE([], [],
-		has_option=yes,
-		has_option=no,)
-	if test $has_option = no; then
-		CFLAGS_EXTRA=
+	NM_COMPILER_WARNING([unknown-warning-option], [])
+
+	CFLAGS_SAVED="$CFLAGS"
+	CFLAGS_MORE_WARNINGS="-Wall -std=gnu89"
+
+	if test "x$set_more_warnings" = xerror; then
+		CFLAGS_MORE_WARNINGS="$CFLAGS_MORE_WARNINGS -Werror"
 	fi
-	unset has_option
 
 	for option in -Wshadow -Wmissing-declarations -Wmissing-prototypes \
 		      -Wdeclaration-after-statement -Wformat-security \
@@ -31,8 +56,8 @@ if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 		      -Wpointer-arith -Winit-self \
 		      -Wmissing-include-dirs -Waggregate-return; do
 		dnl GCC 4.4 does not warn when checking for -Wno-* flags (https://gcc.gnu.org/wiki/FAQ#wnowarning)
-		CFLAGS="$CFLAGS_MORE_WARNINGS $CFLAGS_EXTRA $(printf '%s' "$option" | sed 's/^-Wno-/-W/')  $CFLAGS_SAVED"
-		AC_MSG_CHECKING([whether gcc understands $option])
+		CFLAGS="$CFLAGS_MORE_WARNINGS $(printf '%s' "$option" | sed 's/^-Wno-/-W/')  $CFLAGS_SAVED"
+		AC_MSG_CHECKING([whether compiler understands $option])
 		AC_TRY_COMPILE([], [],
 			has_option=yes,
 			has_option=no,)
@@ -43,12 +68,35 @@ if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 		unset has_option
 	done
 	unset option
-	unset CFLAGS_EXTRA
-	if test "x$set_more_warnings" = xerror; then
-		CFLAGS_MORE_WARNINGS="$CFLAGS_MORE_WARNINGS -Werror"
-	fi
-	CFLAGS="$CFLAGS_MORE_WARNINGS $CFLAGS_SAVED"
+
+	CFLAGS="$CFLAGS_SAVED"
 	unset CFLAGS_SAVED
+
+	dnl Disable warnings triggered by known compiler problems
+
+	dnl https://bugzilla.gnome.org/show_bug.cgi?id=745821
+	NM_COMPILER_WARNING([unknown-attributes], [#include <glib.h>])
+
+	dnl https://llvm.org/bugs/show_bug.cgi?id=21614
+	NM_COMPILER_WARNING([array-bounds],
+		[#include <string.h>]
+		[void f () { strcmp ("something", "0"); }]
+	)
+
+	dnl https://llvm.org/bugs/show_bug.cgi?id=22949
+	NM_COMPILER_WARNING([parentheses-equality],
+		[#include <sys/wait.h>]
+		[void f () { if (WIFCONTINUED(0)) return; }]
+	)
+
+	dnl systemd-dhcp's log_internal macro and our handle_warn are sometimes
+	dnl used in void context,u sometimes in int. Makes clang unhappy.
+	NM_COMPILER_WARNING([unused-value],
+		[#define yolo ({ (666 + 666); })]
+		[int f () { int i = yolo; yolo; return i; }]
+	)
+
+	CFLAGS="$CFLAGS_MORE_WARNINGS $CFLAGS"
 else
 	AC_MSG_RESULT(no)
 fi
-- 
cgit v1.2.1