From 4af7637012413209ce728ec377b265acbbaadc08 Mon Sep 17 00:00:00 2001
From: Nirbheek Chauhan <nirbheek@centricular.com>
Date: Tue, 28 Aug 2018 12:54:07 +0530
Subject: meson: Add build files for androidmedia and opensles

Note that androidmedia requires Android gstgl
---
 sys/androidmedia/meson.build | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 sys/androidmedia/meson.build

(limited to 'sys/androidmedia')

diff --git a/sys/androidmedia/meson.build b/sys/androidmedia/meson.build
new file mode 100644
index 000000000..a52cc0eb8
--- /dev/null
+++ b/sys/androidmedia/meson.build
@@ -0,0 +1,41 @@
+androidmedia_sources = [
+  'gstahcsrc.c',
+  'gstahssrc.c',
+  'gstamcaudiodec.c',
+  'gstamc.c',
+  'gstamcsurface.c',
+  'gstamcsurfacetexture.c',
+  'gstamcvideodec.c',
+  'gstamcvideoenc.c',
+  'gst-android-graphics-imageformat.c',
+  'gst-android-hardware-camera.c',
+  'gst-android-hardware-sensor.c',
+  'gstjniutils.c'
+]
+
+if host_system != 'android' or get_option('androidmedia').disabled()
+  subdir_done()
+endif
+
+if not gstgl_dep.found()
+  if get_option('androidmedia').enabled()
+    error('androidmedia plugin enabled but GL support was not detected')
+  endif
+  subdir_done()
+endif
+
+have_jni_h = cc.has_header('jni.h', required : false)
+if not have_jni_h and get_option('androidmedia').enabled()
+  error('androidmedia plugin enabled but jni.h not found')
+endif
+
+if have_jni_h
+  gstandroidmedia = library('gstandroidmedia',
+    androidmedia_sources,
+    c_args : gst_plugins_bad_args,
+    include_directories : [configinc],
+    dependencies : [gstgl_dep, gstpbutils_dep, gstaudio_dep, gstvideo_dep, gstphotography_dep],
+    install : true,
+    install_dir : plugins_install_dir)
+  pkgconfig.generate(gstandroidmedia, install_dir : plugins_pkgconfig_install_dir)
+endif
-- 
cgit v1.2.1