Fix for bug23218

3 files changed, 78 insertions, 6 deletions

diff --git a/ebin/rabbit_app.in b/ebin/rabbit_app.in
index 4be09c5a..e4d13baf 100644
--- a/ebin/rabbit_app.in
+++ b/ebin/rabbit_app.in
@@ -29,4 +29,5 @@
          {default_user_is_admin, true},
          {default_vhost, <<"/">>},
          {default_permissions, [<<".*">>, <<".*">>, <<".*">>]},
+         {server_properties, []},
          {collect_statistics, none}]}]}.
diff --git a/src/rabbit_reader.erl b/src/rabbit_reader.erl
index e500b111..f2b2bdb6 100644
--- a/src/rabbit_reader.erl
+++ b/src/rabbit_reader.erl
@@ -235,12 +235,29 @@ conserve_memory(Pid, Conserve) ->
 server_properties() ->
     {ok, Product} = application:get_key(rabbit, id),
     {ok, Version} = application:get_key(rabbit, vsn),
-    [{list_to_binary(K), longstr, list_to_binary(V)} ||
-        {K, V} <- [{"product",     Product},
-                   {"version",     Version},
-                   {"platform",    "Erlang/OTP"},
-                   {"copyright",   ?COPYRIGHT_MESSAGE},
-                   {"information", ?INFORMATION_MESSAGE}]].
+
+    %% Get any configuration-specified server properties
+    {ok, RawConfigServerProps} = application:get_env(rabbit, 
+                                                     server_properties),
+
+    %% Normalize the simplifed (2-tuple) and unsimplified (3-tuple) forms 
+    %% from the config and merge them with the generated built-in properties
+    NormalizedConfigServerProps = 
+        [case X of
+             {KeyAtom, Value} -> {atom_to_binary(KeyAtom, latin1),
+                                  longstr,
+                                  list_to_binary(Value)};
+             {BinKey, Type, Value} -> {BinKey, Type, Value}
+         end || X <- RawConfigServerProps ++ 
+                    [{product,     Product}, 
+                     {version,     Version},
+                     {platform,    "Erlang/OTP"},
+                     {copyright,   ?COPYRIGHT_MESSAGE},
+                     {information, ?INFORMATION_MESSAGE}]],
+
+    %% Filter duplicated properties in favor of config file provided values
+    lists:usort(fun ({K1,_,_},{K2,_,_}) -> K1 =< K2 end,
+                NormalizedConfigServerProps).
 
 inet_op(F) -> rabbit_misc:throw_on_error(inet_error, F).
 
diff --git a/src/rabbit_tests.erl b/src/rabbit_tests.erl
index 1b47cdb7..010cebed 100644
--- a/src/rabbit_tests.erl
+++ b/src/rabbit_tests.erl
@@ -73,6 +73,7 @@ all_tests() ->
     passed = test_user_management(),
     passed = test_server_status(),
     passed = maybe_run_cluster_dependent_tests(),
+    passed = test_configurable_server_properties(),
     passed.
 
 maybe_run_cluster_dependent_tests() ->
@@ -1974,3 +1975,56 @@ test_queue_recover() ->
               rabbit_amqqueue:internal_delete(QName)
       end),
     passed.
+
+test_configurable_server_properties() ->
+    %% List of the names of the built-in properties do we expect to find
+    BuiltInPropNames = [<<"product">>, <<"version">>, <<"platform">>,
+                        <<"copyright">>, <<"information">>],
+
+    %% Verify that the built-in properties are initially present
+    ActualPropNames = [Key ||
+                         {Key, longstr, _} <- rabbit_reader:server_properties()],
+    true = lists:all(fun (X) -> lists:member(X, ActualPropNames) end,
+                     BuiltInPropNames),
+
+    %% Get the initial server properties configured in the environment
+    {ok, ServerProperties} = application:get_env(rabbit, server_properties),
+
+    %% Helper functions
+    ConsProp = fun (X) -> application:set_env(rabbit, 
+                                              server_properties, 
+                                              [X | ServerProperties]) end,
+    IsPropPresent = fun (X) -> lists:member(X, 
+                                            rabbit_reader:server_properties())
+                    end,
+
+    %% Add a wholly new property of the simplified {KeyAtom, StringValue} form
+    NewSimplifiedProperty = {NewHareKey, NewHareVal} = {hare, "soup"},
+    ConsProp(NewSimplifiedProperty),
+    %% Do we find hare soup, appropriately formatted in the generated properties?
+    ExpectedHareImage = {list_to_binary(atom_to_list(NewHareKey)),
+                         longstr,
+                         list_to_binary(NewHareVal)},
+    true = IsPropPresent(ExpectedHareImage),
+
+    %% Add a wholly new property of the {BinaryKey, Type, Value} form
+    %% and check for it
+    NewProperty = {<<"new-bin-key">>, signedint, -1},
+    ConsProp(NewProperty),
+    %% Do we find the new property?
+    true = IsPropPresent(NewProperty),
+
+    %% Add a property that clobbers a built-in, and verify correct clobbering
+    {NewVerKey, NewVerVal} = NewVersion = {version, "X.Y.Z."},
+    {BinNewVerKey, BinNewVerVal} = {list_to_binary(atom_to_list(NewVerKey)),
+                                    list_to_binary(NewVerVal)},
+    ConsProp(NewVersion),
+    ClobberedServerProps = rabbit_reader:server_properties(),
+    %% Is the clobbering insert present?
+    true = IsPropPresent({BinNewVerKey, longstr, BinNewVerVal}),
+    %% Is the clobbering insert the only thing with the clobbering key?
+    [{BinNewVerKey, longstr, BinNewVerVal}] =
+        [E || {K, longstr, _V} = E <- ClobberedServerProps, K =:= BinNewVerKey],
+
+    application:set_env(rabbit, server_properties, ServerProperties),
+    passed.