From 171d2a5f80f3d0dc720a291c349486944fd35243 Mon Sep 17 00:00:00 2001
From: Bruno Haible <bruno@clisp.org>
Date: Fri, 24 Mar 2023 11:55:38 +0100
Subject: printf-gnu: New module.

* m4/printf-posix.m4: Renamed from m4/printf-posix-rpl.m4.
(gl_FUNC_PRINTF_IS_POSIX): New macro.
(gl_FUNC_PRINTF_POSIX): Require it. Don't require
gl_FUNC_VFPRINTF_POSIX. Invoke gl_PREREQ_VASNPRINTF_WITH_POSIX_EXTRAS
and gl_REPLACE_VASNPRINTF.
* m4/printf-gnu.m4: New file, based on m4/fprintf-posix.m4.
* modules/printf-posix (Files): Update.
* modules/printf-gnu: New file, based on modules/vasnprintf-gnu.
* doc/posix-functions/printf.texi: Mention the new module.
---
 m4/printf-gnu.m4       | 25 +++++++++++++++++++++++++
 m4/printf-posix-rpl.m4 | 26 --------------------------
 m4/printf-posix.m4     | 36 ++++++++++++++++++++++++++++++++++++
 3 files changed, 61 insertions(+), 26 deletions(-)
 create mode 100644 m4/printf-gnu.m4
 delete mode 100644 m4/printf-posix-rpl.m4
 create mode 100644 m4/printf-posix.m4

(limited to 'm4')

diff --git a/m4/printf-gnu.m4 b/m4/printf-gnu.m4
new file mode 100644
index 0000000000..4d8f3c70ff
--- /dev/null
+++ b/m4/printf-gnu.m4
@@ -0,0 +1,25 @@
+# printf-gnu.m4 serial 1
+dnl Copyright (C) 2023 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([gl_FUNC_PRINTF_GNU],
+[
+  AC_REQUIRE([gl_FUNC_PRINTF_IS_POSIX])
+  AC_REQUIRE([gl_PRINTF_DIRECTIVE_UPPERCASE_B])
+  gl_cv_func_printf_gnu=no
+  if test $gl_cv_func_printf_posix = yes; then
+    case "$gl_cv_func_printf_directive_uppercase_b" in
+      *yes)
+        # printf is already POSIX compliant and GNU compatible.
+        gl_cv_func_printf_gnu=yes
+        ;;
+    esac
+  fi
+  if test $gl_cv_func_printf_gnu = no; then
+    gl_PREREQ_VASNPRINTF_WITH_GNU_EXTRAS
+    gl_REPLACE_VASNPRINTF
+    gl_REPLACE_PRINTF
+  fi
+])
diff --git a/m4/printf-posix-rpl.m4 b/m4/printf-posix-rpl.m4
deleted file mode 100644
index 36156d4350..0000000000
--- a/m4/printf-posix-rpl.m4
+++ /dev/null
@@ -1,26 +0,0 @@
-# printf-posix-rpl.m4 serial 4
-dnl Copyright (C) 2007-2023 Free Software Foundation, Inc.
-dnl This file is free software; the Free Software Foundation
-dnl gives unlimited permission to copy and/or distribute it,
-dnl with or without modifications, as long as this notice is preserved.
-
-AC_DEFUN([gl_FUNC_PRINTF_POSIX],
-[
-  AC_REQUIRE([gl_FUNC_VFPRINTF_POSIX])
-  if test $gl_cv_func_vfprintf_posix = no; then
-    gl_REPLACE_PRINTF
-  fi
-])
-
-AC_DEFUN([gl_REPLACE_PRINTF],
-[
-  AC_REQUIRE([gl_STDIO_H_DEFAULTS])
-  AC_REQUIRE([gl_ASM_SYMBOL_PREFIX])
-  AC_LIBOBJ([printf])
-  REPLACE_PRINTF=1
-  AC_DEFINE([REPLACE_PRINTF_POSIX], [1],
-    [Define if printf is overridden by a POSIX compliant gnulib implementation.])
-  gl_PREREQ_PRINTF
-])
-
-AC_DEFUN([gl_PREREQ_PRINTF], [:])
diff --git a/m4/printf-posix.m4 b/m4/printf-posix.m4
new file mode 100644
index 0000000000..9aebf4002d
--- /dev/null
+++ b/m4/printf-posix.m4
@@ -0,0 +1,36 @@
+# printf-posix.m4 serial 5
+dnl Copyright (C) 2007-2023 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([gl_FUNC_PRINTF_POSIX],
+[
+  AC_REQUIRE([gl_FUNC_PRINTF_IS_POSIX])
+  if test $gl_cv_func_printf_posix = no; then
+    gl_PREREQ_VASNPRINTF_WITH_POSIX_EXTRAS
+    gl_REPLACE_VASNPRINTF
+    gl_REPLACE_PRINTF
+  fi
+])
+
+dnl Test whether printf is POSIX compliant.
+dnl Result is gl_cv_func_printf_posix.
+AC_DEFUN([gl_FUNC_PRINTF_IS_POSIX],
+[
+  AC_REQUIRE([gl_FUNC_VFPRINTF_IS_POSIX])
+  gl_cv_func_printf_posix="$gl_cv_func_vfprintf_posix"
+])
+
+AC_DEFUN([gl_REPLACE_PRINTF],
+[
+  AC_REQUIRE([gl_STDIO_H_DEFAULTS])
+  AC_REQUIRE([gl_ASM_SYMBOL_PREFIX])
+  AC_LIBOBJ([printf])
+  REPLACE_PRINTF=1
+  AC_DEFINE([REPLACE_PRINTF_POSIX], [1],
+    [Define if printf is overridden by a POSIX compliant gnulib implementation.])
+  gl_PREREQ_PRINTF
+])
+
+AC_DEFUN([gl_PREREQ_PRINTF], [:])
-- 
cgit v1.2.1