# Copyright (c) 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/protobuf/proto_library.gni")

static_library("drive") {
  sources = [
    "drive_api_util.cc",
    "drive_api_util.h",
    "drive_notification_manager.cc",
    "drive_notification_manager.h",
    "drive_notification_observer.h",
    "drive_pref_names.cc",
    "drive_pref_names.h",
    "drive_uploader.cc",
    "drive_uploader.h",
    "event_logger.cc",
    "event_logger.h",
    "file_errors.cc",
    "file_errors.h",
    "file_system_core_util.cc",
    "file_system_core_util.h",
    "resource_metadata_storage.cc",
    "resource_metadata_storage.h",
    "service/drive_api_service.cc",
    "service/drive_api_service.h",
    "service/drive_service_interface.cc",
    "service/drive_service_interface.h",
  ]
  deps = [
    "//base",
    "//components/invalidation/public",
    "//components/keyed_service/core",
    "//google_apis/drive",
    "//services/device/public/mojom",
    "//services/network/public/cpp:cpp",
    "//third_party/leveldatabase",
    "//third_party/re2",
  ]
  public_deps = [ ":proto" ]
}

proto_library("proto") {
  sources = [ "drive.proto" ]
}

static_library("test_support") {
  testonly = true
  sources = [
    "service/dummy_drive_service.cc",
    "service/dummy_drive_service.h",
    "service/fake_drive_service.cc",
    "service/fake_drive_service.h",
    "service/test_util.cc",
    "service/test_util.h",
  ]
  deps = [
    ":drive",
    "//base",
    "//google_apis/drive:test_support",
    "//net:net",
  ]
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "drive_api_util_unittest.cc",
    "drive_notification_manager_unittest.cc",
    "drive_uploader_unittest.cc",
    "event_logger_unittest.cc",
    "resource_metadata_storage_unittest.cc",
    "service/drive_api_service_unittest.cc",
    "service/fake_drive_service_unittest.cc",
  ]

  deps = [
    ":drive",
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//components/invalidation/impl:test_support",
    "//content/test:test_support",
    "//google_apis/drive:test_support",
    "//testing/gtest",
  ]

  if (is_chromeos) {
    sources += [ "search_metadata_unittest.cc" ]

    deps += [ ":drive_chromeos" ]
  }
}

if (is_chromeos) {
  source_set("drive_chromeos") {
    sources = [
      "chromeos/search_metadata.cc",
      "chromeos/search_metadata.h",
    ]
    deps = [
      ":drive",
      "//base",
      "//base:i18n",
      "//net",
    ]
  }
}