build: Update to new autoconf constructs.

* configure.ac Replace AC_GNU_SOURCE to Use AC_USE_SYSTEM_EXTENSIONS.
Replace AC_HELP_STRING to AS_HELP_STRING.
* m4/estream.m4: Replace AC_TRY_LINK to AC_LINK_IFELSE.
* m4/gnupg-misc.m4: Replace AC_TRY_COMPILE to AC_COMPILE_IFELSE.
* m4/libtool.m4: Use AC_LANG_PUSH/AC_LANG_POP instead of
AC_LANG_SAVE/AC_LANG_RESTORE.
* m4/readline.m4: Replace AC_HELP_STRING to AS_HELP_STRING.
Fix quote for _combo.
* m4/threadlib.m4: Replace AC_HELP_STRING to AS_HELP_STRING.

Signed-off-by: NIIBE Yutaka <gniibe@fsij.org>

6 files changed, 31 insertions, 25 deletions

diff --git a/configure.ac b/configure.ac
index 0e486a5..4928c31 100644
--- a/configure.ac
+++ b/configure.ac
@@ -19,7 +19,7 @@
 
 # (Process this file with autoconf to produce a configure script.)
 # The following lines are used by ./autogen.sh.
-AC_PREREQ(2.59)
+AC_PREREQ([2.59])
 min_automake_version="1.14"
 
 # To build a release you need to create a tag with the version number
@@ -42,7 +42,7 @@ m4_define([mym4_version],      m4_argn(4, mym4_verslist))
 m4_define([mym4_revision],     m4_argn(7, mym4_verslist))
 m4_define([mym4_revision_dec], m4_argn(8, mym4_verslist))
 m4_esyscmd([echo ]mym4_version[>VERSION])
-AC_INIT([mym4_package],[mym4_version], [https://bugs.gnupg.org])
+AC_INIT([mym4_package],[mym4_version],[https://bugs.gnupg.org])
 # LT Version numbers, remember to change them just *before* a release.
 #   (Code changed:			REVISION++)
 #   (Interfaces added/removed/changed:	CURRENT++, REVISION=0)
@@ -80,7 +80,8 @@ AM_PROG_CC_C_O
 AC_PROG_CPP
 AC_PROG_AWK
 AC_CHECK_TOOL(AR, ar, :)
-AC_GNU_SOURCE
+AC_USE_SYSTEM_EXTENSIONS
+
 
 # Taken from mpfr-4.0.1, then modified for LDADD_FOR_TESTS_KLUDGE
 dnl Under Linux, make sure that the old dtags are used if LD_LIBRARY_PATH
@@ -444,7 +445,7 @@ case "${host}" in
         ;;
 esac
 AC_ARG_ENABLE([ld-version-script],
-              AC_HELP_STRING([--enable-ld-version-script],
+              AS_HELP_STRING([--enable-ld-version-script],
                              [enable/disable use of linker version script.
                               (default is system dependent)]),
               [have_ld_version_script=$enableval],
@@ -634,7 +635,7 @@ AC_DEFINE_UNQUOTED(HOST_TRIPLET_STRING, "$host", [The host triplet])
 #
 AC_MSG_CHECKING([whether to enable log_clock])
 AC_ARG_ENABLE(log_clock,
-              AC_HELP_STRING([--enable-log-clock],
+              AS_HELP_STRING([--enable-log-clock],
                              [enable log_clock timestamps]),
               enable_log_clock=$enableval, enable_log_clock=no)
 AC_MSG_RESULT($enable_log_clock)
@@ -649,7 +650,7 @@ fi
 build_gpgscm=no
 #AC_MSG_CHECKING([whether to build gpgscm])
 #AC_ARG_ENABLE(gpgscm,
-#              AC_HELP_STRING([--enable-gpgscm],
+#              AS_HELP_STRING([--enable-gpgscm],
 #                             [build the gpgscm tool]),
 #              build_gpgscm=$enableval, build_gpgscm=no)
 #AC_MSG_RESULT($build_gpgscm)
@@ -661,7 +662,7 @@ AM_CONDITIONAL([BUILD_GPGSCM], [test "x$build_gpgscm" != xno])
 # misbehaving autoconf tests in case the user supplied -Werror.
 #
 AC_ARG_ENABLE(werror,
-   AC_HELP_STRING([--enable-werror],
+   AS_HELP_STRING([--enable-werror],
                   [append -Werror to CFLAGS]),
                   [if test $enableval = yes ; then
                       CFLAGS="$CFLAGS -Werror"
@@ -685,7 +686,7 @@ AC_SUBST(BUILD_VERSION)
 AC_SUBST(BUILD_FILEVERSION)
 
 AC_ARG_ENABLE([build-timestamp],
-  AC_HELP_STRING([--enable-build-timestamp],
+  AS_HELP_STRING([--enable-build-timestamp],
                  [set an explicit build timestamp for reproducibility.
                   (default is the current time in ISO-8601 format)]),
      [if test "$enableval" = "yes"; then
@@ -700,18 +701,18 @@ AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
 
 
 
-AC_ARG_ENABLE(languages, AC_HELP_STRING([--disable-languages],
+AC_ARG_ENABLE(languages, AS_HELP_STRING([--disable-languages],
                         [do not build support for other languages than C]))
 AM_CONDITIONAL([LANGUAGES_SOME], [test "x$enable_languages" != xno])
 
 build_doc=yes
-AC_ARG_ENABLE([doc], AC_HELP_STRING([--disable-doc],
+AC_ARG_ENABLE([doc], AS_HELP_STRING([--disable-doc],
                                     [do not build the documentation]),
                      build_doc=$enableval, build_doc=yes)
 AM_CONDITIONAL([BUILD_DOC], [test "x$build_doc" != xno])
 
 build_tests=yes
-AC_ARG_ENABLE([tests], AC_HELP_STRING([--disable-tests],
+AC_ARG_ENABLE([tests], AS_HELP_STRING([--disable-tests],
                                     [do not build the tests]),
                      build_tests=$enableval, build_tests=yes)
 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != xno])
diff --git a/m4/estream.m4 b/m4/estream.m4
index 548fe08..deb972d 100644
--- a/m4/estream.m4
+++ b/m4/estream.m4
@@ -26,8 +26,9 @@ AC_DEFUN([estream_PRINTF_INIT],
   AC_CHECK_SIZEOF([void *])
   AC_CACHE_CHECK([for nl_langinfo and THOUSEP],
                   estream_cv_langinfo_thousep,
-      [AC_TRY_LINK([#include <langinfo.h>],
-        [char* cs = nl_langinfo(THOUSEP); return !cs;],
+      [AC_LINK_IFELSE(
+        [AC_LANG_PROGRAM([[#include <langinfo.h>]],
+          [[char* cs = nl_langinfo(THOUSEP); return !cs;]])],
         estream_cv_langinfo_thousep=yes,
         estream_cv_langinfo_thousep=no)
       ])
diff --git a/m4/gnupg-misc.m4 b/m4/gnupg-misc.m4
index 12f86d8..c707b35 100644
--- a/m4/gnupg-misc.m4
+++ b/m4/gnupg-misc.m4
@@ -16,7 +16,7 @@ dnl of the usual 2.
 AC_DEFUN([GNUPG_FUNC_MKDIR_TAKES_ONE_ARG],
 [AC_CHECK_HEADERS(sys/stat.h unistd.h direct.h)
 AC_CACHE_CHECK([if mkdir takes one argument], gnupg_cv_mkdir_takes_one_arg,
-[AC_TRY_COMPILE([
+[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 #include <sys/types.h>
 #ifdef HAVE_SYS_STAT_H
 # include <sys/stat.h>
@@ -26,7 +26,7 @@ AC_CACHE_CHECK([if mkdir takes one argument], gnupg_cv_mkdir_takes_one_arg,
 #endif
 #ifdef HAVE_DIRECT_H
 # include <direct.h>
-#endif], [mkdir ("foo", 0);],
+#endif]], [[mkdir ("foo", 0);]])],
         gnupg_cv_mkdir_takes_one_arg=no, gnupg_cv_mkdir_takes_one_arg=yes)])
 if test $gnupg_cv_mkdir_takes_one_arg = yes ; then
   AC_DEFINE(MKDIR_TAKES_ONE_ARG,1,
diff --git a/m4/libtool.m4 b/m4/libtool.m4
index 0cd84af..8795701 100644
--- a/m4/libtool.m4
+++ b/m4/libtool.m4
@@ -7474,7 +7474,7 @@ AC_LANG_POP
 # to write the compiler configuration to `libtool'.
 m4_defun([_LT_LANG_GCJ_CONFIG],
 [AC_REQUIRE([LT_PROG_GCJ])dnl
-AC_LANG_SAVE
+AC_LANG_PUSH([Java])
 
 # Source file extension for Java test sources.
 ac_ext=java
@@ -7530,7 +7530,7 @@ if test -n "$compiler"; then
   _LT_CONFIG($1)
 fi
 
-AC_LANG_RESTORE
+AC_LANG_POP
 
 GCC=$lt_save_GCC
 CC=$lt_save_CC
@@ -7545,7 +7545,7 @@ CFLAGS=$lt_save_CFLAGS
 # to write the compiler configuration to `libtool'.
 m4_defun([_LT_LANG_GO_CONFIG],
 [AC_REQUIRE([LT_PROG_GO])dnl
-AC_LANG_SAVE
+AC_LANG_PUSH([Go])
 
 # Source file extension for Go test sources.
 ac_ext=go
@@ -7601,7 +7601,7 @@ if test -n "$compiler"; then
   _LT_CONFIG($1)
 fi
 
-AC_LANG_RESTORE
+AC_LANG_POP
 
 GCC=$lt_save_GCC
 CC=$lt_save_CC
@@ -7616,7 +7616,9 @@ CFLAGS=$lt_save_CFLAGS
 # to write the compiler configuration to `libtool'.
 m4_defun([_LT_LANG_RC_CONFIG],
 [AC_REQUIRE([LT_PROG_RC])dnl
-AC_LANG_SAVE
+
+dnl Here, something like AC_LANG_PUSH([RC]) is expected.
+dnl But Resource Compiler is not supported as a language by autoconf
 
 # Source file extension for RC test sources.
 ac_ext=rc
@@ -7655,8 +7657,10 @@ if test -n "$compiler"; then
   _LT_CONFIG($1)
 fi
 
+dnl Here, AC_LANG_POP is expected.
 GCC=$lt_save_GCC
-AC_LANG_RESTORE
+dnl Back to C
+AC_LANG([C])
 CC=$lt_save_CC
 CFLAGS=$lt_save_CFLAGS
 ])# _LT_LANG_RC_CONFIG
diff --git a/m4/readline.m4 b/m4/readline.m4
index 0c9619d..2ffbc7b 100644
--- a/m4/readline.m4
+++ b/m4/readline.m4
@@ -14,7 +14,7 @@ dnl found, and sets @LIBREADLINE@ to the necessary libraries.
 AC_DEFUN([GNUPG_CHECK_READLINE],
 [
   AC_ARG_WITH(readline,
-     AC_HELP_STRING([--with-readline=DIR],
+     AS_HELP_STRING([--with-readline=DIR],
 	[look for the readline library in DIR]),
      [_do_readline=$withval],[_do_readline=yes])
 
@@ -30,7 +30,7 @@ AC_DEFUN([GNUPG_CHECK_READLINE],
         _combo="-lreadline${_termcap:+ $_termcap}"
         LIBS="$LIBS $_combo"
 
-        AC_MSG_CHECKING([whether readline via \"$_combo\" is present and sane])
+        AC_MSG_CHECKING([whether readline via "$_combo" is present and sane])
 
         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 #include <stdio.h>
diff --git a/m4/threadlib.m4 b/m4/threadlib.m4
index 32c2ea5..b486395 100644
--- a/m4/threadlib.m4
+++ b/m4/threadlib.m4
@@ -54,8 +54,8 @@ AC_DEFUN([gl_THREADLIB_EARLY_BODY],
     [m4_divert_text([DEFAULTS], [gl_use_threads_default=no])],
     [m4_divert_text([DEFAULTS], [gl_use_threads_default=])])
   AC_ARG_ENABLE([threads],
-AC_HELP_STRING([--enable-threads={posix|solaris|windows}], [specify multithreading API])m4_ifdef([gl_THREADLIB_DEFAULT_NO], [], [
-AC_HELP_STRING([--disable-threads], [build without multithread safety])]),
+AS_HELP_STRING([--enable-threads={posix|solaris|windows}], [specify multithreading API])m4_ifdef([gl_THREADLIB_DEFAULT_NO], [], [
+AS_HELP_STRING([--disable-threads], [build without multithread safety])]),
     [gl_use_threads=$enableval],
     [if test -n "$gl_use_threads_default"; then
        gl_use_threads="$gl_use_threads_default"