# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/jumbo.gni")
import("//build/config/features.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//printing/buildflags/buildflags.gni")

jumbo_static_library("common") {
  sources = [
    "cloud_print_cdd_conversion.cc",
    "cloud_print_cdd_conversion.h",
    "print_messages.cc",
    "print_messages.h",
    "printing_param_traits.cc",
    "printing_param_traits.h",
    "printing_param_traits_macros.h",
  ]

  deps = [
    ":mojo_interfaces",
    "//base",
    "//components/cloud_devices/common:common",
    "//ipc",
    "//printing",
    "//printing/common:common",
    "//printing/mojom",
    "//third_party/blink/public:blink_headers",
    "//ui/accessibility",
    "//ui/gfx/geometry",
    "//ui/gfx/ipc",
    "//ui/gfx/ipc/geometry",
    "//ui/gfx/ipc/skia",
  ]
  if (use_qt) {
    sources -= [
      "cloud_print_cdd_conversion.cc",
      "cloud_print_cdd_conversion.h",
    ]
    deps -= [
      "//components/cloud_devices/common:common",
    ]
  }
}

mojom("mojo_interfaces") {
  sources = [ "print.mojom" ]

  public_deps = [
    "//mojo/public/mojom/base",
    "//printing/mojom",
    "//ui/gfx/geometry/mojom",
  ]

  enabled_features = []
  if (enable_print_preview) {
    enabled_features += [ "enable_print_preview" ]
  }
  if (enable_tagged_pdf) {
    public_deps += [ "//ui/accessibility/mojom" ]
    enabled_features += [ "enable_tagged_pdf" ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = [ "printing_param_traits_unittest.cc" ]
  deps = [
    ":common",
    "//ipc:test_support",
    "//printing/mojom",
    "//skia",
    "//testing/gtest",
    "//ui/gfx/geometry",
  ]
}