From 7599e817ca9e12244449ca2fad855b96f6c8b817 Mon Sep 17 00:00:00 2001
From: Bruno Haible <bruno@clisp.org>
Date: Sat, 7 Jul 2007 21:38:16 +0000
Subject: Work around MacOS X wcwidth(0x0301) bug.

---
 m4/wcwidth.m4 | 40 +++++++++++++++++++++++++++++++++++++++-
 1 file changed, 39 insertions(+), 1 deletion(-)

(limited to 'm4/wcwidth.m4')

diff --git a/m4/wcwidth.m4 b/m4/wcwidth.m4
index b6cedc2430..a260998a8b 100644
--- a/m4/wcwidth.m4
+++ b/m4/wcwidth.m4
@@ -1,4 +1,4 @@
-# wcwidth.m4 serial 10
+# wcwidth.m4 serial 11
 dnl Copyright (C) 2006, 2007 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -35,6 +35,44 @@ AC_DEFUN([gl_FUNC_WCWIDTH],
 
   if test $ac_cv_func_wcwidth = no; then
     REPLACE_WCWIDTH=1
+  else
+    dnl On MacOS X 10.3, wcwidth(0x0301) (COMBINING ACUTE ACCENT) returns 1.
+    dnl This leads to bugs in 'ls' (coreutils).
+    AC_CACHE_CHECK([whether wcwidth works reasonably in UTF-8 locales],
+      [gl_cv_func_wcwidth_works],
+      [
+        AC_TRY_RUN([
+#include <locale.h>
+/* AIX 3.2.5 declares wcwidth in <string.h>. */
+#include <string.h>
+/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
+   <wchar.h>.
+   BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
+   before <wchar.h>.  */
+#include <stddef.h>
+#include <stdio.h>
+#include <time.h>
+#include <wchar.h>
+#if !HAVE_DECL_WCWIDTH
+extern
+# ifdef __cplusplus
+"C"
+# endif
+int wcwidth (int);
+#endif
+int main ()
+{
+  if (setlocale (LC_ALL, "fr_FR.UTF-8") != NULL)
+    if (wcwidth (0x0301) > 0)
+      return 1;
+  return 0;
+}], [gl_cv_func_wcwidth_works=yes], [gl_cv_func_wcwidth_works=no],
+          [gl_cv_func_wcwidth_works="guessing no"])
+      ])
+    case "$gl_cv_func_wcwidth_works" in
+      *yes) ;;
+      *no) REPLACE_WCWIDTH=1 ;;
+    esac
   fi
   if test $REPLACE_WCWIDTH = 1; then
     AC_LIBOBJ([wcwidth])
-- 
cgit v1.2.1