don't define GNOMELOCALEDIR in INCLUDES.NAUTILUS_2_9_2

2004-01-11  James Henstridge  <james@jamesh.id.au>

	* test/Makefile.am: don't define GNOMELOCALEDIR in INCLUDES.

	* src/Makefile.am: remove desktop and server files on clean.
	Don't include GNOMELOCALEDIR in INCLUDES, since it is now defined
	in config.h.

	* Makefile.am: remove desktop files on clean, and intltool files
	on distclean.

	* acconfig.h: remove, since it isn't needed anymore.

	* configure.in: remove some macro calls not needed with newer
	automakes, and use newer versions of some macros.

	* autogen.sh: require Automake >= 1.7.

1 files changed, 75 insertions, 77 deletions

diff --git a/configure.in b/configure.in
index 6f092ba47..ade4392fc 100644
--- a/configure.in
+++ b/configure.in
@@ -1,49 +1,54 @@
-AC_INIT(src)
+AC_PREREQ(2.54)
 
 dnl ===========================================================================
 
-ART_REQUIRED=2.3.10
-BONOBO_ACTIVATION_REQUIRED=2.1.0
-BONOBO_REQUIRED=2.1.0
-EEL_REQUIRED=2.9.2
-ESOUND_REQUIRED=0.2.27
-GLIB_REQUIRED=2.6.0
-GNOME_DESKTOP_REQUIRED=2.1.0
-GNOME_REQUIRED=2.1.1
-GNOME_UI_REQUIRED=2.6.0
-GNOME_VFS_REQUIRED=2.9.1
-ORBIT_REQUIRED=2.4.0
-PANGO_REQUIRED=1.1.2
-GTK_REQUIRED=2.3.0
-RSVG_REQUIRED=2.0.1
-XML_REQUIRED=2.4.7
-STARTUP_NOTIFICATION_REQUIRED=0.5
-EXIF_REQUIRED=0.5.12
-
-AC_SUBST(ART_REQUIRED)
-AC_SUBST(BONOBO_ACTIVATION_REQUIRED)
-AC_SUBST(BONOBO_REQUIRED)
-AC_SUBST(EEL_REQUIRED)
-AC_SUBST(ESOUND_REQUIRED)
-AC_SUBST(GLIB_REQUIRED)
-AC_SUBST(GNOME_DESKTOP_REQUIRED)
-AC_SUBST(GNOME_REQUIRED)
-AC_SUBST(GNOME_UI_REQUIRED)
-AC_SUBST(GNOME_VFS_REQUIRED)
-AC_SUBST(ORBIT_REQUIRED)
-AC_SUBST(PANGO_REQUIRED)
-AC_SUBST(GTK_REQUIRED)
-AC_SUBST(RSVG_REQUIRED)
-AC_SUBST(XML_REQUIRED)
-AC_SUBST(STARTUP_NOTIFICATION_REQUIRED)
+m4_define(art_minver,                  2.3.10)
+m4_define(bonobo_activation_minver,    2.1.0)
+m4_define(bonobo_minver,               2.1.0)
+m4_define(eel_minver,                  2.9.2)
+m4_define(esound_minver,               0.2.27)
+m4_define(glib_minver,                 2.6.0)
+m4_define(gnome_desktop_minver,        2.1.0)
+m4_define(gnome_minver,                2.1.1)
+m4_define(gnome_ui_minver,             2.6.0)
+m4_define(gnome_vfs_minver,            2.9.1)
+m4_define(orbit_minver,                2.4.0)
+m4_define(pango_minver,                1.1.2)
+m4_define(gtk_minver,                  2.3.0)
+m4_define(rsvg_minver,                 2.0.1)
+m4_define(xml_minver,                  2.4.7)
+m4_define(startup_notification_minver, 0.5)
+m4_define(exif_minver,                 0.5.12)
+
+AC_INIT(nautilus, 2.9.2,
+        [http://bugzilla.gnome.org/enter_bug.cgi?product=nautilus])
 
 dnl ===========================================================================
 
-AM_INIT_AUTOMAKE(nautilus, 2.9.2)
-AM_CONFIG_HEADER(config.h)
+AC_CONFIG_SRCDIR(src)
+AC_CONFIG_HEADERS(config.h)
 
-AM_SANITY_CHECK
+AM_INIT_AUTOMAKE
 AM_MAINTAINER_MODE
+AC_SUBST([ACLOCAL_AMFLAGS], ["\${ACLOCAL_FLAGS}"])
+
+AC_SUBST(ART_REQUIRED, [art_minver])
+AC_SUBST(BONOBO_ACTIVATION_REQUIRED, [bonobo_activation_minver])
+AC_SUBST(BONOBO_REQUIRED, [bonobo_minver])
+AC_SUBST(EEL_REQUIRED, [eel_minver])
+AC_SUBST(ESOUND_REQUIRED, [esound_minver])
+AC_SUBST(GLIB_REQUIRED [glib_minver])
+AC_SUBST(GNOME_DESKTOP_REQUIRED, [gnome_desktop_minver])
+AC_SUBST(GNOME_REQUIRED, [gnome_minver])
+AC_SUBST(GNOME_UI_REQUIRED, [gnome_ui_minver])
+AC_SUBST(GNOME_VFS_REQUIRED, [gnome_vfs_minver])
+AC_SUBST(ORBIT_REQUIRED, [orbit_minver])
+AC_SUBST(PANGO_REQUIRED, [pango_minver])
+AC_SUBST(GTK_REQUIRED, [gtk_minver])
+AC_SUBST(RSVG_REQUIRED, [rsvg_minver])
+AC_SUBST(XML_REQUIRED, [xml_minver])
+AC_SUBST(STARTUP_NOTIFICATION_REQUIRED, [startup_notification_minver])
+
 
 AC_C_BIGENDIAN
 AC_C_CONST
@@ -58,9 +63,10 @@ AC_LIBTOOL_WIN32_DLL
 AM_PROG_LIBTOOL
 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 
-if $PKG_CONFIG --atleast-version $STARTUP_NOTIFICATION_REQUIRED libstartup-notification-1.0; then
+if $PKG_CONFIG --atleast-version startup_notification_minver libstartup-notification-1.0; then
   echo "Building with libstartup-notification"
-  AC_DEFINE(HAVE_STARTUP_NOTIFICATION)
+  AC_DEFINE(HAVE_STARTUP_NOTIFICATION, 1,
+            [define to enable startup notification support])
   with_startup_notification=yes
   STARTUP_NOTIFICATION_PACKAGE=libstartup-notification-1.0
   EXTRA_CORE_MODULES="$EXTRA_CORE_MODULES libstartup-notification-1.0"
@@ -72,32 +78,34 @@ fi
 
 AC_SUBST(STARTUP_NOTIFICATION_PACKAGE)
 
-PKG_CHECK_MODULES(ALL, \
-	esound >= $ESOUND_REQUIRED \
-	bonobo-activation-2.0 >= $BONOBO_ACTIVATION_REQUIRED \
-	eel-2.0 >= $EEL_REQUIRED \
-	glib-2.0 >= $GLIB_REQUIRED \
-	gnome-desktop-2.0 >= $GNOME_DESKTOP_REQUIRED \
-	gnome-vfs-2.0 >= $GNOME_VFS_REQUIRED \
-	ORBit-2.0 >= $ORBIT_REQUIRED\
-	pango >= $PANGO_REQUIRED \
-	gtk+-2.0 >= $GTK_REQUIRED \
-	libart-2.0 >= $ART_REQUIRED \
-	libbonobo-2.0 >= $BONOBO_REQUIRED \
-	libgnome-2.0 >= $GNOME_REQUIRED \
-	libgnomeui-2.0 >= $GNOME_UI_REQUIRED \
-	librsvg-2.0 >= $RSVG_REQUIRED \
-	libxml-2.0 >= $XML_REQUIRED \
-	$STARTUP_NOTIFICATION_PACKAGE)
+PKG_CHECK_MODULES(ALL, 
+ [esound >= esound_minver dnl
+  bonobo-activation-2.0 >= bonobo_activation_minver dnl
+  eel-2.0 >= eel_minver dnl
+  glib-2.0 >= glib_minver dnl
+  gnome-desktop-2.0 >= gnome_desktop_minver dnl
+  gnome-vfs-2.0 >= gnome_vfs_minver dnl
+  ORBit-2.0 >= orbit_minver dnl
+  pango >= pango_minver dnl
+  gtk+-2.0 >= gtk_minver dnl
+  libart-2.0 >= art_minver dnl
+  libbonobo-2.0 >= bonobo_minver dnl
+  libgnome-2.0 >= gnome_minver dnl
+  libgnomeui-2.0 >= gnome_ui_minver dnl
+  librsvg-2.0 >= rsvg_minver dnl
+  libxml-2.0 >= xml_minver dnl
+  $STARTUP_NOTIFICATION_PACKAGE])
 dnl ==========================================================================
 
 ALL_LINGUAS="af am ar az be bg bn bs ca cs cy da de el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu id is it ja ko li lt lv mi mk ml mn ms nb ne nl nn no nso pa pl pt pt_BR ro ru sk sl sq sr sr@Latn sr@ije sv ta th tk tr uk vi wa yi zh_CN zh_TW zu"
 
 GETTEXT_PACKAGE=nautilus
 AC_SUBST(GETTEXT_PACKAGE)
-AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
+AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
+                   [the gettext translation domain])
 
 AM_GLIB_GNU_GETTEXT
+GLIB_DEFINE_LOCALEDIR(GNOMELOCALEDIR)
 
 AC_PROG_INTLTOOL
 
@@ -105,9 +113,9 @@ dnl ==========================================================================
 
 ENABLE_PROFILER=
 AC_ARG_ENABLE(profiler,
-[  --enable-profiler		Enable profiler],
-ENABLE_PROFILER=1
-AC_DEFINE(ENABLE_PROFILER))
+ AC_HELP_STRING([--enable-profiler], [Enable profiler]),
+ [ENABLE_PROFILER=1
+  AC_DEFINE(ENABLE_PROFILER, 1, [define to enable the profiler])])
 
 profiling_support=off
 if test "x$ENABLE_PROFILER" = "x1"
@@ -186,16 +194,6 @@ AC_CHECK_LIB(X11, XOpenDisplay, :,
 
 dnl ==========================================================================
 
-dnl cdda
-
-AM_CONDITIONAL(HAVE_CDDA, false)
-AC_CHECK_HEADERS(cdda_interface.h cdda_paranoia.h, [
-	CDDA_LIBS="-lcdda_paranoia -lcdda_interface"
-	AM_CONDITIONAL(HAVE_CDDA, true)
-	])
-
-dnl ==========================================================================
-
 dnl jw (for doc build)
 
 AC_PATH_PROG(JW,jw,no)
@@ -213,11 +211,9 @@ dnl exif checking
 
 AC_MSG_CHECKING(for libExif)
 
-PKG_CHECK_MODULES(EXIF, libexif >= $EXIF_REQUIRED, have_exif=yes, have_exif=no)
+PKG_CHECK_MODULES(EXIF, libexif >= exif_minver, have_exif=yes, have_exif=no)
 if test "x$have_exif" = "xyes"; then
-  AC_DEFINE(HAVE_EXIF,1)
-  AC_SUBST(EXIF_CFLAGS)
-  AC_SUBST(EXIF_LIBS)
+  AC_DEFINE(HAVE_EXIF,1, [define to enable EXIF support])
 fi
 
 dnl ==========================================================================
@@ -225,7 +221,7 @@ dnl ==========================================================================
 dnl Turn on the additional warnings last, so -Werror doesn't affect other tests.
 
 AC_ARG_ENABLE(more-warnings,
-[  --enable-more-warnings  Maximum compiler warnings],
+AC_HELP_STRING([--enable-more-warnings], [Maximum compiler warnings]),
 set_more_warnings="$enableval",[
 if test -f $srcdir/CVSVERSION; then
 	is_cvs_version=true
@@ -327,7 +323,7 @@ fi
 
 AM_GCONF_SOURCE_2
 
-AC_OUTPUT([
+AC_CONFIG_FILES([
 Makefile
 cut-n-paste-code/Makefile
 cut-n-paste-code/libegg/Makefile
@@ -355,6 +351,8 @@ src/file-manager/Makefile
 test/Makefile
 ])
 
+AC_OUTPUT
+
 dnl ==========================================================================
 echo "
 nautilus-$VERSION: