build: Port to meson build system

meson is a build system focused on speed an ease of use, which
helps speeding up the software development. This patch adds meson
support along autotools.

https://bugzilla.gnome.org/show_bug.cgi?id=786149

2 files changed, 59 insertions, 0 deletions

diff --git a/monitor/afc/Makefile.am b/monitor/afc/Makefile.am
index 48c7978f..2a1821db 100644
--- a/monitor/afc/Makefile.am
+++ b/monitor/afc/Makefile.am
@@ -55,6 +55,7 @@ CLEANFILES = \
 	$(NULL)
 
 EXTRA_DIST = \
+	meson.build \
 	$(service_in_files) \
 	$(systemd_user_in_files) \
 	$(remote_volume_monitors_DATA) \
diff --git a/monitor/afc/meson.build b/monitor/afc/meson.build
new file mode 100644
index 00000000..776341f0
--- /dev/null
+++ b/monitor/afc/meson.build
@@ -0,0 +1,58 @@
+afc_monitor = files('afc.monitor')
+
+install_data(
+  afc_monitor,
+  install_dir: gvfs_remote_volume_monitors_dir
+)
+
+service = gvfs_namespace + '.AfcVolumeMonitor.service'
+
+afc_service = configure_file(
+  input: service + '.in',
+  output: service,
+  install: true,
+  install_dir: gvfs_dbus_service_dir,
+  configuration: service_conf
+)
+
+if have_systemd_user_unit
+  service = 'gvfs-afc-volume-monitor.service'
+
+  configure_file(
+    input: service + '.in',
+    output: service,
+    install: true,
+    install_dir: systemd_user_dir,
+    configuration: service_conf
+  )
+endif
+
+sources = files(
+  'afcvolumemonitordaemon.c',
+  'afcvolume.c',
+  'afcvolumemonitor.c'
+)
+
+deps = glib_deps + [
+  libimobiledevice_dep,
+  libplist_dep,
+  libgvfscommon_dep,
+  libgvfsproxyvolumemonitordaemon_noin_dep
+]
+
+cflags = [
+  '-DG_LOG_DOMAIN="GVFS-AFC"',
+  '-DGIO_MODULE_DIR="@0@"'.format(gio_module_dir),
+  '-DGVFS_LOCALEDIR="@0@"'.format(gvfs_localedir)
+]
+
+executable(
+  'gvfs-afc-volume-monitor',
+  sources,
+  include_directories: top_inc,
+  dependencies: deps,
+  c_args: cflags,
+  install: true,
+  install_rpath: gvfs_rpath,
+  install_dir: gvfs_libexecdir
+)