Dtrace on Solaris:

fix excessive relinking that results from rerunning
dtrace -G second time on the objects that come into 
static library. 
The reason for relinking is that dtrace -G changes 
timestamp for the object file, which in turn results
in re-archiving the mysys on next time make runs, 
which causes relinking of the whole mysql, because
everything depends on mysys.

The fix is to copy objects into temp before running 
dtrace -G in mysqld pre-build step. This way dtrace 
does not affect the object timestamp.

1 files changed, 54 insertions, 6 deletions

diff --git a/cmake/dtrace_prelink.cmake b/cmake/dtrace_prelink.cmake
index ae475a90921..37e560cdaf8 100644
--- a/cmake/dtrace_prelink.cmake
+++ b/cmake/dtrace_prelink.cmake
@@ -19,17 +19,65 @@
 
 # Do not follow symlinks in GLOB_RECURSE
 CMAKE_POLICY(SET CMP0009 NEW)
+FILE(REMOVE ${OUTFILE})
+
+MACRO(CONVERT_TO_RELATIVE_PATHS files rel_paths)
+  GET_FILENAME_COMPONENT(abs_dir . ABSOLUTE)
+  SET(${rel_paths})
+  FOREACH(file ${files})
+    FILE(RELATIVE_PATH rel  ${abs_dir} ${file})
+    LIST(APPEND ${rel_paths} ${rel})
+  ENDFOREACH()
+ENDMACRO()
+
+IF(TYPE STREQUAL "MERGE")
+  # Rerun dtrace on objects that are already in static libraries.
+  # Object paths are stored in text files named 'dtrace_objects'
+  # in the input directores. We have to copy the objects into temp.
+  # directory, as running dtrace -G on original files will change
+  # timestamps and cause rebuilds or the libraries / excessive 
+  # relink
+  FILE(REMOVE_RECURSE dtrace_objects_merge)
+  MAKE_DIRECTORY(dtrace_objects_merge)
+
+  FOREACH(dir ${DIRS})
+    FILE(STRINGS ${dir}/dtrace_objects  OBJS)
+    FOREACH(obj ${OBJS})
+      IF(obj)
+        EXECUTE_PROCESS(COMMAND cp ${obj} dtrace_objects_merge)
+      ENDIF()
+    ENDFOREACH()
+  ENDFOREACH()
+  FILE(GLOB_RECURSE OBJECTS dtrace_objects_merge/*.o)
+  CONVERT_TO_RELATIVE_PATHS("${OBJECTS}" REL_OBJECTS)
+  EXECUTE_PROCESS(
+     COMMAND ${DTRACE} ${DTRACE_FLAGS} -o ${OUTFILE}  -G -s ${DFILE}  ${REL_OBJECTS}
+  )
+  RETURN()
+ENDIF()
+
 FOREACH(dir ${DIRS})
   FILE(GLOB_RECURSE OBJECTS  ${dir}/*.o)
-  #  Use relative paths to generate shorter command line
-  GET_FILENAME_COMPONENT(CURRENT_ABS_DIR . ABSOLUTE)
-  FOREACH(OBJ ${OBJECTS})
-    FILE(RELATIVE_PATH REL  ${CURRENT_ABS_DIR} ${OBJ})
-    LIST(APPEND REL_OBJECTS  ${REL})
-  ENDFOREACH()
+  CONVERT_TO_RELATIVE_PATHS("${OBJECTS}" REL)
+  LIST(APPEND REL_OBJECTS ${REL})
 ENDFOREACH()
 
+FILE(WRITE  dtrace_timestamp "")
 EXECUTE_PROCESS(
  COMMAND ${DTRACE} ${DTRACE_FLAGS} -o ${OUTFILE}  -G -s ${DFILE}  ${REL_OBJECTS}
 )
 
+# Save objects that contain dtrace probes in a file.
+# This file is used when script is called with -DTYPE=MERGE
+# to dtrace from static libs.
+# To find objects with probes, look at the timestamp, it was updated
+# by dtrace -G run
+IF(TYPE MATCHES "STATIC")
+  FILE(WRITE dtrace_objects "")
+  FOREACH(obj  ${REL_OBJECTS})
+    IF(${obj} IS_NEWER_THAN dtrace_timestamp)
+      GET_FILENAME_COMPONENT(obj_absolute_path ${obj} ABSOLUTE)
+      FILE(APPEND dtrace_objects "${obj_absolute_path}\n" )
+    ENDIF()
+  ENDFOREACH()
+ENDIF()