1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
|
{
{-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
{-# OPTIONS -w -Wwarn #-}
-- The above warning supression flag is a temporary kludge.
-- While working on this module you are encouraged to remove it and fix
-- any warnings in the module. See
-- http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
-- for details
module Parser (parse) where
import Lexer (lex_tok)
import ParserM (Token(..), ParserM, run_parser, get_pos, show_pos,
happyError)
import Syntax
}
%name parsex
%expect 0
%tokentype { Token }
%monad { ParserM }
%lexer { lex_tok } { TEOF }
%token
'->' { TArrow }
'=>' { TDArrow }
'=' { TEquals }
',' { TComma }
'(' { TOpenParen }
')' { TCloseParen }
'(#' { TOpenParenHash }
'#)' { THashCloseParen }
'{' { TOpenBrace }
'}' { TCloseBrace }
'[' { TOpenBracket }
']' { TCloseBracket }
'<' { TOpenAngle }
'>' { TCloseAngle }
section { TSection }
primop { TPrimop }
pseudoop { TPseudoop }
primtype { TPrimtype }
primclass { TPrimclass }
with { TWith }
defaults { TDefaults }
true { TTrue }
false { TFalse }
dyadic { TDyadic }
monadic { TMonadic }
compare { TCompare }
genprimop { TGenPrimOp }
fixity { TFixity }
infix { TInfixN }
infixl { TInfixL }
infixr { TInfixR }
nothing { TNothing }
vector { TVector }
SCALAR { TSCALAR }
VECTOR { TVECTOR }
VECTUPLE { TVECTUPLE }
thats_all_folks { TThatsAllFolks }
lowerName { TLowerName $$ }
upperName { TUpperName $$ }
string { TString $$ }
integer { TInteger $$ }
noBraces { TNoBraces $$ }
%%
info :: { Info }
info : pDefaults pEntries thats_all_folks { Info $1 $2 }
pDefaults :: { [Option] }
pDefaults : defaults pOptions { $2 }
pOptions :: { [Option] }
pOptions : pOption pOptions { $1 : $2 }
| {- empty -} { [] }
pOption :: { Option }
pOption : lowerName '=' false { OptionFalse $1 }
| lowerName '=' true { OptionTrue $1 }
| lowerName '=' pStuffBetweenBraces { OptionString $1 $3 }
| lowerName '=' integer { OptionInteger $1 $3 }
| vector '=' pVectorTemplate { OptionVector $3 }
| fixity '=' pInfix { OptionFixity $3 }
pInfix :: { Maybe Fixity }
pInfix : infix integer { Just $ Fixity $2 InfixN }
| infixl integer { Just $ Fixity $2 InfixL }
| infixr integer { Just $ Fixity $2 InfixR }
| nothing { Nothing }
pEntries :: { [Entry] }
pEntries : pEntry pEntries { $1 : $2 }
| {- empty -} { [] }
pEntry :: { Entry }
pEntry : pPrimOpSpec { $1 }
| pPrimTypeSpec { $1 }
| pPrimClassSpec { $1 }
| pPseudoOpSpec { $1 }
| pSection { $1 }
pPrimOpSpec :: { Entry }
pPrimOpSpec : primop upperName string pCategory pType
pDesc pWithOptions
{ PrimOpSpec {
cons = $2,
name = $3,
cat = $4,
ty = $5,
desc = $6,
opts = $7
}
}
pPrimTypeSpec :: { Entry }
pPrimTypeSpec : primtype pType pDesc pWithOptions
{ PrimTypeSpec { ty = $2, desc = $3, opts = $4 } }
pPrimClassSpec :: { Entry }
pPrimClassSpec : primclass pType pDesc pWithOptions
{ PrimClassSpec { cls = $2, desc = $3, opts = $4 } }
pPseudoOpSpec :: { Entry }
pPseudoOpSpec : pseudoop string pType pDesc pWithOptions
{ PseudoOpSpec { name = $2, ty = $3, desc = $4, opts = $5 } }
pSection :: { Entry }
pSection : section string pDesc { Section { title = $2, desc = $3 } }
pWithOptions :: { [Option] }
pWithOptions : with pOptions { $2 }
| {- empty -} { [] }
pCategory :: { Category }
pCategory : dyadic { Dyadic }
| monadic { Monadic }
| compare { Compare }
| genprimop { GenPrimOp }
pDesc :: { String }
pDesc : pStuffBetweenBraces { $1 }
| {- empty -} { "" }
pStuffBetweenBraces :: { String }
pStuffBetweenBraces : '{' pInsides '}' { $2 }
pInsides :: { String }
pInsides : pInside pInsides { $1 ++ $2 }
| {- empty -} { "" }
pInside :: { String }
pInside : '{' pInsides '}' { "{" ++ $2 ++ "}" }
| noBraces { $1 }
pVectorTemplate :: { [(String, String, Int)] }
pVectorTemplate : '[' pVectors ']' { $2 }
pVectors :: { [(String, String, Int)] }
pVectors : pVector ',' pVectors { [$1] ++ $3 }
| pVector { [$1] }
| {- empty -} { [] }
pVector :: { (String, String, Int) }
pVector : '<' upperName ',' upperName ',' integer '>' { ($2, $4, $6) }
pType :: { Ty }
pType : paT '->' pType { TyF $1 $3 }
| paT '=>' pType { TyC $1 $3 }
| paT { $1 }
-- Atomic types
paT :: { Ty }
paT : pTycon ppTs { TyApp $1 $2 }
| pUnboxedTupleTy { $1 }
| '(' pType ')' { $2 }
| lowerName { TyVar $1 }
pUnboxedTupleTy :: { Ty }
pUnboxedTupleTy : '(#' pCommaTypes '#)' { TyUTup $2 }
pCommaTypes :: { [Ty] }
pCommaTypes : pType ',' pCommaTypes { $1 : $3 }
| pType { [$1] }
ppTs :: { [Ty] }
ppTs : ppT ppTs { $1 : $2 }
| {- empty -} { [] }
-- Primitive types
ppT :: { Ty }
ppT : lowerName { TyVar $1 }
| pTycon { TyApp $1 [] }
pTycon :: { TyCon }
pTycon : upperName { TyCon $1 }
| '(' ')' { TyCon "()" }
| SCALAR { SCALAR }
| VECTOR { VECTOR }
| VECTUPLE { VECTUPLE }
{
parse :: String -> Either String Info
parse = run_parser parsex
}
|
