dnl Process this file with autoconf to produce a configure script.
AC_INIT()
dnl AC_CONFIG_HEADER(config.h)

AC_PREFIX_DEFAULT(/usr/local)

AC_CANONICAL_SYSTEM
AC_DEFINE_UNQUOTED(T_CPU, "$target_cpu")
AC_DEFINE_UNQUOTED(T_VENDOR, "$target_vendor")
AC_DEFINE_UNQUOTED(T_OS, "$target_os")

GNUTLS_MAJOR_VERSION=0
GNUTLS_MINOR_VERSION=0
GNUTLS_MICRO_VERSION=6
GNUTLS_VERSION=$GNUTLS_MAJOR_VERSION.$GNUTLS_MINOR_VERSION.$GNUTLS_MICRO_VERSION


AM_INIT_AUTOMAKE(gnutls, $GNUTLS_VERSION)
AM_CONFIG_HEADER(config.h)


GNUTLS_MOST_RECENT_INTERFACE=$GNUTLS_MINOR_VERSION
GNUTLS_CURRENT_INTERFACE_IMPLEMENTATION_NUMBER=$GNUTLS_MICRO_VERSION
GNUTLS_OLDEST_INTERFACE=0

AM_PATH_GCRYPT(1.1.1a,,
 	AC_MSG_ERROR([[
***  
*** libgcrypt was not found. You may want to get it from
*** ftp://ftp.gnupg.org/pub/gcrypt/alpha/gnupg/
***
]]))

AC_SUBST(GNUTLS_MAJOR_VERSION)
AC_SUBST(GNUTLS_MINOR_VERSION)
AC_SUBST(GNUTLS_MICRO_VERSION)
AC_SUBST(GNUTLS_VERSION)

AC_SUBST(GNUTLS_MOST_RECENT_INTERFACE)
AC_SUBST(GNUTLS_CURRENT_INTERFACE_IMPLEMENTATION_NUMBER)
AC_SUBST(GNUTLS_OLDEST_INTERFACE)

LT_CURRENT=$GNUTLS_MOST_RECENT_INTERFACE
LT_REVISION=$GNUTLS_CURRENT_INTERFACE_IMPLEMENTATION_NUMBER
LT_AGE=`expr $GNUTLS_MOST_RECENT_INTERFACE - $GNUTLS_OLDEST_INTERFACE`
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

opt_maintainer_mode=no
AC_MSG_CHECKING([whether in maintanance mode])
AC_ARG_ENABLE(maintainer-mode,
[  --enable-maintainer-mode enable maintainer mode],
opt_maintainer_mode=$enableval)
AC_MSG_RESULT($opt_maintainer_mode)

opt_profiler_mode=no
AC_MSG_CHECKING([whether in profile mode])
AC_ARG_ENABLE(profile-mode,
[  --enable-profile-mode enable profiler (gcov/gprof)],
opt_profiler_mode=$enableval)
AC_MSG_RESULT($opt_profiler_mode)


AC_PROG_CC

AC_TYPE_SIZE_T

AC_C_CONST
AC_C_INLINE

dnl Checks for programs.
AC_PROG_INSTALL

dnl AC_PROG_MAKE_SET


AC_ARG_WITH( mcrypt, [  --with-mcrypt           enable mcrypt support],
 [  AC_CHECK_LIB(dl, dlopen)
  AC_CHECK_LIB(mcrypt, mcrypt_module_open,
  LIBS="${LIBS} -lmcrypt"
  AC_DEFINE(USE_MCRYPT),
  [
    AC_CHECK_LIB(dld, dld_init)
    AC_CHECK_LIB(ltdl, lt_dlinit)
    AC_CHECK_LIB(mcrypt, mcrypt_enc_get_key_size,
    LIBS="${LIBS} -lmcrypt"
    AC_DEFINE(USE_MCRYPT),
    AC_MSG_ERROR("You need libmcrypt 2.4.x or libmcrypt-nm to compile this program. http://mcrypt.hellug.gr"))
  ])
 ]

)

AC_ARG_WITH( mhash, [  --with-mhash            enable mhash support],
 [AC_CHECK_LIB(mhash, mhash_init, AC_DEFINE(USE_MHASH) 
LIBS="${LIBS} -lmhash")])

if test $ac_cv_prog_gcc != no; then

	if test $opt_profiler_mode = yes; then
	  CFLAGS="${CFLAGS} -O0 -fprofile-arcs -ftest-coverage -pg"
	else
	  CFLAGS="${CFLAGS} -O2 -ffast-math"
	fi
		
	if test $opt_maintainer_mode = yes; then
	  CFLAGS="${CFLAGS} -g -Wall -Wpointer-arith"
	fi
fi

AC_HEADER_STDC
AC_CHECK_HEADERS(unistd.h pwd.h locale.h strings.h stdarg.h)
AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h sys/wait.h sys/socket.h)
AC_CHECK_HEADERS(utime.h signal.h zlib.h errno.h)
AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
AC_CHECK_FUNCS(bzero signal sigaction memset fcntl fsync siglongjmp,,)
AC_CHECK_FUNCS(lstat stat umask utime memmove bcopy getpwuid waitpid,,)

AC_CHECK_LIB(z, compress,,AC_MSG_WARN("ZLIB was not found. You will not be able to use ZLIB compression."))

dnl Checks for libraries.
AC_C_BIGENDIAN
AC_TYPE_SIGNAL
AC_CHECK_SIZEOF(unsigned long long, 8)
AC_CHECK_SIZEOF(unsigned long int, 4)
AC_CHECK_SIZEOF(unsigned int, 4)
AC_CHECK_SIZEOF(unsigned short int, 2)
AC_CHECK_SIZEOF(unsigned char, 1)

AM_PROG_LIBTOOL

AC_OUTPUT([Makefile src/Makefile lib/Makefile doc/Makefile ])