blob: e2ecacd835e037fa0a95e7f73d051c4d558b4059 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
requires(contains(QT_CONFIG, accessibility))
TARGET = qtquickcontrolsplugin
TARGETPATH = QtQuick/Controls
IMPORT_VERSION = 1.5
QT += qml quick quick-private qml-private gui-private core-private
QMAKE_DOCS = $$PWD/doc/qtquickcontrols.qdocconf
CONTROLS_QML_FILES = \
ApplicationWindow.qml \
Button.qml \
BusyIndicator.qml \
Calendar.qml \
CheckBox.qml \
ComboBox.qml \
GroupBox.qml \
Label.qml \
MenuBar.qml \
Menu.qml \
StackView.qml \
ProgressBar.qml \
RadioButton.qml \
ScrollView.qml \
Slider.qml \
SpinBox.qml \
SplitView.qml \
StackViewDelegate.qml \
StackViewTransition.qml \
StatusBar.qml \
Switch.qml \
Tab.qml \
TabView.qml \
TableView.qml \
TableViewColumn.qml \
TreeView.qml \
TextArea.qml \
TextField.qml \
ToolBar.qml \
ToolButton.qml
!qtquickcompiler: QML_FILES += $$CONTROLS_QML_FILES
qtquickcompiler: DEFINES += ALWAYS_LOAD_FROM_RESOURCES
SOURCES += $$PWD/plugin.cpp
HEADERS += $$PWD/plugin.h
OTHER_FILES += doc/src/*
include(plugin.pri)
include(Private/private.pri)
include(Styles/styles.pri)
osx: LIBS_PRIVATE += -framework Carbon
!static {
# Create the resource file
GENERATED_RESOURCE_FILE = $$OUT_PWD/controls.qrc
INCLUDED_RESOURCE_FILES = \
$$CONTROLS_QML_FILES \
$$PRIVATE_QML_FILES \
$$STYLES_QML_FILES
RESOURCE_CONTENT = \
"<RCC>" \
"<qresource prefix=\"/QtQuick/Controls\">"
for(resourcefile, INCLUDED_RESOURCE_FILES) {
resourcefileabsolutepath = $$absolute_path($$resourcefile)
relativepath_in = $$relative_path($$resourcefileabsolutepath, $$_PRO_FILE_PWD_)
relativepath_out = $$relative_path($$resourcefileabsolutepath, $$OUT_PWD)
RESOURCE_CONTENT += "<file alias=\"$$relativepath_in\">$$relativepath_out</file>"
}
RESOURCE_CONTENT += \
"</qresource>" \
"</RCC>"
write_file($$GENERATED_RESOURCE_FILE, RESOURCE_CONTENT)|error("Aborting.")
RESOURCES += $$GENERATED_RESOURCE_FILE
} else {
QML_FILES *= $$CONTROLS_QML_FILES \
$$PRIVATE_QML_FILES \
$$STYLES_QML_FILES
OTHER_FILES += $$QML_FILES
}
CONFIG += no_cxx_module
load(qml_plugin)
|
