Move qtwayland over to use the new configuration system

Re-use configuration results from qtbase where possible and move
all pkg-config handling over to be done at configuration time.

Since waylandclient and waylandcompositor are two independent libs,
this required some duplication of features and libraries used by
both in the configure.json files.

Change-Id: I1f3ec56c85cb780324cc7634a3ad7951125853a0
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@qt.io>
Reviewed-by: Paul Olav Tvete <paul.tvete@qt.io>

5 files changed, 30 insertions, 57 deletions

diff --git a/src/plugins/decorations/bradient/bradient.pro b/src/plugins/decorations/bradient/bradient.pro
index 0f62db9c..843149e0 100644
--- a/src/plugins/decorations/bradient/bradient.pro
+++ b/src/plugins/decorations/bradient/bradient.pro
@@ -5,12 +5,7 @@ OTHER_FILES += \
 
 SOURCES += main.cpp
 
-contains(QT_CONFIG, no-pkg-config) {
-    LIBS += -lwayland-client
-} else {
-    CONFIG += link_pkgconfig
-    PKGCONFIG += wayland-client
-}
+QMAKE_USE += wayland-client
 
 PLUGIN_TYPE = wayland-decoration-client
 load(qt_plugin)
diff --git a/src/plugins/hardwareintegration/client/client.pro b/src/plugins/hardwareintegration/client/client.pro
index 37a90ab0..a5967c71 100644
--- a/src/plugins/hardwareintegration/client/client.pro
+++ b/src/plugins/hardwareintegration/client/client.pro
@@ -1,21 +1,15 @@
 TEMPLATE=subdirs
+QT_FOR_CONFIG += waylandclient-private
 
-config_wayland_egl: \
+qtConfig(wayland-egl): \
     SUBDIRS += wayland-egl
-
-config_brcm_egl: \
+qtConfig(wayland-brcm): \
     SUBDIRS += brcm-egl
-
-config_xcomposite {
-    contains(QT_CONFIG, egl): \
-        SUBDIRS += xcomposite-egl
-
-    !contains(QT_CONFIG, opengles2):config_glx: \
-        SUBDIRS += xcomposite-glx
-}
-
-config_drm_egl_server: \
+qtConfig(xcomposite-egl): \
+    SUBDIRS += xcomposite-egl
+qtConfig(xcomposite-glx): \
+    SUBDIRS += xcomposite-glx
+qtConfig(drm-egl-server): \
     SUBDIRS += drm-egl-server
-
-config_libhybris_egl_server: \
+qtConfig(libhybris-egl-server): \
     SUBDIRS += libhybris-egl-server
diff --git a/src/plugins/hardwareintegration/compositor/compositor.pro b/src/plugins/hardwareintegration/compositor/compositor.pro
index 1ecfe37a..29911625 100644
--- a/src/plugins/hardwareintegration/compositor/compositor.pro
+++ b/src/plugins/hardwareintegration/compositor/compositor.pro
@@ -1,20 +1,15 @@
 TEMPLATE = subdirs
+QT_FOR_CONFIG += waylandcompositor-private
 
-config_wayland_egl: \
+qtConfig(wayland-egl): \
     SUBDIRS += wayland-egl
-config_brcm_egl: \
+qtConfig(wayland-brcm): \
     SUBDIRS += brcm-egl
-
-config_xcomposite {
-    contains(QT_CONFIG, egl): \
-        SUBDIRS += xcomposite-egl
-
-    !contains(QT_CONFIG, opengles2):config_glx: \
-        SUBDIRS += xcomposite-glx
-}
-
-config_drm_egl_server: \
+qtConfig(xcomposite-egl): \
+    SUBDIRS += xcomposite-egl
+qtConfig(xcomposite-glx): \
+    SUBDIRS += xcomposite-glx
+qtConfig(drm-egl-server): \
     SUBDIRS += drm-egl-server
-
-config_libhybris_egl_server: \
+qtConfig(libhybris-egl-server): \
     SUBDIRS += libhybris-egl-server
diff --git a/src/plugins/platforms/platforms.pro b/src/plugins/platforms/platforms.pro
index 4bee8929..ec589ae8 100644
--- a/src/plugins/platforms/platforms.pro
+++ b/src/plugins/platforms/platforms.pro
@@ -1,19 +1,17 @@
 TEMPLATE=subdirs
 CONFIG+=ordered
+QT_FOR_CONFIG += waylandclient-private
 
 SUBDIRS += qwayland-generic
 
-config_wayland_egl {
+qtConfig(wayland-egl): \
     SUBDIRS += qwayland-egl
-}
 
 #The following integrations are only useful with QtWaylandCompositor
-config_brcm_egl: \
+qtConfig(wayland-brcm): \
     SUBDIRS += qwayland-brcm-egl
 
-config_xcomposite {
-    contains(QT_CONFIG, egl): \
-        SUBDIRS += qwayland-xcomposite-egl
-    !contains(QT_CONFIG, opengles2):config_glx: \
-        SUBDIRS += qwayland-xcomposite-glx
-}
+qtConfig(xcomposite-egl): \
+    SUBDIRS += qwayland-xcomposite-egl
+qtConfig(xcomposite-glx): \
+    SUBDIRS += qwayland-xcomposite-glx
diff --git a/src/plugins/shellintegration/ivi-shell/ivi-shell.pro b/src/plugins/shellintegration/ivi-shell/ivi-shell.pro
index 8fd77473..d254b9fc 100644
--- a/src/plugins/shellintegration/ivi-shell/ivi-shell.pro
+++ b/src/plugins/shellintegration/ivi-shell/ivi-shell.pro
@@ -1,22 +1,13 @@
 PLUGIN_TYPE = wayland-shell-integration
 load(qt_plugin)
 
-QT += waylandclient-private
+QT += gui-private waylandclient-private
 CONFIG += wayland-scanner
 
-!contains(QT_CONFIG, no-pkg-config) {
-    PKGCONFIG += wayland-client wayland-cursor
-    CONFIG += link_pkgconfig
-} else {
-    LIBS += -lwayland-client -lwayland-cursor
-}
+QMAKE_USE += wayland-client
 
-config_xkbcommon {
-    !contains(QT_CONFIG, no-pkg-config) {
-        PKGCONFIG += xkbcommon
-    } else {
-        LIBS += -lxkbcommon
-    }
+qtConfig(xkbcommon-evdev) {
+    QMAKE_USE += xkbcommon_evdev
 } else {
     DEFINES += QT_NO_WAYLAND_XKB
 }