From 3c920b658404007e1be19814e6709f2f0982a4a0 Mon Sep 17 00:00:00 2001
From: enge <enge@211d60ee-9f03-0410-a15a-8952a2c7a4e4>
Date: Tue, 30 Aug 2011 13:49:32 +0000
Subject: m4/valgrind-tests.m4: imported original gnulib macro configure.ac,
 mpc.texi: updated accordingly

git-svn-id: svn://scm.gforge.inria.fr/svn/mpc/trunk@1040 211d60ee-9f03-0410-a15a-8952a2c7a4e4
---
 m4/valgrind-tests.m4 | 35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)
 create mode 100644 m4/valgrind-tests.m4

(limited to 'm4')

diff --git a/m4/valgrind-tests.m4 b/m4/valgrind-tests.m4
new file mode 100644
index 0000000..422f402
--- /dev/null
+++ b/m4/valgrind-tests.m4
@@ -0,0 +1,35 @@
+# valgrind-tests.m4 serial 2
+dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson
+
+# gl_VALGRIND_TESTS()
+# -------------------
+# Check if valgrind is available, and set VALGRIND to it if available.
+AC_DEFUN([gl_VALGRIND_TESTS],
+[
+  AC_ARG_ENABLE(valgrind-tests,
+    AS_HELP_STRING([--enable-valgrind-tests],
+                   [run self tests under valgrind]),
+    [opt_valgrind_tests=$enableval], [opt_valgrind_tests=yes])
+
+  # Run self-tests under valgrind?
+  if test "$opt_valgrind_tests" = "yes" && test "$cross_compiling" = no; then
+    AC_CHECK_PROGS(VALGRIND, valgrind)
+  fi
+
+  if test -n "$VALGRIND" && $VALGRIND -q true > /dev/null 2>&1; then
+    opt_valgrind_tests=yes
+    VALGRIND="$VALGRIND -q --error-exitcode=1 --leak-check=full"
+  else
+    opt_valgrind_tests=no
+    VALGRIND=
+  fi
+
+  AC_MSG_CHECKING([whether self tests are run under valgrind])
+  AC_MSG_RESULT($opt_valgrind_tests)
+])
+
-- 
cgit v1.2.1