1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
|
package Unicode::Collate::Locale;
use strict;
use Carp;
use base qw(Unicode::Collate);
our $VERSION = '0.60';
use File::Spec;
(my $ModPath = $INC{'Unicode/Collate/Locale.pm'}) =~ s/\.pm$//;
my $KeyPath = File::Spec->catfile('allkeys.txt');
my $PL_EXT = '.pl';
my %LocaleFile = map { ($_, $_) } qw(
af az ca cs cy da eo es et fi fil fo fr ha haw
is kl lt lv mt nn nso om pl ro sk sl sv sw tn tr vi wo yo
);
$LocaleFile{'default'} = '';
$LocaleFile{'de__phonebook'} = 'de_phone';
$LocaleFile{'es__traditional'} = 'es_trad';
$LocaleFile{'nb'} = 'nn';
sub _locale {
my $locale = shift;
if ($locale) {
$locale = lc $locale;
$locale =~ tr/\-\ \./_/;
$locale =~ s/_phone\z/_phonebook/;
$locale =~ s/_trad\z/_traditional/;
$LocaleFile{$locale} and return $locale;
my ($l,$t,$v) = split(/_/, $locale.'__');
for my $loc ("${l}_${t}_$v", "${l}_$t", "${l}__$v", "${l}__$t", $l) {
$LocaleFile{$loc} and return $loc;
}
}
return 'default';
}
sub getlocale {
return shift->{accepted_locale};
}
sub _fetchpl {
my $accepted = shift;
my $f = $LocaleFile{$accepted};
return if !$f;
$f .= $PL_EXT;
my $path = File::Spec->catfile($ModPath, $f);
my $h = do $path;
croak "Unicode/Collate/Locale/$f can't be found" if !$h;
return $h;
}
sub new {
my $class = shift;
my %hash = @_;
$hash{accepted_locale} = _locale($hash{locale});
if (exists $hash{table}) {
croak "your table can't be used with Unicode::Collate::Locale";
}
$hash{table} = $KeyPath;
my $href = _fetchpl($hash{accepted_locale});
while (my($k,$v) = each %$href) {
if (exists $hash{$k}) {
croak "$k is reserved by $hash{locale}, can't be overwritten";
}
$hash{$k} = $v;
}
return $class->SUPER::new(%hash);
}
1;
__END__
=head1 NAME
Unicode::Collate::Locale - Linguistic tailoring for DUCET via Unicode::Collate
=head1 SYNOPSIS
use Unicode::Collate::Locale;
$Collator = Unicode::Collate::Locale->
new(locale => $locale_name, %tailoring);
@sorted = $Collator->sort(@not_sorted);
=head1 DESCRIPTION
This module provides linguistic tailoring for it
taking advantage of C<Unicode::Collate>.
=head2 Constructor
The C<new> method returns a collator object.
A parameter list for the constructor is a hash, which can include
a special key C<'locale'> and its value (case-insensitive) standing
for a two-letter language code (ISO-639) like C<'en'> for English.
For example, C<Unicode::Collate::Locale-E<gt>new(locale =E<gt> 'FR')>
returns a collator tailored for French.
C<$locale_name> may be suffixed with a territory(country)
code or a variant code, which are separated with C<'_'>.
E.g. C<en_US> for English in USA,
C<es_ES_traditional> for Spanish in Spain (Traditional),
If C<$localename> is not defined,
fallback is selected in the following order:
1. language_territory_variant
2. language_territory
3. language__variant
4. language
5. default
Tailoring tags provided by C<Unicode::Collate> are allowed
as long as they are not used for C<'locale'> support.
Esp. the C<table> tag is always untailorable
since it is reserved for DUCET.
E.g. a collator for French, which ignores diacritics and case difference
(i.e. level 1), with reversed case ordering and no normalization.
Unicode::Collate::Locale->new(
level => 1,
locale => 'fr',
upper_before_lower => 1,
normalization => undef
)
=head2 Methods
C<Unicode::Collate::Locale> is a subclass of C<Unicode::Collate>
and methods other than C<new> are inherited from C<Unicode::Collate>.
Here is a list of additional methods:
=over 4
=item C<$Collator-E<gt>getlocale>
Returns a language code accepted and used actually on collation.
If linguistic tailoring is not provided for a language code you passed
(intensionally for some languages, or due to the incomplete implementation),
this method returns a string C<'default'> meaning no special tailoring.
=back
=head2 A list of tailorable locales
locale name description
----------------------------------------------------------
af Afrikaans
az Azerbaijani (Azeri)
ca Catalan
cs Czech
cy Welsh
da Danish
de__phonebook German (umlaut as 'ae', 'oe', 'ue')
eo Esperanto
es Spanish
es__traditional Spanish ('ch' and 'll' as a grapheme)
et Estonian
fi Finnish
fil Filipino
fo Faroese
fr French
ha Hausa
haw Hawaiian
is Icelandic
kl Kalaallisut
lt Lithuanian
lv Latvian
mt Maltese
nb Norwegian Bokmal
nn Norwegian Nynorsk
nso Northern Sotho
om Oromo
pl Polish
ro Romanian
sk Slovak
sl Slovenian
sv Swedish
sw Swahili
tn Tswana
tr Turkish
vi Vietnamese
wo Wolof
yo Yoruba
=head1 INSTALL
Installation of Unicode::Collate::Locale requires F<Collate/Locale.pm>,
F<Collate/Locale/*.pm> and F<Collate/allkeys.txt>. On building,
Unicode::Collate::Locale doesn't require F<data/*.txt> and F<mklocale>.
Tests for Unicode::Collate::Locale are named F<t/loc_*.t>.
=head1 CAVEAT
=over 4
=item tailoring is not maximum
If a certain letter is tailored, its equivalents are not always
tailored as well as it. For example, even though W is tailored,
fullwidth W (C<U+FF37>), W with acute (C<U+1E82>), etc. are not
tailored. Thus the result may depend on whether source strings
are normalized or not.
=back
=head1 AUTHOR
The Unicode::Collate::Locale module for perl was written
by SADAHIRO Tomoyuki, <SADAHIRO@cpan.org>.
This module is Copyright(C) 2004-2010, SADAHIRO Tomoyuki. Japan.
All rights reserved.
This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.
=head1 SEE ALSO
=over 4
=item Unicode Collation Algorithm - UTS #10
L<http://www.unicode.org/reports/tr10/>
=item The Default Unicode Collation Element Table (DUCET)
L<http://www.unicode.org/Public/UCA/latest/allkeys.txt>
=item CLDR - Unicode Common Locale Data Repository
L<http://cldr.unicode.org/>
=item L<Unicode::Collate>
=item L<Unicode::Normalize>
=back
=cut
|
