1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
|
<?xml version='1.0'?>
<!--
-
- Licensed to the Apache Software Foundation (ASF) under one
- or more contributor license agreements. See the NOTICE file
- distributed with this work for additional information
- regarding copyright ownership. The ASF licenses this file
- to you under the Apache License, Version 2.0 (the
- "License"); you may not use this file except in compliance
- with the License. You may obtain a copy of the License at
-
- http://www.apache.org/licenses/LICENSE-2.0
-
- Unless required by applicable law or agreed to in writing,
- software distributed under the License is distributed on an
- "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
- KIND, either express or implied. See the License for the
- specific language governing permissions and limitations
- under the License.
-
-->
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:amqp="http://amqp.org">
<xsl:import href="code_utils.xsl"/>
<!--
===============================
Template: client_handler_impl_h
===============================
Template to generate the AMQP_ClientHandlerImpl class header file.
-->
<xsl:template match="amqp" mode="client_handler_impl_h">
<xsl:param name="domain-cpp-table"/>
<xsl:result-document href="AMQP_ClientHandlerImpl.h" format="textFormat">
<xsl:value-of select="amqp:copyright()"/>
<xsl:text>
#ifndef _AMQP_ClientHandlerImpl_
#define _AMQP_ClientHandlerImpl_
#include "AMQP_ClientOperations.h"
#include "qpid/framing/FieldTable.h"
namespace qpid {
namespace framing {
class AMQP_ClientHandlerImpl : virtual public AMQP_ClientOperations
{
</xsl:text>
<!-- List of pointers to each inner class instance -->
<xsl:for-each select="class">
<xsl:variable name="class" select="concat(amqp:cpp-class-name(@name), 'Handler')"/>
<xsl:text> AMQP_ClientOperations::</xsl:text><xsl:value-of select="$class"/><xsl:text>* </xsl:text>
<xsl:value-of select="$class"/><xsl:text>Ptr;
</xsl:text>
</xsl:for-each>
<xsl:text>
public:
AMQP_ClientHandlerImpl();
virtual ~AMQP_ClientHandlerImpl();

</xsl:text>
<!-- List of functions to return pointer to each inner class instance -->
<xsl:for-each select="class">
<xsl:variable name="class" select="concat(amqp:cpp-class-name(@name), 'Handler')"/>
<xsl:text> inline AMQP_ClientOperations::</xsl:text>
<xsl:value-of select="$class"/><xsl:text>* get</xsl:text><xsl:value-of select="$class"/>
<xsl:text>() { return </xsl:text><xsl:value-of select="$class"/><xsl:text>Ptr; }
</xsl:text>
</xsl:for-each>
<xsl:text>
</xsl:text>
<!-- Inner classes -->
<xsl:for-each select="class">
<xsl:variable name="class" select="concat(amqp:cpp-class-name(@name), 'Handler')"/>
<!-- Inner class documentation & rules -->
<xsl:if test="doc">
<xsl:text>
/**
</xsl:text>
<xsl:text>===== Class: </xsl:text><xsl:value-of select="$class"/><xsl:text>Impl =====
</xsl:text>
<xsl:value-of select="amqp:process-docs(doc)"/>
<xsl:text>*/
</xsl:text>
</xsl:if>
<!-- Inner class definition -->
<xsl:text> class </xsl:text><xsl:value-of select="$class"/>
<xsl:text>Impl : virtual public AMQP_ClientOperations::</xsl:text><xsl:value-of select="$class"/>
<xsl:text>
 {
public:
/* Constructors and destructors */
</xsl:text><xsl:value-of select="$class"/><xsl:text>Impl();
virtual ~</xsl:text><xsl:value-of select="$class"/><xsl:text>Impl();
/* Protocol methods */
</xsl:text>
<!-- Inner class methods (only if the chassis is set to "client") -->
<xsl:for-each select="method">
<xsl:if test="chassis[@name='client']">
<xsl:variable name="method" select="amqp:cpp-name(@name)"/>
<!-- Inner class method documentation & rules -->
<xsl:if test="doc">
<xsl:text>
/**
</xsl:text>
<xsl:text>----- Method: </xsl:text><xsl:value-of select="$class"/>
<xsl:text>Impl.</xsl:text><xsl:value-of select="@name"/><xsl:text> -----
</xsl:text>
<xsl:value-of select="amqp:process-docs(doc)"/>
<xsl:text>*/
</xsl:text>
</xsl:if>
<xsl:for-each select="rule">
<xsl:text>
/**
</xsl:text>
<xsl:text>Rule "</xsl:text><xsl:value-of select="@name"/><xsl:text>":
</xsl:text>
<xsl:value-of select="amqp:process-docs(doc)"/>
<xsl:text>*/
</xsl:text>
</xsl:for-each>
<!-- Inner class method definition -->
<xsl:text>
 virtual void </xsl:text><xsl:value-of select="$method"/>
<xsl:text>( u_int16_t channel</xsl:text>
<!-- Inner class method parameter definition -->
<xsl:if test="field">
<xsl:text>,
 </xsl:text>
<xsl:for-each select="field">
<xsl:variable name="domain-cpp-type" select="amqp:cpp-lookup(@domain, $domain-cpp-table)"/>
<xsl:value-of select="concat($domain-cpp-type, amqp:cpp-arg-ref($domain-cpp-type), ' ', amqp:cpp-name(@name))"/>
<xsl:if test="position()!=last()">
<xsl:text>,
 </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:if>
<xsl:text> );
</xsl:text>
</xsl:if>
</xsl:for-each>
<xsl:text>
 }; /* class </xsl:text><xsl:value-of select="$class"/><xsl:text>Impl */
</xsl:text>
</xsl:for-each>
<xsl:text>
}; /* AMQP_ClientHandlerImpl */
} /* namespace framing */
} /* namespace qpid */
#endif
</xsl:text>
</xsl:result-document>
</xsl:template>
<!--
=================================
Template: client_handler_impl_cpp
=================================
Template to generate the AMQP_ClientHandlerImpl class stubs.
-->
<xsl:template match="amqp" mode="client_handler_impl_cpp">
<xsl:param name="domain-cpp-table"/>
<xsl:result-document href="AMQP_ClientHandlerImpl.cpp" format="textFormat">
<xsl:value-of select="amqp:copyright()"/>
<xsl:text>
#include "AMQP_ClientHandlerImpl.h"
namespace qpid {
namespace framing {
AMQP_ClientHandlerImpl::AMQP_ClientHandlerImpl() :
 </xsl:text>
<xsl:for-each select="class">
<xsl:variable name="class" select="amqp:cpp-class-name(@name)"/>
<xsl:value-of select="$class"/>
<xsl:text>HandlerPtr( new </xsl:text><xsl:value-of select="$class"/><xsl:text>HandlerImpl() )</xsl:text>
<xsl:if test="position()!=last()">
<xsl:text>,
 </xsl:text>
</xsl:if>
</xsl:for-each>
<xsl:text>
{
}
AMQP_ClientHandlerImpl::~AMQP_ClientHandlerImpl()
{
</xsl:text>
<xsl:for-each select="class">
<xsl:text> delete </xsl:text><xsl:value-of select="amqp:cpp-class-name(@name)"/><xsl:text>HandlerPtr;
</xsl:text>
</xsl:for-each>}
<xsl:for-each select="class">
<xsl:variable name="class" select="amqp:cpp-class-name(@name)"/>
<xsl:text>
/* ===== Class: </xsl:text><xsl:value-of select="$class"/><xsl:text>HandlerImpl ===== */

</xsl:text>
<xsl:text>AMQP_ClientHandlerImpl::</xsl:text><xsl:value-of select="$class"/><xsl:text>HandlerImpl::</xsl:text>
<xsl:value-of select="$class"/><xsl:text>HandlerImpl()
{
}

</xsl:text>
<xsl:text>AMQP_ClientHandlerImpl::</xsl:text><xsl:value-of select="$class"/><xsl:text>HandlerImpl::~</xsl:text>
<xsl:value-of select="$class"/><xsl:text>HandlerImpl()
{
}

</xsl:text>
<xsl:for-each select="method">
<xsl:if test="chassis[@name='client']">
<xsl:text>void AMQP_ClientHandlerImpl::</xsl:text><xsl:value-of select="$class"/><xsl:text>HandlerImpl::</xsl:text>
<xsl:value-of select="amqp:cpp-name(@name)"/><xsl:text>( u_int16_t /*channel*/</xsl:text>
<xsl:if test="field">
<xsl:text>,
 </xsl:text>
<xsl:for-each select="field">
<xsl:variable name="domain-cpp-type" select="amqp:cpp-lookup(@domain, $domain-cpp-table)"/>
<xsl:value-of select="concat($domain-cpp-type, amqp:cpp-arg-ref($domain-cpp-type), ' /*', amqp:cpp-name(@name), '*/')"/>
<xsl:if test="position()!=last()">
<xsl:text>,
 </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:if><xsl:text> )
{
}

</xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:for-each>
<xsl:text>
} /* namespace framing */
} /* namespace qpid */

</xsl:text>
</xsl:result-document>
</xsl:template>
</xsl:stylesheet>
|
