blob: 66828c874cea224158871cf4e03b4bf0bfd6592d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
|
load(moc)
qtPrepareTool(QDBUSXML2CPP, qdbusxml2cpp)
defineReplace(am_qdbusOutputBasename) {
return($$lower($$section($$list($$basename(1)),.,-2,-2)))
}
adaptors_header.commands = $$QDBUSXML2CPP -i dbus-utilities.h -a ${QMAKE_FILE_OUT}: ${QMAKE_FILE_IN}
adaptors_header.depends += $$QDBUSXML2CPP_EXE
adaptors_header.output = ${QMAKE_FUNC_FILE_IN_am_qdbusOutputBasename}_adaptor$${first(QMAKE_EXT_H)}
adaptors_header.name = DBUS adaptor header for ${QMAKE_FILE_IN}
adaptors_header.variable_out = dbus_adaptor_headers
adaptors_header.input = ADAPTORS_XML
adaptors_header.CONFIG += target_predep
QMAKE_EXTRA_COMPILERS += adaptors_header
adaptors_moc.commands = $$moc_header.commands
adaptors_moc.depends += $$QMAKE_MOC_EXE
adaptors_moc.output = $$moc_header.output
adaptors_moc.input = dbus_adaptor_headers
adaptors_moc.variable_out = GENERATED_SOURCES
adaptors_moc.name = DBUS adaptor MOC headers
QMAKE_EXTRA_COMPILERS += adaptors_moc
|
