1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
|
version_header = configure_file(
input: 'tracker-version-generated.h.meson.in',
output: 'tracker-version-generated.h',
configuration: conf)
enum_types = gnome.mkenums('tracker-sparql-enum-types',
sources: ['tracker-notifier.h', 'tracker-connection.h'],
c_template: 'tracker-sparql-enum-types.c.template',
h_template: 'tracker-sparql-enum-types.h.template',
install_dir: join_paths(get_option('prefix'), get_option('includedir'), 'tracker-@0@'.format(tracker_api_version), 'libtracker-sparql'),
install_header: true,
)
tracker_sparql_vapi = files('tracker-sparql.vapi')
tracker_sparql_vapi_dep = meson.get_compiler('vala').find_library('tracker-sparql', dirs: meson.current_source_dir())
libtracker_sparql_c_sources = files(
'tracker-batch.c',
'tracker-connection.c',
'tracker-cursor.c',
'tracker-endpoint.c',
'tracker-endpoint-dbus.c',
'tracker-error.c',
'tracker-namespace-manager.c',
'tracker-notifier.c',
'tracker-resource.c',
'tracker-statement.c',
'tracker-serializer.c',
'tracker-serializer-json.c',
'tracker-serializer-xml.c',
'tracker-uri.c',
'tracker-utils.c',
'tracker-version.c',
)
libtracker_sparql_c_public_headers = files(
'tracker-batch.h',
'tracker-connection.h',
'tracker-cursor.h',
'tracker-endpoint.h',
'tracker-endpoint-dbus.h',
'tracker-endpoint-http.h',
'tracker-error.h',
'tracker-namespace-manager.h',
'tracker-notifier.h',
'tracker-ontologies.h',
'tracker-resource.h',
'tracker-statement.h',
'tracker-utils.h',
'tracker-version.h',
)
libtracker_sparql_intermediate = static_library('tracker-sparql-intermediate',
enum_types,
libtracker_sparql_c_sources,
dependencies: [tracker_common_dep, json_glib, libxml2],
gnu_symbol_visibility: 'hidden',
)
sparqlinc = [include_directories('.'), meson.current_build_dir()]
tracker_sparql_intermediate_dep = declare_dependency(
link_with: [libtracker_sparql_intermediate],
include_directories: [srcinc, include_directories('.')],
dependencies: [ tracker_sparql_vapi_dep, tracker_data_dep ],
sources: enum_types[1],
)
install_headers(
libtracker_sparql_c_public_headers,
'tracker-ontologies.h',
'tracker-sparql.h',
version_header,
subdir: 'tracker-@0@/libtracker-sparql'.format(tracker_api_version))
install_data(
tracker_sparql_vapi,
rename: ['tracker-sparql-' + tracker_api_version + '.vapi'],
install_dir: vapi_dir,
)
install_data(
'tracker-sparql.deps',
rename: ['tracker-sparql-' + tracker_api_version + '.deps'],
install_dir: vapi_dir,
)
subdir('bus')
subdir('direct')
tracker_remote_dependencies = [json_glib, libxml2]
remote_sources = [
'tracker-endpoint-http.c',
'remote/tracker-json-cursor.vala',
'remote/tracker-xml-cursor.vala',
'remote/tracker-remote.vala',
]
if libsoup2.found()
libtracker_remote_soup2 = shared_module('tracker-remote-soup2', remote_sources,
dependencies: tracker_remote_dependencies + [tracker_common_dep, tracker_sparql_intermediate_dep, libsoup2],
c_args: tracker_c_args + [
'-include', 'config.h',
'-include', 'libtracker-sparql/tracker-private.h',
],
vala_args: [
'--debug',
'--pkg', 'posix',
# FIXME: Meson has code to add --target-glib automatically, but it
# doesn't seem to work here.
'--target-glib', glib_required,
'--define=SOUP2',
],
install: true,
install_dir: tracker_internal_libs_dir,
)
endif
if libsoup3.found()
libtracker_remote_soup3 = shared_module('tracker-remote-soup3', remote_sources,
dependencies: tracker_remote_dependencies + [tracker_common_dep, tracker_sparql_intermediate_dep, libsoup3],
c_args: tracker_c_args + [
'-include', 'config.h',
'-include', 'libtracker-sparql/tracker-private.h',
],
vala_args: [
'--debug',
'--pkg', 'posix',
# FIXME: Meson has code to add --target-glib automatically, but it
# doesn't seem to work here.
'--target-glib', glib_required,
],
install: true,
install_dir: tracker_internal_libs_dir,
)
endif
libtracker_sparql = library('tracker-sparql-' + tracker_api_version,
'../libtracker-common/libtracker-common.vapi',
'../libtracker-data/libtracker-data.vapi',
'direct/tracker-direct.vapi',
'tracker-backend.vala',
'tracker-remote-module.c',
tracker_gresources,
gnu_symbol_visibility: 'hidden',
soversion: soversion,
version: libversion,
install: true,
install_rpath: tracker_internal_libs_dir,
c_args: [
'-include', 'libtracker-sparql/tracker-private.h',
'-DPRIVATE_LIBDIR="@0@"'.format(tracker_internal_libs_dir),
'-DBUILD_LIBDIR="@0@"'.format(meson.current_build_dir()),
'-DBUILDROOT="@0@"'.format(meson.project_build_root()),
],
link_whole: [libtracker_sparql_intermediate],
dependencies: [tracker_common_dep, tracker_sparql_bus_dep, tracker_sparql_direct_dep, tracker_sparql_vapi_dep, gmodule, libdl],
)
tracker_sparql_dep = declare_dependency(
link_with: libtracker_sparql,
include_directories: srcinc,
dependencies: [glib, gio],
)
pkg.generate(libtracker_sparql,
description: 'Tracker : A SPARQL triple store library',
requires: [glib, gio, gobject],
subdirs: [
'tracker-' + tracker_api_version,
'tracker-' + tracker_api_version / 'libtracker-sparql',
],
variables: [
'exec_prefix=${prefix}',
'libexecdir=${prefix}' / get_option('libexecdir'),
'datadir=${prefix}' / get_option('datadir'),
'tracker_datadir=${datadir}' / tracker_versioned_name,
'ontologies_dir=' + tracker_ontologies_dir,
],
)
if get_option('introspection').enabled()
tracker_sparql_gir = gnome.generate_gir(libtracker_sparql,
sources: libtracker_sparql_c_sources + libtracker_sparql_c_public_headers,
nsversion: tracker_api_version,
namespace: 'Tracker',
identifier_prefix: 'Tracker',
symbol_prefix: 'tracker',
includes : ['GLib-2.0', 'GObject-2.0', 'Gio-2.0' ],
link_with: libtracker_sparql,
install: true,
extra_args: [
'--c-include',
'libtracker-sparql/tracker-sparql.h',
'-DTRACKER_COMPILATION',
],
export_packages: 'tracker-sparql-3.0')
endif
tracker_sparql_uninstalled_dir = meson.current_build_dir()
|
