blob: 3618699d836a5b0f2d7ff76c6dee5891b11299fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
load(functions)
load(qt_build_paths)
TEMPLATE = aux
qtConfig(debug_and_release): CONFIG += debug_and_release build_all
defineTest(writeForwardingPri) {
module = $$1
configuration = $$2
cmake_build_dir = $$ROOT_BUILD_DIR/$$configuration
forwarding_pri_name = $$MODULE_QMAKE_OUTDIR/mkspecs/modules/qt_lib_$${module}.pri
FORWARDING_PRI_CONTENTS += \
"QT_MODULE_BIN_BASE = $$cmake_build_dir/bin" \
"QT_MODULE_INCLUDE_BASE = $$cmake_build_dir/DerivedSources/ForwardingHeaders" \
"QT_MODULE_LIB_BASE = $$cmake_build_dir/lib" \
"QT_MODULE_HOST_LIB_BASE = $$cmake_build_dir/lib" \
"include($$cmake_build_dir/Source/WebKit/qt_lib_$${module}.pri)"
FORWARDING_PRI_CONTENTS += \
"QT.$${module}.priority = 1" \
"QT.$${module}.includes += $$ROOT_WEBKIT_DIR/Source"
message("Writing $$forwarding_pri_name")
write_file($$forwarding_pri_name, FORWARDING_PRI_CONTENTS)|error()
}
debug_and_release {
!build_pass {
# Use release build in case of debug_and_release
writeForwardingPri(webkit, release)
writeForwardingPri(webkitwidgets, release)
}
} else {
CONFIG(debug, debug|release) {
configuration = debug
} else {
configuration = release
}
writeForwardingPri(webkit, $$configuration)
writeForwardingPri(webkitwidgets, $$configuration)
}
|
