# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//testing/test.gni")

assert(is_chromeos, "Non-ChromeOS builds cannot depend on //chromeos")

# To add a unit test to this target, make a "unit_test" source_set in your
# component and add a reference here.
test("chromeos_components_unittests") {
  sources = [
    "chromeos_components_test_suite.cc",
    "chromeos_components_test_suite.h",
    "run_all_unittests.cc",
  ]

  deps = [
    "//base",
    "//base/test:test_support",
    "//build:chromeos_buildflags",
    "//chromeos/components/account_manager:unit_tests",
    "//chromeos/components/bloom:unit_tests",
    "//chromeos/components/cdm_factory_daemon:unit_tests",
    "//chromeos/components/diagnostics_ui/backend:unit_tests",
    "//chromeos/components/drivefs:unit_tests",
    "//chromeos/components/local_search_service:unit_tests",
    "//chromeos/components/local_search_service/public/mojom:unit_tests",
    "//chromeos/components/mojo_bootstrap:unit_tests",
    "//chromeos/components/multidevice:unit_tests",
    "//chromeos/components/phonehub:unit_tests",
    "//chromeos/components/power:unit_tests",
    "//chromeos/components/proximity_auth:unit_tests",
    "//chromeos/components/quick_answers:unit_tests",
    "//chromeos/components/scanning:unit_tests",
    "//chromeos/components/security_token_pin:unit_tests",
    "//chromeos/components/sensors:unit_tests",
    "//chromeos/components/smbfs:unit_tests",
    "//chromeos/components/string_matching:unit_tests",
    "//chromeos/components/sync_wifi:unit_tests",
    "//chromeos/components/tether:unit_tests",
    "//chromeos/components/trial_group:unit_tests",
    "//mojo/core/embedder",
    "//ui/base:base",
  ]

  if (!is_official_build) {
    deps += [ "//chromeos/components/telemetry_extension_ui:unit_tests" ]
  }

  data_deps = [
    "//chromeos/strings:chromeos_test_strings",
    "//ui/resources:ui_test_pak_data",
  ]
}

group("closure_compile") {
  testonly = true
  deps = [
    "//chromeos/components/camera_app_ui:closure_compile",
    "//chromeos/components/connectivity_diagnostics:closure_compile",
    "//chromeos/components/diagnostics_ui:closure_compile",
    "//chromeos/components/help_app_ui:closure_compile",
    "//chromeos/components/media_app_ui:closure_compile",
    "//chromeos/components/multidevice/debug_webui/resources:closure_compile",
    "//chromeos/components/print_management:closure_compile",
    "//chromeos/components/scanning:closure_compile",
    "//chromeos/components/system_apps:closure_compile",
  ]

  if (!is_official_build) {
    deps += [
      "//chromeos/components/file_manager/resources:closure_compile",
      "//chromeos/components/sample_system_web_app_ui:closure_compile",
      "//chromeos/components/telemetry_extension_ui:closure_compile",
    ]
  }
}