From c426f10d3b7157c5e1b290192e2abf7e902bc2b3 Mon Sep 17 00:00:00 2001
From: Matthias Clasen <maclas@gmx.de>
Date: Tue, 17 Jun 2003 20:31:22 +0000
Subject: Add rule to regenerate man pages from Docbook. (man_MANS): Add

2003-06-17  Matthias Clasen  <maclas@gmx.de>

	* docs/Makefile.am: Add rule to regenerate man pages from
	Docbook.
	(man_MANS): Add pango-querymodules.1.
	(content_files): Add pangoe-querymodules.xml.

	* docs/pango-querymodules.xml: New refentry.

	* docs/pango-querymodules.1: Man page generated from the .xml source.

	* docs/pango-docs.sgml: Include pango-querymodules.xml.

	* acinclude.m4 (JH_PATH_XML_CATALOG, JH_CHECK_XML_CATALOG): New
	macros to check for XML catalog contents and path, borrowed from
	gtk-doc.

	* configure.in: New option --enable-man to enable regeneration of
	man pages from Docbook, if the necessary tools are found.
---
 acinclude.m4 | 46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 acinclude.m4

(limited to 'acinclude.m4')

diff --git a/acinclude.m4 b/acinclude.m4
new file mode 100644
index 00000000..65036719
--- /dev/null
+++ b/acinclude.m4
@@ -0,0 +1,46 @@
+# Checks the location of the XML Catalog
+# Usage:
+#   JH_PATH_XML_CATALOG
+# Defines XMLCATALOG and XML_CATALOG_FILE substitutions
+AC_DEFUN([JH_PATH_XML_CATALOG],
+[
+  # check for the presence of the XML catalog
+  AC_ARG_WITH([xml-catalog],
+              AC_HELP_STRING([--with-xml-catalog=CATALOG],
+                             [path to xml catalog to use]),,
+              [with_xml_catalog=/etc/xml/catalog])
+  XML_CATALOG_FILE="$with_xml_catalog"
+  AC_MSG_CHECKING([for XML catalog ($XML_CATALOG_FILE)])
+  if test -f "$XML_CATALOG_FILE"; then
+    AC_MSG_RESULT([found])
+  else
+    AC_MSG_RESULT([not found])
+    AC_MSG_ERROR([XML catalog not found])
+  fi
+  AC_SUBST([XML_CATALOG_FILE])
+
+  # check for the xmlcatalog program
+  AC_PATH_PROG(XMLCATALOG, xmlcatalog, no)
+  if test "x$XMLCATALOG" = xno; then
+    AC_MSG_ERROR([could not find xmlcatalog program])
+  fi
+])
+
+# Checks if a particular URI appears in the XML catalog
+# Usage:
+#   JH_CHECK_XML_CATALOG(URI, [FRIENDLY-NAME], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+AC_DEFUN([JH_CHECK_XML_CATALOG],
+[
+  AC_REQUIRE([JH_PATH_XML_CATALOG])dnl
+  AC_MSG_CHECKING([for ifelse([$2],,[$1],[$2]) in XML catalog])
+  if AC_RUN_LOG([$XMLCATALOG --noout "$XML_CATALOG_FILE" "$1" >&2]); then
+    AC_MSG_RESULT([found])
+    ifelse([$3],,,[$3
+])dnl
+  else
+    AC_MSG_RESULT([not found])
+    ifelse([$4],,
+       [AC_MSG_ERROR([could not find ifelse([$2],,[$1],[$2]) in XML catalog])],
+       [$4])
+  fi
+])
-- 
cgit v1.2.1