Move Encode from ext/ to cpan/

2 files changed, 248 insertions, 0 deletions

diff --git a/cpan/Encode/CN/CN.pm b/cpan/Encode/CN/CN.pm
new file mode 100644
index 0000000000..9f120fb7f1
--- /dev/null
+++ b/cpan/Encode/CN/CN.pm
@@ -0,0 +1,78 @@
+package Encode::CN;
+BEGIN {
+    if ( ord("A") == 193 ) {
+        die "Encode::CN not supported on EBCDIC\n";
+    }
+}
+use strict;
+use warnings;
+use Encode;
+our $VERSION = do { my @r = ( q$Revision: 2.2 $ =~ /\d+/g ); sprintf "%d." . "%02d" x $#r, @r };
+use XSLoader;
+XSLoader::load( __PACKAGE__, $VERSION );
+
+# Relocated from Encode.pm
+
+use Encode::CN::HZ;
+
+# use Encode::CN::2022_CN;
+
+1;
+__END__
+
+=head1 NAME
+
+Encode::CN - China-based Chinese Encodings
+
+=head1 SYNOPSIS
+
+    use Encode qw/encode decode/; 
+    $euc_cn = encode("euc-cn", $utf8);   # loads Encode::CN implicitly
+    $utf8   = decode("euc-cn", $euc_cn); # ditto
+
+=head1 DESCRIPTION
+
+This module implements China-based Chinese charset encodings.
+Encodings supported are as follows.
+
+  Canonical   Alias		Description
+  --------------------------------------------------------------------
+  euc-cn      /\beuc.*cn$/i	EUC (Extended Unix Character)
+          /\bcn.*euc$/i
+              /\bGB[-_ ]?2312(?:\D.*$|$)/i (see below)
+  gb2312-raw			The raw (low-bit) GB2312 character map
+  gb12345-raw			Traditional chinese counterpart to 
+                GB2312 (raw)
+  iso-ir-165			GB2312 + GB6345 + GB8565 + additions
+  MacChineseSimp                GB2312 + Apple Additions
+  cp936				Code Page 936, also known as GBK 
+                (Extended GuoBiao)
+  hz				7-bit escaped GB2312 encoding
+  --------------------------------------------------------------------
+
+To find how to use this module in detail, see L<Encode>.
+
+=head1 NOTES
+
+Due to size concerns, C<GB 18030> (an extension to C<GBK>) is distributed
+separately on CPAN, under the name L<Encode::HanExtra>. That module
+also contains extra Taiwan-based encodings.
+
+=head1 BUGS
+
+When you see C<charset=gb2312> on mails and web pages, they really
+mean C<euc-cn> encodings.  To fix that, C<gb2312> is aliased to C<euc-cn>.
+Use C<gb2312-raw> when you really mean it.
+
+The ASCII region (0x00-0x7f) is preserved for all encodings, even though
+this conflicts with mappings by the Unicode Consortium.  See
+
+L<http://www.debian.or.jp/~kubota/unicode-symbols.html.en>
+
+to find out why it is implemented that way.
+
+=head1 SEE ALSO
+
+L<Encode>
+
+=cut
diff --git a/cpan/Encode/CN/Makefile.PL b/cpan/Encode/CN/Makefile.PL
new file mode 100644
index 0000000000..6d54404a3d
--- /dev/null
+++ b/cpan/Encode/CN/Makefile.PL
@@ -0,0 +1,170 @@
+use 5.7.2;
+use strict;
+use ExtUtils::MakeMaker;
+use strict;
+
+my %tables = (euc_cn_t   => ['euc-cn.ucm',
+                 'cp936.ucm',
+                 'macChinsimp.ucm',
+                 ],
+          '2312_t'    => ['gb2312.ucm'],
+          '12345_t'  => ['gb12345.ucm'],
+          ir_165_t   => ['ir-165.ucm'],
+             );
+
+unless ($ENV{AGGREGATE_TABLES}){
+    my @ucm;
+    for my $k (keys %tables){
+    push @ucm, @{$tables{$k}};
+    }
+    %tables = ();
+    my $seq = 0;
+    for my $ucm (sort @ucm){
+    # 8.3 compliance !
+    my $t = sprintf ("%s_%02d_t", substr($ucm, 0, 2), $seq++);
+    $tables{$t} = [ $ucm ];
+    }
+}
+
+my $name = 'CN';
+
+WriteMakefile(
+              INC		=> "-I../Encode",
+          NAME		=> 'Encode::'.$name,
+          VERSION_FROM	=> "$name.pm",
+          OBJECT		=> '$(O_FILES)',
+          'dist'		=> {
+          COMPRESS	=> 'gzip -9f',
+          SUFFIX	=> 'gz',
+          DIST_DEFAULT => 'all tardist',
+          },
+          MAN3PODS	=> {},
+          # OS 390 winges about line numbers > 64K ???
+          XSOPT => '-nolinenumbers',
+              XSPROTOARG => '-noprototypes',
+          );
+
+package MY;
+
+sub post_initialize
+{
+    my ($self) = @_;
+    my %o;
+    my $x = $self->{'OBJ_EXT'};
+    # Add the table O_FILES
+    foreach my $e (keys %tables)
+    {
+    $o{$e.$x} = 1;
+    }
+    $o{"$name$x"} = 1;
+    $self->{'O_FILES'} = [sort keys %o];
+    my @files = ("$name.xs");
+    $self->{'C'} = ["$name.c"];
+    $self->{SOURCE} .= " $name.c"
+        if $^O eq 'MacOS' && $self->{SOURCE} !~ /\b$name\.c\b/;
+    $self->{'H'} = [$self->catfile($self->updir,'Encode', 'encode.h')];
+    my %xs;
+    foreach my $table (keys %tables) {
+    push (@{$self->{'C'}},"$table.c");
+    # Do NOT add $table.h etc. to H_FILES unless we own up as to how they
+    # get built.
+    foreach my $ext (qw($(OBJ_EXT) .c .h .exh .fnm)) {
+        push (@files,$table.$ext);
+    }
+    $self->{SOURCE} .= " $table.c"
+        if $^O eq 'MacOS' && $self->{SOURCE} !~ /\b$table\.c\b/;
+    }
+    $self->{'XS'} = { "$name.xs" => "$name.c" };
+    $self->{'clean'}{'FILES'} .= join(' ',@files);
+    open(XS,">$name.xs") || die "Cannot open $name.xs:$!";
+    print XS <<'END';
+#include <EXTERN.h>
+#include <perl.h>
+#include <XSUB.h>
+#define U8 U8
+#include "encode.h"
+END
+    foreach my $table (keys %tables) {
+    print XS qq[#include "${table}.h"\n];
+    }
+    print XS <<"END";
+
+static void
+Encode_XSEncoding(pTHX_ encode_t *enc)
+{
+ dSP;
+ HV *stash = gv_stashpv("Encode::XS", TRUE);
+ SV *sv    = sv_bless(newRV_noinc(newSViv(PTR2IV(enc))),stash);
+ int i = 0;
+ PUSHMARK(sp);
+ XPUSHs(sv);
+ while (enc->name[i])
+  {
+   const char *name = enc->name[i++];
+   XPUSHs(sv_2mortal(newSVpvn(name,strlen(name))));
+  }
+ PUTBACK;
+ call_pv("Encode::define_encoding",G_DISCARD);
+ SvREFCNT_dec(sv);
+}
+
+MODULE = Encode::$name	PACKAGE = Encode::$name
+PROTOTYPES: DISABLE
+BOOT:
+{
+END
+    foreach my $table (keys %tables) {
+    print XS qq[#include "${table}.exh"\n];
+    }
+    print XS "}\n";
+    close(XS);
+    return "# Built $name.xs\n\n";
+}
+
+sub postamble
+{
+    my $self = shift;
+    my $dir  = $self->catdir($self->updir,'ucm');
+    my $str  = "# $name\$(OBJ_EXT) depends on .h and .exh files not .c files - but all written by enc2xs\n";
+    $str    .= "$name.c : $name.xs ";
+    foreach my $table (keys %tables)
+    {
+    $str .= " $table.c";
+    }
+    $str .= "\n\n";
+    $str .= "$name\$(OBJ_EXT) : $name.c\n\n";
+
+    my $enc2xs = $self->catfile($self->updir,'bin', 'enc2xs');
+    foreach my $table (keys %tables)
+    {
+    my $numlines = 1;
+    my $lengthsofar = length($str);
+    my $continuator = '';
+    $str .= "$table.c : $enc2xs Makefile.PL";
+    foreach my $file (@{$tables{$table}})
+    {
+        $str .= $continuator.' '.$self->catfile($dir,$file);
+        if ( length($str)-$lengthsofar > 128*$numlines )
+        {
+        $continuator .= " \\\n\t";
+        $numlines++;
+        } else {
+        $continuator = '';
+        }
+    }
+    my $plib   = $self->{PERL_CORE} ? '"-I$(PERL_LIB)"' : '';
+    $plib .= " -MCross=$::Cross::platform" if defined $::Cross::platform;
+    my $ucopts = '-"Q"';
+    $str .=  
+        qq{\n\t\$(PERL) $plib $enc2xs $ucopts -o \$\@ -f $table.fnm\n\n};
+    open (FILELIST, ">$table.fnm")
+        || die "Could not open $table.fnm: $!";
+    foreach my $file (@{$tables{$table}})
+    {
+        print FILELIST $self->catfile($dir,$file) . "\n";
+    }
+    close(FILELIST);
+    }
+    return $str;
+}
+