# Copyright 2017 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//build/config/ui.gni")
import("//components/viz/viz.gni")

# Generate a buildflag header to determine which tests should be enabled.
buildflag_header("buildflags") {
  header = "buildflags.h"

  flags = [
    "ENABLE_GL_BACKEND_TESTS=$enable_gl_backend_tests",
    "ENABLE_VULKAN_BACKEND_TESTS=$enable_vulkan_backend_tests",
    "ENABLE_DAWN_BACKEND_TESTS=$enable_dawn_backend_tests",
  ]
}

viz_static_library("test_support") {
  testonly = true
  sources = [
    "begin_frame_args_test.cc",
    "begin_frame_args_test.h",
    "begin_frame_source_test.cc",
    "begin_frame_source_test.h",
    "compositor_frame_helpers.cc",
    "compositor_frame_helpers.h",
    "fake_compositor_frame_sink_client.cc",
    "fake_compositor_frame_sink_client.h",
    "fake_delay_based_time_source.cc",
    "fake_delay_based_time_source.h",
    "fake_display_client.cc",
    "fake_display_client.h",
    "fake_external_begin_frame_source.cc",
    "fake_external_begin_frame_source.h",
    "fake_host_frame_sink_client.cc",
    "fake_host_frame_sink_client.h",
    "fake_output_surface.cc",
    "fake_output_surface.h",
    "fake_skia_output_surface.cc",
    "fake_skia_output_surface.h",
    "fake_surface_observer.cc",
    "fake_surface_observer.h",
    "gpu_host_impl_test_api.cc",
    "gpu_host_impl_test_api.h",
    "host_frame_sink_manager_test_api.cc",
    "host_frame_sink_manager_test_api.h",
    "mock_compositor_frame_sink_client.cc",
    "mock_compositor_frame_sink_client.h",
    "mock_display_client.cc",
    "mock_display_client.h",
    "mock_helper.h",
    "paths.cc",
    "paths.h",
    "stub_surface_client.cc",
    "stub_surface_client.h",
    "surface_id_allocator_set.cc",
    "surface_id_allocator_set.h",
    "test_context_provider.cc",
    "test_context_provider.h",
    "test_context_support.cc",
    "test_context_support.h",
    "test_frame_sink_manager.cc",
    "test_frame_sink_manager.h",
    "test_gles2_interface.cc",
    "test_gles2_interface.h",
    "test_gpu_memory_buffer_manager.cc",
    "test_gpu_memory_buffer_manager.h",
    "test_gpu_service_holder.cc",
    "test_gpu_service_holder.h",
    "test_image_factory.cc",
    "test_image_factory.h",
    "test_in_process_context_provider.cc",
    "test_in_process_context_provider.h",
    "test_latest_local_surface_id_lookup_delegate.cc",
    "test_latest_local_surface_id_lookup_delegate.h",
    "test_output_surface_provider.cc",
    "test_output_surface_provider.h",
    "test_shared_bitmap_manager.cc",
    "test_shared_bitmap_manager.h",
    "test_types.cc",
    "test_types.h",
  ]
  deps = [
    "//base",
    "//base/test:test_support",
    "//components/viz/host",
    "//components/viz/service",
    "//gpu:raster",
    "//gpu:test_support",
    "//gpu/command_buffer/client:gles2_implementation",
    "//gpu/skia_bindings",
    "//services/viz/privileged/mojom",
    "//testing/gmock",
    "//testing/gtest",
    "//ui/gfx/geometry",
    "//ui/gl",
    "//ui/latency:test_support",
  ]

  public_deps = [ ":buildflags" ]

  if (enable_vulkan) {
    deps += [ "//gpu/vulkan/init" ]
  }
}

viz_source_set("test_suite") {
  testonly = true
  sources = [
    "viz_test_suite.cc",
    "viz_test_suite.h",
  ]
  deps = [
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//ui/events/platform",
    "//ui/gl:test_support",
  ]
  if (use_x11) {
    deps += [ "//ui/events/platform/x11" ]
  }
}

viz_source_set("unit_tests") {
  testonly = true
  sources = [
    "begin_frame_source_test_unittest.cc",
    "mock_helper_unittest.cc",
    "test_gles2_interface_unittest.cc",
  ]
  deps = [
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//testing/gmock",
    "//testing/gtest",
  ]
}