blob: 95c24f440e2a3bc7f0305b909b210277a39fd692 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
#!perl
use strict;
use warnings;
require './test.pl';
plan('no_plan');
# Fail for every PERL_ARGS_ASSERT* macro that was declared but not used.
my %declared;
my %used;
my $prefix = '';
unless (-d 't' && -f 'MANIFEST') {
# we'll assume that we are in t then.
# All files are interal to perl, so Unix-style is sufficiently portable.
$prefix = '../';
}
{
my $proto = $prefix . 'proto.h';
open my $fh, '<', $proto or die "Can't open $proto: $!";
while (<$fh>) {
$declared{$1}++ if /^#define\s+(PERL_ARGS_ASSERT[A-Za-z_]+)\s+/;
}
}
cmp_ok(scalar keys %declared, '>', 0, 'Some macros were declared');
if (!@ARGV) {
my $manifest = $prefix . 'MANIFEST';
open my $fh, '<', $manifest or die "Can't open $manifest: $!";
while (<$fh>) {
# *.c or */*.c
push @ARGV, $prefix . $1 if m!^((?:[^/]+/)?[^/]+\.c)\t!;
}
}
while (<>) {
$used{$1}++ if /^\s+(PERL_ARGS_ASSERT_[A-Za-z_]+);$/;
}
my %unused;
foreach (keys %declared) {
$unused{$_}++ unless $used{$_};
}
if (keys %unused) {
fail("$_ is declared but not used") foreach sort keys %unused;
} else {
pass('Every PERL_ARGS_ASSERT* macro declared is used');
}
|
