[inseparable changes from match from perl-5.003_93 to perl-5.003_94]

 BUILD PROCESS

Subject: Don't use db 2.x, we're not yet ready for it
From: Paul Marquess <pmarquess@bfsec.bt.co.uk>
Files: Configure

Subject: Warn if #! command is longer than 32 chars
From: Chip Salzenberg <chip@perl.com>
Files: Configure

Subject: patches re perl -wc install{perl,man}
Date: Tue, 11 Mar 97 13:13:16 GMT
From: Robin Barker <rmb1@cise.npl.co.uk>
Files: installman installperl

    I got the new installhtml from CPAN
    (TOMC/scripts/pod2html-v2.0beta.shar.gz)
    
    I had problems getting the system call to splitpod at line 376 to work.
    
    1. splitroot was not being found
    2. splitroot was not finding its library
    3. I changed htmlroot to podroot at line 175 to match the documentation.
    
    p5p-msgid: 3180.9703270906@tempest.cise.npl.co.uk
    private-msgid: 21544.9703111313@tempest.cise.npl.co.uk

Subject: 3_93 doesn't install pods
Date: Sun, 16 Mar 1997 02:21:35 -0500
From: Spider Boardman <spider@orb.nashua.nh.us>
Files: installperl
Msg-ID: 199703160721.CAA08339@Orb.Nashua.NH.US

    (applied based on p5p patch as commit 43506a616735d616e03d277d64fbae1e864024bf)

Subject: When installing, use File::Copy instead of `cp`
From: Chip Salzenberg <chip@perl.com>
Files: installperl

Subject: Make hint files' warnings more visible
Date: Thu, 20 Mar 1997 23:18:03 +0100 (MET)
From: Hallvard B Furuseth <h.b.furuseth@usit.uio.no>
Files: hints/3b1.sh hints/apollo.sh hints/cxux.sh hints/dcosx.sh hints/dgux.sh hints/esix4.sh hints/freebsd.sh hints/hpux.sh hints/irix_4.sh hints/mips.sh hints/next_3_0.sh hints/os2.sh hints/qnx.sh hints/sco_2_3_3.sh hints/sco_2_3_4.sh hints/solaris_2.sh hints/ultrix_4.sh hints/utekv.sh

    private-msgid: 199703202218.XAA09041@bombur2.uio.no

 CORE LANGUAGE CHANGES

Subject: Defer creation of array and hash elements as parameters
From: Chip Salzenberg <chip@perl.com>
Files: dump.c global.sym mg.c op.c op.h perl.h pp.c pp_hot.c proto.h sv.c

Subject: New special literal: __PACKAGE__
From: Chip Salzenberg <chip@perl.com>
Files: keywords.pl pod/perldata.pod toke.c

Subject: Abort compilation at C<BEGIN{}> or C<use> after errors
From: Chip Salzenberg <chip@perl.com>
Files: op.c pod/perldiag.pod t/pragma/subs.t

Subject: allow C<substr 'hello', -10>
Date: Mon, 10 Mar 1997 15:55:44 -0800
From: David Dyck <dcd@tc.fluke.com>
Files: pp.c
Msg-ID: 97Mar10.155517pst.35716-2@gateway.fluke.com

    (applied based on p5p patch as commit 77f720bf92f3d0100352416caeedd57936807ff2)

Subject: Regularize C<x % y>, esp. when y is negative
From: Chip Salzenberg <chip@perl.com>
Files: pp.c

Subject: Flush before C<flock(FOO, LOCK_UN)>
From: Chip Salzenberg <chip@perl.com>
Files: pod/perldelta.pod pod/perlfunc.pod pp_sys.c

Subject: Close loopholes in prototype mismatch warning
From: Chip Salzenberg <chip@perl.com>
Files: op.c sv.c toke.c

Subject: Warn on C<while ($x = each %y) {}>
From: Chip Salzenberg <chip@perl.com>
Files: op.c pod/perldiag.pod

Subject: Don't warn on C<print $fh func()>
From: Chip Salzenberg <chip@perl.com>
Files: toke.c

 CORE PORTABILITY

Subject: Don't say 'static var = 1'
Date: Sun, 9 Mar 1997 15:19:57 +0200 (EET)
From: Jarkko Hietaniemi <jhi@iki.fi>
Files: malloc.c

    private-msgid: 199703091319.PAA24714@alpha.hut.fi

Subject: HP/UX hint comments
Date: Fri, 21 Mar 1997 15:43:07 -0500 (EST)
From: Andy Dougherty <doughera@fractal.phys.lafayette.edu>
Files: hints/hpux.sh

    private-msgid: Pine.SOL.3.95q.970321153918.28770B-100000@fractal.lafayette.

Subject: VMS update
Date: Tue, 11 Mar 1997 22:00:55 -0500 (EST)
From: Charles Bailey <bailey@hmivax.humgen.upenn.edu>
Files: lib/ExtUtils/MM_VMS.pm lib/Test/Harness.pm t/op/taint.t utils/perlbug.PL vms/descrip.mms
Msg-ID: 1997Mar11.220056.1873182@hmivax.humgen.upenn.edu

    (applied based on p5p patch as commit 2b5725676da60b49978f38b85bb7f8ee20b4cb55)

Subject: vmsish.t and related patches
Date: Fri, 21 Mar 1997 01:32:47 -0500 (EST)
From: Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>
Files: MANIFEST perl.h vms/descrip.mms vms/ext/vmsish.t vms/vms.c

    private-msgid: 01IGQW3IP1KK005VFB@hmivax.humgen.upenn.edu

Subject: Win32 update (four patches)
From: Gurusamy Sarathy <gsar@engin.umich.edu>
Files: MANIFEST README.win32 lib/AutoSplit.pm lib/Cwd.pm lib/ExtUtils/Command.pm lib/ExtUtils/Install.pm lib/ExtUtils/MM_OS2.pm lib/ExtUtils/MM_Unix.pm lib/ExtUtils/MM_Win32.pm lib/ExtUtils/MakeMaker.pm lib/ExtUtils/Mksymlists.pm lib/File/Basename.pm lib/File/Path.pm mg.c t/comp/cpp.t t/comp/script.t t/harness t/io/argv.t t/io/dup.t t/io/fs.t t/io/inplace.t t/lib/filehand.t t/lib/io_dup.t t/lib/io_sel.t t/lib/io_taint.t t/op/closure.t t/op/exec.t t/op/glob.t t/op/goto.t t/op/magic.t t/op/misc.t t/op/rand.t t/op/split.t t/op/stat.t t/op/sysio.t t/op/taint.t t/pragma/strict.t t/pragma/subs.t t/pragma/warning.t util.c win32/*

 DOCUMENTATION

Subject: perlfaq.pod
Date: Mon, 17 Mar 1997 16:01:40 -0700
From: Tom Christiansen <tchrist@jhereg.perl.com>
Files: MANIFEST pod/Makefile pod/buildtoc pod/perl.pod pod/perlfaq*.pod pod/roffitall

    private-msgid: 199703172301.QAA12566@jhereg.perl.com

Subject: *.pod changes based on the FAQ
Date: Mon, 17 Mar 1997 09:50:14 -0700 (MST)
From: Nat Torkington <gnat@frii.com>
Files: pod/perldata.pod pod/perlfunc.pod pod/perlipc.pod pod/perlop.pod pod/perlre.pod pod/perlrun.pod pod/perlsec.pod pod/perlvar.pod
Msg-ID: 199703171650.JAA02655@elara.frii.com

    (applied based on p5p patch as commit 3c10ad8e31f7d77e71c048b1746912f41cb540f0)

Subject: Document that $. is not reset on implicit open
From: Chip Salzenberg <chip@perl.com>
Files: pod/perldelta.pod

Subject: Re: Embedding success with _93 
Date: Tue, 11 Mar 1997 17:55:05 -0500
From: Doug MacEachern <dougm@opengroup.org>
Files: pod/perldelta.pod
Msg-ID: 199703112255.RAA22775@postman.osf.org

    (applied based on p5p patch as commit 63a6ff3a1dc8d86edb4d8a7ec1548205e32a7114)

Subject: Patch to document illegal characters
Date: Fri, 14 Mar 1997 09:08:10 -0800 (PST)
From: Tom Phoenix <rootbeer@teleport.com>
Files: pod/perldiag.pod pod/perltrap.pod

    private-msgid: Pine.GSO.3.96.970314090558.15346J-100000@kelly.teleport.com

Subject: Document trap with //o and closures
Date: Mon, 10 Mar 1997 18:08:08 -0500 (EST)
From: Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>
Files: pod/perltrap.pod
Msg-ID: 01IGCHWRNSEU00661G@hmivax.humgen.upenn.edu

    (applied based on p5p patch as commit a54cb1465fdb400848f23705a6f130bb5c34ab70)

Subject: Illegal character in input
Date: Mon, 10 Mar 1997 15:21:21 -0800 (PST)
From: Tom Phoenix <rootbeer@teleport.com>
Files: pod/perldiag.pod

    private-msgid: Pine.GSO.3.95q.970310151512.22489a-100000@kelly.teleport.com

Subject: Patch for docs Re: Lost backslash
Date: Wed, 19 Mar 1997 07:28:57 -0800 (PST)
From: Tom Phoenix <rootbeer@teleport.com>
Files: pod/perlop.pod

    private-msgid: Pine.GSO.3.96.970319071438.24834G-100000@kelly.teleport.com

Subject: XSUB's doc fix
Date: Mon, 10 Mar 1997 11:42:06 -0500
From: Roderick Schertler <roderick@argon.org>
Files: pod/perlcall.pod pod/perlguts.pod pod/perlxstut.pod
Msg-ID: 28804.858012126@eeyore.ibcinc.com

    (applied based on p5p patch as commit 5f43237038ea7a4151d3bf65aeeecd56ceb78a6a)

Subject: Document return from do FILE
Date: Tue, 18 Mar 1997 14:50:10 +0000
From: "M.J.T. Guy" <mjtg@cus.cam.ac.uk>
Files: pod/perlfunc.pod
Msg-ID: E0w70DK-0001yJ-00@ursa.cus.cam.ac.uk

    (applied based on p5p patch as commit ba8d5fb439878113de8abc9b52d2af237d30fb3c)

Subject: Document $^M in perlvar
Date: Thu, 20 Mar 97 21:08:33 GMT
From: Robin Barker <rmb1@cise.npl.co.uk>
Files: pod/perlvar.pod

    private-msgid: 6153.9703202108@tempest.cise.npl.co.uk

Subject: typos in pods of 5.003_93
Date: 19 Mar 1997 10:39:38 -0600
From: Jim Meyering <meyering@asic.sc.ti.com>
Files: pod/perlfunc.pod pod/perlguts.pod pod/perlre.pod pod/perltoot.pod pod/perlxs.pod
Msg-ID: wpgendbzvhx.fsf@asic.sc.ti.com

    (applied based on p5p patch as commit 76a9873e006cf8f48f57062b2a0dd40b5ed45a95)

Subject: Re: Updates to pod punctuations
Date: Fri, 14 Mar 1997 17:00:12 -0500
From: Larry W. Virden <lvirden@cas.org>
Files: pod/*.pod

    private-msgid: 9703141700.AA22911@cas.org

Subject: clarify example in perlfunc
Date: Thu, 20 Mar 1997 19:46:01 +0200 (EET)
From: Jarkko Hietaniemi <jhi@iki.fi>
Files: pod/perlfunc.pod

    private-msgid: 199703201746.TAA25195@alpha.hut.fi

Subject: Regularize headings in DB_File documentation
From: Chip Salzenberg <chip@perl.com>
Files: ext/DB_File/DB_File.pm

 LIBRARY AND EXTENSIONS

Subject: New module: autouse.pm
Date: Thu, 20 Mar 1997 19:34:30 -0500 (EST)
From: Ilya Zakharevich <ilya@math.ohio-state.edu>
Files: MANIFEST lib/autouse.pm
Msg-ID: 199703210034.TAA13469@monk.mps.ohio-state.edu

    (applied based on p5p patch as commit 6757905eccb6dd0440ef65e8128a277a20f7d943)

Subject: Refresh DB_File to 1.12
Date: Wed, 12 Mar 97 15:51:14 GMT
From: Paul Marquess <pmarquess@bfsec.bt.co.uk>
Files: ext/DB_File/DB_File.pm ext/DB_File/DB_File.xs
Msg-ID: 9703121551.AA07435@claudius.bfsec.bt.co.uk

    (applied based on p5p patch as commit b3deed9189f963e9994815307931f9084f60d1d9)

Subject: In File::Path, some systems can't remove read-only files
From: Chip Salzenberg <chip@perl.com>
Files: lib/File/Path.pm

Subject: Fix bugs revealed by prototype warnings
From: Chip Salzenberg <chip@perl.com>
Files: ext/Opcode/Opcode.pm lib/ExtUtils/MakeMaker.pm lib/Getopt/Long.pm

Subject: Problems with SKIP in makemaker
Date: Thu, 20 Mar 1997 23:13:31 -0500 (EST)
From: Ilya Zakharevich <ilya@math.ohio-state.edu>
Files: lib/ExtUtils/MM_Unix.pm
Msg-ID: 199703210413.XAA21601@monk.mps.ohio-state.edu

    (applied based on p5p patch as commit 970322a2e8024294ada6e8d1a027cb98f1f48ee3)

Subject: In Exporter, don't C<require Carp> at file scope
From: Chip Salzenberg <chip@perl.com>
Files: lib/Exporter.pm

Subject: fix for Exporter's $SIG{__WARN__} handler
Date: Thu, 13 Mar 1997 18:40:51 -0500
From: Roderick Schertler <roderick@argon.org>
Files: lib/Exporter.pm
Msg-ID: 2282.858296451@eeyore.ibcinc.com

    (applied based on p5p patch as commit 2768ea1aeef34f42d096f198fbe629c8374ca429)

Subject: Don't try to substr() refs in Carp
From: Chip Salzenberg <chip@perl.com>
Files: lib/Carp.pm

Subject: Re: NUL in die and other messages
Date: Fri, 21 Mar 1997 09:58:17 +0000
From: "M.J.T. Guy" <mjtg@cus.cam.ac.uk>
Files: lib/Carp.pm
Msg-ID: E0w815V-0005xs-00@ursa.cus.cam.ac.uk

    (applied based on p5p patch as commit 52a267c574cb66c4bc35601dcf148a1d7a3bc557)

 OTHER CORE CHANGES

Subject: Guard against buffer overflow in yyerror() and related funcs
From: Chip Salzenberg <chip@perl.com>
Files: toke.c

Subject: For bin compat, rename calllist() and he_{,delay}free
From: Chip Salzenberg <chip@perl.com>
Files: global.sym hv.c op.c perl.c pod/perlguts.pod proto.h

Subject: Fix C<print> on tied default handle
From: Chip Salzenberg <chip@perl.com>
Files: pp_hot.c

Subject: Fix C<local($a, undef, $b) = (1,2,3)>
From: Chip Salzenberg <chip@perl.com>
Files: op.c

Subject: Improve diagnostic on C<@a++>, C<--%a>, @a =~ s/a/b/
From: Chip Salzenberg <chip@perl.com>
Files: pp.c pp_hot.c

Subject: Don't warn on C<$x{y} .= "z"> when %x is tied
From: Chip Salzenberg <chip@perl.com>
Files: pp_hot.c

Subject: Eliminate 'unreachable code' warnings
From: Chip Salzenberg <chip@perl.com>
Files: ext/POSIX/POSIX.xs mg.c pp_ctl.c toke.c

Subject: printf format corrections for -DDEBUGGING
Date: Wed, 19 Mar 1997 12:42:50 -0500
From: Roderick Schertler <roderick@argon.org>
Files: doop.c malloc.c op.c pp_ctl.c regexec.c sv.c x2p/str.c x2p/util.c
Msg-ID: 26592.858793370@eeyore.ibcinc.com

    (applied based on p5p patch as commit e125f273e351a19a92b69d6244af55abbbf0a26d)

Subject: Warn about missing -DMULTIPLICITY if likely a problem
Date: Wed, 19 Mar 1997 18:45:53 -0500
From: Doug MacEachern <dougm@opengroup.org>
Files: perl.c
Msg-ID: 199703192345.SAA15070@postman.osf.org

    (applied based on p5p patch as commit 71aeea1753924e6e19c2461e241e3f7d8a570e90)

1 files changed, 580 insertions, 0 deletions

diff --git a/pod/perlfaq6.pod b/pod/perlfaq6.pod
new file mode 100644
index 0000000000..589d89e495
--- /dev/null
+++ b/pod/perlfaq6.pod
@@ -0,0 +1,580 @@
+=head1 NAME
+
+perlfaq6 - Regexps ($Revision: 1.14 $)
+
+=head1 DESCRIPTION
+
+This section is surprisingly small because the rest of the FAQ is
+littered with answers involving regular expressions.  For example,
+decoding a URL and checking whether something is a number are handled
+with regular expressions, but those answers are found elsewhere in
+this document (in the section on Data and the Networking one on
+networking, to be precise).
+
+=head2 How can I hope to use regular expressions without creating illegible and unmaintainable code?  
+
+Three techniques can make regular expressions maintainable and
+understandable.
+
+=over 4
+
+=item Comments Outside the Regexp
+
+Describe what you're doing and how you're doing it, using normal Perl
+comments.
+
+    # turn the line into the first word, a colon, and the
+    # number of characters on the rest of the line
+    s/^(\w+)(.*)/ lc($1) . ":" . length($2) /ge;
+
+=item Comments Inside the Regexp
+
+The C</x> modifier causes whitespace to be ignored in a regexp pattern
+(except in a character class), and also allows you to use normal
+comments there, too.  As you can imagine, whitespace and comments help
+a lot.
+
+C</x> lets you turn this:
+
+    s{<(?:[^>'"]*|".*?"|'.*?')+>}{}gs;
+
+into this:
+
+    s{ <                    # opening angle bracket
+        (?:                 # Non-backreffing grouping paren
+             [^>'"] *       # 0 or more things that are neither > nor ' nor "
+                |           #    or else
+             ".*?"          # a section between double quotes (stingy match)
+                |           #    or else
+             '.*?'          # a section between single quotes (stingy match)
+        ) +                 #   all occurring one or more times
+       >                    # closing angle bracket
+    }{}gsx;                 # replace with nothing, i.e. delete
+
+It's still not quite so clear as prose, but it is very useful for
+describing the meaning of each part of the pattern.
+
+=item Different Delimiters
+
+While we normally think of patterns as being delimited with C</>
+characters, they can be delimited by almost any character.  L<perlre>
+describes this.  For example, the C<s///> above uses braces as
+delimiters.  Selecting another delimiter can avoid quoting the
+delimiter within the pattern:
+
+    s/\/usr\/local/\/usr\/share/g;	# bad delimiter choice
+    s#/usr/local#/usr/share#g;		# better
+
+=back
+
+=head2 I'm having trouble matching over more than one line.  What's wrong?
+
+Either you don't have newlines in your string, or you aren't using the
+correct modifier(s) on your pattern.
+
+There are many ways to get multiline data into a string.  If you want
+it to happen automatically while reading input, you'll want to set $/
+(probably to '' for paragraphs or C<undef> for the whole file) to
+allow you to read more than one line at a time.
+
+Read L<perlre> to help you decide which of C</s> and C</m> (or both)
+you might want to use: C</s> allows dot to include newline, and C</m>
+allows caret and dollar to match next to a newline, not just at the
+end of the string.  You do need to make sure that you've actually
+got a multiline string in there.
+
+For example, this program detects duplicate words, even when they span
+line breaks (but not paragraph ones).  For this example, we don't need
+C</s> because we aren't using dot in a regular expression that we want
+to cross line boundaries.  Neither do we need C</m> because we aren't
+wanting caret or dollar to match at any point inside the record next
+to newlines.  But it's imperative that $/ be set to something other
+than the default, or else we won't actually ever have a multiline
+record read in.
+
+    $/ = '';  		# read in more whole paragraph, not just one line
+    while ( <> ) {
+	while ( /\b(\w\S+)(\s+\1)+\b/gi ) {
+	    print "Duplicate $1 at paragraph $.\n";
+	} 
+    } 
+
+Here's code that finds sentences that begin with "From " (which would
+be mangled by many mailers):
+
+    $/ = '';  		# read in more whole paragraph, not just one line
+    while ( <> ) {
+	while ( /^From /gm ) { # /m makes ^ match next to \n
+	    print "leading from in paragraph $.\n";
+	}
+    }
+
+Here's code that finds everything between START and END in a paragraph:
+
+    undef $/;  		# read in whole file, not just one line or paragraph
+    while ( <> ) {
+	while ( /START(.*?)END/sm ) { # /s makes . cross line boundaries
+	    print "$1\n";
+	}
+    }
+
+=head2 How can I pull out lines between two patterns that are themselves on different lines?
+
+You can use Perl's somewhat exotic C<..> operator (documented in
+L<perlop>):
+
+    perl -ne 'print if /START/ .. /END/' file1 file2 ...
+
+If you wanted text and not lines, you would use
+
+    perl -0777 -pe 'print "$1\n" while /START(.*?)END/gs' file1 file2 ...
+
+But if you want nested occurrences of C<START> through C<END>, you'll
+run up against the problem described in the question in this section
+on matching balanced text.
+
+=head2 I put a regular expression into $/ but it didn't work. What's wrong?
+
+$/ must be a string, not a regular expression.  Awk has to be better
+for something. :-)
+
+Actually, you could do this if you don't mind reading the whole file into 
+
+    undef $/;
+    @records = split /your_pattern/, <FH>;
+
+=head2 How do I substitute case insensitively on the LHS, but preserving case on the RHS?
+
+It depends on what you mean by "preserving case".  The following
+script makes the substitution have the same case, letter by letter, as
+the original.  If the substitution has more characters than the string
+being substituted, the case of the last character is used for the rest
+of the substitution.
+
+    # Original by Nathan Torkington, massaged by Jeffrey Friedl
+    #
+    sub preserve_case($$)
+    {
+        my ($old, $new) = @_;
+        my ($state) = 0; # 0 = no change; 1 = lc; 2 = uc
+        my ($i, $oldlen, $newlen, $c) = (0, length($old), length($new));
+        my ($len) = $oldlen < $newlen ? $oldlen : $newlen;
+
+        for ($i = 0; $i < $len; $i++) {
+            if ($c = substr($old, $i, 1), $c =~ /[\W\d_]/) {
+                $state = 0;
+            } elsif (lc $c eq $c) {
+                substr($new, $i, 1) = lc(substr($new, $i, 1));
+                $state = 1;
+            } else {
+                substr($new, $i, 1) = uc(substr($new, $i, 1));
+                $state = 2;
+            }
+        }
+        # finish up with any remaining new (for when new is longer than old)
+        if ($newlen > $oldlen) {
+            if ($state == 1) {
+                substr($new, $oldlen) = lc(substr($new, $oldlen));
+            } elsif ($state == 2) {
+                substr($new, $oldlen) = uc(substr($new, $oldlen));
+            }
+        }
+        return $new;
+    }
+
+    $a = "this is a TEsT case";
+    $a =~ s/(test)/preserve_case($1, "success")/gie;
+    print "$a\n";
+
+This prints:
+
+    this is a SUcCESS case
+
+=head2 How can I make C<\w> match accented characters?
+
+See L<perllocale>.
+
+=head2 How can I match a locale-smart version of C</[a-zA-Z]/>?
+
+One alphabetic character would be C</[^\W\d_]/>, no matter what locale
+you're in.  Non-alphabetics would be C</[\W\d_]/> (assuming you don't 
+consider an underscore a letter).
+
+=head2 How can I quote a variable to use in a regexp?  
+
+The Perl parser will expand $variable and @variable references in
+regular expressions unless the delimiter is a single quote.  Remember,
+too, that the right-hand side of a C<s///> substitution is considered
+a double-quoted string (see L<perlop> for more details).  Remember
+also that any regexp special characters will be acted on unless you
+precede the substitution with \Q.  Here's an example:
+
+    $string = "to die?";
+    $lhs = "die?";
+    $rhs = "sleep no more";
+
+    $string =~ s/\Q$lhs/$rhs/;
+    # $string is now "to sleep no more"
+
+Without the \Q, the regexp would also spuriously match "di".
+
+=head2 What is C</o> really for?
+
+Using a variable in a regular expression match forces a re-evaluation
+(and perhaps recompilation) each time through.  The C</o> modifier
+locks in the regexp the first time it's used.  This always happens in a
+constant regular expression, and in fact, the pattern was compiled
+into the internal format at the same time your entire program was.
+
+Use of C</o> is irrelevant unless variable interpolation is used in
+the pattern, and if so, the regexp engine will neither know nor care
+whether the variables change after the pattern is evaluated the I<very
+first> time.
+
+C</o> is often used to gain an extra measure of efficiency by not
+performing subsequent evaluations when you know it won't matter
+(because you know the variables won't change), or more rarely, when
+you don't want the regexp to notice if they do.
+
+For example, here's a "paragrep" program:
+
+    $/ = '';  # paragraph mode
+    $pat = shift;
+    while (<>) {
+        print if /$pat/o;
+    }
+
+=head2 How do I use a regular expression to strip C style comments from a file?
+
+While this actually can be done, it's much harder than you'd think.
+For example, this one-liner
+
+    perl -0777 -pe 's{/\*.*?\*/}{}gs' foo.c
+
+will work in many but not all cases.  You see, it's too simple-minded for
+certain kinds of C programs, in particular, those with what appear to be
+comments in quoted strings.  For that, you'd need something like this,
+created by Jeffrey Friedl:
+
+    $/ = undef;
+    $_ = <>;
+    s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|\n+|.[^/"'\\]*)#$2#g;
+    print;
+
+This could, of course, be more legibly written with the C</x> modifier, adding
+whitespace and comments.
+
+=head2 Can I use Perl regular expressions to match balanced text?
+
+Although Perl regular expressions are more powerful than "mathematical"
+regular expressions, because they feature conveniences like backreferences
+(C<\1> and its ilk), they still aren't powerful enough. You still need
+to use non-regexp techniques to parse balanced text, such as the text
+enclosed between matching parentheses or braces, for example.
+
+An elaborate subroutine (for 7-bit ASCII only) to pull out balanced
+and possibly nested single chars, like C<`> and C<'>, C<{> and C<}>,
+or C<(> and C<)> can be found in
+http://www.perl.com/CPAN/authors/id/TOMC/scripts/pull_quotes.gz .
+
+The C::Scan module from CPAN contains such subs for internal usage,
+but they are undocumented.
+
+=head2 What does it mean that regexps are greedy?  How can I get around it?
+
+Most people mean that greedy regexps match as much as they can.
+Technically speaking, it's actually the quantifiers (C<?>, C<*>, C<+>,
+C<{}>) that are greedy rather than the whole pattern; Perl prefers local
+greed and immediate gratification to overall greed.  To get non-greedy
+versions of the same quantifiers, use (C<??>, C<*?>, C<+?>, C<{}?>).
+
+An example:
+
+        $s1 = $s2 = "I am very very cold";
+        $s1 =~ s/ve.*y //;      # I am cold
+        $s2 =~ s/ve.*?y //;     # I am very cold
+
+Notice how the second substitution stopped matching as soon as it
+encountered "y ".  The C<*?> quantifier effectively tells the regular
+expression engine to find a match as quickly as possible and pass
+control on to whatever is next in line, like you would if you were
+playing hot potato.
+
+=head2  How do I process each word on each line?
+
+Use the split function:
+
+    while (<>) {
+	foreach $word ( split ) { 
+	    # do something with $word here
+	} 
+    } 
+
+Note that this isn't really a word in the English sense; it's just 
+chunks of consecutive non-whitespace characters.  
+
+To work with only alphanumeric sequences, you might consider
+
+    while (<>) {
+	foreach $word (m/(\w+)/g) {
+	    # do something with $word here
+	}
+    }
+
+=head2 How can I print out a word-frequency or line-frequency summary?
+
+To do this, you have to parse out each word in the input stream.  We'll
+pretend that by word you mean chunk of alphabetics, hyphens, or 
+apostrophes, rather than the non-whitespace chunk idea of a word given 
+in the previous question:
+
+    while (<>) {
+	while ( /(\b[^\W_\d][\w'-]+\b)/g ) {   # misses "`sheep'"
+	    $seen{$1}++;
+	} 
+    } 
+    while ( ($word, $count) = each %seen ) {
+	print "$count $word\n";
+    } 
+
+If you wanted to do the same thing for lines, you wouldn't need a
+regular expression:
+
+    while (<>) { 
+	$seen{$_}++;
+    } 
+    while ( ($line, $count) = each %seen ) {
+	print "$count $line";
+    }
+
+If you want these output in a sorted order, see the section on Hashes.
+
+=head2 How can I do approximate matching?
+
+See the module String::Approx available from CPAN.
+
+=head2 How do I efficiently match many regular expressions at once?
+
+The following is super-inefficient:
+
+    while (<FH>) {
+        foreach $pat (@patterns) {
+            if ( /$pat/ ) {
+                # do something
+            }
+        }
+    }
+
+Instead, you either need to use one of the experimental Regexp extension
+modules from CPAN (which might well be overkill for your purposes),
+or else put together something like this, inspired from a routine
+in Jeffrey Friedl's book:
+
+    sub _bm_build {
+        my $condition = shift;
+        my @regexp = @_;  # this MUST not be local(); need my()
+        my $expr = join $condition => map { "m/\$regexp[$_]/o" } (0..$#regexp);
+        my $match_func = eval "sub { $expr }";
+        die if $@;  # propagate $@; this shouldn't happen!
+        return $match_func;
+    }
+
+    sub bm_and { _bm_build('&&', @_) }
+    sub bm_or  { _bm_build('||', @_) }
+
+    $f1 = bm_and qw{
+            xterm
+            (?i)window
+    };
+
+    $f2 = bm_or qw{
+            \b[Ff]ree\b
+            \bBSD\B
+            (?i)sys(tem)?\s*[V5]\b
+    };
+
+    # feed me /etc/termcap, prolly
+    while ( <> ) {
+        print "1: $_" if &$f1;
+        print "2: $_" if &$f2;
+    }
+
+=head2 Why don't word-boundary searches with C<\b> work for me?
+
+Two common misconceptions are that C<\b> is a synonym for C<\s+>, and
+that it's the edge between whitespace characters and non-whitespace
+characters.  Neither is correct.  C<\b> is the place between a C<\w>
+character and a C<\W> character (that is, C<\b> is the edge of a
+"word").  It's a zero-width assertion, just like C<^>, C<$>, and all
+the other anchors, so it doesn't consume any characters.  L<perlre>
+describes the behaviour of all the regexp metacharacters.
+
+Here are examples of the incorrect application of C<\b>, with fixes:
+
+    "two words" =~ /(\w+)\b(\w+)/;	    # WRONG
+    "two words" =~ /(\w+)\s+(\w+)/;	    # right
+
+    " =matchless= text" =~ /\b=(\w+)=\b/;   # WRONG
+    " =matchless= text" =~ /=(\w+)=/;       # right
+
+Although they may not do what you thought they did, C<\b> and C<\B>
+can still be quite useful.  For an example of the correct use of
+C<\b>, see the example of matching duplicate words over multiple
+lines.
+
+An example of using C<\B> is the pattern C<\Bis\B>.  This will find
+occurrences of "is" on the insides of words only, as in "thistle", but
+not "this" or "island".
+
+=head2 Why does using $&, $`, or $' slow my program down?
+
+Because once Perl sees that you need one of these variables anywhere
+in the program, it has to provide them on each and every pattern
+match.  The same mechanism that handles these provides for the use of
+$1, $2, etc., so you pay the same price for each regexp that contains
+capturing parentheses. But if you never use $&, etc., in your script,
+then regexps I<without> capturing parentheses won't be penalized. So
+avoid $&, $', and $` if you can, but if you can't (and some algorithms
+really appreciate them), once you've used them once, use them at will,
+because you've already paid the price.
+
+=head2 What good is C<\G> in a regular expression?
+
+The notation C<\G> is used in a match or substitution in conjunction the
+C</g> modifier (and ignored if there's no C</g>) to anchor the regular
+expression to the point just past where the last match occurred, i.e. the
+pos() point.
+
+For example, suppose you had a line of text quoted in standard mail
+and Usenet notation, (that is, with leading C<E<gt>> characters), and
+you want change each leading C<E<gt>> into a corresponding C<:>.  You
+could do so in this way:
+
+     s/^(>+)/':' x length($1)/gem;
+
+Or, using C<\G>, the much simpler (and faster):
+
+    s/\G>/:/g;
+
+A more sophisticated use might involve a tokenizer.  The following
+lex-like example is courtesy of Jeffrey Friedl.  It did not work in
+5.003 due to bugs in that release, but does work in 5.004 or better:
+
+    while (<>) {
+      chomp;
+      PARSER: {
+           m/ \G( \d+\b    )/gx     && do { print "number: $1\n";  redo; };
+           m/ \G( \w+      )/gx     && do { print "word:   $1\n";  redo; };
+           m/ \G( \s+      )/gx     && do { print "space:  $1\n";  redo; };
+           m/ \G( [^\w\d]+ )/gx     && do { print "other:  $1\n";  redo; };
+      }
+    }
+
+Of course, that could have been written as
+
+    while (<>) {
+      chomp;
+      PARSER: {
+	   if ( /\G( \d+\b    )/gx  { 
+		print "number: $1\n";
+		redo PARSER;
+	   }
+	   if ( /\G( \w+      )/gx  {
+		print "word: $1\n";
+		redo PARSER;
+	   }
+	   if ( /\G( \s+      )/gx  {
+		print "space: $1\n";
+		redo PARSER;
+	   }
+	   if ( /\G( [^\w\d]+ )/gx  {
+		print "other: $1\n";
+		redo PARSER;
+	   }
+      }
+    }
+
+But then you lose the vertical alignment of the regular expressions.
+
+=head2 Are Perl regexps DFAs or NFAs?  Are they POSIX compliant?
+
+While it's true that Perl's regular expressions resemble the DFAs
+(deterministic finite automata) of the egrep(1) program, they are in
+fact implemented as NFAs (non-deterministic finite automata) to allow
+backtracking and backreferencing.  And they aren't POSIX-style either,
+because those guarantee worst-case behavior for all cases.  (It seems
+that some people prefer guarantees of consistency, even when what's
+guaranteed is slowness.)  See the book "Mastering Regular Expressions"
+(from O'Reilly) by Jeffrey Friedl for all the details you could ever
+hope to know on these matters (a full citation appears in
+L<perlfaq2>).
+
+=head2 What's wrong with using grep or map in a void context?
+
+Strictly speaking, nothing.  Stylistically speaking, it's not a good
+way to write maintainable code.  That's because you're using these
+constructs not for their return values but rather for their
+side-effects, and side-effects can be mystifying.  There's no void
+grep() that's not better written as a C<for> (well, C<foreach>,
+technically) loop.
+
+=head2 How can I match strings with multi-byte characters?
+
+This is hard, and there's no good way.  Perl does not directly support
+wide characters.  It pretends that a byte and a character are
+synonymous.  The following set of approaches was offered by Jeffrey
+Friedl, whose article in issue #5 of The Perl Journal talks about this
+very matter.
+
+Let's suppose you have some weird Martian encoding where pairs of ASCII
+uppercase letters encode single Martian letters (i.e. the two bytes
+"CV" make a single Martian letter, as do the two bytes "SG", "VS",
+"XX", etc.). Other bytes represent single characters, just like ASCII.
+
+So, the string of Martian "I am CVSGXX!" uses 12 bytes to encode the nine
+characters 'I', ' ', 'a', 'm', ' ', 'CV', 'SG', 'XX', '!'.
+
+Now, say you want to search for the single character C</GX/>. Perl
+doesn't know about Martian, so it'll find the two bytes "GX" in the
+"I am CVSGXX!"  string, even though that character isn't there: it just
+looks like it is because "SG" is next to "XX", but there's no real "GX".
+This is a big problem.
+
+Here are a few ways, all painful, to deal with it:
+
+   $martian =~ s/([A-Z][A-Z])/ $1 /g; # Make sure adjacent ``maritan'' bytes
+                                      # are no longer adjacent.
+   print "found GX!\n" if $martian =~ /GX/;
+
+Or like this:
+
+   @chars = $martian =~ m/([A-Z][A-Z]|[^A-Z])/g;
+   # above is conceptually similar to:     @chars = $text =~ m/(.)/g;
+   #
+   foreach $char (@chars) {
+       print "found GX!\n", last if $char eq 'GX';
+   }
+
+Or like this:
+
+   while ($martian =~ m/\G([A-Z][A-Z]|.)/gs) {  # \G probably unneeded
+       print "found GX!\n", last if $1 eq 'GX';	
+   }
+
+Or like this:
+
+   die "sorry, Perl doesn't (yet) have Martian support )-:\n";
+
+In addition, a sample program which converts half-width to full-width
+katakana (in Shift-JIS or EUC encoding) is available from CPAN as 
+
+=for Tom make it so
+
+There are many double- (and multi-) byte encodings commonly used these
+days.  Some versions of these have 1-, 2-, 3-, and 4-byte characters,
+all mixed.
+
+=head1 AUTHOR AND COPYRIGHT
+
+Copyright (c) 1997 Tom Christiansen and Nathan Torkington.
+All rights reserved.  See L<perlfaq> for distribution information.